Подключение к 1С 7.7 через внешний источник данных, работа со справочниками 7.7 (на примере справочника клиенты)

24.01.13

Интеграция - Внешние источники данных

Подключение к 1С 77 через внешний источник данных, работа со справочниками 77 (на примере справочника клиенты). Вывод иерархической структуры справочника. В прикрепленном файле пошаговая инструкция с картинками.

Скачать файлы

Наименование Файл Версия Размер
Подключение к 1С 77 через внешний источник данных.doc
.doc 2,95Mb
27
.doc 2,95Mb 27 Скачать
ГруппаИЭлемент.bmp
.bmp 1,47Kb
3
.bmp 1,47Kb 3 Скачать

Подключение к 1С 77 через внешний источник данных, работа со справочниками 77 (на примере справочника клиенты)

 

  1. Добавление внешнего источника данных

Шаг 1

 

Шаг 2 (заполняем основные свойства внешнего соединения)

  

Шаг 3 (добавление данных)

Чтобы добавить источник данных удобнее добавить новую таблицу, 1С предложить либо добавить вручную, либо выбрать из списка таблиц источника данных – выбираем из источника)

  

Шаг 4 (добавляем строку соединения с источником данных)

Для добавления строки соединения лучше нажать на кнопку «…» справа от поля «Строка соединения:»

 

Внимание!!! Сохраните данную строку подключения (например в notepad), она понадобится в дальнейшем!!!

 

Если мы сделали все правильно, то 1С выведет нам список таблиц базы данных. Нас интересует справочник 77 «Клиенты». У меня это таблица SC46.

  

2. Подключение справочника

1С корректно определила, что данная таблица – это объектные данные и выбрала все реквизиты данной таблицы (справочника). Для упрощения работы нам будут нужны следующие:

ROWID – уникальный идентификатор записи в таблице SQL

ID – уникальный идентификатор объекта 1С (это будет поле ключа)

PARENTID – идентификатор родителя

CODE – реквизит «Код» 1С77 элемента справочника

DESCR – реквизит «Наименование» 1С77 элемента справочника (это будет поле представления)

ISFOLDER – признак элемент/группа 1С77 справочника

  

И нажимаем «Готово»

  

Попробуем посмотреть, что же у нас получилось… Запускаем 1С в режиме предприятия…

  

Выбираем нашу таблицу «dbo.SC46»… И 1С просит ввести имя пользователя и пароль для подключения к внешнему источнику…

  

Ну что ж… Вводим, через нажатие кнопки «Общие параметры». Вот тут то нам и пригодится сохраненная в notepad строка подключения…

  

Обновляем нашу таблицу, и результат конечно есть, но стремненько…

 

Попробуем сделать так, что бы вид нашей таблицы не отличался от вида стандартного справочника 1С82

 

3. Настройка вида справочника из внешнего источника

Шаг 1 (настраиваем имя таблицы)

  

Шаг 2 (настраиваем поля таблицы)

Особо уделю внимание полю PARENTID. Это же ссылка на родителя. Значит необходимо поменять тип значения со строки (9) на ссылочный тип данных из внешнего источника

  

Шаг 3 (смотрим результат)

Уже конечно лучше, скажем так на троечку…

  

4. Вывод справочника иерархически

Шаг 1 (добавляем общий модуль)

  

Шаг 2 (добавляем в общий модуль код)

 

&НаСервере

Функция ПолучитьИмяИсточникаДанных(пФорма) Экспорт

     лИмя = СтрЗаменить(пФорма.ИмяФормы,"ВнешнийИсточникДанных.Торговля77.Таблица.","");

     лИмя = Лев(лИмя,Найти(лИмя,".")-1);

     Возврат лИмя

КонецФункции

 

&НаСервере

Функция ПолучитьЭлементыРодителя(пСправочник, пРодитель, пР = 0,пМас=0) Экспорт

     Запрос = Новый Запрос;

     Если пРодитель.Ссылка.Пустая() Тогда

              Запрос.Текст =

              "ВЫБРАТЬ

              |         Спр.Ссылка КАК Элемент,

              |         Спр.Наименование КАК Наименование,

              |         Спр.Родитель КАК Родитель,

              |         ВЫБОР

              |                  КОГДА Спр.ЭтоГруппа = 1

              |                            ТОГДА 2

              |                  ИНАЧЕ 1

              |         КОНЕЦ КАК ЭтоГруппа

              |ИЗ

              |         ВнешнийИсточникДанных.Торговля77.Таблица."+пСправочник+" КАК Спр

              |ГДЕ

              |         Спр.РодительИД = ""     0   ""

              |УПОРЯДОЧИТЬ ПО

              |         ЭтоГруппа УБЫВ,

              |         Спр.Наименование";

     Иначе

              Запрос.Текст =

              "ВЫБРАТЬ

              |         Спр.Ссылка КАК Элемент,

              |         Спр.Наименование КАК Наименование,

              |         Спр.Родитель КАК Родитель,

              |         ВЫБОР

              |                  КОГДА Спр.ЭтоГруппа = 1

              |                            ТОГДА 2

              |                  ИНАЧЕ 1

              |         КОНЕЦ КАК ЭтоГруппа

              |ИЗ

              |         ВнешнийИсточникДанных.Торговля77.Таблица."+пСправочник+" КАК Спр

              |ГДЕ

              |         Спр.Родитель = &Родитель

              |

              |УПОРЯДОЧИТЬ ПО

              |         ЭтоГруппа УБЫВ,

              |         Спр.Наименование";

              Запрос.УстановитьПараметр("Родитель",пРодитель);

     КонецЕсли;

    Результат = Запрос.Выполнить();

 

     ВыборкаДетальныеЗаписи = Результат.Выбрать();

    

     лМассив = Новый Массив;   

     Пока ВыборкаДетальныеЗаписи.Следующий() Цикл

              лСтруктураЭл = Новый Структура;

              лСтруктураЭл.Вставить("Элемент",ВыборкаДетальныеЗаписи.Элемент);

          лСтруктураЭл.Вставить("Наименование",ВыборкаДетальныеЗаписи.Наименование);

              лСтруктураЭл.Вставить("Родитель",ВыборкаДетальныеЗаписи.Родитель);

              лСтруктураЭл.Вставить("ЭтоГруппа",ВыборкаДетальныеЗаписи.ЭтоГруппа);

              Если пР = 0 Тогда

                       лМассив.Добавить(лСтруктураЭл);

              ИначеЕсли пР = 1 Тогда

                       пМас.Добавить(лСтруктураЭл);

              КонецЕсли;

     КонецЦикла;

     Если пР = 0 Тогда

              Возврат лМассив;

     Иначе                 

              Возврат пМас;

     КонецЕсли;        

КонецФункции

 

&НаСервере

Процедура ДобавитьДерево(пФорма, пСтруктураОтображенияДерева, пСтруктураДействий) Экспорт

     пСправочник = ОбщийМодульСправочники77.ПолучитьИмяИсточникаДанных(пФорма);

     лМассивЭлементов = ПолучитьЭлементыРодителя(пСправочник, ВнешниеИсточникиДанных.Торговля77.Таблицы[пСправочник].ПустаяСсылка());

     //

     ДеревоОбъект = Новый ДеревоЗначений;

     ДеревоОбъект.Колонки.Добавить("Элемент", Новый ОписаниеТипов("ВнешнийИсточникДанныхТаблицаСсылка.Торговля77."+пСправочник));

     ДеревоОбъект.Колонки.Добавить("Наименование", Новый ОписаниеТипов("Строка"));

     ДеревоОбъект.Колонки.Добавить("ЭтоГруппа", Новый ОписаниеТипов("Число"));

     //

     Для лчНом=0 По лМассивЭлементов.Количество()-1 Цикл

              СтрокаУ1 = ДеревоОбъект.Строки.Добавить();

              СтрокаУ1.Элемент = лМассивЭлементов[лчНом].Элемент;

              СтрокаУ1.Наименование = лМассивЭлементов[лчНом].Наименование;

              СтрокаУ1.ЭтоГруппа = лМассивЭлементов[лчНом].ЭтоГруппа;

              Если лМассивЭлементов[лчНом].ЭтоГруппа=2 Тогда

                       СтрокаУ2 = СтрокаУ1.Строки.Добавить();

                       СтрокаУ2.Элемент = ВнешниеИсточникиДанных.Торговля77.Таблицы[пСправочник].ПустаяСсылка();

                       СтрокаУ2.ЭтоГруппа = 0;

              КонецЕсли;

     КонецЦикла;

    

     // Создание Реквизита формы типа ДанныеФормыДерево

     МассивДобавляемыхРеквизитов = Новый Массив;

     МассивДобавляемыхРеквизитов.Добавить(Новый РеквизитФормы("Дерево",

              Новый ОписаниеТипов("ДеревоЗначений")));

     Для Каждого Колонка Из ДеревоОбъект.Колонки Цикл

              МассивДобавляемыхРеквизитов.Добавить(

                 Новый РеквизитФормы(Колонка.Имя, Колонка.ТипЗначения, "Дерево"));

     КонецЦикла;

     пФорма.ИзменитьРеквизиты(МассивДобавляемыхРеквизитов);

 

     // Преобразование объекта прикладного типа ДеревоЗначений

     // в реквизит управляемой формы (данные формы)

     пФорма.ЗначениеВРеквизитФормы(ДеревоОбъект, "Дерево");

 

     // Создание элемента формы типа ТаблицаФормы для отображения дерева

     ЭлементДерево = пФорма.Элементы.Добавить("Дерево", Тип("ТаблицаФормы"));

     Для Каждого лЭлементОтображенияДерево Из пСтруктураОтображенияДерева Цикл

              ЭлементДерево[лЭлементОтображенияДерево.Ключ] = лЭлементОтображенияДерево.Значение;

     КонецЦикла;

    

     Для Каждого лЭлементДействия Из пСтруктураДействий Цикл

          ЭлементДерево.УстановитьДействие(лЭлементДействия.Ключ,лЭлементДействия.Значение);

     КонецЦикла;

             

     Для Каждого Колонка Из ДеревоОбъект.Колонки Цикл

              НовыйЭлемент = пФорма.Элементы.Добавить(Колонка.Имя, Тип("ПолеФормы"),

                       ЭлементДерево);

              НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;

              НовыйЭлемент.ПутьКДанным = "Дерево." + Колонка.Имя;

              Если Колонка.Имя = "Элемент" Тогда

                       НовыйЭлемент.Видимость = Ложь;

              КонецЕсли;

              Если Колонка.Имя = "ЭтоГруппа" Тогда

                       НовыйЭлемент.Видимость = Ложь;

              КонецЕсли;

     КонецЦикла;

КонецПроцедуры

 

&НаКлиенте

Функция ПроверкаВхожденияЭлемента(пКоллекция, пЭлемент) Экспорт

     лВозврат = 0;

     Для Каждого лЭлемент Из пКоллекция Цикл

              Если лЭлемент.Элемент = пЭлемент Тогда

                       лВозврат = 1;

                       Прервать;

              КонецЕсли;

     КонецЦикла;

     Возврат лВозврат;

КонецФункции

 

&НаКлиенте

Функция НайтиПоСтруктуреВМассиве(пМассив, пИмяЭлСтруктуры, пЗнач) Экспорт

     лИндекс = Неопределено;

     Для лчНом=0 По пМассив.Количество()-1 Цикл

              Если пМассив[лчНом][пИмяЭлСтруктуры] = пЗнач Тогда

                       лИндекс = лчНом;

                       Прервать;

              КонецЕсли;

     КонецЦикла;

    

     Возврат лИндекс;

КонецФункции

 

 

Шаг 3 (добавляем форму списка для нашего справочника)

ВНИМАНИЕ!!! Форма списка должна быть абсолютно пустой!!! Все отображение будет формировать программно!!!

  

Шаг 4 (добавляем в модуль формы код)

 

&НаСервере

Функция ПолучитьИмяДанныхФормы()

     лИсточник = ОбщийМодульСправочники77.ПолучитьИмяИсточникаДанных(ЭтаФорма);

     Возврат лИсточник;

КонецФункции

 

&НаСервере

Функция ПолучитьЭлементыРодителя(пРодитель)

     лИсточник = ПолучитьИмяДанныхФормы();

     Возврат ОбщийМодульСправочники77.ПолучитьЭлементыРодителя(лИсточник, пРодитель);

КонецФункции

 

&НаСервере

Функция ПолучитьПустуюСсылкуВнешнегоИсточникаДанных(пИмя)

     Возврат ВнешниеИсточникиДанных.Торговля77.Таблицы[пИмя].ПустаяСсылка();

КонецФункции

 

&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

     СтруктураОтображенияДерева = Новый Структура;

     СтруктураОтображенияДерева.Вставить("ПутьКДанным","Дерево");

     СтруктураОтображенияДерева.Вставить("Отображение",ОтображениеТаблицы.ИерархическийСписок);

     СтруктураОтображенияДерева.Вставить("КартинкаСтрок",БиблиотекаКартинок.ГруппаИЭлемент);

     СтруктураОтображенияДерева.Вставить("ПутьКДаннымКартинкиСтроки","Дерево.ЭтоГруппа");

    

     СтруктураДействий = Новый Структура;

     СтруктураДействий.Вставить("ПриСменеТекущегоРодителя","ЭлементДеревоПриСменеТекущегоРодителя");

    

     ОбщийМодульСправочники77.ДобавитьДерево(ЭтаФорма, СтруктураОтображенияДерева, СтруктураДействий);

КонецПроцедуры

 

&НаКлиенте

Процедура ЭлементДеревоПриСменеТекущегоРодителя(Элемент)

     ИДТекущейСтроки = Элементы["Дерево"].ТекущаяСтрока;

     Если ИДТекущейСтроки <> Неопределено Тогда

              РеквизитДерево = ЭтаФорма["Дерево"];

              ЭлементКоллекции = РеквизитДерево.НайтиПоИдентификатору(ИДТекущейСтроки);

              Родитель = ЭлементКоллекции.ПолучитьРодителя();

              Если Родитель <> Неопределено Тогда

                       ПодчинЭлементы = Родитель.ПолучитьЭлементы();

                       ПодчинЭлементы.Очистить();

                       лИсточник = ПолучитьИмяДанныхФормы();

                       лМассивЭлементов=ПолучитьЭлементыРодителя(Родитель.Элемент);

                       Для лчНом =0  По лМассивЭлементов.Количество()-1 Цикл

                                 лПотомок = ПодчинЭлементы.Добавить();

                                 лПотомок.Элемент = лМассивЭлементов[лчНом].Элемент;

                                 лПотомок.Наименование = лМассивЭлементов[лчНом].Наименование;

                                 лПотомок.ЭтоГруппа = лМассивЭлементов[лчНом].ЭтоГруппа;

                                 Если лМассивЭлементов[лчНом].ЭтоГруппа = 2 Тогда

                                          ПустойПодчинЭлемент = лПотомок.ПолучитьЭлементы();

                                          лПустойПотомок = ПустойПодчинЭлемент.Добавить();

                                          лПустойПотомок.Элемент = ПолучитьПустуюСсылкуВнешнегоИсточникаДанных(лИсточник);

                                          лПустойПотомок.ЭтоГруппа = 0;

                                 КонецЕсли;

                       КонецЦикла;

              КонецЕсли;

     КонецЕсли;

КонецПроцедуры

 

Шаг 5

Привязываем код нашей процедуры ПриСозданииНаСервере к форме

 

 

 

Шаг 6

Для вывода иерархии нам нужен идентификатор родителя ParentID, но мы же его перевели в ссылочный тип, поэтому я просто добавил еще одно поле: РодительИД

 

 

Шаг 7

Добавляем в общие картинки (если нет) картинку стандартной библиотеки 1С82 «ГруппаИЭлемент»

 

 

Шаг 8

Запускаем режим предприятия и видим в 1С82 справочник из 1С77 красиво, как и положено…

 

 

Теперь что бы подключить другой справочник из 1С77 нужно провести минимум действий: добавить таблицу во внешний источник, создать пустую форму, и добавить код для формы… Все! Данную таблицу можно использовать в СКД и формировать отчеты средствами 1С82.

 

См. также

Перенос данных из Парус 8 в ЗГУ 3

Зарплата Внешние источники данных Бюджетный учет Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 Государственные, бюджетные структуры Россия Бухгалтерский учет Бюджетный учет Платные (руб)

Обработка позволяет перенести кадровую информацию и данные по заработной плате, фактических удержаниях, НДФЛ, вычетах, страховых взносах из базы Парус 8 учреждений в конфигурацию 1С:Зарплата и кадры государственного учреждения ред. 3 (ЗГУ) и начать с ней работать с любого месяца года.

84000 руб.

19.08.2020    22455    19    1    

22

Перенос данных из Парус 10 в ЗГУ ред.3

Внешние источники данных Кадровый учет Файловый обмен (TXT, XML, DBF), FTP Обмен между базами 1C Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 Государственные, бюджетные структуры Россия Бухгалтерский учет Бюджетный учет Платные (руб)

Обработка позволяет перенести кадровую информацию и данные по заработной плате, фактических удержаниях, НДФЛ, вычетах, страховых взносах из базы Парус 10 учреждений в конфигурацию 1С:Зарплата и кадры государственного учреждения ред. 3 (ЗГУ) и начать с ней работать с любого месяца года.

60000 руб.

05.10.2022    9215    9    8    

10

Перенос данных из Парус 7.хх в ЗГУ ред.3

Внешние источники данных Зарплата Бюджетный учет Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 Государственные, бюджетные структуры Россия Бухгалтерский учет Бюджетный учет Платные (руб)

Обработка позволяет перенести кадровую информацию и данные по заработной плате, фактических удержаниях, НДФЛ, вычетах, страховых взносах из базы Парус 7.хх учреждений в конфигурацию 1С:Зарплата и кадры государственного учреждения ред. 3 (ЗГУ) и начать с ней работать с любого месяца года.

24000 руб.

24.04.2017    48710    96    163    

86

Перенос начальных остатков из Парус 7.71 в БГУ

Внешние источники данных Взаиморасчеты Учет ОС и НМА Логистика, склад и ТМЦ Бюджетный учет Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 2.0 1С:Бухгалтерия государственного учреждения Государственные, бюджетные структуры Россия Бюджетный учет Платные (руб)

Перенос словарей и начальных остатков из ПП Парус-Бухгалтерия Бюджет 7.71 в 1Сv8 БГУ2. Заполнение словарей и документов по вводу начальных остатков. Не требуется установка ПП Парус7. Возможна дозагрузка. Позволит автоматически и наиболее полно ввести данные в программу для начала работы. 

15600 руб.

08.12.2011    81572    128    123    

147

Перенос данных из Парус 10 (Торнадо) в ЗГУ ред.3 через Excel

Внешние источники данных Загрузка и выгрузка в Excel Зарплата Бюджетный учет Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 Государственные, бюджетные структуры Россия Бухгалтерский учет Бюджетный учет Платные (руб)

Обработка позволяет перенести кадровую информацию и данные по заработной плате из Парус 10(Торнадо) учреждений через файлы Excel в конфигурацию 1С:Зарплата и кадры государственного учреждения ред. 3 (ЗГУ). В принципе, обработка может быть использована для загрузки из файлов Excel, полученных из любых информационных систем.

24000 руб.

16.11.2018    30005    20    31    

21

Загрузка спецификаций в УНФ из системы Базис-мебельщик

Производство готовой продукции (работ, услуг) Внешние источники данных Платформа 1С v8.3 1С:Управление нашей фирмой 1.6 Лесное и деревообрабатывающее хозяйство Россия Управленческий учет Платные (руб)

Обработка предназначена для загрузки файлов, выгруженных из системы Базис-мебельщик, в справочник "Спецификации" для последующих процессов учета и диспетчирования полуфабрикатов и изделий.

7200 руб.

24.06.2021    19131    52    50    

29
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. iov 406 24.01.13 16:15 Сейчас в теме
(0) ну так разжевано маленько - отлично усваивается... гуд в целом
2. sdf1979 195 24.01.13 16:24 Сейчас в теме
Это первая ступенька к настройке доступа на чтение 1С77 из 1С82. Настроен доступ на чтение из 1С82 к 1С77 (справочники, документы и регистры). Воьмерка довольно корректно все отображает. Брал только нужные пользователям реквизиты. Очень помогло при переводе предприятия с 77 на 82. Написаны отчеты сравнения, что есть в новой базе 82 и что есть в старой 77.
3. krein 63 25.01.13 08:07 Сейчас в теме
Надо бы указать в заголовке, что это только для SQL-баз статья,
а так рассказано все подробно и понятно,
P.s.: еще можно попробовать вместо PrtScr нажимать Alt+PrtScr
4. sdf1979 195 28.01.13 10:39 Сейчас в теме
Данная статья подходит не только к базе на MS SQL, но и к любой базе, к которой есть драйвера ODBC. Просто взят рабочий пример для 77, которая и лежит в MS SQL. Таким же образом вытаскивал данные с MySQL, PostgreSQL и Access.
5. asved.ru 36 30.01.13 11:52 Сейчас в теме
И через ComОбъект, и при помощи КД гонять данные, ИМХО, куда менее трудозатратно. Не приходится разбирать 1cv7.dd

Статья неплоха в качестве первичного руководства по внешним источникам данных, но в качестве реального метода импорта данных из 7.7 я бы ее использовать не стал.

Кроме того, когда уже во внешних источниках данных будет поддержка не только SELECT, но и INSERT... А лучше - нативного SQL.
6. sdf1979 195 30.01.13 12:04 Сейчас в теме
Реальная база с 2006 года по сей момент разрабатывалась только под прямые запросы MS SQL, компонента 1С++. Так что DD разбирать не пришлось, его уже и так выучили наизусть... При помощи COM или OLE пробовали написать отчет, выводящий несоответсвие данных в двух разных базах при номенклатуре около 100 тыс позиций??? В СКД или T-SQL это банальный INNER JOIN.
7. yuraos 991 31.01.13 07:01 Сейчас в теме
плюс автору за оригинальность использования средств платформы.
правда, если не засовывать внешний источник в СКД,
то наверное лутше обратиться к "первоисточнику" - к ADO.

Для работы с ADO могу посоветовать свои скромные наработки.
8. binex 277 22.12.13 18:46 Сейчас в теме
Похоже у вас данные считываются только в момент навигации по иерархии. А если режим просмотра дерева переключить в "Список", что будет?! Непорядок будет.
9. sdf1979 195 23.12.13 09:59 Сейчас в теме
Я не стал дальше расписывать. Данные считываются при навигации, что бы увеличить быстродействие вывода. Т.к. если считывать сразу все дерево, то на больших справочниках большие тормоза (все таки это не курсор, как в штатной системе). Я просто запретил все другие режимы просмотра, не нужны они для внешних источников.
10. awk 741 09.01.14 15:44 Сейчас в теме
(0) Начиная с п.4 не имеет смысла. Т.к. можно просто указать поле родителя.
11. andrey314 14 19.02.14 20:24 Сейчас в теме
(10) awk, Можете пояснить детальнее?
12. kos 46 21.03.17 05:37 Сейчас в теме
платформа 8.3.8.2088
при подключении к 1с77 для полей "Строка(Х), Х>100" выдает сообщение

ВнешнийИсточникДанных Поле XXX: Для строки фиксированной длины запрещено задавать длину строки более 100 символов

Что делать ?
Прикрепленные файлы:
Оставьте свое сообщение