FAQ или платформа 8 для чайников :)

В: Как убрать пробел в числе 12 600,00?
О: Важно понимать, что здесь используется не символ пробела, а так называемый, «неразрывный пробел», поэтому такая, к примеру, конструкция:

СтрЗаменить(ПеременнаяЧисло," ","");

работать не будет. Есть два варианта решения проблемы, либо указать для замены вместо пробела Символы.НПП, либо используя функцию Формат().

СтрЗаменить(ПеременнаяЧисло,Символы.НПП,"");	// 1-й вариант
Формат(ПеременнаяЧисло,"ЧГ=");		// 2-й вариант

В: Как в запросе задать условие таким образом, что бы в результирующую выборку попали документы только определенного вида?
О: Это можно сделать с помощью оператора языка запросов ССЫЛКА, который позволяет проверить, является ли значение выражения, указанного слева от него, ссылкой на таблицу, указанную справа. Рассмотрим на примере, выберем из регистра накопления РеализацияУслуг только те записи, для которых регистратором является документ РеализацияТоваровУслуг:

Запрос=Новый Запрос("
|ВЫБРАТЬ
|	РеализацияУслуг.Регистратор,
|	РеализацияУслуг.Сумма
|ИЗ
|	РегистрНакопления.РеализацияУслуг КАК РеализацияУслуг
|ГДЕ
|	Регистратор ССЫЛКА Документ.РеализацияТоваровУслуг"); 

В: Как перенести определенные документы/справочники между идентичными конфигурациями?
О: Это можно сделать с помощью типовой обработки ВыгрузкаЗагрузкаДанныхXML.epf, поставляемой на дисках ИТС.

В: Как перенести данные между различными конфигурациями (или из 7.7 в 8)?
О: Оптимальным вариантом, на мой взгляд, является использование типовой конфигурации «Конвертация данных», которая поставляется на дисках ИТС, там же находятся несколько статей с описанием использования этой конфигурации.

В: Как в запросе добавить к полю не строкового типа определенную строку, например ВЫБРАТЬ РеализацияТоваровУслуг.Сумма + " руб."?
О: Никак. В запросе преобразование типов невозможно. Некоторых вводит в заблуждение конструкция языка запросов ВЫРАЗИТЬ, но она только приводит значение составного типа к одному из составляющих это значение типов и, ни в коем случае не преобразует тип, поэтому в данной ситуации не применима.

В: Как в запросе задать условие по полю с типом строка неограниченной длины, например, выбрать все документы с определенным комментарием?
О: Для этого необходимо ограничить длину поля с помощью оператора языка запросов ВЫРАЗИТЬ. Например:

Запрос=Новый Запрос("
|ВЫБРАТЬ
|	РеализацияТоваровУслуг.Ссылка
|ИЗ
|	Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
|ГДЕ
|	ВЫРАЗИТЬ(РеализацияТоваровУслуг.Комментарий КАК СТРОКА(100)) = &Комментарий");

В: Есть ли аналог функции 7.7 КаталогИБ() в v 8?
О: Нет, так как такая функция не имела бы смысла для клиент-серверного режима работы. Тем не менее, для файлового режима работы можно получить каталог информационной базы с помощью следующей конструкции:

КаталогИБ = НСтр(СтрокаСоединенияИнформационнойБазы(),"File");

В: Как отключить узел от распределенной информационной базы?
О: С помощью следующей конструкции:

ПланыОбмена.УстановитьГлавныйУзел(Неопределено);

Или запустить конфигуратор с параметром командной строки /ResetMasterNode (для базовых версий не используется).

В: Как получить имя документа (аналог метода 7.7 Вид())?
О: С помощью метаданных. Например:

ДокументСсылка.Метаданные().Имя;	                // пример: РеализацияТоваровУслуг
ДокументСсылка.Метаданные().ПолноеИмя();	// пример: Документ.РеализацияТоваровУслуг

В: Как одним запросом выбрать документы всех видов?
О: Используя метаданные и возможность объединения запросов:

Запрос=Новый Запрос;
Текст="";
Для Каждого Документ Из Метаданные.Документы Цикл
	Текст=Текст+"ВЫБРАТЬ Ссылка ИЗ Документ."+Документ.Имя+" ОБЪЕДИНИТЬ ";
КонецЦикла;
Запрос.Текст=Лев(Текст,СтрДлина(Текст)-СтрДлина(" ОБЪЕДИНИТЬ "));
Выборка=Запрос.Выполнить().Выбрать();

В: Как прервать выполнение отчета/обработки?
О: С помощью оператора ОбработкаПрерыванияПользователя(), рекомендуется использовать внутри циклов. При нажатии пользователем комбинации клавиш Ctrl+Break, происходит прерывание выполнения и выдается соответствующее сообщение. Например:

Пока Выборка.Следующий() Цикл
	ОбработкаПрерыванияПользователя();
	…
КонецЦикла;

В: На форме имеется ТабличноеПоле с типом ДеревоЗначений и установленным свойством Дерево. Почему не отображается ДеревоЗначений?
О: Необходимо кроме этого, для одной из колонок установить свойство ОтображатьИерархию.

В: Как использовать регламентные задания в файловом режиме работы информационной базы?
О: В отличие от клиент-серверного, в файловом режиме, ответственность за реализацию автоматического запуска регламентных заданий возлагается на разработчика. Что бы реализовать автозапуск заданий, нужен ОбработчикОжидания периодически проверяющий «просроченные» задания и запускающий их. Настоятельно рекомендуется использовать для этого отдельный сеанс. Пример:

Процедура ПроверкаЗаданий()
	ВыполнитьОбработкуЗаданий();
КонецПроцедуры
ПодключитьОбработчикОжидания("ПроверкаЗаданий",3);

В: Как из строки с разделителями получить массив?
О: В качестве примера, приведу свой вариант функции, которая работает «в обоих направлениях», т.е. при передаче строки с разделителями – формирует массив, а при передаче массива – формирует из него строку с разделителями.

Функция СтрокаМассив(Знач Значение,Разделитель)
	Если ТипЗнч(Значение)=Тип("Строка") Тогда
		МнСтр=СтрЗаменить(Значение,Разделитель,Символы.ПС);
		Массив=Новый Массив;
		Для н=1 По СтрЧислоСтрок(МнСтр) Цикл
			Массив.Добавить(СтрПолучитьСтроку(МнСтр,н));
		КонецЦикла;
		Возврат Массив;
	ИначеЕсли ТипЗнч(Значение)=Тип("Массив") Тогда
		Строка="";
		Для Каждого Элемент Из Значение Цикл
			Строка=Строка+?(Строка<>"",Разделитель,"")+Элемент;
		КонецЦикла;
		Возврат Строка;
	Иначе
		Возврат Неопределено;	
	КонецЕсли;
КонецФункции

В: Как включить возможность внесения изменений в конфигураторе в типовой конфигурации?
О: Так как типовые конфигурации находятся на поддержке (что позволяет в автоматическом режиме производить обновление), то по умолчанию, возможность внесения изменений в конфигурацию выключена. Чтобы включить эту возможность необходимо в конфигураторе выбрать пункт меню «Конфигурация > Поддержка > Настройка поддержки» и в открывшемся окне нажать кнопку «Включить возможность изменений».

В: Как установить пароль на обработку/конфигурацию?
О: В 1С v 8 пароли можно устанавливать только на модули объектов. Что бы установить пароль необходимо открыть модуль объекта и выбрать пункт меню «Текст > Установить пароль». Так же существует возможность поставки конфигурации без исходных текстов модулей объектов (настраивается «Конфигурация > Поставка конфигурации > Настройка поставки»). Хочется заметить, что на данный момент, ни один из этих способов не является надежной защитой от просмотра исходного текста модуля.

В: Почему не работает поиск документа с помощью метода НайтиПоНомеру(<Номер документа>)?
О: Необходимо помнить, что в случае, если для данного вида документов в конфигураторе задана периодическая нумерация, кроме номера документа обязательно нужно указывать дату интервала вторым параметром. Иначе будет осуществляться поиск документа с пустой датой, что очевидно не приведет к желаемому результату.

В: В 1С 8.1 при необходимости подключиться к уже запущенному приложению для отладки (Конфигуратор > Отладка > Подключение) в доступных предметах отладки пусто. В чем причина?
О: Дело в том, что для приложения, которое собираемся отлаживать, нужно явным образом разрешить отладку. Меню Сервис > Параметры > закладка Системные > флаг «Отладка разрешена».

В: Как организовать перебор строк динамического списка (например, СправочникСписок или ДокументСписок)?
О: Это можно сделать с помощью построителя отчетов, например:

Построитель=Новый ПостроительОтчета;
Построитель.ИсточникДанных=Новый ОписаниеИсточникаДанных(ДокументСписок);
Выборка=Построитель.Результат.Выбрать();
Пока Выборка.Следующий() Цикл
	Сообщить(Выборка.Ссылка);
КонецЦикла;

Замечание: в выборку попадут строки в соответствии с установленным в текущий момент отбором.

В: Как проверить значения свойств объектов метаданных? Например, вид иерархии справочника или режим записи регистра, или периодичность номера документа?
О: Все эти свойства являются перечислимыми свойствами объектов метаданных. Получить значения такого типа, можно так же через метаданные. Примеры:

// Пример 1. ВидИерархии справочника
Если Метаданные.Справочники[ИмяСправочника].ВидИерархии=Метаданные.СвойстваОбъектов.ВидИерархии.ИерархияГруппИЭлементов Тогда ...
// Пример 2. РежимЗаписиРегистра
Если Метаданные.РегистрыСведений[ИмяРегистра].РежимЗаписиРегистра=Метаданные.СвойстваОбъектов.РежимЗаписиРегистра.ПодчинениеРегистратору Тогда ...
// Пример 3. Переодичность номера документа
Если Метаданные.Документы[ИмяДокумента].ПериодичностьНомера=Метаданные.СвойстваОбъектов.ПериодичностьНомераДокумента.Непериодический Тогда ...

В: Как реализовать в дереве значений флажок с тремя состояниями?
О: Рассмотрим более подробно постановку задачи. На форме имеется табличное поле, источником данных для которого является дерево значений. В одной из колонок расположен элемент управления «Флажок». Необходимо что бы он мог принимать три состояния «Включен», «Выключен» и «Неопределено». При этом состояние «Неопределено» или так называемый «серый флажок», т.е. выбранный частично, устанавливается в том случае, если не у всех подчиненных строк состояние флажка одинаковое. Так же если строка имеет подчиненные строки, то при изменении её флажка, соответствующим образом должны изменяться флажки и всех подчиненных строк.
Во-первых, добавим нашу колонку с флажком в дерево значений:

Дерево.Колонки.Добавить("Пометка",Новый ОписаниеТипов("Число"));
ЭлементыФормы.Дерево.СоздатьКолонки();
КолонкиДерева=ЭлементыФормы.Дерево.Колонки;
КолонкиДерева.Пометка.ДанныеФлажка="Пометка";
КолонкиДерева.Пометка.УстановитьЭлементУправления(Тип("Флажок"));
КолонкиДерева.Пометка.РежимРедактирования=РежимРедактированияКолонки.Непосредственно;
КолонкиДерева.Пометка.ТриСостоянияФлажка=Истина;

Во-вторых, при изменении флажка нужно устанавливать соответствующие значения в подчиненных строках и контролировать значение флажка в «строке-родителе»:

Процедура ДеревоПриИзмененииФлажка(Элемент, Колонка)
	ТекущаяСтрока=Элемент.ТекущаяСтрока;
	Если ТекущаяСтрока.Пометка=2 Тогда
		ТекущаяСтрока.Пометка=0;	
	КонецЕсли;
	УстановкаФлажков(ТекущаяСтрока,ТекущаяСтрока.Пометка);	
	Пока ТекущаяСтрока.Родитель<>Неопределено Цикл 
		ТекущаяСтрока.Родитель.Пометка=?(УстановленноДляВсех(ТекущаяСтрока),ТекущаяСтрока.Пометка,2);
		ТекущаяСтрока=ТекущаяСтрока.Родитель;
	КонецЦикла;
КонецПроцедуры

Здесь процедура УстановкаФлажков() рекурсивно устанавливает флажки в подчиненных строках:

Процедура УстановкаФлажков(ТекущаяСтрока,Значение)
	Для Каждого Стр Из ТекущаяСтрока.Строки Цикл
		Стр.Пометка=Значение;
		УстановкаФлажков(Стр,Стр.Пометка);
	КонецЦикла;
КонецПроцедуры

А функция УстановленноДляВсех() проверяет установлено ли одинаковое значение для всех строк на текущем уровне:

Функция УстановленноДляВсех(Строка)
	Для Каждого Стр Из Строка.Родитель.Строки Цикл
		Если Стр.Пометка<>Строка.Пометка Тогда
			Возврат Ложь;	
		КонецЕсли;
	КонецЦикла;
	Возврат Истина;
КонецФункции

В: Как в форме списка реализовать сортировку по своему реквизиту?
О: Если реквизит примитивного типа, то достаточно установить для свойства реквизита «Индексировать» значение «Индексировать» или «Индексировать с доп. упорядочиванием» (не доступно для реквизитов типа ХранилищеЗначения). Если же реквизит ссылочного типа, то необходимо явно разрешить для него доступность сортировки. Например:

ЭлементУП=ЭлементыФормы.СправочникСписок.НастройкаПорядка.Найти("Реквизит1");
Если ЭлементУП<>Неопределено Тогда
	ЭлементУП.Доступность=Истина;	
КонецЕсли;   

В: Можно ли в запросе, в качестве источника данных, использовать таблицу значений?
О: Да. Это можно сделать с помощью временных таблиц:

// Сначала помещаем ТЗ во временную таблицу
Запрос=Новый Запрос;
Запрос.МенеджерВременныхТаблиц=Новый МенеджерВременныхТаблиц;
Запрос.Текст="ВЫБРАТЬ * ПОМЕСТИТЬ ТЗ ИЗ &ТЗ КАК ТЗ";
Запрос.УстановитьПараметр("ТЗ",ТЗ);
Запрос.Выполнить();
// Теперь ТЗ можно использовать в запросе:
Запрос.Текст="
|ВЫБРАТЬ
|	ТЗ.Номенклатура,
|	Остатки.КоличествоОстаток
|ИЗ
|	ТЗ
|ЛЕВОЕ СОЕДИНЕНИЕ
|	РегистрНакопления.ТоварыНаСкладах.Остатки() КАК Остатки
|ПО
|	ТЗ.Номенклатура=Остатки.Номенклатура";
Выборка=Запрос.Выполнить().Выбрать();

В: При использовании в запросе таблицы значений, возникает ошибка: «Тип не может быть выбран в запросе». Почему?
О: Дело в том, что колонки таблицы значений, передаваемой в запрос в качестве источника данных, должны быть явно ТИПИЗИРОВАНЫ. Т.е. если мы используем таблицу значений, так же в свою очередь выгруженную из результата запроса или из табличной части документа например – то такой проблемы не возникает, т.к. в таком случае колонки будут типизированными. А если мы сами создаем таблицу значений, то нужно явно указать тип для каждой колонки:

ТЗ=Новый ТаблицаЗначений;
ТЗ.Колонки.Добавить("Номенклатура",Новый ОписаниеТипов("СправочникСсылка.Номенклатура"));