Данная статья ни в коей мере не претендует на полное рассмотрение использования механизмов БСП при работе с общей формой "ФормаОтчета". Тема слишком объемна, чтобы описать её в одной статье. Поэтому решился описать хотя бы возможность открытия тех или иных типовых отчетов с возможностью отбора.
Общая последовательность действий при установке отборов представлена на схеме:
На схеме красным цветом представлен сторонний объект, вызывающий отчет. Это может быть документ, обработка и т.д. Синим цветом - вызываемый отчет и его модуль. Процедуры и функции этого модуля вызываются при выводе отчета в общей форме. Зелёным цветом - общая форма "ФормаОтчета".
Рассмотрим последовательность выполняемых процедур для установки отбора в отчёте:
1. Команда документа (или обработки) заполняет параметры, которые необходимо передать в отчет. Структура параметров должна содержать ключ варианта отчета, "ПараменрКоманды" в который помещается структура из вида сравнения со значением отбора и значение отбора и "ИмяКоманды", по которому в модуле отчета будет определятся по какому из выводимых полей будет произведён отбор.
2. Открывается форма отчета с передачей параметров. Поскольку у отчета нет своей формы, то открывается общая форма "ФормаОтчета" и все параметры передаются в эту общую форму.
3. Перед тем, как открыться, в форме отчета срабатывают несколько процедур. В первую очередь это процедура ПриСозданииНаСервере(), в которой выполняются следующие действия:
- СохранитьПараметрыФормы() - процедура вызывает общий модуль ВариантыОтчетов и его процедура СохраняемыеПараметрыФормыОтчета(Параметры). Параметры, пришедшие в форму сохраняются в реквизит формы "ФормаПараметры" для того чтобы их можно было использовать не только при создании формы на сервере, но и в других процедурах и функциях.
- НастройкиОтчета = НастройкиОтчета(ОтчетОбъект) - в форму отчета получают все настройки из ОтчетОбъект (основной реквизит формы - сам вызываемый отчет), а так же заполняются настройки, необходимые для выполнения дальнейших алгоритмов формирования отчета. Настройки из ОтчетОбъект получают обращением к процедуре в модуле отчета ОпределитьНастройкиФормы(...). Одной из ключевых настроек для программной установки отбора является возможность вызова процедуры модуля отчета "ПриСозданииНаСервере"
Настройки.События.ПриСозданииНаСервере = Истина;
- Вызов процедуры ОпределитьНастройкиФормы() происходит внутри конструкции ПОПЫТКА ... ИСКЛЮЧЕНИЕ...КОНЕЦПОПЫТКИ так как в отчёте подобная процедура может и не использоваться. В случае, если этой функции в отчете нет, то происходит исключение, внутри которого проверятся не является ли отчет внешним и если является, то настройки заполняются типовыми значениями.
- В том случае если в настройках в структуре "События" установлено, что должна использоваться процедура ПриСозданииНаСервере() выполняемого отчета, то данная процедура выполняется.
Если НастройкиОтчета.События.ПриСозданииНаСервере Тогда
ОтчетОбъект.ПриСозданииНаСервере(ЭтотОбъект, Отказ, СтандартнаяОбработка);
КонецЕсли;
4. В процедуре ПриСозданииНаСервере() модуля отчета проверяется есть ли у формы параметр "ПараметрКоманды" и по имени команды определяется как должен использоваться данный параметр - в реквизит формы "ФормаПараметры" в свойство "Отбор" вставляется указание по какому полю устанавливать отбор и порядок отбора, указанный ранее в "ПараметрКоманды" - вид сравнения и значение сравнения.
5. Опуская выполнение процедуры формы ПередЗагрузкойВариантаНаСервере() переходим к процедуре ПриЗагрузкеВариантаНаСервере(). В данной процедуре вызывается общий модуль "ОтчетыСервер", в процедуре УстановитьФиксированныеОтборы(...) и используется реквизит формы "ФормаПараметры"
ОтчетыСервер.УстановитьФиксированныеОтборы(ФормаПараметры.Отбор, Отчет.КомпоновщикНастроек.Настройки,
НастройкиОтчета);
В теле этой процедуры вызывается следующий общий модуль где и анализируется необходимость и создание элемента отбора.
ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбора(ОтборыКД, Имя, Значение, ВидСравненияКД, Представление, Истина, РежимОтображения, Идентификатор);
На этом работу с программной установкой отборов можно считать завершённой.
Учитывая вышеизложенное, хотелось бы привести два примера. Первый продемонстрирует работу с отчетом, в модуле которого уже есть процедура "ПриСозданииНаСервере" и данная процедура заявлена в параметрах как используемая. Второй пример позволит обозначить системе что данная процедура будет использоваться, хотя ранее её применение не подразумевалось.
Для реализации обоих примеров была написана внешняя обработка, которая запускает два вида отчета программно с установкой отборов в данных отчетах. А так же расширение конфигурации, в котором будут изменены и добавлены соответствующие процедуры.
Пример 1. Буду использовать типовой отчет "ТоварыНаСкладахПоСрокамГодности". В модуле отчета уже указано, что процедура "ПриСозданииНаСервере" должна использоваться. В этой процедуре прописано, что возможен отбор по Номенклатуре в случае использования одного из вариантов отчета. В расширении пропишем возможность указывать отбор по складу в зависимости от имени команды.
Представляю программный код расширения с внесёнными правками в процедуру с дерективой &Вместо
&Вместо("ПриСозданииНаСервере")
Процедура ИО_ПриСозданииНаСервере(ЭтаФорма, Отказ, СтандартнаяОбработка)
Параметры = ЭтаФорма.Параметры;
Если Параметры.Свойство("ПараметрКоманды") Тогда
Если Параметры.Свойство("ОписаниеКоманды")
И Параметры.ОписаниеКоманды.Свойство("ДополнительныеПараметры") Тогда
Если Параметры.ОписаниеКоманды.ДополнительныеПараметры.ИмяКоманды = "ОстаткиНоменклатурыПоСрокамГодности" Тогда
ЭтаФорма.ФормаПараметры.Отбор.Очистить();
ЭтаФорма.ФормаПараметры.Отбор.Вставить("Номенклатура", Параметры.ПараметрКоманды);
КонецЕсли;
//++ добавим в расширении другой отбор - по складу (потребуется изменить имя команды - его и указать при вызове отчета)
Если Параметры.ОписаниеКоманды.ДополнительныеПараметры.ИмяКоманды = "КакоеТоДругоеИмяКомандыСогласноСтандартам1С" Тогда
ЭтаФорма.ФормаПараметры.Отбор.Очистить();
ЭтаФорма.ФормаПараметры.Отбор.Вставить("Склад", Параметры.ПараметрКоманды);
КонецЕсли;
//--
Иначе
ЭтаФорма.ФормаПараметры.Отбор.Вставить("ПересчетТоваров", Параметры.ПараметрКоманды);
КонецЕсли;
КонецЕсли;
КонецПроцедуры
Соответственно процедуры вызова данного отчета с отбором отдельно по номенклатуре и отдельно по складу (процедура СписокТоваровПоАртикулу() составляет список значений номенклатуры по заданному на форме артикулу):
&НаКлиенте
Процедура ПоказатьТоварыНаСкладахПоСрокамГодности(Команда)
СписокНоменклатуры.Очистить();
СписокТоваровПоАртикулу();
////визуальная проверка непустого списка для тестирования
//Для Каждого ТекСтр Из СписокНоменклатуры Цикл
// Сообщить(ТекСтр.Значение);
//КонецЦикла;
ПараметрыФормы = Новый Структура;
//ПараметрыФормы.Вставить("КлючВарианта", "ПоНоменклатуреКонтекст");
ПараметрыФормы.Вставить("КлючВарианта", "ОстаткиТоваровПоСрокамГодности");
ПараметрыФормы.Вставить("ПараметрКоманды", Новый Структура("ВидСравнения, ПравоеЗначение", ВидСравненияКомпоновкиДанных.ВСписке, СписокНоменклатуры));
ПараметрыФормы.Вставить("ОписаниеКоманды", Новый Структура("ДополнительныеПараметры", Новый Структура("ИмяКоманды", "ОстаткиНоменклатурыПоСрокамГодности")));
ПараметрыФормы.Вставить("СформироватьПриОткрытии", Истина);
ОткрытьФорму("Отчет.ТоварыНаСкладахПоСрокамГодности.Форма", ПараметрыФормы, ЭтаФорма, Истина);
КонецПроцедуры
&НаКлиенте
Процедура ПоказатьТоварыПоСКЛАДУПоСрокамГодности(Команда)
ПараметрыФормы = Новый Структура;
//ПараметрыФормы.Вставить("КлючВарианта", "ПоНоменклатуреКонтекст");
ПараметрыФормы.Вставить("КлючВарианта", "ОстаткиТоваровПоСрокамГодности");
ПараметрыФормы.Вставить("ПараметрКоманды", Новый Структура("ВидСравнения, ПравоеЗначение", ВидСравненияКомпоновкиДанных.Равно, СкладОстатка));
ПараметрыФормы.Вставить("ОписаниеКоманды", Новый Структура("ДополнительныеПараметры", Новый Структура("ИмяКоманды", "КакоеТоДругоеИмяКомандыСогласноСтандартам1С")));
ПараметрыФормы.Вставить("СформироватьПриОткрытии", Истина);
ОткрытьФорму("Отчет.ТоварыНаСкладахПоСрокамГодности.Форма", ПараметрыФормы, ЭтаФорма, Истина);
КонецПроцедуры
Результат работы обеих процедур обработки и работы БСП:
Если кого-то удивит, что по артикулу в отбор кроме крупы гречневой попало ещё и молоко, то спешу успокоить: в Демо базе ERP обе номенклатуры проходят под одним артикулом (см.Молоко "Домик в деревне" 4,5%). Так что никакой ошибки нет )))))))))))))))))) оставим это на совести создателей демо-базы.
Пример 2. Рассмотрим типовой отчет "ТоварыКОтгрузке". Для того, чтобы понять какие отборы возможно установить в отчете, понадобится открыть основной макет и перейти на закладку Настройки. Из настроек видно что используются поля "Склад" и "Номенклатура". По ним и будем делать отборы.
Программный код, используемый в расширении:
&Вместо("ОпределитьНастройкиФормы")
Процедура ИО_ОпределитьНастройкиФормы(Форма, КлючВарианта, Настройки)
// Вставить содержимое метода.
ПродолжитьВызов(Форма, КлючВарианта, Настройки);
Настройки.События.ПриСозданииНаСервере = Истина;
КонецПроцедуры
Процедура ПриСозданииНаСервере(ЭтаФорма, Отказ, СтандартнаяОбработка) Экспорт
Параметры = ЭтаФорма.Параметры;
Если Параметры.Свойство("ПараметрКоманды") Тогда
Если Параметры.Свойство("ОписаниеКоманды")
И Параметры.ОписаниеКоманды.Свойство("ДополнительныеПараметры") Тогда
Если Параметры.ОписаниеКоманды.ДополнительныеПараметры.ИмяКоманды = "ВыполнениеСборкиОтгрузкиТоваров" Тогда
ЭтаФорма.ФормаПараметры.Отбор.Вставить("Склад", Параметры.ПараметрКоманды);
КонецЕсли;
Если Параметры.ОписаниеКоманды.ДополнительныеПараметры.ИмяКоманды = "ВыполнениеСборкиОтгрузкиТоваровНоменклатура" Тогда
ЭтаФорма.ФормаПараметры.Отбор.Вставить("Номенклатура", Параметры.ПараметрКоманды);
КонецЕсли;
//Так же можно установить сразу два и более отборов в открываемом отчете
КонецЕсли;
КонецЕсли;
КонецПроцедуры
Ещё раз обращаю внимание, что в данном отчете не было процедуры ПриСозданииНаСервере() поэтому в расширении добавлена данная процедура. А в процедуре ИО_ОпределитьНастройкиФормы() указана необходимость использовать данное событие.
В обработке для вызова данного отчета с отбором применяется следующий программный код:
&НаКлиенте
Процедура ПоказатьТоварыКОтгрузкеСклад(Команда)
ПараметрыФормы = Новый Структура;
ПараметрыФормы.Вставить("КлючВарианта", "ВыполнениеСборкиОтгрузкиТоваров");
ПараметрыФормы.Вставить("ПараметрКоманды", Новый Структура("ВидСравнения, ПравоеЗначение", ВидСравненияКомпоновкиДанных.Равно, СкладОстатка));
ПараметрыФормы.Вставить("ОписаниеКоманды", Новый Структура("ДополнительныеПараметры", Новый Структура("ИмяКоманды", "ВыполнениеСборкиОтгрузкиТоваров")));
ПараметрыФормы.Вставить("СформироватьПриОткрытии", Истина);
ОткрытьФорму("Отчет.ТоварыКОтгрузке.Форма", ПараметрыФормы, ЭтаФорма, Истина);
КонецПроцедуры
&НаКлиенте
Процедура ПоказатьТоварыКОтгрузкеТовар(Команда)
СписокНоменклатуры.Очистить();
СписокТоваровПоАртикулу();
ПараметрыФормы = Новый Структура;
ПараметрыФормы.Вставить("КлючВарианта", "ВыполнениеСборкиОтгрузкиТоваров");
ПараметрыФормы.Вставить("ПараметрКоманды", Новый Структура("ВидСравнения, ПравоеЗначение", ВидСравненияКомпоновкиДанных.ВСписке, СписокНоменклатуры));
ПараметрыФормы.Вставить("ОписаниеКоманды", Новый Структура("ДополнительныеПараметры", Новый Структура("ИмяКоманды", "ВыполнениеСборкиОтгрузкиТоваровНоменклатура")));
ПараметрыФормы.Вставить("СформироватьПриОткрытии", Истина);
ОткрытьФорму("Отчет.ТоварыКОтгрузке.Форма", ПараметрыФормы, ЭтаФорма, Истина);
КонецПроцедуры
&НаКлиенте
Процедура ПоказатьТоварыКОтгрузкеСкладТовар(Команда)
//процедура позволяет сформировать отчет с двумя отборами
КонецПроцедуры
Результат работы программного кода:
Помимо вышеописанных вариантов в прилагаемом архиве в расширении и в обработке смоделирована возможность указать сразу два отбора: по номенклатуре и по складу.
На этом завершаю статью. Буду признателен за ценные дополнения.
Расширение и обработка тестировались на платформе 1С:Предприятие 8.3.23.1865, в конфигурации 1С:ERP Управление предприятием 2 (2.5.14.74) ДЕМО.
