Сервисы интеграции. Уведомления через колокольчик

Процедура ОтправитьСообщениеКолокольчикПользователям(МассивПолучателей,Сообщение,СсылкаНаОбъект) Экспорт    
	
	Если Не ЗначениеЗаполнено(Сообщение) Тогда
		Возврат;	
	КонецЕсли;	
	
	ИмяОтпраителя = ПараметрыСеанса.ТекущийПользователь.Наименование; 
	
	НавигационнаяСсылка = "";
	Если ЗначениеЗаполнено(СсылкаНаОбъект) Тогда
		НавигационнаяСсылка = ПолучитьНавигационнуюСсылку(СсылкаНаОбъект); 
	КонецЕсли;	
	
	// храним сообщение 20 дней
	ДатаУстаревания = ТекущаяДатаСеанса() + 20 * 86400;
	
	Для каждого Получатель Из МассивПолучателей Цикл   
		
		СообщениеСервиса = СервисыИнтеграции.Д_Оповещения.СоздатьСообщение(ДатаУстаревания);
		
		СообщениеСервиса.КодПолучателя = Строка(Получатель.ИдентификаторПользователяИБ);
		СообщениеСервиса.КодОтправителя = Строка(Получатель.ИдентификаторПользователяИБ);
		
		СтруктураТела = Новый Структура("Сообщение, НавигационнаяСсылка, Отправитель", 
		Сообщение, НавигационнаяСсылка, ИмяОтпраителя);
		
		РезультатJS = ЗаписатьДанныеВJSON(, СтруктураТела);
		
		ТекстСообщения = ?(РезультатJS.Отработал, РезультатJS.Результат, ""); 
		
		Тело = СообщениеСервиса.ПолучитьТелоКакПоток();
		Буфер = ПолучитьБуферДвоичныхДанныхИзСтроки(ТекстСообщения);
		Тело.Записать(Буфер, 0, Буфер.Размер);
		Тело.Закрыть();
		
		СообщениеСервиса.Параметры.Вставить("РазмерСообщения", Буфер.Размер);
		СообщениеСервиса.Параметры.Вставить("ТипСообщения", "Оповещение");
		
		СервисыИнтеграции.Д_Оповещения.Д_ОповещениеПользователей.ОтправитьСообщение(СообщениеСервиса);
	КонецЦикла;
	
КонецПроцедуры  

Функция СтандартныеПараметрыJSON() Экспорт
	
	Результат = Новый Структура;
	Результат.Вставить("ПереносСтрок",					ПереносСтрокJSON.Нет);
	Результат.Вставить("СимволОтступа",					" ");
	Результат.Вставить("ИспользоватьДвойныеКавычки",	Истина);
	Результат.Вставить("ЭкранированиеСимволов",			ЭкранированиеСимволовJSON.Нет);
	Результат.Вставить("ЭкранироватьАмперсанд",			Ложь);
	Результат.Вставить("ЭкранироватьОдинарныеКавычки",	Ложь);
	Результат.Вставить("ЭкранироватьРазделителиСтрок",	Ложь);
	Результат.Вставить("ЭкранироватьУгловыеСкобки",		Ложь);
	Результат.Вставить("ЭкранироватьСлеш",				Ложь);	
	
	Возврат Результат;		
	
КонецФункции

Функция ЗаписатьДанныеВJSON(ВходящиеПараметры = Неопределено, ВходныеДанные = "") Экспорт
	
	Результат = Новый Структура("Отработал, ТекстОшибки", Истина, "");
	
	Если ВходящиеПараметры = Неопределено Тогда 
		ВходящиеПараметры = СтандартныеПараметрыJSON(); 	
	КонецЕсли;	
	
	ПараметрыJSON	= Новый ПараметрыЗаписиJSON(ВходящиеПараметры.ПереносСтрок,
	ВходящиеПараметры.СимволОтступа,
	ВходящиеПараметры.ИспользоватьДвойныеКавычки,
	ВходящиеПараметры.ЭкранированиеСимволов,
	ВходящиеПараметры.ЭкранироватьУгловыеСкобки,
	ВходящиеПараметры.ЭкранироватьРазделителиСтрок,
	ВходящиеПараметры.ЭкранироватьАмперсанд,
	ВходящиеПараметры.ЭкранироватьОдинарныеКавычки,
	ВходящиеПараметры.ЭкранироватьСлеш);
	
	
	Попытка
		ЗаписьJSON						= Новый ЗаписьJSON;
		ЗаписьJSON.ПроверятьСтруктуру 	= Истина;
		ЗаписьJSON.УстановитьСтроку(ПараметрыJSON);	
		ЗаписатьJSON(ЗаписьJSON, ВходныеДанные);
		Результат.Вставить("Результат",	ЗаписьJSON.Закрыть());
	Исключение
		Результат.Отработал 			= Ложь;
		Результат.ТекстОшибки 			= ПодробноеПредставлениеОшибки(ИнформацияОбОшибке());
	КонецПопытки;
	
	Возврат Результат;
	
КонецФункции

Функция ПолучитьСтруктуруПользователя() Экспорт
	
	ТекПользовательФормы = ПользователиИнформационнойБазы.ТекущийПользователь(); 
	СтруктураПользователяФормы = Новый Структура("Имя,Идентификатор",
	ТекПользовательФормы.Имя, 
	Строка(ТекПользовательФормы.УникальныйИдентификатор));
	
	Возврат СтруктураПользователяФормы;
	
КонецФункции	

Функция ПолучитьСообщения(Сервис, Канал, ПользовательФормы) Экспорт   
	
	Отбор = Новый Структура;
	Отбор.Вставить("КодПолучателя", ПользовательФормы.Идентификатор);
	
	ПараметрыОтбора = Новый Соответствие;
	ПараметрыОтбора.Вставить("ТипСообщения", "Оповещение");  
	
	СообщенияСервиса = СервисыИнтеграции[Сервис][Канал].ВыбратьСообщения(Отбор);
	
	МассивСообщений = Новый Массив;
	Для Каждого текСообщение Из СообщенияСервиса Цикл 
		
		СткруктураСообщения = Новый Структура;	
		СткруктураСообщения.Вставить("Идентификатор", текСообщение.Идентификатор);
		
		РазмерСообщения = текСообщение.Параметры.Получить("РазмерСообщения");
		
		Если РазмерСообщения <> Неопределено Тогда
			РазмерБуфера = Число(РазмерСообщения); 
		Иначе
			РазмерБуфера = 1024;    
		КонецЕсли;
		
		Если РазмерБуфера = 0 Тогда 
			
			ВходящееСообщение = "";
			
		Иначе
			
			Тело  = Новый БуферДвоичныхДанных(0);
			Буфер = Новый БуферДвоичныхДанных(РазмерБуфера);
			Поток = текСообщение.ПолучитьТелоКакПоток();	
			
			Пока Истина Цикл
				
				Прочитано = Поток.Прочитать(Буфер, 0, РазмерБуфера);
				
				Если Прочитано > 0 Тогда
					
					Тело = Тело.Соединить(Буфер);  
					
				КонецЕсли;   
				
				Если Прочитано < РазмерБуфера Тогда
					
					Прервать; 
					
				КонецЕсли; 
				
			КонецЦикла; 
			
			ВходящееСообщение = ПолучитьСтрокуИзБуфераДвоичныхДанных(Тело);   
			
		КонецЕсли;
		
		Если Не ПустаяСтрока(ВходящееСообщение) Тогда 
			
			РезультатJS = ЧтениеДанныхИзJSON(ВходящееСообщение);
			
			Если РезультатJS.Отработал Тогда 
				
				ТелоРезультат = РезультатJS.Результат;
				
				СткруктураСообщения.Вставить("Сообщение", ТелоРезультат.Сообщение);	
				СткруктураСообщения.Вставить("НавигационнаяСсылка", ТелоРезультат.НавигационнаяСсылка);
				СткруктураСообщения.Вставить("Отправитель", ТелоРезультат.Отправитель);
				
			КонецЕсли;	
			
		КонецЕсли;
		
		
		МассивСообщений.Добавить(СткруктураСообщения);
		
	КонецЦикла;
	
	Возврат МассивСообщений;
	
КонецФункции

Процедура ОчиститьВсеСообщенияНаСервере(Сервис, Канал, МассивСообщений = Неопределено) Экспорт 
	
	Если ЗначениеЗаполнено(МассивСообщений) Тогда 
		Для Каждого ИдентификаторСообщения Из МассивСообщений Цикл 
			СервисыИнтеграции[Сервис][Канал].УдалитьСообщения(ИдентификаторСообщения);	
		КонецЦикла;	
	КонецЕсли;
	
КонецПроцедуры   

Функция ЧтениеДанныхИзJSON(СтрокаJSON) Экспорт
	
	Результат = Новый Структура("Отработал, ТекстОшибки", Истина, "");
	
	Попытка
		ЧтениеJSON 				= Новый ЧтениеJSON;
		ЧтениеJSON.УстановитьСтроку(СтрокаJSON);
		Результат.Вставить("Результат",ПрочитатьJSON(ЧтениеJSON));
	Исключение
		Результат.Отработал 	= Ложь;
		Результат.ТекстОшибки 	= ПодробноеПредставлениеОшибки(ИнформацияОбОшибке());
	КонецПопытки;
	
	Возврат Результат;
	
КонецФункции

//КЕ
&НаКлиенте
Перем СтруктураПользователяФормы; 
//КЕ


&НаКлиенте
Процедура ПриОткрытии(Отказ)
	
	//КЕ  
	СтруктураПользователяФормы = Д_ОповещениеПользователей.ПолучитьСтруктуруПользователя();
	ПодключитьОбработчикОжидания("ПолучитьСообщенияДляОповещения", 15, Ложь);
	//КЕ
	
КонецПроцедуры 

//КЕ
&НаКлиенте
Процедура ПолучитьСообщенияДляОповещения()
	
	МассивСообщений = Д_ОповещениеПользователей.ПолучитьСообщения("Д_Оповещения", "Д_ОповещениеПользователей", СтруктураПользователяФормы);	
	Если МассивСообщений.Количество() > 0 Тогда
		Для Каждого ТекСообщение Из МассивСообщений Цикл 
			
			Если Не ТекСообщение.Свойство("Сообщение") Тогда 				
				Продолжить;
			КонецЕсли;	
			
			Если ТекСообщение.Свойство("НавигационнаяСсылка") Тогда	 	
				ПоказатьОповещениеПользователя(ТекСообщение.Сообщение
				,ТекСообщение.НавигационнаяСсылка
				,?(ТекСообщение.Свойство("Отправитель"),ТекСообщение.Отправитель,""),
				,СтатусОповещенияПользователя.Важное
				,ТекСообщение.Идентификатор);
				
			Иначе	
				ПоказатьОповещениеПользователя(ТекСообщение.Сообщение,
				,?(ТекСообщение.Свойство("Отправитель"),ТекСообщение.Отправитель,""),
				,СтатусОповещенияПользователя.Важное
				,ТекСообщение.Идентификатор);
			КонецЕсли;			
			
		КонецЦикла;
		
		
		Д_ОповещениеПользователей.ОчиститьВсеСообщенияНаСервере("Д_Оповещения", "Д_ОповещениеПользователей", МассивСообщений);			
	КонецЕсли;	
	
КонецПроцедуры    
//КЕ

&НаСервере
Процедура ОтправитьСообщениеВКолокольчикНаСервере()      
	
	МассивПолучатели = Получатели.Выгрузить().ВыгрузитьКолонку("Пользователь");
	Д_ОповещениеПользователей.ОтправитьСообщениеКолокольчикПользователям(МассивПолучатели,Сообщение,Док);
	
КонецПроцедуры 

&НаКлиенте
Процедура ОтправитьСообщениеВКолокольчик(Команда)      
	
	ОтправитьСообщениеВКолокольчикНаСервере();
	
КонецПроцедуры