Опять "Поле объекта не обнаружено". Способы проверки

Справедливости  ради, возможны ситуации, когда без "Попытки" не обойтись. Но, как минимум, не следует без необходимости включать в "операторные скобки" страница текста. Выбрав минимальный отрезок кода, когда другие способы не подошли, обрабатываем проверку свойства. Очевидное достоинства: простота и универсальность  

Попытка
	ЗначениеСвойства = НашОбъект.Свойство
Исключение
	ЗначениеСвойства = Неопределено;
КонецПопытки;

1. Проверка свойств Структуры(Фиксированной структуры)
Достаточно известный способ. Но от этого ошибок по свойствам структуры меньше не становится.
Проверка существования свойства (ключа структуры) производится методом свойство Свойство(<Ключ>, <НайденноеЗначение>), возвращающим Истина при существовании свойства

ТестОбъект = Новый Структура;
ТестОбъект.Вставить("Эл1","Ок");
ТестОбъект.Вставить("Эл2","Ок");

//Приведет к ошибке
Сообщить(ТестОбъект.Эл3);
	
// Проверка 1й вариант
Если ТестОбъект.Свойство("Эл3") Тогда
	Сообщить(ТестОбъект.Эл3);
Иначе
	Сообщить("Поле Эл3 не существует!");
КонецЕсли           

При использовании метода Свойство() можно задать необязательный 2й параметр. Это позволяет повторно не обращаться к значению свойства, это значение сразу же вернется в переданную переменную.  Согласно документации, при отсутвии ключа в структуре, <НайденноеЗначение> возвращается Неопределено. Но нужно понимать, что элемент структуры вполне может иметь значение Неопределено и <НайденноеЗначение> = Неопределено еще не говорит, что ключ в структуре отсутствует.

//2й вариант
ЗначениеЭл3 = Неопределено;
Если ТестОбъект.Свойство("Эл3", ЗначениеЭл3) Тогда
	Сообщить(ЗначениеЭл3);
Иначе
	Сообщить("Поле Эл3 не существует!");
КонецЕсли;            

Метод Свойство() с аналогичными параметрами доступен для проверки свойств интерфейсных объектов управляемых форм: ДанныеФормыЭлементКоллекции, ДанныеФормыСтруктура, ДанныеФормыСтруктураСКоллекцией и ДанныеФормыЭлементДерева 

2. Существование документа/справочника и других объектов дерева метаданных верхнего уровня при обращении к менеджеру, типу и пр.
Удобно проводить с использованием свойства глобального контекста Метаданные

Если Метаданные.Документы.Найти("ПриходнаяНакладная") = Неопределено Тогда
	Сообщить("Документ не найден");
Иначе
	Док = Документы.ПриходнаяНакладная.СоздатьДокумент();
	Сообщить("Документ создан");
		
КонецЕсли;  

3. Проверка реквизитов объектов документов/справочников и пр.

Основные реквизиты (шапки)
 

Если Метаданные.Документы.Документ1.Реквизиты.Найти("Реквизит2") = Неопределено Тогда
	Сообщить("Реквизит не найден");
Иначе
	//Реквизит на месте	
КонецЕсли;

Полностью аналогичный способ - получение метаданных из ссылки/объекта справочника документа. Например:

ДокументОбъект = Документы.Документ1.СоздатьДокумент();
Если ДокументОбъект.Метаданные().Реквизиты.Найти("Реквизит2") = Неопределено Тогда
	Сообщить("Реквизит не найден");
Иначе
	//Реквизит на месте	
КонецЕсли; 

Аналогичным образом можно проверить как существование табличной части по имени, так и реквизита выбранной табличной части.

Для значения перечисления

Если Метаданные.Перечисления["Перечисление1"].ЗначенияПеречисления.Найти("ЗначениеПеречисления2") = Неопределено Тогда
	Сообщить("Значение перечисления не найдено");
Иначе
	//Есть значение
КонецЕсли;

4. Проверка колонок Таблицы значений/Дерева значений/Результата запроса

Здесь следует обращаться к коллекции колонок.

ТестТаблица = Новый ТаблицаЗначений;
ТестТаблица.Колонки.Добавить("Колонка1");
ТестТаблица.Колонки.Добавить("Колонка2");
ТестТаблица.Колонки.Добавить("Колонка3");
	
Если ТестТаблица.Колонки.Найти("Колонка4") = Неопределено Тогда
	Сообщить("Колонка4 отсутвует")
Иначе
	//Все на месте
КонецЕсли;

5. Элементы управляемых форм

ЕстьЭлемент = Не Элементы.Найти("КнопкаПроверка") = Неопределено;
Сообщить("Кнопка "+ЕстьЭлемент);

6. Труднодоступные для проверки свойства

Существование свойств некоторых объектов невозможно однозначно определить через поиск. В некоторых случаях свойство можно проверить перебором коллекции свойств, часто встречается в объектах Системы компоновки данных. Но, например, существования параметра области таблицы невозможно проверить даже перебором.

7. Еще один универсальный способ

Ну и напоследок... По-своему гениальный способ, элементы которого были обнаружены в одной из типовых конфигураций.

Используется универсальный метод глобального контекста ЗаполнитьЗначениеСвойств().

Его назначение - заполнение свойств Источника данными приемника по пересекающимся текстовым ключам (имена свойств). Если не указаны дополнительные параметры, отсутствие свойства Приемника 
в Источнике или наоборот, игнорируется и не приводит к ошибке. Это можно использовать для проверки.

Например, оформим такую проверку в виде функции

Функция УниверсальнаяПроверка(Коллекция,Реквизит)
	
	ВременнаяСтруктура = Новый Структура(Реквизит,Неопределено);
	ЗаполнитьЗначенияСвойств(ВременнаяСтруктура,Коллекция);
	
	Возврат НЕ ВременнаяСтруктура[Реквизит] = Неопределено;
	
КонецФункции

Здесь проверяемый реквизит (имя передается в параметре Реквизит) добавляется в структуру. Далее происходит попытка заместить значение элемента структуры соответствующим элементом коллекции. После этого проверяется, изменилось ли значение элемента.

Но, здесь опять возвращаемся к оговорке 1го раздела. Значение свойства объекта Неопределено не говорит о том, что свойство отсутствует.

Если это важно, можно несколько усложнить алгоритм, присвоив свойству проверочной структуры значение, повторение которого маловероятно. Например, случайное число или уникальный идентификатор. Функция проверки будет выглядеть следующим образом.

Функция УниверсальнаяПроверкаGUID(Коллекция,Реквизит)
	
	УникальныйИдентификатор = Новый УникальныйИдентификатор;
	
	ВременнаяСтруктура = Новый Структура(Реквизит,УникальныйИдентификатор);
	ЗаполнитьЗначенияСвойств(ВременнаяСтруктура,Коллекция);
	
	Возврат НЕ ВременнаяСтруктура[Реквизит] = УникальныйИдентификатор;
	
КонецФункции

Конечно, это далеко не полный список всех способов и особенностей проверок свойств.

Кто готов поделиться своими секретами, буду ждать в комментариях для пополнения базы знаний по борьбе с ошибками.

Дополнение от 29.01.2025

8. Метод БСП

Как верно уточнил ixijixi, в БСП реализован метод универсальной проверки существования реквизита/свойства объекта:

ОбщегоНазначенияКлиентСервер.ЕстьРеквизитИлиСвойствоОбъекта(Объект, Свойство)

Данная функция полностью реализует универсальный алгоритм раздела 7, в варианте с использованием уникального идентификатора.

9. Параметры запросов

Чаще всего, параметры запроса устанавливают с использованием метода объекта типа запрос УстановитьПараметр(<Имя>, <Значение>).

При указании имени отсутствующего в запросе параметра, возникает ошибка.

По сути, УстановитьПараметр - лишь добавляет пару [<Имя>, <Значение>] в структуру запроса Параметры.

То есть

Запрос = Новый Запрос;
/// 
Запрос.УстановитьПараметр("Параметр",Значение);

// эквивалентно

Запрос.Параметры.Вставить("Параметр",Значение);

Однако 2й способ (через вставку элемента структуры) при указании несуществующего параметра не вызовет ошибку и при выполнении запроса будет проигнорирован. Что может являться своего рода проверкой.

При этом, следует понимать, что изначально структура параметров пустая. Элементы в нее добавляются описанными выше способами. Таким образом проверить существование с тексте запроса какого-либо параметра через стандартную проверку существования элемента структуры Свойство(), невозможно.

Однако существует вариант проверить наличие параметра в тексте запроса до его выполнения. Очевидно, что данный метод не "смотрит вперед" и такая проверка возможна только при исполнении после задания текста запроса. В общем случае, конечно, после окончательного варианта текста.

Итак, метод объекта типа запрос НайтиПараметры() доступен до выполнения запроса и возвращает объект типа ОписаниеПараметровЗапроса.

У данного типа предусмотрен метод Найти(<Имя>), который возвращает объект типа ОписаниеПараметраЗапроса. Данный объект обладает свойством ТипЗначения, которое позволяет определить заданный тип параметра (насколько точно, непонятно).

Но нам важно, что в случае отсутствия в тексте запроса параметра с заданным именем, метод Найти(<Имя>)  вернет Неопределено.

Таким образом, проверка будет выглядеть так:

Запрос = Новый Запрос;

Запрос.Текст = "........";

Несуществует = Запрос.НайтиПараметры.Найти(<Имя>) = Неопределено

Дополнение от 01.03.2026

10. Выборка из результата запроса

В разделе 4 наряду с поиском колонок Таблицы значений и Дерева значений описан аналогичный по синтаксису метод проверки существования колонки Результата запроса, другими словами наличия в исходном запросе поля с соответствующим псевдонимом.

Если Не РезультатЗапроса.Колонки.Найти("Поле1") = Неопределено Тогда
Сообщить("Колонка Поле1 существует!");
КонецЕсли

Однако при разработке встречаются случаи, когда в распоряжении имеется не сам Результат запроса, а выборка из него. Например, именно выборка передана в параметр некоторой процедуры:

........
Процедура1(РезультатЗапроса.Выбрать())
........

Процедура Процедура1(ВыборкаИзРезультатаЗапроса)
........
КонецПроцедуры

  Для проверки наличия поля по имени для Выборки из результата запроса необходимо сначала получить "владельца" (Результат запроса) и уже для него выполнить проверку способом, описанным выше.

Если Не ВыборкаИзРезультатаЗапроса.Владелец().Колонки.Найти("Поле1") = Неопределено Тогда
Сообщить("Колонка Поле1 существует!");
КонецЕсли

Дополнение от 17.04.2026

11. О параметрах области Табличного документа/Макета

В разделе 6 обнаружилась не совсем точная формулировка относительно невозможности проверки существования параметра табличного документа. Некоторые способы выкрутиться возможны.

Обычно для исключения возможности ошибки при попытке заполнения отсутствующего параметра, параметры заполняются не напрямую, а через переменную типа Структура. Ключом является имя предполагаемого параметра, значением - значение этого параметра. Тогда при заполнении:

Область.Параметры.Заполнить(СтруктураПараметров)

Или, что тоже самое:

ЗаполнитьЗначениеСвойств(Область.Параметры,СтруктураПараметров)

отсутствующие в ключах структуры параметры будут проигнорированы, это не вызовет ошибку.

Но существует и способ проверки существования параметра по имени путем перебора, правда неочевидный и явно устаревший относительно организации обхода большинства иных коллекций.

С помощью метода Количество() можно определить количество параметров в области. Далее, перебором по индексу получить все имена параметров области, используя обращение в скобках [Индекс] Или через Получить(Индекс).

Таким образом:

ПараметрНайден = Ложь;

Для ИндексПараметра = 0 По Область.Параметры.Количество() -1 Цикл
    Если ОбластьПодвалаНакладной.Параметры[ИндексПараметра] = ИмяИсходногоПараметра Тогда
        ПараметрНайден = Истина;
        Прервать;
    КонецЕсли;
КонецЦикла;

Если Не ПараметрНайден Тогда
    Сообщить("Параметр не найден");
КонецЕсли;