Введение
Задача была такой: "Нужно было создавать документы в 1С через мобильного клиента".
Нужно сканировать маркированные коды для отбраковки.
Через расширение был создан документ "Отбраковка КМ". Далее на телефон установили мобильного клиента. Открыв список документов, высветилось сообщение.
Такое сообщение нежелательно бы было показывать пользователю. Поэтому принято решение убрать его.
Как искали место появления сообщения
В самом начале было неизвестно, где искать, так как в интернете никакой информации не было найдено. После того, как пооткрывали другие документы типовой конфигурации, стало известно, что счет на оплату и реализация открываются, не выдавая сообщения. Стали сравнивать формы и код модулей формы. Там нашелся код адаптации формы.
Который выглядел примерно так (код переписан для более простой формы):
&НаСервере
Процедура МобильныйКлиентАдаптацияФормы()
Если Не ОбщегоНазначения.ЭтоМобильныйКлиент() Тогда
Возврат;
КонецЕсли;
МобильныйКлиентБПФормаСписка.НастроитьФормуОбъекта(ЭтотОбъект);
МобильныйКлиентБПФормаСписка.ВстроитьЭлементВГруппуМКСписок(ЭтотОбъект, Элементы.Список);
АдаптироватьМККоманднаяПанельФормы();
АдаптироватьМКСписокФормы();
АдаптироватьМККонтекстСписокФормы();
КонецПроцедуры
&НаСервере
Процедура АдаптироватьМККоманднаяПанельФормы()
КомандыПоля = МобильныйКлиентБПФормаСписка.НовыйОписаниеКомандТабличноеПоле();
КомандыПоля.КомандаСоздать = "ФормаСоздать";
МобильныйКлиентБПФормаСписка.АдаптироватьМККоманднаяПанельФормы(ЭтотОбъект, КомандыПоля);
КонецПроцедуры
&НаКлиенте
Процедура Подключаемый_КомандаМКПоказатьСкрытьПрочиеКолонки(Команда)
МобильныйКлиентБПФормаОбъектаКлиентСервер.УправлениеФормойСпискаКолонкаПрочее(ЭтотОбъект);
КонецПроцедуры
&НаКлиенте
Процедура Подключаемый_КомандаМКПоказатьСкрытьОтбор(Команда)
МобильныйКлиентБПФормаОбъектаКлиентСервер.УправлениеФормойОтбораМК(ЭтотОбъект);
КонецПроцедуры
&НаСервере
Процедура АдаптироватьМККонтекстСписокФормы()
МобильныйКлиентБПФормаОбъекта.АдаптироватьКонтекстноеМеню(ЭтотОбъект);
КонецПроцедуры
&НаСервере
Процедура АдаптироватьМКСписокФормы()
МобильныйКлиентБПФормаСписка.ПодготовитьСписокФормы(ЭтотОбъект);
Элементы.Дата.РастягиватьПоГоризонтали = Истина;
МобильныйКлиентБПФормаСписка.ВстроитьЭлементВГруппуМК_ДатаНомер(ЭтотОбъект, Элементы.Дата);
ПолеМК_Номер = Элементы.Добавить("ПолеМК_Номер", Тип("ПолеФормы"), Элементы.Список);
ПолеМК_Номер.ПутьКДанным = "Список.Номер";
ПолеМК_Номер.Вид = ВидПоляФормы.ПолеНадписи;
МобильныйКлиентБПФормаСписка.ВстроитьЭлементВГруппуМК_ДатаНомер(ЭтотОбъект, ПолеМК_Номер);
МобильныйКлиентБПФормаСписка.ВстроитьЭлементыВГруппуМК_Прочее(ЭтотОбъект, "Список");
КонецПроцедуры
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
МобильныйКлиентАдаптацияФормы();
КонецПроцедуры
Вставив этот код отображение документов на форме изменится, но форма с сообщением никуда не денется.
Думая дальше мы скопировали форму из счета в новый документ и сделали ее основной, скопированная форма вела себя также как и остальные формы документа.
Решение
Следующим решением было поискать подходящее место в БСП. И как результат - оно нашлось!
В общем модуле "МобильныйКлиентБП" нашелся метод.
Процедура ОткрытьДоступнуюНаМобильномФорму(Источник, ВидФормы, Параметры, ВыбраннаяФорма, СтандартнаяОбработка)
Если Не ОбщегоНазначения.ЭтоМобильныйКлиент() Тогда
Возврат;
КонецЕсли;
Если Параметры.Свойство("ОтключитьПроверкуПриОткрытииФорм")
И Параметры.ОтключитьПроверкуПриОткрытииФорм Тогда
Возврат;
КонецЕсли;
ЧастиИсточника = СтрРазделить(Источник, ".");
Менеджер = ЧастиИсточника[0];
ИмяОбъекта = ЧастиИсточника[1];
//Переопределение форм рег. отчетности см. ОткрытьДоступнуюФормуРегламентированнойОтчетности
//Стандартные формы БРО не адаптированы под мобильный клиент
Если ИмяОбъекта = "РегламентированныйОтчет" Тогда
Возврат;
КонецЕсли;
//Проверяются только основные формы объектов: ФормаОбъекта, ФормаСписка, ФормаВыбора, ОсновнаяФорма
//В подписку включены все: Документы, ЖурналыДокументов.
//Отчеты и обработки частично:
//У которых можно и нужно переопределить основную форму на заглушку
//Часть недоступных обработок и отчетов - заблокированы в командах в интерфейсе
ФормаДоступнаБезЗапроса = Ложь;
Если Менеджер = "ЖурналДокументовМенеджер" Тогда
ФормаДоступнаБезЗапроса = ФормаЖурналаДокументовАдаптирована(ИмяОбъекта, ВидФормы);
ИначеЕсли Менеджер = "ДокументМенеджер" Тогда
ФормаДоступнаБезЗапроса = (ВидФормы = "ФормаВыбора")
Или ФормаДокументаАдаптирована(ИмяОбъекта, ВидФормы);
КонецЕсли;
МобильныйКлиентБППереопределяемый.ПриОпределенииДоступностиФормы(Менеджер, ИмяОбъекта, ВидФормы, ФормаДоступнаБезЗапроса);
Если ФормаДоступнаБезЗапроса Тогда
Возврат;
КонецЕсли;
//Если форма включена в подписку, но не запрещена - покажем предупреждение
//Запрещенные - явно блокируем
ФормаДоступнаСПредупреждением = Не ФормаЗапрещенаВМобильном(Менеджер, ИмяОбъекта, ВидФормы);
// Выбираем режим открытия для формы.
ОткрываемаяФормаУказанаЯвно = (ВыбраннаяФорма <> Неопределено
И ТипЗнч(ВыбраннаяФорма) <> Тип("Строка"));
Если ОткрываемаяФормаУказанаЯвно Тогда // форма-объект метаданных
ИмяФормы = ВыбраннаяФорма.ПолноеИмя();
Иначе // требуется подобрать форму
ОписаниеИсточника = Метаданные.НайтиПоТипу(ТипЗнч(Источник));
ИмяФормы = ОписаниеИсточника.ПолноеИмя() + "." +
?(ВыбраннаяФорма = Неопределено, ВидФормы, "Форма." + ВыбраннаяФорма);
КонецЕсли;
ЗаголовокФормы = "";
Если Не Параметры.Свойство("Заголовок", ЗаголовокФормы) Тогда
Если ОткрываемаяФормаУказанаЯвно Тогда
ЗаголовокФормы = ВыбраннаяФорма.Синоним;
Иначе
Если ВидФормы = "ФормаСписка"
И Не ПустаяСтрока(ОписаниеИсточника.РасширенноеПредставлениеСписка) Тогда
ЗаголовокФормы = ОписаниеИсточника.РасширенноеПредставлениеСписка;
ИначеЕсли ВидФормы = "ФормаСписка"
И Не ПустаяСтрока(ОписаниеИсточника.ПредставлениеСписка) Тогда
ЗаголовокФормы = ОписаниеИсточника.ПредставлениеСписка;
Иначе
ЗаголовокФормы = ОписаниеИсточника.Синоним;
КонецЕсли;
КонецЕсли;
КонецЕсли;
Ключ = Неопределено;
Параметры.Свойство("Ключ", Ключ);
ОписаниеНедоступногоДействия = ОписаниеНедоступногоДействия(ИмяФормы, ВидФормы, ЗаголовокФормы, Ключ);
СтандартнаяОбработка = Ложь;
ВыбраннаяФорма = "ОбщаяФорма.НедоступноНаМобильномКлиенте";
ПараметрыОткрываемойФормы = Новый Структура;
Для каждого ПараметрФормы Из Параметры Цикл
ПараметрыОткрываемойФормы.Вставить(ПараметрФормы.Ключ, ПараметрФормы.Значение);
КонецЦикла;
ПараметрыОткрытия = МобильныйКлиентБПКлиентСервер.НовыйПараметрыОткрытияФормыСПредупреждением();
ПараметрыОткрытия.ИмяФормы = ИмяФормы;
ПараметрыОткрытия.Заголовок = ЗаголовокФормы;
ПараметрыОткрытия.ПереопределенаНаСервере = Истина;
Параметры.Очистить();
ПараметрыФормыНедоступно = МобильныйКлиентБПКлиентСервер.НовыйПараметрыФормаНедоступноНаМобильном();
ПараметрыФормыНедоступно.ОписаниеНедоступногоДействия = ОписаниеНедоступногоДействия;
ПараметрыФормыНедоступно.ФормаДоступнаСПредупреждением = ФормаДоступнаСПредупреждением;
Параметры.Вставить("ПараметрыФормыНедоступно", ПараметрыФормыНедоступно);
Параметры.Вставить("ПараметрыОткрываемойФормы", ПараметрыОткрываемойФормы);
Параметры.Вставить("ПереопределенаНаСервере", ПараметрыОткрытия.ПереопределенаНаСервере);
Параметры.Вставить("ПараметрыОткрытия", ПараметрыОткрытия);
КонецПроцедуры
В этом методе интересен стал кусок этот кода:
Если Менеджер = "ЖурналДокументовМенеджер" Тогда
ФормаДоступнаБезЗапроса = ФормаЖурналаДокументовАдаптирована(ИмяОбъекта, ВидФормы);
ИначеЕсли Менеджер = "ДокументМенеджер" Тогда
ФормаДоступнаБезЗапроса = (ВидФормы = "ФормаВыбора")
Или ФормаДокументаАдаптирована(ИмяОбъекта, ВидФормы);
КонецЕсли;
Точнее, метод "ФормаДокументаАдаптирована".
В типовом виде он выглядит так:
Функция ФормаДокументаАдаптирована(ИмяОбъекта, ВидФормы)
ФормаАдаптирована =
ИмяОбъекта = "СчетНаОплатуПокупателю"
или ИмяОбъекта = "СчетНаОплатуПоставщика"
или ИмяОбъекта = "ПлатежноеПоручение"
или ИмяОбъекта = "ПоступлениеНаРасчетныйСчет"
или ИмяОбъекта = "СписаниеСРасчетногоСчета"
или ИмяОбъекта = "ПриходныйКассовыйОрдер"
или ИмяОбъекта = "РасходныйКассовыйОрдер"
или ИмяОбъекта = "АктСверкиВзаиморасчетов"
или ИмяОбъекта = "ВозвратТоваровОтПокупателя"
или ИмяОбъекта = "ВозвратТоваровПоставщику"
или ИмяОбъекта = "Доверенность"
или ИмяОбъекта = "КоммерческоеПредложение"
или ИмяОбъекта = "ПоступлениеТоваровУслуг"
или ИмяОбъекта = "РеализацияТоваровУслуг"
или ИмяОбъекта = "РеализацияОтгруженныхТоваров"
или ИмяОбъекта = "РозничнаяПродажа"
или ИмяОбъекта = "ОтчетОРозничныхПродажах"
или ИмяОбъекта = "ОплатаПлатежнойКартой"
или ИмяОбъекта = "СчетФактураПолученный"
или ИмяОбъекта = "СчетФактураВыданный"
или ИмяОбъекта = "ПоступлениеДопРасходов"
или ИмяОбъекта = "ОперацияСПатентом"
или ИмяОбъекта = "ИнвентаризацияТоваровНаСкладе"
или ИмяОбъекта = "ЭлектронноеПисьмоИсходящее"
или ИмяОбъекта = "ЭлектронноеПисьмоВходящее"
или ИмяОбъекта = "УведомлениеОбИсчисленныхСуммахНалогов"
или ИмяОбъекта = "УведомлениеОбУменьшенииНалогаПоПатенту"
или ИмяОбъекта = "УстановкаЦенНоменклатуры"
или ИмяОбъекта = "АвансовыйОтчет"
или ИмяОбъекта = "РасходыПредпринимателя"
или ИмяОбъекта = "ПутевойЛист"
или ИмяОбъекта = "ОказаниеУслуг"
или ИмяОбъекта = "ИнвентаризацияОС"
или ИмяОбъекта = "ЭлектронныйДокументВходящийЭДО"
или ИмяОбъекта = "ЭлектронныйДокументИсходящийЭДО"
//Добавлен для целостности учета, но не адаптирован
или ИмяОбъекта = "ДокументРасчетовСКонтрагентом"
или ИмяОбъекта = "ТелефонныйЗвонок"
или ИмяОбъекта = "Встреча"
или ИмяОбъекта = "ПрочееВзаимодействие";
Возврат ФормаАдаптирована;
КонецФункции
Для того чтобы убрать сообщение, мы добавили этот метод в расширение с изменением и контролем.
В результате получилось вот так.
&ИзменениеИКонтроль("ФормаДокументаАдаптирована")
Функция КПК_ФормаДокументаАдаптирована(ИмяОбъекта, ВидФормы)
ФормаАдаптирована =
ИмяОбъекта = "СчетНаОплатуПокупателю"
или ИмяОбъекта = "СчетНаОплатуПоставщика"
или ИмяОбъекта = "ПлатежноеПоручение"
или ИмяОбъекта = "ПоступлениеНаРасчетныйСчет"
или ИмяОбъекта = "СписаниеСРасчетногоСчета"
или ИмяОбъекта = "ПриходныйКассовыйОрдер"
или ИмяОбъекта = "РасходныйКассовыйОрдер"
или ИмяОбъекта = "АктСверкиВзаиморасчетов"
или ИмяОбъекта = "ВозвратТоваровОтПокупателя"
или ИмяОбъекта = "ВозвратТоваровПоставщику"
или ИмяОбъекта = "Доверенность"
или ИмяОбъекта = "КоммерческоеПредложение"
или ИмяОбъекта = "ПоступлениеТоваровУслуг"
или ИмяОбъекта = "РеализацияТоваровУслуг"
или ИмяОбъекта = "РеализацияОтгруженныхТоваров"
или ИмяОбъекта = "РозничнаяПродажа"
или ИмяОбъекта = "ОтчетОРозничныхПродажах"
или ИмяОбъекта = "ОплатаПлатежнойКартой"
или ИмяОбъекта = "СчетФактураПолученный"
или ИмяОбъекта = "СчетФактураВыданный"
или ИмяОбъекта = "ПоступлениеДопРасходов"
или ИмяОбъекта = "ОперацияСПатентом"
или ИмяОбъекта = "ИнвентаризацияТоваровНаСкладе"
или ИмяОбъекта = "ЭлектронноеПисьмоИсходящее"
или ИмяОбъекта = "ЭлектронноеПисьмоВходящее"
или ИмяОбъекта = "УведомлениеОбИсчисленныхСуммахНалогов"
или ИмяОбъекта = "УведомлениеОбУменьшенииНалогаПоПатенту"
или ИмяОбъекта = "УстановкаЦенНоменклатуры"
или ИмяОбъекта = "АвансовыйОтчет"
или ИмяОбъекта = "РасходыПредпринимателя"
или ИмяОбъекта = "ПутевойЛист"
или ИмяОбъекта = "ОказаниеУслуг"
или ИмяОбъекта = "ИнвентаризацияОС"
или ИмяОбъекта = "ЭлектронныйДокументВходящийЭДО"
или ИмяОбъекта = "ЭлектронныйДокументИсходящийЭДО"
//Добавлен для целостности учета, но не адаптирован
или ИмяОбъекта = "ДокументРасчетовСКонтрагентом"
или ИмяОбъекта = "ТелефонныйЗвонок"
или ИмяОбъекта = "Встреча"
#Вставка
или ИмяОбъекта = "ОтбраковкаКМ"
#КонецВставки
или ИмяОбъекта = "ПрочееВзаимодействие";
Возврат ФормаАдаптирована;
КонецФункции
Заключение
После выполненных действий конфигурация стала думать, что добавленный нами документ был адаптирован для мобильного клиента.
При этом даже если в форме никакой адаптации не было прописано.
Данный способ, по-моему, выглядит немного костыльно, и если вдруг кто знает другие способы решения, просьба - подскажите в комментариях.
Вступайте в нашу телеграмм-группу Инфостарт