Перезапуск обработки или отчета с сохранением введенных данных (Обычные формы) !

18.09.15

Разработка - Универсальные функции

Отлично выручает, когда в обработке много заполняемых реквизитов, и нужно постоянно её перезапускать для отладки.

Приведенная ниже функция перезапускает внешнюю обработку или отчет с сохранением введенных на форме данных. Таких как:

  • Реквизиты
  • Табличные части
  • Таблицы значений
  • Дерево значений
  • Отбор компоновщикаСКД
  • Выбранные поля компоновщикаСКД
  • Список значений

 

Процедура ПерезапуститьВнешнююОбработку()
	
	ЭтоФайл = Найти(ТипЗнч(ЭтотОбъект),"Внешн")=1;
	КоманднаяПанель = ЭтаФорма.ЭлементыФормы.Найти("ОсновныеДействияФормы");
	
	Если КоманднаяПанель = Неопределено Тогда
		КоманднаяПанель = ЭтаФорма.ЭлементыФормы.Найти("ДействияФормы");
	КонецЕсли; 
	
	Если (НЕ ЭтоФайл) ИЛИ (КоманднаяПанель = Неопределено) Тогда
		Возврат;
	КонецЕсли; 
	
	КнопкаПерезапустить_УжеСуществует = КоманднаяПанель.Кнопки.Найти("Перезапустить") <> Неопределено;
	Если КнопкаПерезапустить_УжеСуществует Тогда
		
		СохранятьЗначенияРеквизитов = Истина;
		
		// Перезапустить обработку
		Для Каждого Форма Из ЭтаФорма.Метаданные().Формы Цикл
			
			ТекущаяФорма = ПолучитьФорму(Форма);
			Если НЕ ТекущаяФорма = ЭтаФорма Тогда
				Продолжить;
			КонецЕсли;
			
			// Сохранить значения реквизитов
			СписокСохраняемыхРеквизитов = Новый Структура(); 
			СписокСохраняемыхТабЧастей = Новый Структура();
			Если СохранятьЗначенияРеквизитов Тогда
				Для Каждого итЭлемент Из ТекущаяФорма.ЭлементыФормы Цикл
					Если ТипЗнч(итЭлемент) = Тип("ПолеВвода")
						ИЛИ ТипЗнч(итЭлемент) = Тип("ПолеВыбора")
						ИЛИ ТипЗнч(итЭлемент) = Тип("Флажок") 
						ИЛИ ТипЗнч(итЭлемент) = Тип("Переключатель")Тогда
						СписокСохраняемыхРеквизитов.Вставить(итЭлемент.Имя, итЭлемент.Значение); 
					ИначеЕсли ТипЗнч(итЭлемент) = Тип("ТабличноеПоле") Тогда
						СписокСохраняемыхТабЧастей.Вставить(итЭлемент.Имя, итЭлемент.Значение);
					КонецЕсли;
				КонецЦикла; // Элементы формы
			КонецЕсли;
			
			ЭтаФорма.Закрыть();
			ЭтоОбработка = Найти(Строка(ТипЗнч(ЭтотОбъект)), "Внешняя обработка объект:") = 1;
			
			Если ЭтоОбработка Тогда
				Форма = ВнешниеОбработки.Создать(ЭтотОбъект.ИспользуемоеИмяФайла).ПолучитьФорму(Форма.Имя);
			Иначе 
				Форма = ВнешниеОтчеты.Создать(ЭтотОбъект.ИспользуемоеИмяФайла).ПолучитьФорму(Форма.Имя);
			КонецЕсли;
			
			
			
			// Восстанавить значения реквизитов
			Для каждого итЭлемент Из СписокСохраняемыхРеквизитов Цикл
				Попытка
					Форма.ЭлементыФормы[итЭлемент.Ключ].Значение = итЭлемент.Значение;
				Исключение
				КонецПопытки;
			КонецЦикла; 
			
			
			// Восстанавить значения ТабЧастей
			ВосстановитьПослеОткрытия = Новый Структура();
			Для каждого итЭлемент Из СписокСохраняемыхТабЧастей Цикл
				Попытка
					Если ТипЗнч(итЭлемент.Значение) = Тип("СписокЗначений") Тогда 
						Форма.ЭлементыФормы[итЭлемент.Ключ].Значение.ЗагрузитьЗначения(итЭлемент.Значение.ВыгрузитьЗначения())
						
					ИначеЕсли ТипЗнч(итЭлемент.Значение) = Тип("ОтборКомпоновкиДанных") Тогда 
						ВосстановитьПослеОткрытия.Вставить(итЭлемент.Ключ,итЭлемент.Значение);
					ИначеЕсли ТипЗнч(итЭлемент.Значение) = Тип("ВыбранныеПоляКомпоновкиДанных") Тогда 
						ВосстановитьПослеОткрытия.Вставить(итЭлемент.Ключ,итЭлемент.Значение);
						
					ИначеЕсли ТипЗнч(итЭлемент.Значение) = Тип("ТаблицаЗначений") ИЛИ ТипЗнч(итЭлемент.Значение) = Тип("ДеревоЗначений") Тогда 
						Форма.ЭлементыФормы[итЭлемент.Ключ].Значение = итЭлемент.Значение;
						Форма.ЭлементыФормы[итЭлемент.Ключ].СоздатьКолонки();
					Иначе // пока для всех остальных
						Форма.ЭлементыФормы[итЭлемент.Ключ].Значение.Загрузить(итЭлемент.Значение.Выгрузить());
					КонецЕсли;
				Исключение
				КонецПопытки;
			КонецЦикла;
			
			Форма.Открыть();
			
			//Восстановить значния табличных частей после открытия формы
			//
			Для каждого итЭлемент Из ВосстановитьПослеОткрытия Цикл
				
				Если ТипЗнч(итЭлемент.Значение) = Тип("ОтборКомпоновкиДанных") Тогда 
					Форма.ЭлементыФормы[итЭлемент.Ключ].Значение.Элементы.Очистить();
					Для Каждого ЭлементОтбора Из итЭлемент.Значение.Элементы Цикл
						ЗаполнитьЗначенияСвойств(Форма.ЭлементыФормы[итЭлемент.Ключ].Значение.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных")), ЭлементОтбора); 
					КонецЦикла;
				КонецЕсли;
				
				Если ТипЗнч(итЭлемент.Значение) = Тип("ВыбранныеПоляКомпоновкиДанных") Тогда 
					Форма.ЭлементыФормы[итЭлемент.Ключ].Значение.Элементы.Очистить();
					Для Каждого ЭлементВыбранноеПоле Из итЭлемент.Значение.Элементы Цикл
						ЗаполнитьЗначенияСвойств(Форма.ЭлементыФормы[итЭлемент.Ключ].Значение.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных")), ЭлементВыбранноеПоле); 
					КонецЦикла;
				КонецЕсли;
				
			КонецЦикла;
			
		КонецЦикла;
		
	Иначе
		
		КоманднаяПанель.Кнопки.Добавить("РазделительПерезапустить", ТипКнопкиКоманднойПанели.Разделитель);
		
		// Добавить кнопку
		Действие = Новый Действие("ПерезапуститьВнешнююОбработку");
		НоваяКнопка = КоманднаяПанель.Кнопки.Добавить("Перезапустить", ТипКнопкиКоманднойПанели.Действие, "Перезапустить", Действие);
		НоваяКнопка.Картинка = БиблиотекаКартинок.Обновить;
		НоваяКнопка.Отображение = ОтображениеКнопкиКоманднойПанели.НадписьКартинка; 
		НоваяКнопка.СочетаниеКлавиш = Новый СочетаниеКлавиш(Клавиша.F4, , , Истина); // Shift-F4
		
	КонецЕсли;
	
КонецПроцедуры

 

 

Обработку легко дорабатывать и связывать с другим функционалом, например, перед перезапуском открывать форму, где можно выбрать, что перезаполнить, но это уже другие заморочки.  

Практически везде пишут только код перезапуска. Пользуйтесь на здоровье. Wink

 

 

Перезапуск переоткрытие

См. также

Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024    2670    0    John_d    8    

54

GUID в 1С 8.3 - как с ними быть

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.

12.02.2024    4608    atdonya    22    

45

Переоткрытие внешних обработок

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    3961    ke.92@mail.ru    16    

61

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8822    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2071    21    progmaster    7    

3

Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    16144    133    sapervodichka    112    

129

Система контроля ведения учета [БСП]

Универсальные функции Механизмы типовых конфигураций БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данном материале рассмотрим типовой алгоритм подсистемы контроля учета БСП в конфигурациях на примерах.

18.07.2022    7243    quazare    8    

109
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. DoctorRoza 18.09.15 09:18 Сейчас в теме
Лови +, заслужил, код забираю в must have! :)
2. Rupert69 38 18.09.15 10:10 Сейчас в теме
Забыл указать в статье: Процедуру удобно вызывать при открытии формы. (ну может кто не догадается) =)
3. olbu 18.09.15 12:39 Сейчас в теме
Я правильно ее использую? В форме ПриОткрытии запускаю это процедуру?

Блин, сам не догадался, и уже после увидел сообщение...
4. movis08 23.06.16 13:55 Сейчас в теме
Оставьте свое сообщение