SOAP-сервисы с предварительной Cookie-аутентификацией

05.06.16

Интеграция - WEB-интеграция

Платформа 1С не позволяет использовать cookie при работе со статичной WS-ссылкой или WS-прокси. Вследствие этого работа со многими веб-сервисами крупных поставщиков (например, DHL) напрямую невозможна.

Рассмотрим постановку задачи и её решение.

Задача:

Есть soap-сервис крупного поставщика DHL, построенный на ASP.NET. При обращении к сервису веб-сервер поставщика производит 302-редирект на страницу аутентификации:

После ввода логина и пароля открывается wsdl-описание.

Требуется организовать работу с методами данного веб-сервиса из кода 1С.

Типовые объекты WSОпределение и WSПрокси с данным веб-сервисом работать не могут, поскольку не имеют возможности указания произвольных заголовков HTTP-запроса для передачи значения cookie-аутентификации.

Решение:

План таков:

  1. Получим страницу аутентификации GET-запросом и сохраним предварительно устанавливаемое в cookie случайное значение. Это значение впоследствии используется для идентификации сеанса.
  2. POST-запросом проведём отправку данных формы аутентификации. В ответе сервера получим cookie-аутентификации.
  3. С методами веб-сервиса будем работать с помощью POST-запросов, устанавливая полученные cookie.
  4. Чтобы упростить сборку требуемых для методов сервиса soap-запросов, воспользуемся XDTO-описанием параметров и результатов методов, полученным от поставщика.

Пример SOAP-запроса и ответа:

Запрос:

<?xml version="1.0" encoding="utf-8"?> 
<soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"> 
<soap:Body> 
<GetPtsList xmlns="http://tempuri.org/"> 
<auth> 
<Login>string</Login> 
<Password>string</Password> 
</auth> 
<startDate>dateTime</startDate> 
<endDate>dateTime</endDate> 
</GetPtsList> 
</soap:Body> 
</soap:Envelope>

Ответ:

<?xml version="1.0" encoding="utf-8"?>
<soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
  <soap:Body>
    <GetPtsListResponse xmlns="http://tempuri.org/">
      <GetPtsListResult>
        <PtsItemInfo>
          <DealerReceiveDate>dateTime</DealerReceiveDate>
          <PickupDate>dateTime</PickupDate>
          <ReferenceNumber>string</ReferenceNumber>
          <RegistrationDate>dateTime</RegistrationDate>
          <PtsNumber>string</PtsNumber>
          <VinNumber>string</VinNumber>
          <DhlStation>string</DhlStation>
          <DestinationDhlStation>string</DestinationDhlStation>
          <Dealer>string</Dealer>
          <Model>string</Model>
          <Gtd>string</Gtd>
          <Brand>string</Brand>
          <PtsStatus>string</PtsStatus>
          <BrandCode>string</BrandCode>
          <DealerCode>string</DealerCode>
          <Awb>string</Awb>
        </PtsItemInfo>
      </GetPtsListResult>
    </GetPtsListResponse>
  </soap:Body>
</soap:Envelope>

Для удобной генерации XML запроса и ответа создадим XDTO-пакет с описанием объектов GetPtsListauthGetPtsListResponseGetPtsListResultPtsItemInfo с пространством имён http://tempuri.org/ .

Реализация:

1. Получение страницы аутентификации GET-запросом и отправка данных формы (username, password):

Функция АвторизацияНаВебСервере() Экспорт
    
    СтруктураСоединение = Новый Структура("Результат, HTTPСоединение, Заголовки, НастройкиПодключения");
    СтруктураСоединение.Результат = Ложь;
  
    // из регистра сведений получаем сервер, url, логин, пароль для подключения
    НастройкиПодключения = ПолучитьНастройкиПодключения();
    
    Если НастройкиПодключения.Количество()=0 Тогда
        Возврат СтруктураСоединение;
    КонецЕсли;
    
    НастройкаПодключения = НастройкиПодключения[0];
    
    АдресСервера = СокрЛП(НастройкаПодключения.ДопПараметр1);
    АдресАвторизации = СокрЛП(НастройкаПодключения.ДопПараметр2);    
    
    UserName = СокрЛП(НастройкаПодключения.Пользователь);
    Password = СокрЛП(НастройкаПодключения.Пароль);
    
    // данные авторизации - значения параметров формы авторизации, их можно подсмотреть с помощью, например, Advanced REST client
    ДанныеАвторизации = "&UserName="+UserName+"&Password="+Password+"&RememberMe=true&CustomAuthKey=";
    
    Попытка
        Соединение = Новый HTTPСоединение(АдресСервера);
        
        // получим страницу GET-запросом, в Заголовки0 вернутся предварительные cookie
        Заголовки0 = Новый Соответствие;
        Результат0 = ВыполнитьGETЗапрос(Соединение, АдресАвторизации, Заголовки0);    
        
        Если Результат0.Ответ.КодСостояния<>200 Тогда
            Возврат СтруктураСоединение;
        КонецЕсли;
        
        // отправим POST-запросом данные формы для аутентификации, в Заголовки1 вернутся новые cookie, 
        // уже со значением успешной аутентификации. Эти новые cookie мы сохраним и будем использовать 
        // при выполнении методов сервиса
        Заголовки1 = Новый Соответствие;
        Заголовки1.Вставить("Cookie",Результат0.Ответ.Заголовки["Set-Cookie"]);    
        Заголовки1.Вставить("Content-Type", "application/x-www-form-urlencoded");
        
        Результат1 = ВыполнитьPOSTЗапрос(Соединение,АдресАвторизации,Заголовки1,ДанныеАвторизации);
        
        Если Результат1.Ответ.КодСостояния<>302  Тогда
            Возврат СтруктураСоединение;
        КонецЕсли;
        СтруктураСоединение.HTTPСоединение = Соединение;
        СтруктураСоединение.Заголовки = Новый Соответствие;
        
        // в Результат1.Ответ.Заголовки["Set-Cookie"] находится заветный ключ
        СтруктураСоединение.Заголовки.Вставить("Cookie",Результат1.Ответ.Заголовки["Set-Cookie"]);
        СтруктураСоединение.Результат = Истина;
        СтруктураСоединение.НастройкиПодключения = НастройкаПодключения;
        
    Исключение
        ЗаписьЖурналаРегистрации("ИнтеграцияСDHL.АвторизацияНаВебСервере",
                                УровеньЖурналаРегистрации.Ошибка,
                                ,,ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
    КонецПопытки;    
    
    Возврат СтруктураСоединение;
    
КонецФункции

2. Сборка soap-запроса, его выполнение посредством POST-запроса и получение результата в XDTO:

Функция GetMethodName(СтруктураПараметров) Экспорт
    
    ОбъектXDTO = Неопределено;
    
    СтруктураСоединение = АвторизацияНаВебСервере();
    Если НЕ СтруктураСоединение.Результат Тогда
        Возврат ОбъектXDTO;
    КонецЕсли;
    
    ПутьКМетодуСервиса = "urlpart1/Service.asmx?op=GetMethodName";
   
    // предварительно в метаданных опишем XDTO-пакеты для параметров сервиса и для возвращаемых значений.
    ТипGetPtsList = ФабрикаXDTO.Тип("http://tempuri.org/","GetPtsList");
    Типauth = ФабрикаXDTO.Тип("http://tempuri.org/","auth");
    
    ПараметрXDTO = ФабрикаXDTO.Создать(ТипGetPtsList);
    ПараметрXDTO.startDate = СтруктураПараметров.startDate;
    ПараметрXDTO.endDate = СтруктураПараметров.endDate;
    Параметрauth = ФабрикаXDTO.Создать(Типauth);
    Параметрauth.Login = СтруктураСоединение.НастройкиПодключения.Пользователь;
    Параметрauth.Password = СтруктураСоединение.НастройкиПодключения.Пароль;
    ПараметрXDTO.auth = Параметрauth;
    
    Запись = Новый ЗаписьXML;
    Запись.УстановитьСтроку();
    
    // генерируем XML для параметров метода сервиса
    ФабрикаXDTO.ЗаписатьXML(Запись,ПараметрXDTO);
    
    СтрXML = Запись.Закрыть();

    // для указания нужных пространств имён в xml-запросе и ответе применена быстрая и грубая замена подстрок
    СтрXML = СтрЗаменить(СтрXML," xmlns:xs=""http://www.w3.org/2001/XMLSchema"" xmlns:xsi=""http://www.w3.org/2001/XMLSchema-instance""","");
    
    SOAPЗапрос = "<?xml version=""1.0"" encoding=""utf-8""?>
                |<soap:Envelope xmlns:xsi=""http://www.w3.org/2001/XMLSchema-instance"" xmlns:xsd=""http://www.w3.org/2001/XMLSchema"" xmlns:soap=""http://schemas.xmlsoap.org/soap/envelope/"">
                |  <soap:Body>"
                +СтрXML+
                "</soap:Body>
                |</soap:Envelope>";
                
    ФайлЗапроса = ПолучитьИмяВременногоФайла();
    ТекстовыйФайл = Новый ТекстовыйДокумент;
    ТекстовыйФайл.УстановитьТекст(SOAPЗапрос);
    ТекстовыйФайл.Записать(ФайлЗапроса,КодировкаТекста.ANSI);

    ФайлРезультата = ПолучитьИмяВременногоФайла();
    
    ЗаголовокНТТР = Новый Соответствие;
    ЗаголовокНТТР.Вставить("Cookie",СтруктураСоединение.Заголовки["Cookie"]);    
    
    ФайлОтправки = Новый Файл(ФайлЗапроса);
    РазмерФайлаОтправки = XMLСтрока(ФайлОтправки.Размер());

    ЗаголовокНТТР.Вставить("Content-Type", "text/xml; charset=utf-8");
    ЗаголовокНТТР.Вставить("Content-Lenght", РазмерФайлаОтправки);

    СтруктураСоединение.HTTPСоединение.ОтправитьДляОбработки(ФайлЗапроса,ПутьКМетодуСервиса,ФайлРезультата,ЗаголовокНТТР);
    
    // Получаем ответ в виде строки

    ТекстовыйФайлОтвет = Новый ТекстовыйДокумент;
    ТекстовыйФайлОтвет.Прочитать(ФайлРезультата,КодировкаТекста.UTF8);
    СтрокаРезультат = ТекстовыйФайлОтвет.ПолучитьТекст();

    // постобработка xml:
    СтрокаРезультат = СтрЗаменить(СтрокаРезультат,"<soap:Envelope xmlns:soap=""http://schemas.xmlsoap.org/soap/envelope/"" xmlns:xsi=""http://www.w3.org/2001/XMLSchema-instance"" xmlns:xsd=""http://www.w3.org/2001/XMLSchema""><soap:Body>","");
    СтрокаРезультат = СтрЗаменить(СтрокаРезультат,"</soap:Body></soap:Envelope>","");
    СтрокаРезультат = СтрЗаменить(СтрокаРезультат, "xmlns=""http://tempuri.org/""","xmlns=""http://tempuri.org/"" xmlns:xsi=""http://www.w3.org/2001/XMLSchema-instance"" xmlns:xs=""http://www.w3.org/2001/XMLSchema""");
    
    Попытка
        ТипGetPtsListResponse = ФабрикаXDTO.Тип("http://tempuri.org/","GetPtsListResponse");

        Чтение = Новый ЧтениеXML;
        Чтение.УстановитьСтроку(СтрокаРезультат);
        ОбъектXDTO = ФабрикаXDTO.ПрочитатьXML(Чтение,ТипGetPtsListResponse);
    Исключение
        ЗаписьЖурналаРегистрации("GetMethodName",
                                УровеньЖурналаРегистрации.Ошибка,
                                ,,ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));    
    КонецПопытки;
    
    // уборка
    Попытка
        УдалитьФайлы(ФайлЗапроса);
        УдалитьФайлы(ФайлРезультата);
    Исключение
        
    КонецПопытки;
    
    Возврат ОбъектXDTO;
    
КонецФункции

Реализация функция GET-запроса и POST-запроса:

// Выполняет прозвольный POST-запрос
Функция ВыполнитьPOSTЗапрос(Соединение, АдресРесурса, ЗаголовкиЗапроса, ДанныеЗапроса) Экспорт
    
    СтруктураРезультат = Новый Структура;

    Запрос = Новый HTTPЗапрос(АдресРесурса,ЗаголовкиЗапроса); 

    Запрос.УстановитьТелоИзСтроки(ДанныеЗапроса); 
    Ответ = Соединение.ОтправитьДляОбработки(Запрос); 
    ОтветВВидеСтроки = Ответ.ПолучитьТелоКакСтроку("UTF-8"); 

    СтруктураРезультат.Вставить("Ответ",Ответ);
    СтруктураРезультат.Вставить("ТекстОтвета",ОтветВВидеСтроки);
    
    Возврат СтруктураРезультат;

КонецФункции

// Выполняет произвольный GET-запрос
Функция ВыполнитьGETЗапрос(Соединение, АдресРесурса, ЗаголовкиЗапроса) Экспорт
    
    СтруктураРезультат = Новый Структура;
    
    ИмяВыходногоФайлаGET = ПолучитьИмяВременногоФайла("txt");
    HTTPЗапросGET = Новый HTTPЗапрос(АдресРесурса,ЗаголовкиЗапроса);
    HTTPОтветGET = Соединение.Получить(HTTPЗапросGET,ИмяВыходногоФайлаGET);
    
    КодСостоянияGET = HTTPОтветGET.КодСостояния;
    ТекстОтветаGET = HTTPОтветGET.ПолучитьТелоКакСтроку();    
    
    ЧтениеФайла = Новый ТекстовыйДокумент;
    ЧтениеФайла.Прочитать(ИмяВыходногоФайлаGET);
    
    ТекстОтвета = ЧтениеФайла.ПолучитьТекст();
    
    СтруктураРезультат.Вставить("Ответ",HTTPОтветGET);
    СтруктураРезультат.Вставить("ТекстОтвета",ТекстОтвета);
    
    Попытка
        УдалитьФайлы(ИмяВыходногоФайлаGET);
    Исключение
        
    КонецПопытки;
    
    Возврат СтруктураРезультат;

КонецФункции

В результате получилось использовать методы soap-сервисов поставщика с предварительной аутентфикацией посредством cookie.

Скорее всего, можно сделать более красивой сборку текста xml-запроса, но это уже в следующей статье!

soap веб-сервисы аутентификация cookie

См. также

Интеграция Альфа Авто 5 / Альфа Авто 6 и AUTOCRM / Инфотек

Сайты и интернет-магазины WEB-интеграция Платформа 1С v8.3 Конфигурации 1cv8 1С:Управление торговлей 11 Автомобили, автосервисы Россия Управленческий учет Платные (руб)

Интеграционный модуль обмена между конфигурацией Альфа Авто 5 и Альфа Авто 6 и порталом AUTOCRM. Данный модуль универсален. Позволяет работать с несколькими обменами AUTOCRM разных брендов в одной информационной базе в ручном и автоматическом режиме.

36000 руб.

03.08.2020    15750    10    17    

11

Интеграция 1С — Битрикс24. Обмен задачами

Сайты и интернет-магазины Интеграция WEB-интеграция Платформа 1С v8.3 Конфигурации 1cv8 Управленческий учет Платные (руб)

Интеграция 1С и Битрикс24. Разработка имеет двухстороннюю синхронизацию 1С и Битрикс24 задачами. Решение позволяет создавать пользователя в 1С из Битрикс24 и наоборот. Данная разработка технически подходит под все основные конфигурации линейки продуктов 1С:Предприятие 8.3 (8.3.18.1289). При приобретении предоставляется 1 месяц бесплатных обновлений разработки. Доступна демо-версия продукта с подключением Вашего Битрикс24

5040 руб.

04.05.2021    17557    6    15    

13

Интеграция с сервисом vetmanager

WEB-интеграция Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Бытовые услуги, сервис Платные (руб)

Внешняя обработка разрабатывалась для загрузки документов из Ветменеджер в 1С: Бухгалтерия 3.0

12000 руб.

02.02.2021    16363    42    49    

23

[Расширение] БОР-Навигатор.Культура

Зарплата Бюджетный учет WEB-интеграция Обмен с ГосИС Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и кадры государственного учреждения 3 Государственные, бюджетные структуры Россия Бюджетный учет Платные (руб)

Расширение конфигурации, включающее в себя объекты, необходимые для подготовки и сдачи отчета "Штатная численность" системы "БОР-Навигатор.Культура" в программе "1С:Зарплата и кадры государственного учреждения", редакция 3.1.

8400 руб.

01.02.2019    25746    9    0    

7

Заполнение по ИНН или наименованию реквизитов контрагента по данным сайта ФНС

Обмен с ГосИС WEB-интеграция Платформа 1С v8.3 Управляемые формы 1С:Комплексная автоматизация 1.х 1С:Бухгалтерия 2.0 1С:Управление торговлей 10 1С:Управление производственным предприятием 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия государственного учреждения 1С:Документооборот 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Платные (руб)

Обработка является альтернативой механизму, разработанному фирмой 1С и заполняющему реквизиты контрагента по ИНН или наименованию. Не требуется действующей подписки ИТС. Вызывается как внешняя дополнительная обработка, т.е. используется, непосредственно, из карточки контрагента. Заполнение по ИНН или наименованию реквизитов контрагента по данным сайта ФНС (egrul.nalog.ru) для БП 2.0, БП 3.0, БГУ 1.0, БГУ 2.0, УТ 10.3, УТ 11.x, КА 1.1, КА 2.x, УПП 1.x, ERP 2.x, УНФ 1.5, УНФ 1.6, УНФ 3.0, ДО 2.1

2400 руб.

28.04.2016    88589    160    215    

318
Оставьте свое сообщение