Программное отключение сеансов 1С 8.2.
База данных - Инструменты администратора БД
Причины возникновения проблемы
Лично у меня на релизах от 8.2.9.х до текущего 8.2.12.96 не всегда происходит полное отключение сеансов. Например, устанавливаю обновление, умный конфигуратор мне выдает кнопку "Завершить сеансы и продолжить", после нажатия на которую остается несколько подключенных соединений.
Также в течение дня часто остаются соединения по закрытым сеансам.
Зачем это нужно
Для себя нашел два пути применения:
1. Перед инсталляцией обновлений необходимо отключить пользователей от системы;
2. Регламентное задание, отвечающее за резервное копирование, должно отключить все подключенные сеансы.
В первом случае удобство состоит в том, что есть кнопка в режиме предприятия, нажав на которую происходит полное завершение.
Как это сделать
Первое, что нам нужно - это определить имя базы и сервер, на котором она расположена. Для этого разбираем строку соединения базы.
Если Найти(СтрокаСоединенияИнформационнойБазы(), "Srvr") > 0 Тогда
// серверный вариант
Поиск1 = Найти(СтрокаСоединенияИнформационнойБазы(), "Srvr=");
ПодстрокаПоиска = Сред(СтрокаСоединенияИнформационнойБазы(), Поиск1 + 6);
ИмяСервера = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1);
// теперь ищем имя базы
Поиск1 = Найти(СтрокаСоединенияИнформационнойБазы(), "Ref=");
ПодстрокаПоиска = Сред(СтрокаСоединенияИнформационнойБазы(), Поиск1 + 5);
ИмяБазы = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1);
Иначе
// для других способов подключения алгоритм не актуален
Возврат;
КонецЕсли;
Для работы с агентом сервера необходимо использовать COM-объект
Коннектор = Новый COMОбъект("v82.COMConnector");
который позволяет подключится к агенту сервера:
Агент = Коннектор.ConnectAgent(ИмяСервера);
Теперь перебираем все кластеры, в которых учавствует агент:
Кластеры = Агент.GetClusters();
Для каждого Кластер из Кластеры Цикл
Чтобы получить доступ к процессам кластера, необходимо аутентифицироваться, если для кластера задан администратор:
АдминистраторКластера = "Имя администратора кластера";
ПарольКластера = "Пароль администратора кластера";
Агент.Authenticate(Кластер, АдминистраторКластера, ПарольКластера);
если кластер без ограничения доступа, то следует писать так:
Агент.Authenticate(Кластер, , );
Теперь необходимо получить перечень процессов, которые обрабатывают данный кластер:
Процессы = Агент.GetWorkingProcesses(Кластер);
Для каждого Процесс из Процессы Цикл
Т.к. к рабочему процессу необходимо подключаться через коннектор, то необходимо вычислить порт, на котором работает данный процесс:
Порт = Процесс.MainPort;
// теперь есть адрес и порт для подключения к рабочему процессу
РабПроц = Коннектор.ConnectWorkingProcess(ИмяСервера + ":" + СтрЗаменить(Порт, Символы.НПП, ""));
Рабочий процесс необходимо для разрыва соединений. Разрыв сессий происходит через агента. Опишем подробно. Сначала необходимо аутентифицироваться в рабочем процесс по имени и паролю пользователя, у которого в базе данных есть право "Администратор":
РабПроц.AddAuthentication("Имя администратора БД", "Пароль администратора БД");
На этом этапе есть объект агента и рабочего процесса, который обслуживает текущий кластер. Далее необходимо найти искомую базу данных:
ИнформационнаяБаза = "";
Базы = Агент.GetInfoBases(Кластер);
Для каждого База из Базы Цикл
Если База.Name = ИмяБазы Тогда
ИнформационнаяБаза = База;
Прервать;
КонецЕсли;
КонецЦикла;
Если ИнформационнаяБаза = "" Тогда
// база не найдена
КонецЕсли;
Отключение сеансов
Итак у нас есть все необходимые объекты для непосредственного обрыва сессий. При это рекомендую полностью разобраться, какие именно сессии мы будем разрывать, иначе можно отключить сессию, в которой выполняется этот код
:
Сеансы = Агент.GetInfoBaseSessions(Кластер, ИнформационнаяБаза);
Для каждого Сеанс из Сеансы Цикл
Если нРег(Сеанс.AppID) = "backgroundjob" ИЛИ нРег(Сеанс.AppID) = "designer" Тогда
// если это сеансы конфигуратора или фонового задания, то не отключаем
Продолжить;
КонецЕсли;
Если Сеанс.UserName = ИмяПользователя() Тогда
// это текущий пользователь
Продолжить;
КонецЕсли;
Агент.TerminateSession(Кластер, Сеанс);
КонецЦикла;
Также у типа "Сеанс" есть ещё много разных свойств, например, имя компьютера, данные о языке, времени и длительности подключения и тп.
Отключение соединений
Отключение соединений происходит через объект рабочего процесса. Обрабатывает соединение тип "Соединение", у которого структура свойств напоминает тип "Сеанс". Итак, как отключенить соединения:
СоединенияБазы = Агент.GetInfoBaseConnections(Кластер, ИнформационнаяБаза);
// Разорвать соединения клиентских приложений.
Для Каждого Соединение Из СоединенияБазы Цикл
Если нРег(Соединение.Application) = "backgroundjob" ИЛИ нРег(Соединение.Application) = "designer" Тогда
// если это соединение конфигуратора или фонового задания, то не отключаем
Продолжить;
КонецЕсли;
Если Соединение.UserName = ИмяПользователя() Тогда
// это текущий пользователь
Продолжить;
КонецЕсли;
РабПроц.Disconnect(Соединение);
КонецЦикла;
Выводы
Получен пример отключения сеансов и соединений с информационной базы. При должном знании свойств каждого типа (рабочий процесс, агент сервера, сеанс, соединение) можно, например, сделать откючение конкретного пользователя по расписанию (однако, совершенно другой вопрос зачем это делать) либо, используя данные конструкции, написать внешнее приложение, которое будет использовать COM-объект "v82.COMConnector".
P.S.
Для понимающих работу с этими типами: код намеренно раздут, для того, чтобы под отладчиком было удобнее просматривать значения всех типов. Да, некоторые места можно написать короче и элегантнее, однако цель была в наглядности кода.
Код целиком
Если Найти(СтрокаСоединенияИнформационнойБазы(), "Srvr") > 0 Тогда
// серверный вариант
Поиск1 = Найти(СтрокаСоединенияИнформационнойБазы(), "Srvr=");
ПодстрокаПоиска = Сред(СтрокаСоединенияИнформационнойБазы(), Поиск1 + 6);
ИмяСервера = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1);
// теперь ищем имя базы
Поиск1 = Найти(СтрокаСоединенияИнформационнойБазы(), "Ref=");
ПодстрокаПоиска = Сред(СтрокаСоединенияИнформационнойБазы(), Поиск1 + 5);
ИмяБазы = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1);
Иначе
// для других способов подключения алгоритм не актуален
Возврат;
КонецЕсли;
Коннектор = Новый COMОбъект("v82.COMConnector");
Агент = Коннектор.ConnectAgent(ИмяСервера);
Кластеры = Агент.GetClusters();
Для каждого Кластер из Кластеры Цикл
АдминистраторКластера = "Имя администратора кластера";
ПарольКластера = "Пароль администратора кластера";
Агент.Authenticate(Кластер, АдминистраторКластера, ПарольКластера);
Процессы = Агент.GetWorkingProcesses(Кластер);
Для каждого Процесс из Процессы Цикл
Порт = Процесс.MainPort;
// теперь есть адрес и порт для подключения к рабочему процессу
РабПроц = Коннектор.ConnectWorkingProcess(Имяервера + ":" + СтрЗаменить(Порт, Символы.НПП, ""));
РабПроц.AddAuthentication("Имя администратора БД", "Пароль администратора БД");
ИнформационнаяБаза = "";
Базы = Агент.GetInfoBases(Кластер);
Для каждого База из Базы Цикл
Если База.Name = ИмяБазы Тогда
ИнформационнаяБаза = База;
Прервать;
КонецЕсли;
КонецЦикла;
Если ИнформационнаяБаза = "" Тогда
// база не найдена
КонецЕсли;
Сеансы = Агент.GetInfoBaseSessions(Кластер, ИнформационнаяБаза);
Для каждого Сеанс из Сеансы Цикл
Если нРег(Сеанс.AppID) = "backgroundjob" ИЛИ нРег(Сеанс.AppID) = "designer" Тогда
// если это сеансы конфигуратора или фонового задания, то не отключаем
Продолжить;
КонецЕсли;
Если Сеанс.UserName = ИмяПользователя() Тогда
// это текущий пользователь
Продолжить;
КонецЕсли;
Агент.TerminateSession(Кластер, Сеанс);
КонецЦикла;
СоединенияБазы = Агент.GetInfoBaseConnections(Кластер, ИнформационнаяБаза);
// Разорвать соединения клиентских приложений.
Для Каждого Соединение Из СоединенияБазы Цикл
Если нРег(Соединение.Application) = "backgroundjob" ИЛИ нРег(Соединение.Application) = "designer" Тогда
// если это соединение конфигуратора или фонового задания, то не отключаем
Продолжить;
КонецЕсли;
Если Соединение.UserName = ИмяПользователя() Тогда
// это текущий пользователь
Продолжить;
КонецЕсли;
РабПроц.Disconnect(Соединение);
КонецЦикла;
КонецЦикла;
КонецЦикла;
Вступайте в нашу телеграмм-группу Инфостарт
Вы можете заказать платную адаптацию этой статьи под ваши задачи на «Бирже заказов».
- 0% комиссии — оплата напрямую исполнителю;
- Исполнители любого масштаба — от отдельных специалистов до команд под проект;
- Прямой обмен контактами между заказчиком и исполнителем;
- Безопасная сделка — при необходимости;
- Рейтинги, кейсы и прозрачная система откликов.
См. также
Инструментарий разработчика Чистка данных Свертка базы Инструменты администратора БД Системный администратор Разработчик Руководитель проекта 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 Россия Платные (руб)
Инструмент представляет собой обработку для проведения свёртки или обрезки баз данных. Работает на ЛЮБЫХ конфигурациях (УТ, БП, ERP, УНФ, КА и т.д.). Поддерживаются серверные и файловые базы, управляемые и обычные формы, интерфейс 8.5. Может выполнять свертку одновременно в несколько потоков, а также без непосредственного участия пользователя. Решение в Реестре отечественного ПО.
24900 руб.
20.08.2024 84411 436 171
Инструменты администратора БД Инструментарий разработчика Роли и права Разработчик 1С:Предприятие 8 1C:Бухгалтерия Россия Платные (руб)
Расширение позволяет без изменения кода конфигурации выполнять проверки при вводе данных, скрывать от пользователя недоступные ему данные, выполнять код в обработчиках. Не изменяет данные конфигурации, легко устанавливается практически на любую конфигурацию на управляемых формах.
17000 руб.
10.11.2023 28989 104 46
Инструменты администратора БД Роли и права Системный администратор Разработчик Пользователь 1С 8.3 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:Документооборот 1С:Зарплата и кадры государственного учреждения 3 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Платные (руб)
Роли… Вы тратите много времени и сил на подбор ролей среди около 2400 в ERP или 1500 в Рознице 2, пытаясь понять какими правами они обладают? Вы все время смотрите права в конфигураторе или отчетах чтоб создать нормальные профили доступа? Вы хотите наглядно видеть какие права дает профиль и редактировать все в простом виде? А может хотите просто указать подсистему и дать права на просмотр и добавление на объекты и не лезть в дебри прав и чтоб обработка сама подобрала нужные роли? Все это теперь стало возможно! Обновление от 17.04.2026, версия 1.4.1, работает в 1С:ФРЕШ!
23180 руб.
06.12.2023 25247 85 14
Поиск данных Инструменты администратора БД Корректировка данных Разработчик Бухгалтер Пользователь 1С:Предприятие 8 1С:Управление торговлей 10 1С:Управление производственным предприятием 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x 1С:Управление нашей фирмой 3.0 Россия Платные (руб)
Решение для автоматической сверки данных между любыми конфигурациями 1С. Помогает контролировать и проверять обмены, проверять наличие документов при переносах данных, находить изменения в закрытых периодах
9760 руб.
14.11.2025 6347 28 8
Инструментарий разработчика Инструменты администратора БД Системный администратор Разработчик Аналитик 1С:Предприятие 8 1С 8.3 1С 8.5 1C:ERP 1С:УТ 1С:ДО 1С:Бухгалтерия 3.0 1С:ERP. Управление холдингом 1С:Зарплата и Управление Персоналом 3.x 1С:Управление нашей фирмой 3.0 1С:Управление торговлей 11 Россия Платные (руб)
Универсальный инструмент программиста для администрирования конфигураций. Сборник наиболее часто используемых обработок под единым интерфейсом.
5000 руб.
14.01.2013 217730 1256 0
Информационная безопасность Инструменты администратора БД Инструментарий разработчика Учет документов Системный администратор Разработчик Аналитик Бухгалтер Пользователь Руководитель проекта 1С 8.3 1С 8.5 Розничная и сетевая торговля (FMCG) Платные (руб)
Контроль ввода данных в 1С: проверка заполнения реквизитов, обязательные поля, контроль перед записью и проведением, запрет проведения документа. Позволяет настраивать любые проверки данных в 1С 8.3/8.5 от обязательных полей до сложных условий – без открытия конфигуратора и написания кода. Готовое расширение, которое подключается и работает сразу.
6000 руб.
15.04.2026 4350 12 0
Закрытие периода Инструменты администратора БД Корректировка данных Бухгалтер Пользователь 1С:Предприятие 8 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Платные (руб)
Расширение «Оперативное проведение» в 4 раза уменьшает время проведения документов и закрытия месяца. Является комплексным решением проблем 62 и 60 счетов. Оптимизирует проведение при включенной функциональной опции «Раздельный учет НДС». Используется в более 10 организациях уже 2 года. Совместимо с конфигурацией Бухгалтерия 3.0 (+КОРП).
14640 руб.
29.04.2020 53155 146 164
Файловый обмен (TXT, XML, DBF), FTP Поиск данных Инструменты администратора БД Корректировка данных Системный администратор Разработчик 1С:Предприятие 8 1C:Бухгалтерия 1С:Розница 2 1С:Управление нашей фирмой 1.6 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Управление нашей фирмой 3.0 1С:Розница 3.0 Платные (руб)
Данная обработка позволит Вам легко и просто, а главное - быстро, выполнить сравнение данных между ЛЮБЫМИ базами (и РИБ, по правилам конвертаций) по контрольным суммам выбранных объектов баз 1С, работающих на платформах 8.3 и выше. Удобный и понятный интерфейс в виде "мастера". Высокая скорость сравнения достигается за счет специального алгоритма расчета контрольной суммы объекта/записи и сравнения по данным суммам объектов 2х баз через файл. Имеется возможность выбора реквизитов, по которым система будет сравнивать объекты. Сравнение количества записей в движениях документов, возможность сравнивать данные по правилам конвертации и не только! Выбор объектов конфигурации для КАЖДОГО узла в отдельности с индивидуальным отбором для каждого объекта конфигурации, работа с FTP, сохранение или загрузка настроек, сохранение или загрузка результата сравнения, регистрация на обмен объекта и его движений. (Обновление от 12.11.2024, версия 2.2-2.5)
24400 руб.
27.10.2017 47969 33 15
Но есть пару непоняток (для меня):
я заменил "Сервер" на "ИмяСервера" в строке
РабПроц = Коннектор.ConnectWorkingProcess(Сервер + ":" + СтрЗаменить(Порт, Символы.НПП, ""));
и в COMОбъекте Соединение нет значения UserName, т.е. не могу проверить на ИмяПользователя(). Но и в Сеанс, и в Соединение есть SessionID, пришлось выкручиваться через него (получать в Сеанс и проверять в Соединение). UserName только у меня отсутствует? Платформа 8.2.11.236.
РабПроц.Disconnect(Соединение);
по причине:
Типы не совпадают (1)
Как не пробовал, одно и тоже :(
Вариант кода следующий:
Если нРег(Соединение.Application) = "backgroundjob" ИЛИ нРег(Соединение.Application) = "designer" Тогда
// если это соединение конфигуратора или фонового задания, то не отключаем
Продолжить;
КонецЕсли;
//Если Соединение.UserName = ИмяПользователя() Тогда
// // это текущий пользователь
// Продолжить;
//КонецЕсли;
Если (Соединение.Application = ТекПользовательApplication) и (Соединение.ConnId = ТекПользовательConnId) и (Соединение.Host = ТекПользовательHost) Тогда
// это текущий пользователь
Продолжить;
КонецЕсли;
РабПроц.Disconnect(Соединение);
КонецЦикла;
Осталось только разобраться как получить не описание соединений, а сами соединения... :D
ИнформационнаяБаза2 = РабПроц.CreateInfoBaseInfo();
ИнформационнаяБаза2.Name = ИмяБазы;
Соединения = РабПроц.GetInfoBaseConnections(ИнформационнаяБаза2);
При этом проверять запущенные приложения нужно не по Соединение.Application, а по Соединение.AppID. Плюс не мешало бы добавить проверку не только backgroundjob, designer, а и comconsole - а то выкинет и только что аутентифицированное COM-соединение...
Все вышесказанное абсолютно не претендует на истину - пробуйте на свой страх и риск... :D
"Плюс не мешало бы добавить проверку не только backgroundjob, designer, а и comconsole - а то выкинет и только что аутентифицированное COM-соединение... " я показал лишь пример, дальше можно расширять как угодно :) моей целью было НЕ убивать текущее фоновое задание и НЕ закрывать конфигуратор, в котором я могу что-то не сохранить :) да и вообще сама идея мочить конфигуратор - ужас.
(4) Модуль довольно специфичен, но суть проста. Объясню на примере:
01:00 запуск регламетного задания, которое генерирует *.bat файл пакетного запуска конфигуратора в режиме выгрузки ИБ, после чего мочит все соединения
01:20 регламентное задание винды стартует *.bat файл.
Поделиться можно, но там код весь на константах и не очень красив, чтобы на люди показывать :)
Если Соединение.UserName = ИмяПользователя() Тогда
// это текущий пользователь
Продолжить;
КонецЕсли;
ИМХО, чтобы не убить своё собственное соединение лучше использовать проверку на SessionID (ConnID), который есть и в соединении (сеансе). Получить SessionID (ConnID) текущего (своего) подключения можно через НомерСеансаИнформационнойБазы() (НомерСоединенияИнформационнойБазы()).
При подключении к Агенту выдает такую ошибку:
{Форма.Форма.Форма(108)}: Ошибка при вызове метода контекста (ConnectAgent)
СлужбаСервера = Соединитель.ConnectAgent(СерверБД);
по причине:
Произошла исключительная ситуация (V82.COMConnector.1): descr=Сервер недоступен (Не отвечает, завершается аварийно или порт занят другим приложением) line=556 file=Src\RemoteCreatorImpl.cpp
Кто нибудь с такой сталкивался?
Заменил строку - все заработало:
//ИмяСервера = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1); //для стандартного порта (1541)
ИмяСервера = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 6); //для не стандартного порта (7) artur.antipin,
Тоже столкнулся с этой проблемой.
//ИмяСервера = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1); //для стандартного порта (1541)
ИмяСервера = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 6); //для не стандартного порта (7) artur.antipin,
Вот не уверен, что это правильно.
Вообще говоря, то ИмяСервера (включая порт), которое мы получаем таким образом, это адрес кластера 1с, на котором крутится эта база. Если порт стандартный, то он совпадает с именем сервера (читай агента сервера). Если порты не стандартные - то они разные.
Так вот. Если вы просто обрежете порт из адреса кластера, то получите обращение по стандартному порту, т.е. 1541, и скорее всего, попадете на другой сервер, не тот, на котором крутится данная база.
Вот в связи с этим вопрос: можно ли как то узнать полный адрес агента сервера, на котором крутится эта база?
вот обобщенный (рабочий!) вариант:
Если Найти(СтрокаСоединенияИнформационнойБазы(), "Srvr") > 0 Тогда
// серверный вариант
Поиск1 = Найти(СтрокаСоединенияИнформационнойБазы(), "Srvr=");
ПодстрокаПоиска = Сред(СтрокаСоединенияИнформационнойБазы(), Поиск1 + 6);
ИмяСервера = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1);
// теперь ищем имя базы
Поиск1 = Найти(СтрокаСоединенияИнформационнойБазы(), "Ref=");
ПодстрокаПоиска = Сред(СтрокаСоединенияИнформационнойБазы(), Поиск1 + 5);
ИмяБазы = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1);
Иначе
// для других способов подключения алгоритм не актуален
Возврат;
КонецЕсли;
Коннектор = Новый COMОбъект("v82.COMConnector");
Агент = Коннектор.ConnectAgent(ИмяСервера);
Кластеры = Агент.GetClusters();
Для каждого Кластер из Кластеры Цикл
АдминистраторКластера = "Имя администратора кластера";
ПарольКластера = "Пароль администратора кластера";
//Агент.Authenticate(Кластер, АдминистраторКластера, ПарольКластера);
Агент.Authenticate(Кластер,,);
Процессы = Агент.GetWorkingProcesses(Кластер);
Для каждого Процесс из Процессы Цикл
Порт = Процесс.MainPort;
// теперь есть адрес и порт для подключения к рабочему процессу
РабПроц = Коннектор.ConnectWorkingProcess(ИмяСервера + ":" + СтрЗаменить(Порт, Символы.НПП, ""));
РабПроц.AddAuthentication("admin", "pass");
ИнформационнаяБаза = "";
Базы = Агент.GetInfoBases(Кластер);
Для каждого База из Базы Цикл
Если База.Name = ИмяБазы Тогда
ИнформационнаяБаза = База;
Прервать;
КонецЕсли;
КонецЦикла;
Если ИнформационнаяБаза = "" Тогда
// база не найдена
КонецЕсли;
Сеансы = Агент.GetInfoBaseSessions(Кластер, ИнформационнаяБаза);
Для каждого Сеанс из Сеансы Цикл
Если нРег(Сеанс.AppID) = "backgroundjob" ИЛИ нРег(Сеанс.AppID) = "comconsole" Тогда
// если это сеансы com-приложения или фонового задания, то не отключаем
Продолжить;
КонецЕсли;
Если Сеанс.UserName = ИмяПользователя() Тогда
// это текущий пользователь
Продолжить;
КонецЕсли;
Агент.TerminateSession(Кластер, Сеанс);
Сообщить("Отключен сеанс "+строка(Сеанс.UserName));
КонецЦикла;
ИнформационнаяБаза2 = РабПроц.CreateInfoBaseInfo();
ИнформационнаяБаза2.Name = ИмяБазы;
СоединенияБазы = РабПроц.GetInfoBaseConnections(ИнформационнаяБаза2);
// Разорвать соединения клиентских приложений.
Для Каждого Соединение Из СоединенияБазы Цикл
Если нРег(Соединение.AppID) = "backgroundjob" ИЛИ нРег(Соединение.AppID) = "comconsole" Тогда
Продолжить;
КонецЕсли;
Если Соединение.UserName = ИмяПользователя() Тогда
// это текущий пользователь
Продолжить;
КонецЕсли;
РабПроц.Disconnect(Соединение);
КонецЦикла;
КонецЦикла;
КонецЦикла;
Предупреждение("Завершается работа...", 5);
ЗавершитьРаботуСистемы(Ложь);
запускаю из батника
C:\"Program Files"\1cv82\8.2.13.219\bin\1cv8.exe ENTERPRISE /sИмяСервера\ИмяБазы /nПользователь /pПароль /wa- /DisableStartupMessages /RunModeOrdinaryApplication /ExecuteShutdownusers.epf
Shutdownusers.epf - в этой внешней обработке код
Если ВРЕГ(База.Name) = ВРЕГ(ИмяБазы) Тогда
ИнформационнаяБаза = База;
Прервать;
КонецЕсли;
Соединение.UserName = ИмяПользователя()
ERROR:
Поле объекта не обнаружено (UserName)
FAQ:
Соединение (IInfoBaseConnectionInfo)
UserName (UserName)
Использование:
Только чтение.
Описание:
Тип: Строка.
Содержит имя пользователя 1С:Предприятия, подсоединенного к информационной базе.
Доступность:
Интеграция.
Что не так???
У меня такая же проблема
сделал так
ТекПользовательApplication = "";
ТекПользовательConnId = "";
ТекПользовательHost = "";
Сеансы = Агент.GetInfoBaseSessions(Кластер, ИнформационнаяБаза);
Для каждого Сеанс из Сеансы Цикл
Если нРег(Сеанс.AppID) = "backgroundjob" ИЛИ нРег(Сеанс.AppID) = "designer" Тогда
// если это сеансы конфигуратора или фонового задания, то не отключаем
Продолжить;
КонецЕсли;
Если Сеанс.UserName = ИмяПользователя() Тогда
// это текущий пользователь
ТекПользовательApplication = Сеанс.Connection.Application;
ТекПользовательConnId = Сеанс.Connection.ConnId;
ТекПользовательHost = Сеанс.Connection.Host;
Продолжить;
КонецЕсли;
Агент.TerminateSession(Кластер, Сеанс);
Сообщить(строка(Сеанс.UserName) + " - " + нРег(Сеанс.AppID));
КонецЦикла;
СоединенияБазы = Агент.GetInfoBaseConnections(Кластер, ИнформационнаяБаза);
// Разорвать соединения клиентских приложений.
Для Каждого Соединение Из СоединенияБазы Цикл
Если нРег(Соединение.Application) = "backgroundjob" ИЛИ нРег(Соединение.Application) = "designer" Тогда
// если это соединение конфигуратора или фонового задания, то не отключаем
Продолжить;
КонецЕсли;
//Если Соединение.UserName = ИмяПользователя() Тогда
// // это текущий пользователь
// Продолжить;
//КонецЕсли;
Если (Соединение.Application = ТекПользовательApplication) и (Соединение.ConnId = ТекПользовательConnId) и (Соединение.Host = ТекПользовательHost) Тогда
// это текущий пользователь
Продолжить;
КонецЕсли;
РабПроц.Disconnect(Соединение);
КонецЦикла;
В таком варианте не возникает ошибка
Если Найти(СтрокаСоединенияИнформационнойБазы(), "Srvr") > 0 Тогда
// серверный вариант
Поиск1 = Найти(СтрокаСоединенияИнформационнойБазы(), "Srvr=");
ПодстрокаПоиска = Сред(СтрокаСоединенияИнформационнойБазы(), Поиск1 + 6);
ИмяСервера = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1);
// теперь ищем имя базы
Поиск1 = Найти(СтрокаСоединенияИнформационнойБазы(), "Ref=");
ПодстрокаПоиска = Сред(СтрокаСоединенияИнформационнойБазы(), Поиск1 + 5);
ИмяБазы = Лев(ПодстрокаПоиска, Найти(ПодстрокаПоиска, """") - 1);
Иначе
// для других способов подключения алгоритм не актуален
Возврат;
КонецЕсли;
Коннектор = Новый COMОбъект("v82.COMConnector");
Агент = Коннектор.ConnectAgent(ИмяСервера);
Кластеры = Агент.GetClusters();
Для ТекущийИндекс = Кластеры.GetLowerBound() По Кластеры.GetUpperBound() Цикл
// Ищем нужный нам кластер
Кластер = Кластеры.GetValue(ТекущийИндекс);
Если (ВРЕГ(Кластер.HostName) = ИмяСервера) Тогда
Прервать;
КонецЕсли
КонецЦикла;
Если Кластер = НЕОПРЕДЕЛЕНО Тогда
Сообщить("Не удалось определить рабочий кластер серверов 1С предприятия", СтатусСообщения.Важное);
Возврат;
КонецЕсли;
Агент.Authenticate(Кластер, , );
РабочиеСервера = Агент.GetWorkingServers(Кластер);
Для Каждого РабочийСервер Из РабочиеСервера Цикл
РабочиеПроцессы = Агент.GetServerWorkingProcesses(Кластер, РабочийСервер);
Если РабочиеПроцессы <> НЕОПРЕДЕЛЕНО Тогда
Для Каждого Процесс Из РабочиеПроцессы Цикл
Если Процесс.Running <> 1 Тогда
Продолжить; //Не тратим время на неработающие процессы
КонецЕсли;
ЕстьРегПроцесса = Ложь;
СтрокаСоединения = "TCP://" + Процесс.HostName+":"+XMLСтрока(Процесс.MainPort);
РабПроц = Коннектор.ConnectWorkingProcess(СтрокаСоединения);
Если РабПроц <> Неопределено Тогда
Базы = РабПроц.GetInfoBases();
Если Базы <> НЕОПРЕДЕЛЕНО Тогда
Для Каждого База ИЗ Базы Цикл
// Ищем нашу базу
Если База.Name <> ИмяБазы Тогда
Продолжить;
КонецЕсли;
// Восстановим админское подключение к базе (в случае ошибки и при переходе на другой рабочий процесс)
Если НЕ ЕстьРегПроцесса Тогда
Попытка
РабПроц.AddAuthentication(ИмяАдминистратора, ПарольАдминистратора);
ЕстьРегПроцесса=Истина;
Исключение
Сообщить(ОписаниеОшибки(), СтатусСообщения.Важное);
КонецПопытки;
КонецЕсли;
// Получим и обойдем все соединения с нашей базой в текущем рабочем процессе
СоединенияБазы = РабПроц.GetInfoBaseConnections(База);
Если СоединенияБазы <> НЕОПРЕДЕЛЕНО Тогда
Для Каждого Соединение Из СоединенияБазы Цикл
UserName = Соединение.UserName;
ConnID = Соединение.ConnID;
AppID = НРег(Соединение.AppID);
Если AppID = "backgroundjob" ИЛИ AppID = "designer" ИЛИ AppID = "comconsole" Тогда
// если это соединение конфигуратора, фонового задания или наше COM-соединение или то не отключаем
Продолжить;
КонецЕсли;
Попытка
Если UserName = ИмяПользователя() И ConnID <> НомерСоединенияИнформационнойБазы() Тогда
Сообщить("Отключено соединение: " + "User=["+UserName+"] ConnID=["+ConnID+"] AppID=["+AppID+"]", СтатусСообщения.Важное);
РабПроц.Disconnect(Соединение);
КонецЕсли;
Исключение
ЕстьРегПроцесса=Ложь;
КонецПопытки;
КонецЦикла; // По соединениям
Соединение = НЕОПРЕДЕЛЕНО;
СоединенияБазы = НЕОПРЕДЕЛЕНО;
КонецЕсли;
КонецЦикла; // По базам
База = НЕОПРЕДЕЛЕНО;
Базы = НЕОПРЕДЕЛЕНО;
КонецЕсли;
КонецЕсли;
КонецЦикла; // по рабочим процессам
КонецЕсли;
РабПроц = НЕОПРЕДЕЛЕНО;
Процесс = НЕОПРЕДЕЛЕНО;
РабочиеПроцессы = НЕОПРЕДЕЛЕНО;
КонецЦикла; // по серверам ПоказатьОт себя добавлю: если администратор кластера не указан, то аутентификацию к агенту сервера нужно осуществлять кодом:
АгентСервера.Authenticate(Кластер,"","");Если подключаться так, как указано в статье
Агент.Authenticate(Кластер,,);то будет ошибка: "Указанное число параметров не соответствует ожидаемому числу".
мМассивСтрокиСоединения = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(СтрокаСоединенияИнформационнойБазы(),";");
мСтрокаИБ = мМассивСтрокиСоединения[0];
мСтрокаИБ = СтрЗаменить(мСтрокаИБ,"Srvr=","");
СерверПорт = СтрЗаменить(мСтрокаИБ,"""","");
мМассивСерверПорт = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(СерверПорт,":");
Если мМассивСерверПорт.Количество() > 1 Тогда
Сервер = мМассивСерверПорт[0];
Порт = СтрЗаменить(Строка(Число(мМассивСерверПорт[1])-1), Символы.НПП, "");
ИначеЕсли мМассивСерверПорт.Количество() = 1 Тогда
Сервер = мМассивСтрокиСоединения[0];
Порт = 1540;
Иначе
Сервер = "localhost";
Порт = 1540;
КонецЕсли;
мСтрокаИБ = мМассивСтрокиСоединения[1];
мСтрокаИБ = СтрЗаменить(мСтрокаИБ,"Ref=","");
База = СтрЗаменить(мСтрокаИБ,"""","");
Соединение с рабочим процессом (IWorkingProcessConnection)
CreateInfoBase (CreateInfoBase)
Синтаксис:
CreateInfoBase(<ИнформационнаяБаза>, <Режим>)
Параметры:
<ИнформационнаяБаза> (обязательный)
Тип: Информационная база.
Информационная база. Все свойства, необходимые для создания информационной базы (Name, dbServerName, dbName, dbUser, dbPassword, Locale, [DateOffset]) должны быть заполнены.
<Режим> (обязательный)
Тип: Число.
Режим создания информационной базы:
0 - при создании информационной базы базу данных не создавать;
1 - при создании информационной базы создавать базу данных.
Возвращаемое значение:
Тип: Информационная база.
Описание:
Создает информационную базу с заданными параметрами. Требуется аутентификация администратора кластера.
Доступность:
Интеграция.
TerminateSession() - убиваем сеансы
GetInfoBaseConnections() - получаем соединения
Disconnect() - убиваем соединения
А как быть с блокировками?
GetInfoBaseLocks() - получаем блокировки
А как их убрать??
Получилось такая ситуация, что при обновлении конфигурации возникает ошибка исключительной блокировки ИБ. Т.к. есть некие зависшие соединения. Эти соединения видны через консоль кластера только в Блокировках. В сеансах и в соединениях - пусто. Как программно решить эту проблему?
До
РабочийПроцес.AddAuthentication("test","pass");
СписокСоединенийСбазой = РабочийПроцес.GetInfoBaseConnections(ИнфоБаза);
для Каждого стр из СписокСоединенийСбазой Цикл
Если нРег(стр.AppID) = "backgroundjob" ИЛИ нРег(стр.AppID) = "comconsole" Тогда
Продолжить;
КонецЕсли;
РабочийПроцес.Disconnect(стр);
//Сообщить(стр.userName);
КонецЦикла; Показатьнужно через процессы сервера получать строку запуска процесса 1с там смотреть порт видимо.
И получив их удалить ?
Ни в переменную "Сеансы", ни в переменную "СоединенияБазы" не попали HTTP-сервисы.
Хотя они точно есть - в Конфигураторе, в "Параметрах отладки" я их вижу.
СерверПорт = НРег( НСтр(СтрокаСоединенияИнформационнойБазы(), "Srvr") );
мСтроки = СтрРазделить( СерверПорт , ":" );
СерверИмя = мСтроки[0];
//СерверПорт = ?( мСтроки.Количество() > 1, мСтроки[1], "");
ИмяБазы = НРег( НСтр(СтрокаСоединенияИнформационнойБазы(), "Ref") );
ПоказатьРейтинг: 359
Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.
№ 77671
Создание 04.11.10 12:19
Обновление 08.11.10 11:21
Просмотры 107181
Загрузки 0
Рейтинг
240
Комментарии 59
Код открыт Не указано
Рубрики Инструменты администратора БД
Кому Разработчик
Тип файла Нет файла
Платформа 1С:Предприятие 8
Конфигурация 1C:Бухгалтерия
Операционная система Не имеет значения
Страна Россия
Отрасль Не имеет значения
Налоги Не имеет значения
Вид учета Не имеет значения
Доступ к файлу Бесплатно (free)