Вывод всей истории в задаче комплексного процесса

//Заменить текст Функции ОбзорЗадачВызовСервераПереопределяемый.ПолучитьОбзорЗадачи
Функция ПолучитьОбзорЗадачи(Задача) Экспорт
	// Было	
	//HTMLТекст = "";
	//
	//Возврат HTMLТекст;
////////////////////////////////////////////////////////////­////////////////////////
// КопиПаста(ОбзорЗадачВызовСервера.ПолучитьОбзорЗадачи()) Начало

//....СЮДА вставляется кусок текста стандартного модуля

	// История выполнения
// КопиПаста(ОбзорЗадачВызовСервера.ПолучитьОбзорЗадачи()) Конец
////////////////////////////////////////////////////////////­////////////////////////
	HTMLТекст = HTMLТекст + ПолучитьИсториюВыполненияHTML(Задача);
	HTMLТекст = HTMLТекст + "</td>";
	HTMLТекст = HTMLТекст + "</tr></table>";
	HTMLТекст = HTMLТекст + "</body></html>";
	Возврат HTMLТекст;
КонецФункции


//Добавить в конец модуля
Функция ПолучитьИсториюВыполненияHTML(Задача)
	ТЗПодчБизнесПроцессы = Новый ТаблицаЗначений;
	ТЗПодчБизнесПроцессы.Колонки.Добавить("БизнесПроцесс");
	ТЗПодчБизнесПроцессы.Колонки.Добавить("ДатаДляСортировки");

	УстановитьПривилегированныйРежим(Истина);
	ВыводимИсторию			= Ложь;
	ИсторияВыполненияHTML	= "";
	
	//Узнаем самый главный БизнессПроцесс
	ГлавныйБизнесПроцесс = Неопределено;
	ГлавнаяВедущаяЗадачаСсылка = Задача;
	Пока ГлавнаяВедущаяЗадачаСсылка <> Неопределено Цикл
		ГлавныйБизнесПроцесс = ГлавнаяВедущаяЗадачаСсылка.БизнесПроцесс;
		ГлавнаяВедущаяЗадачаСсылка = ПолучитьГлавнуюВедущуюЗадачу(ГлавнаяВедущаяЗадачаСсылка.БизнесПроцесс);
	КонецЦикла;
	
	//История по единичному Бизнес-процессу
	Если ГлавныйБизнесПроцесс = Неопределено ИЛИ ГлавныйБизнесПроцесс = Задача.БизнесПроцесс Тогда
		ИсторияВыполненияHTML = ПреобразоватьИсторияВыполненияHTML(РегистрыСведений.ИсторияВыполненияЗадач.ИсторияПоБизнесПроцессу(Задача.БизнесПроцесс));
	Иначе
		//Обработаем дерево Бизнес-процессов
		ТЗРезультат = ПолучитьПодчиненныеБизнесПроцесы(ГлавныйБизнесПроцесс);
		ЗаполнитьДеревоБПДетально(ТЗРезультат, ТЗПодчБизнесПроцессы);
		ТЗПодчБизнесПроцессы.Сортировать("ДатаДляСортировки Убыв");
		Для каждого ТекБП из ТЗПодчБизнесПроцессы Цикл
			ИсторияВыполненияHTML = ИсторияВыполненияHTML
				+ ПреобразоватьИсторияВыполненияHTML(РегистрыСведений.ИсторияВыполненияЗадач.ИсторияПоБизнесПроцессу(
				ТекБП.БизнесПроцесс),"БП: "+СокрЛП(ТекБП.БизнесПроцесс));
		КонецЦикла;
	КонецЕсли;
	Возврат ИсторияВыполненияHTML;
КонецФункции

Функция ПреобразоватьИсторияВыполненияHTML(ИсторияВыполнения, ЗаголовокИстории = "История выполнения:")
	Если ЗначениеЗаполнено(ИсторияВыполнения) Тогда
		ИсторияВыполненияHTML = "<p>";
		ОбзорОбъектовКлиентСервер.ДобавитьПодпись(ИсторияВыполненияHTML, ЗаголовокИстории);
		ИсторияВыполненияHTML = ИсторияВыполненияHTML + "";	
		ОбзорОбъектовКлиентСервер.ДобавитьРеквизит(ИсторияВыполненияHTML, "", ИсторияВыполнения);
		ИсторияВыполненияHTML = СтрЗаменить(ИсторияВыполненияHTML, Символы.Таб, "   ");
		ИсторияВыполненияHTML = СтрЗаменить(ИсторияВыполненияHTML, Символы.ПС+Символы.ПС, "");
		ИсторияВыполненияHTML = СтрЗаменить(ИсторияВыполненияHTML, Символы.ПС, "");
		Возврат ИсторияВыполненияHTML;
	Иначе
		Возврат "";
	КонецЕсли;
КонецФункции
	
Функция ПолучитьГлавнуюВедущуюЗадачу(ИскомыйПроцессСсылка)
	врИскомыйПроцесс = ИскомыйПроцессСсылка.ПолучитьОбъект();
	Если ЗначениеЗаполнено(врИскомыйПроцесс.ВедущаяЗадача) Тогда
		Возврат врИскомыйПроцесс.ВедущаяЗадача;
	КонецЕсли;
	Попытка
		Если ЗначениеЗаполнено(врИскомыйПроцесс.ГлавнаяЗадача) Тогда
			Возврат врИскомыйПроцесс.ГлавнаяЗадача;
		КонецЕсли;
	Исключение
	КонецПопытки;
	Возврат Неопределено;
КонецФункции

Функция ПолучитьПодчиненныеБизнесПроцесы(ГлавныйБизнесПроцесс)
	Запрос = Новый Запрос(
	"ВЫБРАТЬ
	|	ДочерниеБизнесПроцессы.ДочернийПроцесс КАК БизнесПроцесс,
	|	ВЫБОР
	|		КОГДА ДочерниеБизнесПроцессы.ДочернийПроцесс.Завершен
	|			ТОГДА ДочерниеБизнесПроцессы.ДочернийПроцесс.ДатаЗавершения
	|		ИНАЧЕ ДочерниеБизнесПроцессы.ДочернийПроцесс.ДатаНачала
	|	КОНЕЦ КАК ДатаДляСортировки
	|ИЗ
	|	РегистрСведений.ДочерниеБизнесПроцессы КАК ДочерниеБизнесПроцессы
	|ГДЕ
	|	ДочерниеБизнесПроцессы.РодительскийПроцесс = &БизнесПроцесс");		
	Запрос.УстановитьПараметр("БизнесПроцесс", ГлавныйБизнесПроцесс);
	Возврат Запрос.Выполнить().Выгрузить();
КонецФункции

Процедура ЗаполнитьДеревоБПДетально(ТЗПодчинБП, ТЗПодчБизнесПроцессы)
	Для Каждого стрРез Из ТЗПодчинБП Цикл
		ЗаполнитьЗначенияСвойств(ТЗПодчБизнесПроцессы.Добавить(), стрРез);
		ТЗПодчинБП2 = ПолучитьПодчиненныеБизнесПроцесы(стрРез.БизнесПроцесс);
		Если ТЗПодчинБП2.Количество()>0 Тогда
			ЗаполнитьДеревоБПДетально(ТЗПодчинБП2, ТЗПодчБизнесПроцессы);
		КонецЕсли;
	КонецЦикла;
КонецПроцедуры