Мониторинг активности пользователя

11.10.18

База данных - Журнал регистрации

Работает ли пользователь с программой? Сколько времени пользователь работает в программе? Что пользователь делает в программе? - эти вопросы стандартно решаются или просмотром журнала регистрации, или с помощью внешних программ. В данной статье будет предложен способ, как следить за активностью пользователей, используя небольшую доработку конфигурации. Бонусом системы мониторинга является автоматическое завершение сеансов пользователей, не работающих с программой длительное время.

В журнале регистрации мы видим только вход/выход из программы и операции по изменению данных. Если пользователь просматривает отчеты, документы, то мы особо ничего не увидим, только вход и выход. Как понять, работает пользователь в программе или нет?

Основная идея

Если абстрагироваться от конкретных функций, выполняемых пользователем, то внешне работа пользователя заключается в открытии окон, перемещении курсора, вводе значений в поля формы. Таким образом, если  список открытых окон в программе не меняется, а активное поле остается тем же самым, то значит пользователь не работает с программой, даже если программа открыта. Другой способ отслеживать активность пользователя описан здесь, он заключается в проверке движений мышью/нажатий клавиатуры.

Получить список окон можно с помощью функции ПолучитьОкна(), доступной на клиенте. Каждое окно содержит список форм. Проверить активность формы можно с помощью функции формы ВводДоступен(). Текущий элемент формы можно получить у свойства формы ТекущийЭлемент.

Регистр сведений "Активность пользователей"

Чтобы понять, изменилось ли что-нибудь за некоторый интервал времени,  нужно хранить предыдущее состояние окон программы. Очевидно, что хранить весь список окон и форм особого смысла нет, поэтому будем по строке, полученной склеиванием заголовков окон и форм, вычислять хеш-функцию, и записывать значение хеша в регистре сведений. 

Тогда структура регистра  АктивностьПользователей будет выглядеть следующим образом:

Измерения:

  • Пользователь (тип "СправочникСсылка.Пользователи")
  • НомерСеанса (тип "Число")

Ресурсы:

  • Хеш (тип "Число")

Реквизиты:

  • Комментарий (тип "Строка")
  • Ссылка (тип "ЛюбаяСсылка")

Периодический (в пределах секунды), режим записи независимый.

Комментарий и ссылка позволяют записать с каким окном и с каким объектом базы данных работал пользователь. Номер сеанса нужен для того, чтобы исключить ситуацию, когда один пользователь запустил два окна программы и "ушел". По номеру сеанса можно их различать и смотреть активность по каждому сеансу.

Как регистрировать активность пользователя?

Чтобы зарегистрировать активность пользователя программы, нужно периодически сканировать список открытых окон и форм в программе. Для этого нужно подключить обработчик ожидания. Это можно сделать из модуля управляемого приложения.

Модификация модуля управляемого приложения  

В процедуре  ПриНачалеРаботыСистемы() модуля управляемого приложения нужно сделать вызов функции из глобального  клиентского модуля. Например, так:

Процедура ПриНачалеРаботыСистемы()
	
	// СтандартныеПодсистемы
	СтандартныеПодсистемыКлиент.ПриНачалеРаботыСистемы();
	// Конец СтандартныеПодсистемы
	
	// ПодключаемоеОборудование
	МенеджерОборудованияКлиент.ПриНачалеРаботыСистемы();
	// Конец ПодключаемоеОборудование
	
	// Постовалов, 01.08.2018
	ВключитьРегистрациюАктивностиПользователя();
	// ---
	
КонецПроцедуры

Общий модуль АктивностьПользователейГлобальный

Функцию ВключитьРегистрациюАктивностиПользователя() создаем в глобальном клиентском общем модуле (это означает, что у общего модуля должны стоять флажки "глобальный" и "клиент").

Процедура ВключитьРегистрациюАктивностиПользователя() Экспорт
	АктивностьПользователейСервер.РегистрацияАктивностиПользователя(0,,"#Начало работы");//1	
	ПодключитьОбработчикОжидания("ПроверитьАктивностьПользователя", 60);//2
КонецПроцедуры

Прокомментируем эту функцию.

// 1. Первой строкой этой процедуры регистрируем начало нового сеанса пользователя с помощью функции РегистрацияАктивностиПользователя() серверного общего модуля АктивностьПользователейСервер. Эта функция будет описана далее. 

//2. Во второй строке подключается обработчик ожидания, который будет вызывать функцию ПроверитьАктивностьПользователя() каждую минуту. Эта функция располагается в этом же модуле и выглядит следующим образом:

Процедура ПроверитьАктивностьПользователя() Экспорт
Окна = ПолучитьОкна();
ТекстСообщения = "";
Ссылка = Неопределено;
АктивнаяФорма = "";
Для Каждого Окно Из Окна Цикл
	ТекстСообщения = ТекстСообщения + "["+Окно.Заголовок+"] ";
	Формы = Окно.Содержимое;
	Для Каждого Ф Из Формы Цикл
		Если Ф.ВводДоступен() Тогда
			// Это активная форма
			Ссылка = ПолучитьЗначениеСвойства(ПолучитьЗначениеСвойства(Ф,"Объект"),"Ссылка");//3
			Активность="!";
			АктивнаяФорма = Ф.Заголовок;
		Иначе
			Активность="";
		КонецЕсли;	
		ТекстСообщения = ТекстСообщения 
		+ "("+Ф.Заголовок+": "+ПолучитьЗначениеСвойства(Ф.ТекущийЭлемент,"Имя")+Активность+")";
		КонецЦикла;
КонецЦикла;
ЗавершитьСеанс = АктивностьПользователейСервер.РегистрацияАктивностиПользователя(
Хэш(ТекстСообщения),Ссылка,АктивнаяФорма); //4
Если ЗавершитьСеанс Тогда // 5
	ЗавершитьРаботуСистемы(Истина);
КонецЕсли;
КонецПроцедуры

// 3. Чтобы понять, с каким объектом работает пользователь, хотелось бы получить ссылку на объект. Как правило (но, к сожалению, не обязательно), главный реквизит формы справочника или документа называется "Объект". Так как мы не знаем точно, является ли форма формой документа или справочника, то получение значения этого реквизита сделаем через вспомогательную функцию ПолучитьЗначениеСвойства(). С другой стороны, может оказаться, что форма имеет главный реквизит с названием "Объект", но у него нет реквизита Ссылка.

Функция ПолучитьЗначениеСвойства(Переменная, Свойство)
	Если Переменная<>Неопределено 
		И ТипЗнч(Переменная)<>Тип("Null")
		И ТипЗнч(Переменная)<>Тип("Строка")
		И ТипЗнч(Переменная)<>Тип("Число")
		И ТипЗнч(Переменная)<>Тип("Дата")
		И ТипЗнч(Переменная)<>Тип("Булево")
		И ТипЗнч(Переменная)<>Тип("ДекорацияФормы")
		Тогда
		Стр = Новый Структура(Свойство, Неопределено);
		ЗаполнитьЗначенияСвойств(Стр, Переменная);
		Возврат Стр[Свойство];
	КонецЕсли;
	Возврат Неопределено;
КонецФункции

// 4. Хэш-функцию от строки вычисляем по следующему алгоритму:

//////////////////////////////////////////////////////////////////////
 //СтрокаХэш - исходный текст
 //hash- начальное значение hash
 // М - множитель (влияет накачество хэш и производительность)
 // TABLE_SIZE - размер получаемого ключа, как Максимальная величина + 1
Функция Хэш(СтрокаХэш, hash=0, M = 31, TABLE_SIZE = 18446744073709551616)
    //TABLE_SIZE = 18446744073709551615; 64 бита
    //M = 31; Умножитель
    ДлинаСтроки = СтрДлина(СтрокаХэш);
    Для к=1 по ДлинаСтроки цикл
        hash = M * hash + КодСимвола(Сред(СтрокаХэш,к,1));
    конеццикла;
    возврат hash%TABLE_SIZE;
КонецФункции

//5. Если функция  РегистрацияАктивностиПользователя()  вернула Истина, то завершаем сеанс работы пользователя.

Общий модуль АктивностьПользователейСервер

Теперь перейдем к записи в регистр. Функция РегистрацияАктивностиПользователя располагается в серверном общем модуле АктивностьПользователейСервер.

Функция РегистрацияАктивностиПользователя(Хеш,Ссылка=Неопределено,Комментарий = "") Экспорт
	ТекДата = ТекущаяДата();
	НомерСеанса = НомерСеансаИнформационнойБазы();
	ЗавершитьСеанс = Ложь;

	Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	АктивностьПользователейСрезПоследних.Период,
		|	АктивностьПользователейСрезПоследних.Пользователь,
		|	АктивностьПользователейСрезПоследних.Хеш,
		|	АктивностьПользователейСрезПоследних.Комментарий,
		|	АктивностьПользователейСрезПоследних.Ссылка
		|ИЗ
		|	РегистрСведений.АктивностьПользователей.СрезПоследних(
		|			&ТекДата,
		|			Пользователь = &ТекущийПользователь
		|				И НомерСеанса = &НомерСеанса) КАК АктивностьПользователейСрезПоследних";
	
	Запрос.УстановитьПараметр("ТекДата", ТекДата);
	Запрос.УстановитьПараметр("ТекущийПользователь", ПараметрыСеанса.ТекущийПользователь);
	Запрос.УстановитьПараметр("НомерСеанса",НомерСеанса);
	РезультатЗапроса = Запрос.Выполнить();
	Выборка = РезультатЗапроса.Выбрать();
	
	Если Выборка.Следующий() Тогда
		Простой = 0;
		Если НачалоДня(ТекДата)=НачалоДня(Выборка.Период) Тогда
			Простой = ТекДата-Выборка.Период; // в секундах	
		КонецЕсли;
		
		// Проверяем простой
		Если Простой > 3600	Тогда
			ЗавершитьСеанс=Истина;
		КонецЕсли;
		
		Если Выборка.Хеш = Хеш Тогда
			// Активности не было...
			Возврат ЗавершитьСеанс;
		КонецЕсли;
	КонецЕсли;
	
	Рег = РегистрыСведений.ДОРН_АктивностьПользователей.СоздатьМенеджерЗаписи();
	Рег.Период = ТекДата;
	Рег.Пользователь = ПараметрыСеанса.ТекущийПользователь;
	Рег.НомерСеанса = НомерСеанса;
	Рег.Хеш = Хеш;
	Рег.Комментарий = Комментарий;
	Рег.Ссылка=Ссылка;
	Рег.Записать(Истина);
	
	Возврат ЗавершитьСеанс;
КонецФункции	

В функции сначала с помощью запроса получаем текущее состояние активности пользователя. Если хеш не изменился, то вычисляем время простоя. Если время простоя превышает максимально возможное (в примере задано 3600 секунд), то выполняется завершение работы системы. Если значение хеш-функции изменилось, тогда записываем в регистр сведений новое значение хеша.

Насколько мониторинг замедляет работу пользователя?

По проведенным замерам времени проверка активности занимает менее 1 секунды, поэтому визуально для пользователя существенного замедления работы не происходит. 

Результаты

Активность пользователей можно анализировать или непосредственно, просматривая записи регистра (рис.1), или написать специальные отчеты. Например, я немного модифицировал стандартную обработку "Активные пользователи" (рис. 2), добавив туда колонку "Статус" и написал отчет "Распределение работы пользователей"  (рис. 3). 

Регистр сведенийРис. 1.

Активные пользователиРис. 2.

Рис. 3.

активность пользователей определение времени простоя

См. также

LogManager - Внешний журнал регистрации в SQL

Журнал регистрации Платформа 1С v8.3 Конфигурации 1cv8 Платные (руб)

Журнал регистрации платформы 1С в SQL. Общая база хранения всех журналов. Через com-подключение регламентным заданием периодически догружает журналы регистраций из рабочих баз. Предоставляет настраиваемый доступ к журналам по правам подразделений. Формирует отчеты по пользователям и данным.

10000 руб.

23.05.2014    55416    52    16    

47

Версионирование справочников, документов и регистров сведений на SQL-сервере

Журнал регистрации Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Россия Платные (руб)

История изменений реквизитов и табличных частей справочников, документов, независимых регистров сведений, возможность отката изменения, восстановление удаленных объектов, сбор статистики использования базы 1С. Альтернативный журнал регистрации.

22800 руб.

22.02.2018    35117    58    53    

55

Журнал изменений с восстановлением состояния ссылочных объектов и архивацией по HTTP / COM (расширение + конфигурация, 8.3.14+, ЛЮБАЯ конфигурация)

Архивирование (backup) Журнал регистрации Поиск данных Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 1С:Управление торговлей 11 Платные (руб)

База данных «сама» меняет данные в документах/справочниках? Тогда данный журнал изменений для Вас! Практически не влияет на скорость записи объектов за счет быстрого алгоритма! Скорость работы почти в 2 раза выше типового механизма "История изменений"! Позволяет следить за изменениями и удалением в любых ссылочных объектах конфигурации, с возможностью архивации по HTTP(!) или COM, и сверткой данных. А так же, может восстановить состояние реквизитов (значения) до момента изменения или удаления объекта из базы. Есть ДЕМО-база где можно самостоятельно протестировать часть функционала! Работает на любых платформах выше 8.3.14+ и любых конфигурациях! Версия 3.1 от 24.08.2023!

19200 руб.

15.05.2017    42470    10    24    

38

Мониторинг баз и серверов 1С

Журнал регистрации Мониторинг Платформа 1С v8.3 Платные (руб)

В сферу обязанностей при работе с клиентами входит контроль работы баз данных и серверов 1С. Нужно понимать что происходит в базах, есть ли ошибки, зависания у пользователей и фоновых задач, блокировки или какое-то необычное поведение системы, получение информации о причинах возникновения проблем и их оперативное устранение и т.д. В качестве источников информации использую консоль кластеров 1С, технологический журнал 1С, журналы регистрации базы 1С. Для автоматизации части операций мониторинга и анализа создал инструмент на основе 1С.

9000 руб.

28.08.2019    30837    14    21    

65

Версионирование объектов для Альфа-авто, ред 4 и 5.

Оптовая торговля Розничная торговля Журнал регистрации Платформа 1С v8.3 Конфигурации 1cv8 Автомобили, автосервисы Управленческий учет Платные (руб)

Подсистема версионирования объектов для конфигураций Рарус: Альфа-авто на базе типовой подсистемы от 1С. Позволяет хранить историю изменений документов и справочников, кто, что, когда и какие данные изменял, а так же вернуться к предыдущим версиям объекта.

4800 руб.

03.09.2016    42213    32    24    

36

Уведомления на почту по событиям журнала регистрации на email и в Telegram (для УНФ, УТ 11, БП 3.0, ЗУП 3.0, ERP)

Мессенджеры и боты Журнал регистрации Мониторинг Email рассылки Платформа 1С v8.3 Управляемые формы 1С:Управление нашей фирмой 1.6 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Платные (руб)

Рассылка уведомлений о событиях журнала регистрации на электронную почту и в Телеграмм. Программа позволяет анализировать журнал регистрации по заданным критериям, находить в нём интересующие события, и отправлять уведомления об этих событиях на электронную почту (одного или нескольких получателей) или в телеграмм. Может работать и как внешняя обработка, и как регламентное задание. Для УНФ, УТ 11, БП 3.0, ЗУП 3.0, ERP.

10800 руб.

18.06.2017    32256    3    2    

15

Регламентное сокращение журнала регистрации

Инструменты администратора БД Журнал регистрации Платформа 1С v8.3 1С:Управление торговлей 11 Абонемент ($m)

Внешняя обработка для регламентного сокращения журнала регистрации для конфигураций на базе БСП и платформы 8.3.20+

1 стартмани

29.12.2023    1216    11    dima_gsv    1    

12

Магия преобразований: ЖР, ТЖ, RAS/RAC, логи - универсальное решение Vector

Мониторинг Журнал регистрации Технологический журнал Абонемент ($m)

Как легко и быстро с помощью специализированных решений собирать, парсить и передавать логи и метрики.

1 стартмани

13.11.2023    2881    4    AlexSTAL    0    

42
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Darklight 32 11.10.18 16:24 Сейчас в теме
Хорошее решение. Я как раз сейчас делаю аналогичное (!) по завершению сеансов, тоже включающее отслеживание окон (но у меня гораздо больше функционала заложено, поэтому пока не выкладываю, хотя об отслеживании окон уже писал тут недавно в комментариях к другой публикации тоже на тему закрытия неактивных сеансов).

У Вас подсмотрел идею о хешировании строки открытых форм (хотя уже, в общем-то, тоже об этом думал) - не знаю пока - будут ли использовать - у меня иное хранение текущего состояния, думал просто хранить идентификаторы форм списком, т.к. я делаю расширение конфигурации в режиме совместимости для платформы 1С 8.3.9 - а там ещё пока нельзя в расширение изменять структуру данных БД.

Не пойму только, почему Вы применили свою функцию хеширования, а не взяли типовой объект из 8.3 "ХешированиеДанных"?

Ну и жаль, что Вы не привели в описании алгоритм завершения работы системы - там тоже есть свои нюансы.
3. postovalov 199 12.10.18 04:32 Сейчас в теме
(1)
Не пойму только, почему Вы применили свою функцию хеширования, а не взяли типовой объект из 8.3 "ХешированиеДанных"?


Функцию хеширования я взял отсюда: https://infostart.ru/public/70030/. Встроенную функцию не проверял, но думаю, что тоже можно использовать, но заранее не могу сказать, какой вариант будет быстрее, т.к. алгоритмы хеширования разные.
2. shurik_shurik 11.10.18 17:08 Сейчас в теме
Идея интересная, но вопрос, зачем делать обращение к срезПоследних регистра, если у Вас и так есть
"создаем в глобальном клиентском общем модуле (это означает, что у общего модуля должны стоять флажки "глобальный" и "клиент")"

Не проще хранить последние данные в глобальных переменных объявленных в этом модуле ? и не дергать каждый раз базу "по пустякам" ?
4. postovalov 199 12.10.18 04:35 Сейчас в теме
(2) Глобальных переменных в управляемом приложении нет, но использование параметра сеанса должно ускорить работу программы.
5. Darklight 32 12.10.18 09:13 Сейчас в теме
(4)Вот поэтому я храню по-другому, т.к. в расширениях и параметров сеансов нет, которые, всё-равно, доступные только в серверном контексте :-( поэтому, приходится извращаться.
9. azhilichev 213 12.10.18 16:18 Сейчас в теме
(4)
Глобальных переменных в управляемом приложении нет, но использование параметра сеанса должно ускорить работу программы.


Глобальные клиентские переменные можно задавать в модуле управляемого приложения.
postovalov; +1 Ответить
13. postovalov 199 17.10.18 14:18 Сейчас в теме
(9) Попробовал так сделать. Переменная в модуле управляемого приложения действительно сохраняет значение, но пришлось процедуру-обработчик ожидания также перенести также в этот модуль.
6. Иваныч 23 12.10.18 10:12 Сейчас в теме
Нравится, но пока на 7.7 пользуюсь другим. А вам ставлю плюс
7. astracrypt 74 12.10.18 11:12 Сейчас в теме
У нас используют приложение для Windows. Которое измеряет расстояние курсора в метрах пройденное по экрану. Те у кого больше 20 км за месяц тому премию дают.
wauri; succub1_5; +2 Ответить
29. Lonelcor 10 01.04.22 12:23 Сейчас в теме
(7) Работает до первого более менее продвинутого пользователя :) Который может поставить эмулятор движения курсора :) Или написать его в пару строк
8. azhilichev 213 12.10.18 16:13 Сейчас в теме
Если Переменная<>Неопределено 
		И ТипЗнч(Переменная)<>Тип("Null")
		И ТипЗнч(Переменная)<>Тип("Строка")
		И ТипЗнч(Переменная)<>Тип("Число")
		И ТипЗнч(Переменная)<>Тип("Дата")
		И ТипЗнч(Переменная)<>Тип("Булево")
		И ТипЗнч(Переменная)<>Тип("ДекорацияФормы")
		Тогда


Зачем вы заставляете систему делать лишние действия? Так ведь лучше, правда?

ТипЗначения = ТипЗнч(Переменная)
Если Переменная <> Неопределено
   И ТипЗначения <> Тип("NULL") И ТипЗначения <> Тип("Строка")
   И ТипЗначения <> Тип("Число") И ТипЗначения <> Тип("Дата")
   И ТипЗначения <> Тип("Булево") И ТипЗначения <> Тип("ДекорацияФормы") Тогда


Чтобы гарантированно выкинуть пользователя, лучше использовать не ЗавершитьРаботуСистемы(), а ПрекратитьРаботуСистемы(). Если у вас есть модальный диалог, ЗавершитьРаботуСистемы() не отработает.
10. cssprite 28 13.10.18 15:26 Сейчас в теме
(8)
Зачем вы заставляете систему делать лишние действия? Так ведь лучше, правда?
:))

ТипЗначения = ТипЗнч(Переменная);
ЧтотоСделать = НЕ (Переменная = Неопределено
   ИЛИ ТипЗначения = Тип("NULL") ИЛИ ТипЗначения = Тип("Строка")
   ИЛИ ТипЗначения = Тип("Число") ИЛИ ТипЗначения = Тип("Дата")
   ИЛИ ТипЗначения = Тип("Булево") ИЛИ ТипЗначения = Тип("ДекорацияФормы"));
Если ЧтотоСделать  Тогда ...
12. postovalov 199 15.10.18 01:21 Сейчас в теме
(10) не уверен, что так оптимальнее, чем в (8). Насколько я помню, логическое "И" вычисляется до первого ложного значения. А вот для логического "ИЛИ" нужно вычислить все условия.
16. cssprite 28 18.10.18 22:48 Сейчас в теме
(12)
А вот для логического "ИЛИ" нужно вычислить все условия
Зачем, если первое ИСТИНА даст всему выражению ИЛИ - ИСТИНА ?
Про оптимальность прямо не скажешь, зависит от того, какие значения чаще принимает Переменная, просто для выполнения данного условия с использованием И НЕ РАВНО И НЕ РАВНО ... надо проверить все условия И, а для РАВНО ИЛИ РАВНО ... до первой ИСТИНЫ ...

Вообще извиняюсь, прямо к теме отношения не имеет, тут больше субъективное отношение - длинное И НЕ РАВНО И НЕ РАВНО ... режет глаз ))
17. postovalov 199 19.10.18 10:23 Сейчас в теме
(16) Да, вы правы, с точки зрения количества сравнений их будет ровно столько же. Единственное, что вы добавляете еще одну логическую операцию (НЕ) и вспомогательную переменную.

Вообще извиняюсь, прямо к теме отношения не имеет, тут больше субъективное отношение - длинное И НЕ РАВНО И НЕ РАВНО ... режет глаз ))


Мне, наоборот, удобнее, когда условия находятся на разных строках. Так и нагляднее, и добавлять проще. В общем на "вкус и цвет товарищей нет".
11. postovalov 199 15.10.18 01:17 Сейчас в теме
(8) Спасибо за замечание, конечно, нужно поправить. Что касается, ЗавершитьРаботуСистемы() или ПрекратитьРаботуСистемы(), то выбор зависит от того, какая поставлена цель. Если надо убрать сеансы, в которых пользователи открыли программу и не работают, то достаточно ЗавершитьРаботуСистемы(). Если же цель завершить сеанс, даже если имеется открытый (не сохраненный) документ, то да тогда нужно использовать ПрекратитьРаботуСистемы().
14. Vyatcheslav 22 17.10.18 14:29 Сейчас в теме
Интересный подход. Но концептуально странный и даже опасный, если пользователи поймут что к чему. Ведь важно не то, сколько сотрудник ДЕЛАЛ, а то, сколько он СДЕЛАЛ. Почувствуйте разницу. Неопытный сотрудник может очень бурно изображать деятельность, но выхлопа от этого будет мало. Это относится к любой работе и профессии.

Когда я был неопытным специалистом 1С и только начинал, были задачи по УПП, ради решения которых я упорно сидел по несколько дней в конфигураторе в режиме отладки, пытаясь понять поведение системы, хотя задача в теории решалась за 5 минут грамотным консультантом и без захода в конфигуратор.

У нас есть отчет по пользователям в базах 1С, который показывает, кто сколько документов в базе создал за период, сгруппированные по типам документов и с указанием количества строк в ТЧ документов. Дает представление о объеме выполненной работы. Конечно, сильно зависит от должностных обязанностей работников, слепо количественно позволяет только оценивать тех, кто чисто на первичке сидит. У кого обязанности налоговый учет, декларации, закрытие месяца, всякая другая отчетность и т.д., понятно, так не оценить, документов они вводят не много.

Мне симпатичен способ нормирования, когда на одного расчетчика 200 сотрудников + зуп отчетность, например, или на одного буха 2000-4000 основных средств и т.д., но вообще тема очень сложная, пользователь может реально зашиваться и не успевать только потому, что многие функции не автоматизированы и он не знает, что это можно автоматизировать, или функции автоматизированы, но пользователь не знает, как можно работать эффективнее и никто его не учит. Тут только может помочь желание непосредственного руководителя сделать работу пользователя эффективнее + привлечение консультантов-программистов 1С, аудит рабочих и производственных процессов.

ВЫВОД: Универсального счетчика быть не может в принципе, по которому можно объективно оценить любого пользователя, везде необходимо подходить с умом. Там, где сотр решает бизнес-цели, там проще, можно оценивать просто по принесенной выручке/прибыли/выработке и т.д. Там, где обслуживающие подразделения: бухи, юристы, финансисты-экономисты, айтишники и т.д. все намного сложнее.
15. postovalov 199 18.10.18 06:43 Сейчас в теме
(14) В статье описан метод регистрации активности пользователя, но каждый может использовать его для своих целей. Если премию выписывать, то да, это опасный подход, согласен.

Мне симпатичен способ нормирования, когда на одного расчетчика 200 сотрудников + зуп отчетность, например, или на одного буха 2000-4000 основных средств и т.д., но вообще тема очень сложная, пользователь может реально зашиваться и не успевать только потому, что многие функции не автоматизированы и он не знает, что это можно автоматизировать, или функции автоматизированы, но пользователь не знает, как можно работать эффективнее и никто его не учит. Тут только может помочь желание непосредственного руководителя сделать работу пользователя эффективнее + привлечение консультантов-программистов 1С, аудит рабочих и производственных процессов.


Как раз здесь интересно отношение "Объем выполненной работы (количество введенных документов, справочников, строк табличной части и т.п.)" к продолжительности активной работы пользователя. Если у одного пользователя этот показатель будет существенно выше, а у другого существенно ниже, то это предмет для анализа, что пользователь делает неэффективно, почему тратит больше времени на выполнение одних и тех же действий.
18. Si-ned 7 19.10.18 14:09 Сейчас в теме
Повторил весь код для УПП 1.3 для обычного приложения (код вставлял в ПриНачалеРаботыСистемы() обычного приложения). После запуска окно программы запускается, виден интерфейс, но окно заставки не исчезает и висит. Через диспетчер программу не закроешь, так как все диалоги скрываются за окном заставки 1С. Для обычного приложения не работает эта схема что-ли?
19. postovalov 199 19.10.18 16:39 Сейчас в теме
(18) Весь код разработан для управляемого приложения. На обычном не проверял. Думаю, что надо пройти по всем модулям в режиме отладчика.
20. nano1c 170 24.10.18 09:17 Сейчас в теме
(19) ПолучитьОкна() - в обычном не работает. Я делал свою функцию получающую открытые окна в обычном приложении, но через внешнюю компоненту. Вообще у меня давно сделан полный контроль отработанного времени с автоматической рассылкой т13 и т.п. (см. публикацию), но по данным с карт, на другой организации подключил это решение к данным открытий окон - тоже нормально. Сейчас делаю автоматический анализ всех действий - чтобы понять типовые бизнес-маршруты и нетиповые действия анализировать - собирался публикацию писать, но все времени не найду..
postovalov; +1 Ответить
21. xan333 59 05.12.18 10:54 Сейчас в теме
Сделал Расширение для типовых конфигураций 1С на управляемых формах в режиме совместимости 8.3.12. основанное на данной статье https://infostart.ru/public/931108/
22. sp18s 25.02.19 17:37 Сейчас в теме
Ресурсы: Хеш (тип "Число")
Не указали количество знаков хранения. Необходимо 30, по умолчанию 10.
25. postovalov 199 25.06.19 10:07 Сейчас в теме
(22) От этого поля можно вообще отказаться - см. комментарий (2) и далее.
23. letarch 19.06.19 15:16 Сейчас в теме
а использование параметра /LOGUI разве не тоже самое делает?
24. postovalov 199 25.06.19 10:05 Сейчас в теме
(23) Нет, принцип другой: /LOGUI дает журнал всех действий пользователя в отдельном файле. Предлагаемый подход: регистрация активности пользователя с заданной периодичностью в регистре сведений.
26. stepan_shock 112 19.08.21 13:52 Сейчас в теме
Есть ли обновление разработки или замерла?
27. buketov_av 06.12.21 11:22 Сейчас в теме
Получаю такую ошибку. Что не так? Хотя при этом по F12 переходит.

{ОбщийМодуль.АктивностьПользователейГлобальный.Модуль(7,2)}: Переменная не определена (АктивностьПользователейСервер)
<<?>>АктивностьПользователейСервер.РегистрацияАктивностиПользователя(0,,"#Начало работы");//1 (Проверка: Тонкий клиент)
{ОбщийМодуль.АктивностьПользователейГлобальный.Модуль(32,19)}: Переменная не определена (АктивностьПользователейСервер)
ЗавершитьСеанс = <<?>>АктивностьПользователейСервер.РегистрацияАктивностиПользователя( (Проверка: Тонкий клиент)
28. пользователь 16.02.22 18:28
Сообщение было скрыто модератором.
...
31. userOleg 10.02.23 16:01 Сейчас в теме
(27)Такая же ошибка. Что сделали?
33. VladTVN 12.05.23 15:07 Сейчас в теме
(31) В настройках общего модуля "АктивностьПользователейСервер" поставьте флаг "ВызовСервера"
30. patalgen 6 25.08.22 16:59 Сейчас в теме
В колонке статус тип какой указывали?
32. userOleg 10.02.23 16:02 Сейчас в теме
(30) А какой колонке идет речь? где это?
34. ActiveTechnology 01.11.23 16:36 Сейчас в теме
"РегистрСведений.АктивностьПользователей" - это какая конфигурация рассматривается?
35. ActiveTechnology 01.11.23 17:28 Сейчас в теме
Поняли, что это новый регистр. Сообщение выше можно удалить.
36. user1062452 21.12.23 18:12 Сейчас в теме
В статье автор указывает на замедление работы до 1сек.
Вопрос 1 - На какой конфигурации тестировалось? Файловая или серверная ? Железо ? Количество активных пользователей?
Вопрос 2 - Не возникало ли проблем с блокировками ? По сути Объем данных для моментной записи не столь велик и запись должна проходить достаточно быстро и "отпускать" таблицу, но теоретически если активных пользователей в базе около 50 и все активно набивают документы / формируют отчеты/ создают элементы справочника не возникнет ли проблема с блокировками ?
Оставьте свое сообщение