Доброго всем времени суток.
Недавно столкнулся с проблемой. У пользователей при выводе страничек в обработке ИнформацияПриЗапуске вылезала вот такая вот ерунда:
Начал разбираться. К сожалению на просторах интернета не удалось найти не только решения, но даже описания такой проблемы (возможно, я плохо искал). Если вы знаете как можно было легко и просто это исправить без доработок, прошу рассказать в комментариях.
Полез в конфигуратор, посмотрел обработку и обнаружил, что все эти странички хранятся в макетах в виде двоичных данных,которые есть ни что иное как архивы zip, в которых лежат странички htm. У тех страниц, которые отображались некрасиво в <meta> зашита кодировка windows-1251.
Я не знаю почему при чтении этих страниц вылезло вот такое, но предполагаю, что это связанно с тем, что на сервере у нас стоит ОС на english.
Содержание расширения
Дальше я привожу содержание расширения, можете не скачивать файл, а просто повторить у себя изложенное ниже, если вдруг не дай Б-г у Вас такое произойдет. На мой взгляд это слишком мелкая доработка для 1sm =)
Сделал публикацию, чтобы поделиться с сообществом.
Вносится исправления в Общий Модуль ИнформацияПриЗапуске, в функцию чтения данных из макетов:
&ИзменениеИКонтроль("ИзвлечьФайлыПакета")
Функция ИПЗ_ИзвлечьФайлыПакета(НосительМакетов, ИмяМакета)
КаталогВременныхФайлов = ФайловаяСистема.СоздатьВременныйКаталог("extras");
// Извлечение страницы
АрхивПолноеИмя = КаталогВременныхФайлов + "tmp.zip";
Попытка
КоллекцияМакетов = НосительМакетов.Метаданные().Макеты;
ЛокализованноеИмяМакета = ИмяМакета + "_" + ТекущийЯзык().КодЯзыка;
Макет = КоллекцияМакетов.Найти(ЛокализованноеИмяМакета);
Если Макет = Неопределено Тогда
ЛокализованноеИмяМакета = ИмяМакета + "_" + ОбщегоНазначения.КодОсновногоЯзыка();
Макет = КоллекцияМакетов.Найти(ЛокализованноеИмяМакета);
КонецЕсли;
Если Макет = Неопределено Тогда
ЛокализованноеИмяМакета = ИмяМакета;
КонецЕсли;
ДвоичныеДанные = НосительМакетов.ПолучитьМакет(ЛокализованноеИмяМакета);
ДвоичныеДанные.Записать(АрхивПолноеИмя);
Исключение
ЗаписьЖурналаРегистрации(
НСтр("ru = 'Информация при запуске'", ОбщегоНазначения.КодОсновногоЯзыка()),
УровеньЖурналаРегистрации.Ошибка,
,
,
ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
Возврат Неопределено;
КонецПопытки;
ЧтениеZipФайла = Новый ЧтениеZipФайла(АрхивПолноеИмя);
ЧтениеZipФайла.ИзвлечьВсе(КаталогВременныхФайлов, РежимВосстановленияПутейФайловZIP.Восстанавливать);
ЧтениеZipФайла.Закрыть();
ЧтениеZipФайла = Неопределено;
УдалитьФайлы(АрхивПолноеИмя);
Картинки = Новый ТаблицаЗначений;
Картинки.Колонки.Добавить("ОтносительноеИмя", Новый ОписаниеТипов("Строка"));
Картинки.Колонки.Добавить("ОтносительныйКаталог", Новый ОписаниеТипов("Строка"));
Картинки.Колонки.Добавить("Данные");
ВебСтраницы = Новый ТаблицаЗначений;
ВебСтраницы.Колонки.Добавить("ОтносительноеИмя", Новый ОписаниеТипов("Строка"));
ВебСтраницы.Колонки.Добавить("ОтносительныйКаталог", Новый ОписаниеТипов("Строка"));
ВебСтраницы.Колонки.Добавить("Данные");
// Регистрация ссылок страниц и создание списка картинок.
КаталогиФайлов = Новый СписокЗначений;
КаталогиФайлов.Добавить(КаталогВременныхФайлов, "");
Осталось = 1;
Пока Осталось > 0 Цикл
Осталось = Осталось - 1;
Каталог = КаталогиФайлов[0];
КаталогПолныйПуть = Каталог.Значение; // Полный путь в формате файловой системы.
КаталогОтносительныйПуть = Каталог.Представление; // Относительный путь в URL формате.
КаталогиФайлов.Удалить(0);
Найденные = НайтиФайлы(КаталогПолныйПуть, "*", Ложь);
Для Каждого Файл Из Найденные Цикл
ФайлОтносительноеИмя = КаталогОтносительныйПуть + Файл.Имя;
Если Файл.ЭтоКаталог() Тогда
Осталось = Осталось + 1;
КаталогиФайлов.Добавить(Файл.ПолноеИмя, ФайлОтносительноеИмя + "/");
Продолжить;
КонецЕсли;
Расширение = СтрЗаменить(НРег(Файл.Расширение), ".", "");
Если Расширение = "htm" ИЛИ Расширение = "html" Тогда
РазмещениеФайла = ВебСтраницы.Добавить();
#Удаление
ЧтениеТекста = Новый ЧтениеТекста(Файл.ПолноеИмя);
#КонецУдаления
#Вставка
ЧтениеТекста = Новый ЧтениеТекста(Файл.ПолноеИмя);
Данные = ЧтениеТекста.Прочитать();
ЧтениеТекста.Закрыть();
Кодировка1251 = СтрНайти(Данные, "windows-1251");
КодировкаUTF8 = СтрНайти(Данные, "UTF-8");
Если Кодировка1251 <> 0 Тогда
Кодировка = "windows-1251";
ИначеЕсли КодировкаUTF8 <> 0 Тогда
Кодировка = КодировкаТекста.UTF8;
Иначе
Кодировка = КодировкаТекста.ANSI;
КонецЕсли;
ЧтениеТекста = Новый ЧтениеТекста(Файл.ПолноеИмя,Кодировка);
#КонецВставки
Данные = ЧтениеТекста.Прочитать();
ЧтениеТекста.Закрыть();
ЧтениеТекста = Неопределено;
Иначе
РазмещениеФайла = Картинки.Добавить();
Данные = Новый Картинка(Новый ДвоичныеДанные(Файл.ПолноеИмя));
КонецЕсли;
РазмещениеФайла.ОтносительноеИмя = ФайлОтносительноеИмя;
РазмещениеФайла.ОтносительныйКаталог = КаталогОтносительныйПуть;
РазмещениеФайла.Данные = Данные;
КонецЦикла;
КонецЦикла;
// Удаление временных файлов (все файлы были помещены во временные хранилища).
ФайловаяСистема.УдалитьВременныйКаталог(КаталогВременныхФайлов);
Результат = Новый Структура;
Результат.Вставить("Картинки", Картинки);
Результат.Вставить("ВебСтраницы", ВебСтраницы);
Возврат Результат;
КонецФункции
Еще добавлю, что необходимо отключить безопасный режим:
После применения расширения видим нормальные странички:
Проверено на версии Бухгалтерия предприятия, редакция 3.0 (3.0.75.58)
На этом всё, пожалуй)
P.S. Не судите строго, первая моя публикация. Всем добра!
