1. Зачем это надо
Вы можете использовать прилагаемые к статье обработки как шаблоны для быстрой выгрузки/загрузки данных при имеющихся правилах обмена. У меня такая задача возникла после того, как понадобилось быстро предоставить возможность пользователям, которые были плохо знакомы с системой 1С, выгружать из УТ реализации и загружать их как поступления в "Розницу". Причем пользователю необходимо было предоставить возможность самостоятельно выбирать те реализации, которые надо выгружать. Предоставлять возможность использования всех возможностей обработки "Универсальный обмен данными в формате XML" не хотелось. Правила обмена с помощью "Конвертации данных" написать (для этого конкретного случая) довольно просто. Для этого достаточно обладать элементарными знаниями КД (их можно быстро получить из видеолекций Евгения Гилева - http://www.spec8.ru/data-conv).
2. Выгрузка
Форма выгрузки у меня выглядела следующим образом:
При изменении даты табличное поле заполняется документами за выбранную дату. Сами правила обмена были вставлены в обработку как макет с типом "Двоичные данные".
При нажатии на кнопку "Выгрузка" выполняется код:
Процедура ДействияФормыВыгрузка(Кнопка)
ДиалогФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Сохранение);
ДиалогФайла.Фильтр = "Файл данных (*.xml)|*.xml";
ДиалогФайла.ПолноеИмяФайла = "Retail_"+СтрЗаменить(Формат(Дата,"ДФ=dd.MM.yyyy"),".","-");
Если ДиалогФайла.Выбрать() Тогда
ИмяФайла = ДиалогФайла.ПолноеИмяФайла;
Попытка
ВыгрузитьДанные(ИмяФайла);
ДвоичныеДанные = Новый ДвоичныеДанные(ИмяФайла);
ДвоичныеДанные.Записать(ИмяФайла);
Исключение
Предупреждение("Внешний файл не сохранен
|"+ОписаниеОшибки());
КонецПопытки;
КонецЕсли;
КонецПроцедуры
Сама процедура выгрузки выглядит так:
Процедура ВыгрузитьДанные(ИмяФайлаОбмена)
Обработка=Обработки.УниверсальныйОбменДаннымиXML.Создать();
Обработка.РежимОбмена="Выгрузка";
ВремФайл = ПолучитьИмяВременногоФайла("xml");
МакетПравилОбмена = ПолучитьМакет("ПравилаВыгрузки");
МакетПравилОбмена.Записать(ВремФайл);
Обработка.ИмяФайлаПравилОбмена = ВремФайл;//ФайлПравилОбмена;
Обработка.ЗагружатьДанныеВРежимеОбмена = Истина;
Обработка.ЗаписыватьРегистрыНаборамиЗаписей = Истина;
Обработка.ЗапоминатьЗагруженныеОбъекты = Истина;
Обработка.ИспользоватьОтборПоДатеДляВсехОбъектов = Истина;
СписокДок = Новый Массив;
Для каждого Стр Из Документы Цикл
Если НЕ Стр.Флаг Тогда
Продолжить;
КонецЕсли;
СписокДок.Добавить(Стр.Реализация);
КонецЦикла;
Обработка.ДатаНачала = Дата;
Обработка.ДатаОкончания = КонецДня(Дата);
Обработка.ВыгружатьТолькоРазрешенные = Истина;
Обработка.ИмяФайлаОбмена = ИмяФайлаОбмена;
Обработка.ТипУдаленияРегистрацииИзмененийДляУзловОбменаПослеВыгрузки = 0; // 0 - не снимать регистрацию, 1 - снимать регистрацию
Обработка.ЗагрузитьПравилаОбмена();
Обработка.Параметры.Вставить("Документы",СписокДок);
Обработка.ВыполнитьВыгрузку();
КонецПроцедуры
Отбор по документам осуществляется с помощью параметра "Документы", описанного в правилах обмена.
3. Загрузка
А вот это форма для загрузки:
При загрузке отрабатывает следующий код:
ОбработкаОбмена = Обработки.УниверсальныйОбменДаннымиXML.Создать();
ОбработкаОбмена.ИмяФайлаОбмена = ФайлЗагрузки;
ОбработкаОбмена.РежимОбмена = "Загрузка";
ОбработкаОбмена.ОткрытьФайлЗагрузки(Истина);
ОбработкаОбмена.АрхивироватьФайл = Ложь;;
ОбработкаОбмена.ВыполнитьЗагрузку();
ОбработкаОбмена = Неопределено;
4. Заключение
В результате получилась предельно простая для понимания пользователей технология обмена. Теперь нас не будут ждать неожиданности вроде выгрузки данных за большой период и не будут поступать вопросы о том "Почему ничего не выгружается?" при неправильном указании отборов. Сделал и забыл. Быстро, просто, прозрачно.
