Выгрузка и загрузка закупочных цен номенклатуры в формате JSON

&НаСервере
Функция ВыгрузитьУстановкиЦенВJSON(ПутьКФайлу, ДатаНачала, ДатаОкончания, ВидыЦен, ИдентификаторыВидовЦенПриемника)
	
	ТекущийДокументСсылка = Неопределено;
	ОписаниеДокумента = Неопределено;
	МассивСтрок = Новый Массив;
	
	МассивДанных = Новый Соответствие;
	
	Записано = 0;
	КоличествоТоваров = 0;

	ПараметрыЗаписи = Новый ПараметрыЗаписиJSON(, Символы.Таб);

	ЗаписьJSON = Новый ЗаписьJSON();
	ЗаписьJSON.ОткрытьФайл(ПутьКФайлу,,, ПараметрыЗаписи);

	// Начало массива документов
	ЗаписьJSON.ЗаписатьНачалоМассива();
	
	Если ВыгружатьАвтораДокумента Тогда
		ДопПолеОтветственный = СтрШаблон("
			|	УстановкаЦенНоменклатуры.%1 КАК %1,", ИмяРеквизитаОтветственный);
	Иначе
		ДопПолеОтветственный = "";
	КонецЕсли;
		
	Запрос = Новый Запрос;
	Запрос.Текст = СтрШаблон(
		"ВЫБРАТЬ
		|	УстановкаЦенНоменклатуры.Ссылка КАК Ссылка,
		|	УНИКАЛЬНЫЙИДЕНТИФИКАТОР(УстановкаЦенНоменклатуры.Ссылка) КАК ИдДокумента,
		|	УстановкаЦенНоменклатуры.Номер КАК Номер,
		|	УстановкаЦенНоменклатуры.Дата КАК Дата," + ДопПолеОтветственный + "
		|	ЗапросТоваров.Номенклатура КАК Номенклатура,
		|	УНИКАЛЬНЫЙИДЕНТИФИКАТОР(ЗапросТоваров.Номенклатура) КАК ИдНоменклатуры,
		|	ЗапросТоваров.Характеристика КАК Характеристика,
		|	ЗапросТоваров.ВидЦены КАК ВидЦены,
		|	УНИКАЛЬНЫЙИДЕНТИФИКАТОР(ЗапросТоваров.ВидЦены) КАК ИдВидаЦены,
		|	ЗапросТоваров.Цена КАК Цена%3
		|ИЗ
		|	Документ.%1 КАК УстановкаЦенНоменклатуры
		|		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
		|			УстановкаЦенНоменклатурыТовары.Ссылка КАК Ссылка,
		|			УстановкаЦенНоменклатурыТовары.НомерСтроки КАК НомерСтроки,
		|			УстановкаЦенНоменклатурыТовары.Номенклатура КАК Номенклатура,
		|			УстановкаЦенНоменклатурыТовары.Характеристика КАК Характеристика,
		|			УстановкаЦенНоменклатурыТовары.ВидЦены КАК ВидЦены,
		|			УстановкаЦенНоменклатурыТовары.Цена КАК Цена%4
		|		ИЗ
		|			Документ.%1.%2 КАК УстановкаЦенНоменклатурыТовары) КАК ЗапросТоваров
		|		ПО УстановкаЦенНоменклатуры.Ссылка = ЗапросТоваров.Ссылка
		|ГДЕ
		|	УстановкаЦенНоменклатуры.Проведен = ИСТИНА И УстановкаЦенНоменклатуры.Дата МЕЖДУ &ДатаНачала И &ДатаОкончания
		|	И ЗапросТоваров.ВидЦены В(&ВидыЦен)", ИмяДокументаУстановкаЦенНоменклатуры, ИмяТаблицыТоваровДокумента, 
		?(ВыгружатьПолеЦенаИзмененаВручную, ", ЗапросТоваров.ЦенаИзмененаВручную КАК ЦенаИзмененаВручную", ""), ?(ВыгружатьПолеЦенаИзмененаВручную, ", УстановкаЦенНоменклатурыТовары.ЦенаИзмененаВручную КАК ЦенаИзмененаВручную", ""));

	Запрос.УстановитьПараметр("ДатаНачала", ДатаНачала);
	Запрос.УстановитьПараметр("ДатаОкончания", ДатаОкончания);
	Запрос.УстановитьПараметр("ВидыЦен", ВидыЦен);

	Результат = Запрос.Выполнить();
	Выборка = Результат.Выбрать();
	
	Пока Выборка.Следующий() Цикл
		
		Если Выборка.Цена = 0 Тогда
			Продолжить;
		КонецЕсли;

		// Если перешли к новому документу — записываем предыдущий (если был)
		Если ТекущийДокументСсылка <> Неопределено И ТекущийДокументСсылка <> Выборка.Ссылка Тогда
			ЗаписатьДокументВJSON(ЗаписьJSON, ОписаниеДокумента, МассивСтрок, ИмяТаблицыТоваровДокумента);
			Записано = Записано + 1;
			КоличествоТоваров = КоличествоТоваров + МассивСтрок.Количество();
			МассивСтрок.Очистить();
			ТекущийДокументСсылка = Неопределено;
			ОписаниеДокумента = Неопределено;
		КонецЕсли;
			
		Если ОписаниеДокумента = Неопределено Тогда
			ОписаниеДокумента = Новый Структура;
			ОписаниеДокумента.Вставить("Документ", Строка(Выборка.ИдДокумента));
			ОписаниеДокумента.Вставить("Номер", Выборка.Номер);
			ОписаниеДокумента.Вставить("Дата", Выборка.Дата);
			Если ВыгружатьАвтораДокумента Тогда
				ОписаниеДокумента.Вставить(ИмяРеквизитаОтветственный, Строка(Выборка[ИмяРеквизитаОтветственный]));
			КонецЕсли;
			
		КонецЕсли;
		
		Если ТекущийДокументСсылка = Неопределено Тогда
			ТекущийДокументСсылка = Выборка.Ссылка;
			МассивСтрок = Новый Массив;
		КонецЕсли;

		СтрокаТЧ = Новый Структура;
		СтрокаТЧ.Вставить("Номенклатура", Строка(Выборка.ИдНоменклатуры));
		Если ВыгружатьНаименованиеНоменклатуры Тогда
			СтрокаТЧ.Вставить("НаименованиеНоменклатуры", Строка(Выборка.Номенклатура));
		КонецЕсли;
		
		ИдВидаЦены = ИдентификаторыВидовЦенПриемника[Выборка.ВидЦены];
		Если Не ЗначениеЗаполнено(ИдВидаЦены) Тогда
			ИдВидаЦены = Строка(Выборка.ИдВидаЦены);
		КонецЕсли;
		СтрокаТЧ.Вставить("ВидЦены", ИдВидаЦены);
		Если ВыгружатьНаименованиеВидаЦены Тогда
			СтрокаТЧ.Вставить("НаименованиеВидаЦены", Строка(Выборка.ВидЦены));
		КонецЕсли;
		СтрокаТЧ.Вставить("Цена", Выборка.Цена);
		Если ВыгружатьПолеЦенаИзмененаВручную Тогда
			СтрокаТЧ.Вставить("ЦенаИзмененаВручную", Выборка.ЦенаИзмененаВручную);
		КонецЕсли;
		
		МассивСтрок.Добавить(СтрокаТЧ);

	КонецЦикла;

	// Записываем последний документ
	Если ТекущийДокументСсылка <> Неопределено Тогда
		ЗаписатьДокументВJSON(ЗаписьJSON, ОписаниеДокумента, МассивСтрок, ИмяТаблицыТоваровДокумента);
		Записано = Записано + 1;
		КоличествоТоваров = КоличествоТоваров + МассивСтрок.Количество();
	КонецЕсли;

	// Конец массива документов
	ЗаписьJSON.ЗаписатьКонецМассива();
	ЗаписьJSON.Закрыть();
	
	Результат = Новый Структура;
	Результат.Вставить("ИмяФайла", ПутьКФайлу);
	Результат.Вставить("Записано", Записано);
	Результат.Вставить("КоличествоТоваров", КоличествоТоваров);

	Возврат Результат;
КонецФункции

&НаСервере
Функция ЗагрузитьУстановкиЦенИзJSON(ПутьКФайлу)
	
	УровеньМассива = 0;
	
	КоличествоДокументов = 0;
	КоличествоНайденныхДокументов = 0;
	КоличествоПроблемных = 0;
	КоличествоТоваров = 0;
	Добавлено = 0;
	ОбщееКоличествоОшибок = 0;
	
	ОписаниеДокумента = Новый Структура;

	ИмяТабличнойЧасти = "";
	
	СоответствиеНоменклатуры = Новый Соответствие;
	СоответствиеВидаЦен = Новый Соответствие;
	
	ЧтениеJSON = Новый ЧтениеJSON;
	ЧтениеJSON.ОткрытьФайл(ПутьКФайлу);
	
	Пока ЧтениеJSON.Прочитать() Цикл
		
		НачалоМассива = Ложь;

		TипJSON = ЧтениеJSON.ТипТекущегоЗначения;
		Если TипJSON = ТипЗначенияJSON.ИмяСвойства Тогда
		    ИмяСвойства = ЧтениеJSON.ТекущееЗначение;
			Значение = Неопределено;
		ИначеЕсли TипJSON = ТипЗначенияJSON.Число ИЛИ TипJSON = ТипЗначенияJSON.Строка ИЛИ TипJSON = ТипЗначенияJSON.Булево ИЛИ TипJSON = ТипЗначенияJSON.Null Тогда
		    Значение = ЧтениеJSON.ТекущееЗначение;
		ИначеЕсли TипJSON = ТипЗначенияJSON.Комментарий Тогда
		    Комментарий = ЧтениеJSON.ТекущееЗначение;
		КонецЕсли;

		Если TипJSON = ТипЗначенияJSON.НачалоМассива Тогда
			НачалоМассива = Истина;
			УровеньМассива = УровеньМассива + 1;
		КонецЕсли;

		Если УровеньМассива = 1 Тогда
			
			// Массив документов
			Если TипJSON = ТипЗначенияJSON.НачалоОбъекта Тогда
				ОписаниеДокумента.Очистить();
		        //СтрокаТовара = Док.ТабличнаяЧасть.Добавить();
			ИначеЕсли TипJSON = ТипЗначенияJSON.КонецОбъекта Тогда
				// Все данные собраны, можно приступать к обработке документа:
				
				ДанныеДокумента = Неопределено;
				ОписаниеДокумента.Свойство(ИмяТабличнойЧасти, ДанныеДокумента);
				КоличествоДокументов = КоличествоДокументов + 1;
				КоличествоТоваров = КоличествоТоваров + ДанныеДокумента.Количество();
				КоличествоОшибок = 0;
				
				РезультатОбработкиДокумента = СкорректироватьДокументУстановкаЦен(ОписаниеДокумента, ДанныеДокумента, СоответствиеНоменклатуры, СоответствиеВидаЦен,
					ИмяДокументаУстановкаЦенНоменклатуры, ИмяТаблицыТоваровДокумента, ОпределятьВидЦеныПоНаименованию);
				Если РезультатОбработкиДокумента <> Неопределено Тогда
					КоличествоНайденныхДокументов = КоличествоНайденныхДокументов + 1;
					Добавлено = Добавлено + РезультатОбработкиДокумента.Добавлено;
					КоличествоОшибок = РезультатОбработкиДокумента.КоличествоОшибок;
				КонецЕсли;
				Если РезультатОбработкиДокумента = Неопределено Или КоличествоОшибок > 0 Тогда
					КоличествоПроблемных = КоличествоПроблемных + 1;
				КонецЕсли;
				
				ОбщееКоличествоОшибок = ОбщееКоличествоОшибок + КоличествоОшибок;
				
			ИначеЕсли ЗначениеЗаполнено(ИмяСвойства) И ЗначениеЗаполнено(Значение) Тогда
				ОписаниеДокумента.Вставить(ИмяСвойства, Значение);
			КонецЕсли;
	
		ИначеЕсли УровеньМассива = 2 Тогда
			// Массив элементов документа
			Если TипJSON = ТипЗначенияJSON.НачалоМассива Тогда
				ДанныеДокумента = Новый Массив;
				ИмяТабличнойЧасти = ИмяСвойства;
				
			ИначеЕсли TипJSON = ТипЗначенияJSON.НачалоОбъекта Тогда
				ДанныеСтроки = Новый Структура;
				
			ИначеЕсли TипJSON = ТипЗначенияJSON.КонецОбъекта Тогда
				// Данные документа готовы к дальнейшей обработке
				ДанныеДокумента.Добавить(ДанныеСтроки);
				
			ИначеЕсли TипJSON = ТипЗначенияJSON.КонецМассива Тогда
				ОписаниеДокумента.Вставить(ИмяТабличнойЧасти, ДанныеДокумента);
								
			ИначеЕсли ЗначениеЗаполнено(ИмяСвойства) И ЗначениеЗаполнено(Значение) Тогда
				ДанныеСтроки.Вставить(ИмяСвойства, Значение);
			КонецЕсли;
			
		КонецЕсли;

		Если TипJSON = ТипЗначенияJSON.КонецМассива Тогда
		    УровеньМассива = УровеньМассива - 1;
		КонецЕсли;

	КонецЦикла;

	ЧтениеJSON.Закрыть();
	
	Результат = Новый Структура;
	Результат.Вставить("ИмяФайла", ПутьКФайлу);
	Результат.Вставить("КоличествоДокументов", КоличествоДокументов);
	Результат.Вставить("КоличествоТоваров", КоличествоТоваров);
	Результат.Вставить("КоличествоНайденныхДокументов", КоличествоНайденныхДокументов);
	Результат.Вставить("КоличествоПроблемных", КоличествоПроблемных);
	Результат.Вставить("Добавлено", Добавлено);
	Результат.Вставить("КоличествоОшибок", ОбщееКоличествоОшибок);
	Возврат Результат;

КонецФункции