Пример универсальной функции для создания схемы компоновки данных с группировкой колонок

10.10.18

Разработка - Универсальные функции

При использовании функции создания схемы компоновки данных согласно https://infostart.ru/public/575659/ было недостаточно возможности группировки колонок и вывода заголовка документа. Эти возможности и были добавлены в функцию.

Скачать файлы

Наименование Файл Версия Размер
Пример универсальной функции для создания схемы компоновки данных с группировкой колонок:
.epf 9,49Kb
1
.epf 9,49Kb 1 Скачать

Пример работы представлен в обработке:
1. В поле "Заголовок" указать заголовок документа
2. В поле "Текст запроса" ввести текст запроса
3. В поле "Группировка колонок" установить желаемую группировку колонок

Обработка протестирована в Документооборот 8 КОРП, редакция 2.1 (2.1.11.5). Платформа 8.3.12.1595. Текст доработанной функции приведен ниже:

// Создает схему компоновки данных для набора данных
//     запрос (типы: Строка, Запрос)
//     объект (типы: ТаблицаЗначений, ДеревоЗначений)
// Параметры:
//        НаборДанных    - Строка, Запрос, ТаблицаЗначений, ДеревоЗначений    - набор данных для создания схемы
//        СтруктураРесурсов    - Структура    - Структура полей ресурсов:
//            Ключ    - Имя поля
//            Значение    - Строка    - Агрегатная функция
//        ОписаниеКолонок    - ДеревоЗначений    - Описание выводимых колонок в формате:
//            Имя    - Имя колонки
//            Заголовок    - Заголовок колонки
//            ЭтоГруппа    - Истина, если колонка является группой, включающей другие колонки
//        Заголовок    - Строка    - Заголовок отчета
//        АвтоЗаполнениеДоступныхПолей    - Булево    - Значение флага автозаполнения доступных полей
//        ИмяСтандартногоМакетаОформления    - Строка    - Имя макета оформления
//
Функция СоздатьСхемуКомпоновкиДанных(НаборДанных, СтруктураРесурсов = Неопределено, ОписаниеКолонок = Неопределено, Заголовок = "", АвтоЗаполнениеДоступныхПолей = Истина, ИмяСтандартногоМакетаОформления = "")
    СКД = Новый СхемаКомпоновкиДанных;
    КоллекцияКолонок = Новый ТаблицаЗначений;
    КоллекцияКолонок.Колонки.Добавить("Имя");
    КоллекцияКолонок.Колонки.Добавить("ТипЗначения");
    КоллекцияКолонок.Колонки.Добавить("Заголовок");
    
    // Заполнение основных данных схемы
    ИсточникДанных = СКД.ИсточникиДанных.Добавить();
    ИсточникДанных.Имя = "ИсточникДанных";
    ИсточникДанных.ТипИсточникаДанных = "Local";
    
    Если ТипЗнч(НаборДанных) = Тип("Строка") или ТипЗнч(НаборДанных) = Тип("Запрос") Тогда
        ТекущийНаборДанных = СКД.НаборыДанных.Добавить(Тип("НаборДанныхЗапросСхемыКомпоновкиДанных"));
        ТекущийНаборДанных.Имя = "ОсновнойНабор";
        ТекущийНаборДанных.Запрос = ?(ТипЗнч(НаборДанных) = Тип("Строка"), НаборДанных, НаборДанных.Текст);
        ТекущийНаборДанных.ИсточникДанных = "ИсточникДанных";
        ТекущийНаборДанных.АвтоЗаполнениеДоступныхПолей = АвтоЗаполнениеДоступныхПолей;
        
        // Формирование коллекции колонок набора данных
        ПостроительЗапроса = Новый ПостроительЗапроса;
        Если ТипЗнч(НаборДанных) = Тип("Строка") Тогда
            ПостроительЗапроса.Текст = СокрЛП(НаборДанных);
        Иначе 
            ПостроительЗапроса.Текст = СокрЛП(НаборДанных.Текст);
        КонецЕсли;
        ПостроительЗапроса.ЗаполнитьНастройки();
        
        Для каждого Элт из ПостроительЗапроса.ВыбранныеПоля Цикл
            Если ОписаниеКолонок <> Неопределено И ОписаниеКолонок.Строки.Найти(Элт.Имя, "Имя", Истина) = Неопределено Тогда
                Продолжить;
            КонецЕсли;
            
            Колонка    = КоллекцияКолонок.Добавить();
            Колонка.Имя    = Элт.Имя;
            Колонка.Заголовок    = Элт.Представление;
            Колонка.ТипЗначения = ПостроительЗапроса.ДоступныеПоля[Элт.ПутьКДанным].ТипЗначения;
        КонецЦикла;
        
    ИначеЕсли ТипЗнч(НаборДанных) = Тип("ТаблицаЗначений") или ТипЗнч(НаборДанных) = Тип("ДеревоЗначений") Тогда
        ТекущийНаборДанных = СКД.НаборыДанных.Добавить(Тип("НаборДанныхОбъектСхемыКомпоновкиДанных"));
        ТекущийНаборДанных.Имя = "ОсновнойНабор";
        ТекущийНаборДанных.ИмяОбъекта = "ТаблицаИсточник";    
        ТекущийНаборДанных.ИсточникДанных = "ИсточникДанных";
        
        // Формирование коллекции колонок набора данных
        Для каждого Элт из НаборДанных.Колонки Цикл
            Если ОписаниеКолонок <> Неопределено И ОписаниеКолонок.Строки.Найти(Элт.Имя, "Имя", Истина) = Неопределено Тогда
                Продолжить;
            КонецЕсли;
            
            Колонка    = КоллекцияКолонок.Добавить();
            Колонка.Имя    = Элт.Имя;
            Колонка.Заголовок    = Элт.Заголовок;
            Колонка.ТипЗначения = Элт.ТипЗначения;
        КонецЦикла;
    Иначе            
        Возврат Неопределено;
    КонецЕсли;
    
    НастройкиПоУмолчанию = СКД.НастройкиПоУмолчанию;
    
    // Создание структуры.
    // Группировка, детальные записи и автовыбранное поле
    лГруппировка = НастройкиПоУмолчанию.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));
    лГруппировка.Использование = Истина;
    АвтоПоле = лГруппировка.Выбор.Элементы.Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));
    АвтоПоле.Использование = Истина;
    
    // Добавление ресурсов
    Если ТипЗнч(СтруктураРесурсов) = Тип("Структура") Тогда            
        Для Каждого ЭлСтруктуры Из СтруктураРесурсов Цикл
            // Проверка, а существует ли поле ресурса среди полей набора
            Если КоллекцияКолонок.Найти(ЭлСтруктуры.Ключ) <> Неопределено Тогда
                // Проверка на правильность указания агрегатной функции
                Если    ЭлСтруктуры.Значение = "Сумма" 
                    ИЛИ ЭлСтруктуры.Значение = "Среднее"
                    ИЛИ ЭлСтруктуры.Значение = "Максимум"
                    ИЛИ ЭлСтруктуры.Значение = "Минимум"
                    ИЛИ ЭлСтруктуры.Значение = "Количество" Тогда
                    
                    ПолеРесурса             = СКД.ПоляИтога.Добавить();
                    ПолеРесурса.ПутьКДанным = ЭлСтруктуры.Ключ;
                    ПолеРесурса.Выражение   = ЭлСтруктуры.Значение + "(" + ЭлСтруктуры.Ключ + ")";                    
                    
                ИначеЕсли ЭлСтруктуры.Значение = "КоличествоРазличные" Тогда                      
                    
                    ПолеРесурса             = СКД.ПоляИтога.Добавить();
                    ПолеРесурса.ПутьКДанным = ЭлСтруктуры.Ключ;
                    ПолеРесурса.Выражение   = "Количество(Различные " + ЭлСтруктуры.Ключ + ")";
                    
                КонецЕсли;
            КонецЕсли;    
        КонецЦикла;                                         
    КонецЕсли;
        
    // Добавление полей в набор        
    Для каждого НоваяКолонка Из КоллекцияКолонок Цикл
        ПолеНабора = ТекущийНаборДанных.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));
        ПолеНабора.Заголовок = СокрЛП(НоваяКолонка.Заголовок);
        ПолеНабора.Поле = СокрЛП(НоваяКолонка.Имя);
        ПолеНабора.ПутьКДанным = СокрЛП(НоваяКолонка.Имя);
        
        // Удалим неопределено и NULL
        Массив = Новый Массив;
        Для каждого ТекущийТип Из НоваяКолонка.ТипЗначения.Типы() Цикл
            Если ТекущийТип = Тип("Неопределено") или ТекущийТип = Тип("NULL") или ТекущийТип = Неопределено или ТекущийТип = Null Тогда 
                Продолжить; 
            КонецЕсли;
            Массив.Добавить(ТекущийТип);
        КонецЦикла;
        ПолеНабора.ТипЗначения = Новый ОписаниеТипов(Массив,НоваяКолонка.ТипЗначения.КвалификаторыЧисла,НоваяКолонка.ТипЗначения.КвалификаторыСтроки,НоваяКолонка.ТипЗначения.КвалификаторыДаты);
    КонецЦикла;
    
    // Добавление полей в выбранные поля
    Если ОписаниеКолонок = Неопределено Тогда
        Для каждого Колонка из КоллекцияКолонок Цикл
            ВыбранноеПолеКомпоновкиДанных = НастройкиПоУмолчанию.Выбор.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
            ВыбранноеПолеКомпоновкиДанных.Поле = Новый ПолеКомпоновкиДанных(ПолеНабора.ПутьКДанным);
            ВыбранноеПолеКомпоновкиДанных.Использование = Истина;
        КонецЦикла;
    Иначе
        ДобавитьПолеКомпоновкиДанныхВКоллекцию(НастройкиПоУмолчанию.Выбор.Элементы, ОписаниеКолонок.Строки, КоллекцияКолонок);
    КонецЕсли;
    
    // Заголовок
    Если не ПустаяСтрока(Заголовок) Тогда
        ЗначениеПараметраВывода = НастройкиПоУмолчанию.ПараметрыВывода.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("Заголовок"));
        ЗначениеПараметраВывода.Значение = Заголовок;
        ЗначениеПараметраВывода.Использование = Истина;
    КонецЕсли;
        
    // Оформление
    Если не ПустаяСтрока(ИмяСтандартногоМакетаОформления) Тогда
        ЗначениеПараметраВывода = НастройкиПоУмолчанию.ПараметрыВывода.НайтиЗначениеПараметра(Новый ПараметрКомпоновкиДанных("МакетОформления"));
        ЗначениеПараметраВывода.Значение = ИмяСтандартногоМакетаОформления;
        ЗначениеПараметраВывода.Использование = Истина;
    КонецЕсли;
        
    Возврат СКД;
КонецФункции

// ДобавитьПолеКомпоновкиДанныхВКоллекцию
//    процедура добавляет колонки в коллекцию с группировкой
//
// Параметры
//    КоллекцияКолонок    – Коллекция    – коллекция полей компоновки данных
//    ОписаниеКолонок    - КоллекцияСтрокДереваЗначений    – описание колонок табличной части с группировкой
//    КолонкиНабораДанных    - ТаблицаЗначений    – Колонки набора данных
//
Процедура ДобавитьПолеКомпоновкиДанныхВКоллекцию(КоллекцияКолонок, ОписаниеКолонок, КолонкиНабораДанных)
    Для каждого Элт из ОписаниеКолонок Цикл
        Если Элт.ЭтоГруппа Тогда
            Группа    = КоллекцияКолонок.Добавить(Тип("ГруппаВыбранныхПолейКомпоновкиДанных"));
            Группа.Заголовок    = Элт.Заголовок;
            Группа.Использование    = Истина;
            ДобавитьПолеКомпоновкиДанныхВКоллекцию(Группа.Элементы, Элт.Строки, КолонкиНабораДанных);
        Иначе
            Если КолонкиНабораДанных.Найти(Элт.Имя, "Имя") <> Неопределено Тогда
                Поле    = КоллекцияКолонок.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
                Поле.Поле = Новый ПолеКомпоновкиДанных(Элт.Имя);
                Поле.Заголовок    = Элт.Заголовок;
                Поле.Использование = Истина;
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
КонецПроцедуры // ДобавитьПолеКомпоновкиДанныхВКоллекцию

 

СКД

См. также

Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024    2669    0    John_d    8    

54

GUID в 1С 8.3 - как с ними быть

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.

12.02.2024    4604    atdonya    22    

45

Переоткрытие внешних обработок

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    3960    ke.92@mail.ru    16    

61

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    8816    YA_418728146    6    

141

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2071    21    progmaster    7    

3

Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    16143    133    sapervodichka    112    

129

Система контроля ведения учета [БСП]

Универсальные функции Механизмы типовых конфигураций БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данном материале рассмотрим типовой алгоритм подсистемы контроля учета БСП в конфигурациях на примерах.

18.07.2022    7243    quazare    8    

109
Оставьте свое сообщение