После выпуска релиза 1.0.56.10 появилось долгожданное заполнение КОСГУ для 502-х счетов в документе "Покупка материалов". Однако в описании к обновлению указан один неустраненный недостаток:
Внимание!
Если документом покупки материалов НДС принимается к вычету, то КЭК по проводкам Д-т 210.Р2, К-т 302.34, по-прежнему не заполняется. Поэтому, пока рекомендуем денежные обязательства вводить посредством документа «Принятое денежное обязательство» для возможности ручной корректировки КЭК.
Безусловно, верится, что это недоразумение будет устранено разработчиками, но при желании можно воспользоваться нижеописанным решением.
Далее приведена функция из модуля документа "МЗ_Покупка", которой можно заменить типовую (изменен только запрос).
Функция ПолучитьЗапросДляДО() Экспорт
Запрос = Новый Запрос;
Запрос.УстановитьПараметр("Ссылка", Ссылка);
Запрос.Текст =
"ВЫБРАТЬ
| МЗ_Покупка.Ссылка КАК ДокументОснование,
| МЗ_Покупка.Учреждение КАК Учреждение,
| МЗ_Покупка.Дата КАК ДатаДок,
| МЗ_Покупка.Баланс,
| МЗ_Покупка.НомерПервичногоДокумента,
| МЗ_Покупка.ДатаПервичногоДокумента,
| МЗ_Покупка.ВидПервичногоДокумента,
| МЗ_Покупка.КВД,
| МЗ_Покупка.ЛицевойСчет,
| МЗ_Покупка.КБКСчетКредита КАК КБК,
| МЗ_Покупка.СчетКредита КАК СчетКредитаОснования,
| МЗ_Покупка.СубконтоСчетКредита2 КАК Контрагент,
| ВЫБОР
| КОГДА ТИПЗНАЧЕНИЯ(МЗ_Покупка.СубконтоСчетКредита3) = ТИП(Документ.АвансПодотчетномуЛицу)
| ТОГДА ВЫРАЗИТЬ(МЗ_Покупка.СубконтоСчетКредита3 КАК Документ.АвансПодотчетномуЛицу).Обязательство
| ИНАЧЕ МЗ_Покупка.СубконтоСчетКредита3
| КОНЕЦ КАК Договор,
| МЗ_Покупка.РазделЛицевогоСчета,
| МЗ_Покупка.СубконтоОбязательств4
|ПОМЕСТИТЬ Шапка
|ИЗ
| Документ.МЗ_Покупка КАК МЗ_Покупка
|ГДЕ
| МЗ_Покупка.Ссылка = &Ссылка
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| Шапка.ДокументОснование,
| Шапка.Учреждение,
| Шапка.ДатаДок,
| Шапка.Баланс,
| Шапка.НомерПервичногоДокумента,
| Шапка.ДатаПервичногоДокумента,
| Шапка.ВидПервичногоДокумента,
| Шапка.КВД,
| Шапка.ЛицевойСчет
|ИЗ
| Шапка КАК Шапка
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ РАЗРЕШЕННЫЕ
| Шапка.КВД,
| Шапка.КБК,
| Шапка.СчетКредитаОснования,
| Шапка.Контрагент,
| Шапка.Договор,
| Шапка.РазделЛицевогоСчета,
| Шапка.СубконтоОбязательств4,
| СУММА(ЕПСБУДвиженияССубконто.Сумма) КАК Сумма,
| ЕПСБУДвиженияССубконто.СубконтоДт1 КАК КОСГУКорр
|ИЗ
| РегистрБухгалтерии.ЕПСБУ.ДвиженияССубконто(
| ,
| ,
| Активность = ИСТИНА
| И Регистратор = &Ссылка
| И СчетКт В
| (ВЫБРАТЬ
| Таб.СчетКредитаОснования
| ИЗ
| Шапка КАК Таб)
| И ПОДСТРОКА(СчетДт.Код, 1, 3) <> ""210"",
| ,
| ) КАК ЕПСБУДвиженияССубконто,
| Шапка КАК Шапка
|
|СГРУППИРОВАТЬ ПО
| Шапка.КВД,
| Шапка.РазделЛицевогоСчета,
| Шапка.Договор,
| Шапка.Контрагент,
| Шапка.СчетКредитаОснования,
| Шапка.СубконтоОбязательств4,
| Шапка.КБК,
| ЕПСБУДвиженияССубконто.СубконтоДт1
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| Шапка.КВД,
| Шапка.КБК,
| Шапка.СчетКредитаОснования,
| Шапка.Контрагент,
| Шапка.Договор,
| Шапка.РазделЛицевогоСчета,
| Шапка.СубконтоОбязательств4,
| МЗ_ПокупкаМатериалы.СуммаНДС,
| МЗ_ПокупкаМатериалы.КОСГУСчетДебета
|ИЗ
| Шапка КАК Шапка,
| Документ.МЗ_Покупка.Материалы КАК МЗ_ПокупкаМатериалы
|ГДЕ
| МЗ_ПокупкаМатериалы.Ссылка = &Ссылка
| И МЗ_ПокупкаМатериалы.Ссылка.УчитыватьНДС = ИСТИНА";
МассивРезультатов = Запрос.ВыполнитьПакет();
СтруктураДанных = Новый Структура;
СтруктураДанных.Вставить("Шапка", МассивРезультатов[1]);
СтруктураДанных.Вставить("Таблица", МассивРезультатов[2]);
Возврат СтруктураДанных;
КонецФункции
Вступайте в нашу телеграмм-группу Инфостарт
