Поле "Отбор" в управляемой форме используя СКД

17.05.19

Разработка - СКД

Пример, который осуществляет отбор ссылок при помощи СКД, макет компоновки создается программно.

Скачать файлы

Наименование Файл Версия Размер
:Отбор кодом
.epf 8,33Kb
24
.epf 8,33Kb 24 Скачать

Несмотря на опыт работы, такая задача, как вытащить отбор СКД на управляемую форму, часто становится многочасовой потерей времени.

Поэтому реализовал пример, который осуществляет отбор ссылок при помощи СКД.

Для выбора объекта метаданных используется БСП 2.1  - 2.4, но имя объекта метаданных можно написать текстом.

Работает, например, в УТ 11.4.

Для реализации примера достаточно добавить поля в новую обработку согласно изображениям. У поля "ОбъектНазначения" 2 события:

"ОбъектНазначенияОкончаниеВводаТекста" И "ОбъектНазначенияНачалоВыбора", параметр кнопка выбора "Да"

И добавлена одна команда "Отобрать" с одноименным событием.

Привожу модуль формы:

// СКД программно

// Процедура удаляет все элементы настроек СхемыКД 
//
&НаСервереБезКонтекста
Процедура ОчиститьНастройкиСКД(Настройки)
	
	Если Настройки = Неопределено ИЛИ Тип(Настройки) <> Тип("НастройкиКомпоновкиДанных") Тогда
		Возврат;
	КонецЕсли;
	
	Для Каждого Параметр Из Настройки.ПараметрыДанных.Элементы Цикл
		Параметр.Значение = Неопределено;
		Параметр.Использование = Ложь;
	КонецЦикла;
	
	Настройки.ПользовательскиеПоля.Элементы.Очистить();
	Настройки.Отбор.Элементы.Очистить();
	Настройки.Порядок.Элементы.Очистить();
	Настройки.Структура.Очистить();
	Настройки.Выбор.Элементы.Очистить();
	
КонецПроцедуры

// Добавляет отбор в набор отборов компоновщика или группы отборов.
// 
&НаСервереБезКонтекста
Функция ДобавитьОтбор(ЭлементСтруктуры, Знач Поле, Значение, ВидСравнения = Неопределено, Использование = Истина) Экспорт
	
	Если ТипЗнч(Поле) = Тип("Строка") Тогда
		Поле = Новый ПолеКомпоновкиДанных(Поле);
	КонецЕсли;
	
	Если ТипЗнч(ЭлементСтруктуры) = Тип("КомпоновщикНастроекКомпоновкиДанных") Тогда
		Отбор = ЭлементСтруктуры.Настройки.Отбор;
	Иначе
		Отбор = ЭлементСтруктуры;
	КонецЕсли;
	
	Если ВидСравнения = Неопределено Тогда
		ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
	КонецЕсли;
	
	НовыйЭлемент = Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
	НовыйЭлемент.Использование  = Использование;
	НовыйЭлемент.ЛевоеЗначение  = Поле;
	НовыйЭлемент.ВидСравнения   = ВидСравнения;
	НовыйЭлемент.ПравоеЗначение = Значение;
	Возврат НовыйЭлемент;
	
КонецФункции

// Создает и сохраняет компоновку данных во временном хранилище.
// Важно то что настройки не могут существовать без схемы компоновки.
&НаСервере
Процедура УстановитьКомпоновку()
	
	Если НЕ ЗначениеЗаполнено(ОбъектНазначения) Тогда
		Возврат;
	КонецЕсли;
	
	
	ОчиститьНастройкиСКД(КомпоновщикНастроек.Настройки);
	СхемаКомпоновки = Новый СхемаКомпоновкиДанных();		
	
	Источник = СхемаКомпоновки.ИсточникиДанных.Добавить();
	Источник.Имя = "ИсточникДанных";
	Источник.СтрокаСоединения="";
	Источник.ТипИсточникаДанных = "local";
	
	
	НаборДанных = СхемаКомпоновки.НаборыДанных.Добавить(Тип("НаборДанныхЗапросСхемыКомпоновкиДанных"));
	НаборДанных.Запрос = "Выбрать * из "+ОбъектНазначения;
	НаборДанных.Имя = "НаборДанныхЗапроса";
	НаборДанных.ИсточникДанных = Источник.Имя;
	НаборДанных.АвтоЗаполнениеДоступныхПолей = Истина;
	
	АдресСхемы = ПоместитьВоВременноеХранилище(СхемаКомпоновки, УникальныйИдентификатор);
	
	КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(АдресСхемы)); 
	
	ГруппировкаСКД = КомпоновщикНастроек.Настройки.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));
	ГруппировкаСКД.Использование = Истина;
	
	ПолеОбъект = Новый ПолеКомпоновкиДанных("Ссылка");
	
	ВыбранноеПоле = ГруппировкаСКД.Выбор.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
	ВыбранноеПоле.Использование = Истина;
	ВыбранноеПоле.Поле = ПолеОбъект;
	
	Для каждого ЭлементДоступногоОтбора Из КомпоновщикНастроек.Настройки.ДоступныеПоляОтбора.Элементы Цикл
		ДобавитьОтбор(КомпоновщикНастроек.Настройки.Отбор, ЭлементДоступногоОтбора.Поле, , ВидСравненияКомпоновкиДанных.Равно, Ложь);
	КонецЦикла;
	
КонецПроцедуры


// Команда Отобрать на сервере.
&НаСервере
Процедура КомандаНаСервере()
	
	СКД = ПолучитьИзВременногоХранилища(АдресСхемы);
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СКД, КомпоновщикНастроек.ПолучитьНастройки(),,,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
	
	ПроцессорКД = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКД.Инициализировать(МакетКомпоновки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
	ПроцессорВывода.ОтображатьПроцентВывода = Истина;
	Результат = Новый ТаблицаЗначений;
	ПроцессорВывода.УстановитьОбъект(Результат);
	ПроцессорВывода.Вывести(ПроцессорКД);
	
	
	ТаблицаРезультата.Загрузить( Результат);
	
КонецПроцедуры

// Команда Отобрать
&НаКлиенте
Процедура Отобрать(Команда)
	КомандаНаСервере()
КонецПроцедуры

// выбор метаданного

&НаКлиенте
Процедура ОбъектНазначенияОкончаниеВводаТекста(Элемент, Текст, ДанныеВыбора, СтандартнаяОбработка)
	Оповестить("УстановитьКомпоновку",Текст,Этаформа);
КонецПроцедуры

&НаКлиенте
Процедура ОбработкаОповещения(ИмяСобытия, Параметр, Источник)
	Если ИмяСобытия = "ВыборОбъектовМетаданных" Тогда
		ОбъектНазначения = Параметр[0].Значение;
		УстановитьКомпоновку();
	ИначеЕсли ИмяСобытия = "УстановитьКомпоновку" Тогда
		ОбъектНазначения = Параметр;
		УстановитьКомпоновку();
	КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура ОбъектНазначенияНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	ПараметрыФормы = ПодготовитьПараметрыФормыВыборОбъектовМетаданных();
	ОткрытьФорму("ОбщаяФорма.ВыборОбъектовМетаданных", ПараметрыФормы,Элемент);
	СтандартнаяОбработка = Ложь;
КонецПроцедуры

&НаСервере
Функция ПодготовитьПараметрыФормыВыборОбъектовМетаданных()
	
	ФильтрПоОбъектамМетаданных = Новый СписокЗначений;
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
	"ВЫБРАТЬ
	|	ИдентификаторыОбъектовМетаданных.ПолноеИмя
	|ИЗ
	|	Справочник.ИдентификаторыОбъектовМетаданных КАК ИдентификаторыОбъектовМетаданных
	|ГДЕ
	|	ИдентификаторыОбъектовМетаданных.Родитель В(&Родитель)";
	
	Родитель = Новый Массив;
	Родитель.Добавить(Справочники.ИдентификаторыОбъектовМетаданных.НайтиПоНаименованию("Документы"));
	Родитель.Добавить(Справочники.ИдентификаторыОбъектовМетаданных.НайтиПоНаименованию("Справочники"));
	
	Запрос.УстановитьПараметр("Родитель", Родитель);
	
	Результат = Запрос.Выполнить();
	
	ВыборкаДетальныеЗаписи = Результат.Выбрать();
	
	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
		ФильтрПоОбъектамМетаданных.Добавить(ВыборкаДетальныеЗаписи.ПолноеИмя);
	КонецЦикла;
	
	ПараметрыФормы = Новый Структура;
	ПараметрыФормы.Вставить("ФильтрПоОбъектамМетаданных", ФильтрПоОбъектамМетаданных);
	ПараметрыФормы.Вставить("ВыборЕдинственного", Истина);
	ПараметрыФормы.Вставить("РежимВыбора", Истина);
	ПараметрыФормы.Вставить("Заголовок", НСтр("ru = 'Назначение дополнительной обработки'"));
	
	Возврат ПараметрыФормы;
КонецФункции


 

Отбор форма СКД пример программно схема компоновки данных УФ управляемые

См. также

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

13000 руб.

02.09.2020    119920    656    389    

701

Генератор схемы компоновки данных (СКД), написание кода схемы программно

Инструментарий разработчика СКД Платформа 1С v8.3 Конфигурации 1cv8 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

По выбранной схеме компоновки данных генерирует программный код, который генерирует СКД, аналогичную исходной схеме. Есть дополнительные инструменты для просмотра дерева схемы, сравнение исходной схемы и полученной по коду, а также сравнение изменений в сгенерированном коде для исходной схемы и для измененной.

3 стартмани

05.02.2024    3889    24    obmailok    17    

63

Набор-объект для СКД по тексту или запросу

Запросы СКД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    1964    2    Yashazz    0    

29

СКД на JavaScript в 1С

СКД WEB-интеграция Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Долгое время поддерживаю web-портал, в котором появилась необходимость создавать отчеты. Просмотрев различные фреймворки на js, я решил сделать свое решение, которое позволяло бы быстро разрабатывать и добавлять новые отчеты на web-портал.

2 стартмани

11.12.2023    8029    20    John_d    25    

122

Использование менеджера временных таблиц в СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Бесплатно (free)

Рассмотрим еще не получивший широкого распространения способ работы с внешними данным в СКД. В процессе обсуждения работы с СКД выяснилось, что многие не знакомы со способом помещения туда временной таблицы, полученной предварительно. Статья будет полезна разработчикам, знакомым с программным созданием СКД.

05.12.2023    4528    PROSTO-1C    13    

61

Модель СКД

Инструментарий разработчика СКД Платформа 1С v8.3 Система компоновки данных Абонемент ($m)

DSL для работы с СКД.

1 стартмани

15.11.2023    5710    15    kalyaka    5    

85

Пользовательские настройки отчетов 1С. Часть 1. Простые и расширенные настройки

СКД Инструкции пользователю Платформа 1С v8.3 Конфигурации 1cv8 1С:Бухгалтерия 3.0 Россия Бесплатно (free)

Простые приемы работы с отчетами на СКД. Что нужно знать пользователю про настройку отчетов, чтобы использовать их на полную катушку.

18.09.2023    6331    accounting_cons    5    

29

Разрыв страницы в СКД. Легко!

СКД Платформа 1С v8.3 Система компоновки данных Бесплатно (free)

Когда отчет надо разделить по страницам, это всегда проблема для разработчика. Поскольку в СКД нет стандартных вариантов, как это сделать. Нашел (на свой взгляд) самое простое и оптимальное решение.

01.09.2023    4407    KVIKS    15    

80
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. DrAku1a 1678 16.06.21 10:04 Сейчас в теме
БСП
ОтборыСписковКлиентСервер.УстановитьЭлементОтбораСписка
Вместо
Функция ДобавитьОтбор


Ошибка в
Если Настройки = Неопределено ИЛИ Тип(Настройки) <> Тип("НастройкиКомпоновкиДанных") Тогда...

Вместо "Тип(Настройки)" надо "ТипЗнч(Настройки)".
Проверка на "Неопределено" в данном случае - необязательна.
2. Pryanishnikov_Vladimir 18.10.21 15:35 Сейчас в теме
Функционал доп реквизитов бы добавить.
3. fom_iv@list.ru 06.11.21 18:59 Сейчас в теме
Спасибо за обработку. Все лаконично и четко. У меня похожая задача, но для нее решил, что еще короче будет использовать динамический список (ДС). Его легко добавить на форму. У него уже есть СКД-отбор (тоже перетягиваем на форму). У меня пользователь выбирает сочетание нек. параметров из доп.таблицы. При выборе - запихиваем их в отбор (программно). В ДС пользователь видит соответствующие записи справочника. При желании пользователь может сам поправить отбор "вручную". Получается наглядно и просто.
4. user1795343 06.10.22 14:32 Сейчас в теме
ещё нужно у формы добавить "обработка оповещения" событие
5. salus 28 06.07.23 12:06 Сейчас в теме
А можно это использовать для регистра сведений?
6. salus 28 06.07.23 12:17 Сейчас в теме
когда подставляю настройку при компановке. "Не обнаружена ссылка"
Для документов и справочников все
норм
7. salus 28 06.07.23 12:33 Сейчас в теме
Это ограничение использования настроек? Только для ссылочных данных или я не прав?
Оставьте свое сообщение