Работа с графической схемой в объектной модели DOM

04.06.19

Пример кода для работы с графической схемой в объектной модели DOM, платформа 8.3.12.

Файлы

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование	Скачано	Купить файл	По подписке PRO
Пример конфигурации .cf 21,63Kb ver:1 19	19	2 500 руб. Купить	1 SM Скачать

Вы можете заказать платную доработку или адаптацию этой разработки под вашу конфигурацию на «Бирже заказов».

0% комиссии — оплата напрямую исполнителю;
Исполнители любого масштаба — от отдельных специалистов до команд под проект;
Прямой обмен контактами между заказчиком и исполнителем;
Безопасная сделка — при необходимости;
Рейтинги, кейсы и прозрачная система откликов.

За основу взята статья Виталия Барилко //infostart.ru/public/336564/

Изучая возможность создания универсального конструктора процессов в самописной конфигурации, естественно первой же мыслью было использовать родные бизнес процессы платформы с подменой карты маршрута. И самая первая сложность - как при создании карты маршрута на стороне клиента суметь понять ее состав и связи.

Привожу полный код модуля, отвечающий за логику работы, и пример его использования.

Общий модуль "УниверсальныеКартыМаршрутовКлиентСервер"


#Область ПрограммныйИнтерфейс

Функция ПолучитьОписаниеЭлементовГрафическойСхемы() Экспорт
	
	// значения itemType
	
	Результат = Новый Соответствие;
	
	Результат.Вставить(0, "Декорация");
	Результат.Вставить(1, "Линия");
	Результат.Вставить(2, "Старт");
	Результат.Вставить(3, "Завершение");
	Результат.Вставить(4, "Условие");
	Результат.Вставить(5, "Действие");
	Результат.Вставить(6, "Выбор варианта");
	Результат.Вставить(7, "Разделение");
	Результат.Вставить(8, "Слияние");
	Результат.Вставить(9, "Точка обработки");
	Результат.Вставить(10, "Вложенный бизнес-процесс");
	
	Возврат Результат;
	
КонецФункции


Функция ПолучитьXMLГрафическойСхемы(ГрафическаяСхема) Экспорт
	
	Результат = "";
	
	ЗаписьXML = Новый ЗаписьXML;
	ЗаписьXML.УстановитьСтроку();
	
	Сериализатор = Новый СериализаторXDTO(ФабрикаXDTO);
	Сериализатор.ЗаписатьXML(ЗаписьXML, ГрафическаяСхема, НазначениеТипаXML.Явное);
	
	Результат = ЗаписьXML.Закрыть();
	
	Возврат Результат;
	
КонецФункции

Функция ПолучитьDOMГрафическойСхемы(ГрафическаяСхема) Экспорт
	
	Результат = Неопределено;
	
	XMLГрафическойСхемы = ПолучитьXMLГрафическойСхемы(ГрафическаяСхема);
	
	ЧтениеXML = Новый ЧтениеXML;
	ЧтениеXML.УстановитьСтроку(XMLГрафическойСхемы);
	
	ПостроительDOM = Новый ПостроительDOM;
	
	Результат = ПостроительDOM.Прочитать(ЧтениеXML);
	
	Возврат Результат;
	
КонецФункции

Функция ПолучитьГрафическуюСхемуИзXML(СтрокаXML) Экспорт
	
	Результат = Неопределено;
	
	ЧтениеXML = Новый ЧтениеXML;
	ЧтениеXML.УстановитьСтроку(СтрокаXML);
	
	Сериализатор = Новый СериализаторXDTO(ФабрикаXDTO);
	
	Результат = Сериализатор.ПрочитатьXML(ЧтениеXML);
	
	Возврат Результат;
	
КонецФункции

Функция ПолучитьГрафическуюСхемуИзDOM(ДокументDOM) Экспорт
	
	Результат = Неопределено;
	
	ЗаписьXML = Новый ЗаписьXML;
	ЗаписьXML.УстановитьСтроку();
	
	ЗаписьDOM = Новый ЗаписьDOM();
	ЗаписьDOM.Записать(ДокументDOM.ДочерниеУзлы[0] , ЗаписьXML);
	
	XMLГрафическойСхемы = ЗаписьXML.Закрыть();
	
	ЧтениеXML = Новый ЧтениеXML;
	ЧтениеXML.УстановитьСтроку(XMLГрафическойСхемы);
	
	Сериализатор = Новый СериализаторXDTO(ФабрикаXDTO);
	
	Результат = Сериализатор.ПрочитатьXML(ЧтениеXML);
	
	Возврат Результат;
	
КонецФункции


Функция НайтиЭлементПоЗначениюСвойства(ДокументDOM, ИмяСвойства, Значение) Экспорт
	
	Результат = Неопределено;
	
	СписокЭлементовDOM = ДокументDOM.ПолучитьЭлементыПоИмени(ИмяСвойства);
	
	Для Каждого Элемент Из СписокЭлементовDOM Цикл
		
		Если Элемент.ТекстовоеСодержимое = Значение Тогда
			
			Результат = Элемент.РодительскийУзел;
			Прервать;
			
		КонецЕсли;
		
	КонецЦикла;
	
	Возврат Результат;
	
КонецФункции

Функция ПолучитьЗначениеСвойстваЭлемента(ЭлементDOM, ИмяСвойства) Экспорт
	
	СписокЭлементовDOM = ЭлементDOM.ПолучитьЭлементыПоИмени(ИмяСвойства);
	
	Если СписокЭлементовDOM.Количество() = 1 Тогда
		Возврат СписокЭлементовDOM[0].ТекстовоеСодержимое;
	Иначе
		Возврат Неопределено;
	КонецЕсли;
	
КонецФункции

Процедура УстановитьЗначениеСвойстваЭлемента(ЭлементDOM, ИмяСвойства, Значение) Экспорт
	
	СписокЭлементовDOM = ЭлементDOM.ПолучитьЭлементыПоИмени(ИмяСвойства);
	
	Если СписокЭлементовDOM.Количество() = 1 Тогда
		СписокЭлементовDOM[0].ТекстовоеСодержимое = Значение;
	КонецЕсли;
	
КонецПроцедуры

#КонецОбласти

Хранить карту маршрута будем в справочнике БизнесПроцессы в реквизите КартаМаршрутаXML.

Форма элемента справочника имеет следующую структуру:

Модуль формы элемента справочника


#Область ОбработчикиСобытийФормы

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	
	Если ЗначениеЗаполнено(Объект.КартаМаршрутаXML) Тогда
		ГрафическаяСхема = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьГрафическуюСхемуИзXML(Объект.КартаМаршрутаXML);
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура ПередЗаписью(Отказ, ПараметрыЗаписи)
	
	Объект.КартаМаршрутаXML = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьXMLГрафическойСхемы(ГрафическаяСхема);
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийГрафическойСхемы

&НаКлиенте
Процедура ГрафическаяСхемаПриИзменении(Элемент)
	
	Модифицированность = Истина;
	
	ОписаниеЭлементов = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьОписаниеЭлементовГрафическойСхемы();
	
	ИдентификаторыЭлементов = Новый Массив;
	
	// пример работы с DOM графической схемы
	ДокументDOM = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьDOMГрафическойСхемы(ГрафическаяСхема);
	
	// каждый элемент схемы "item" представлен свойством "itemType"
	СписокЭлементовDOM = ДокументDOM.ПолучитьЭлементыПоИмени("itemType");
	
	Для Каждого Элемент Из СписокЭлементовDOM Цикл
		
		ТипЭлемента = Число(Элемент.ТекстовоеСодержимое);
		
		Если ТипЭлемента = 0
			ИЛИ ТипЭлемента = 1 Тогда
			
			// декорации и линии пропускаем
			Продолжить;
			
		КонецЕсли;
		
		УзелТочкиМаршрута = Элемент.РодительскийУзел;
		
		// каждый элемент схемы имеет itemId
		ИдентификаторЭлемента = Число(УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьЗначениеСвойстваЭлемента(УзелТочкиМаршрута, "itemId"));
		
		// заполняеем перечень текущих идентификаторов
		ИдентификаторыЭлементов.Добавить(ИдентификаторЭлемента);
		
		// находим, есть ли данный узел в точках маршрута
		ПараметрыОтбора = Новый Структура("ИдентификаторЭлемента", ИдентификаторЭлемента);
		
		РезультатПоиска = Объект.ТочкиМаршрута.НайтиСтроки(ПараметрыОтбора);
		
		Если РезультатПоиска.Количество() = 0 Тогда
			
			НоваяСтрока = Объект.ТочкиМаршрута.Добавить();
			
			НоваяСтрока.ИдентификаторЭлемента = ИдентификаторЭлемента;
			НоваяСтрока.ТипЭлемента = ТипЭлемента;
			НоваяСтрока.ТипЭлементаПредставление = ОписаниеЭлементов[ТипЭлемента];
			НоваяСтрока.Наименование = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьЗначениеСвойстваЭлемента(УзелТочкиМаршрута, "content");
			
		КонецЕсли;
		
		// пример, код установки красной линии (текущее действие в запущенном БП)
		Если ТипЭлемента = 5 Тогда
			
			// данные свойства нашел опытным путем, может что и не так, но работает...
			УниверсальныеКартыМаршрутовКлиентСервер.УстановитьЗначениеСвойстваЭлемента(УзелТочкиМаршрута, "passageState", "2");
			УниверсальныеКартыМаршрутовКлиентСервер.УстановитьЗначениеСвойстваЭлемента(УзелТочкиМаршрута, "isAddrZoneDivideValid", "true");
			УниверсальныеКартыМаршрутовКлиентСервер.УстановитьЗначениеСвойстваЭлемента(УзелТочкиМаршрута, "addrZoneDivideYPos", "16");
			
		КонецЕсли;
		
	КонецЦикла;
	
	ГрафическаяСхема = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьГрафическуюСхемуИзDOM(ДокументDOM);
	
	// удалим из таблицы точек маршрута те элементы, которые удалили на схеме
	СтрокиКУдалению = Новый Массив;
	
	Для Каждого СтрокаТЧ Из Объект.ТочкиМаршрута Цикл
		
		Если ИдентификаторыЭлементов.Найти(СтрокаТЧ.ИдентификаторЭлемента) = Неопределено Тогда
			СтрокиКУдалению.Добавить(СтрокаТЧ);
		КонецЕсли;
		
	КонецЦикла;
	
	Для Каждого СтрокаТЧ Из СтрокиКУдалению Цикл
		Объект.ТочкиМаршрута.Удалить(СтрокаТЧ);
	КонецЦикла;
	
КонецПроцедуры

#КонецОбласти

#Область ОбработчикиСобытийЭлементовТаблицыФормыТочкиМаршрута

&НаКлиенте
Процедура ТочкиМаршрутаНаименованиеПриИзменении(Элемент)
	
	ТекущиеДанные = Элементы.ТочкиМаршрута.ТекущиеДанные;
	
	ИдентификаторЭлемента = Строка(ТекущиеДанные.ИдентификаторЭлемента);
	
	ДокументDOM = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьDOMГрафическойСхемы(ГрафическаяСхема);
	
	УзелТочкиМаршрута = УниверсальныеКартыМаршрутовКлиентСервер.НайтиЭлементПоЗначениюСвойства(ДокументDOM, "itemId", ИдентификаторЭлемента);
	УниверсальныеКартыМаршрутовКлиентСервер.УстановитьЗначениеСвойстваЭлемента(УзелТочкиМаршрута, "content", ТекущиеДанные.Наименование);
	
	ГрафическаяСхема = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьГрафическуюСхемуИзDOM(ДокументDOM);
	
КонецПроцедуры

#КонецОбласти

Пример работы:

В файлах приложил демо конфигурацию примера.

Вступайте в нашу телеграмм-группу Инфостарт

графическая схема DOM пример кода

+51 –

См. также

ДО+ для 1С:Документооборот

Универсальные функции 1С 8.3 1С:Документооборот Россия Платные (руб)

ДО+ — расширение конфигурации, в котором собран постоянно пополняемый набор из 33 востребованных доработок для 1С:Документооборот КОРП 3.0: согласование задач прямо из мессенджеров MAX и Telegram, отзыв согласования и исполнения, гибкие повторные круги, эскалация с точностью до минут, контроль исполнительской дисциплины, выгрузка вложений в ZIP и склейка PDF, реестр документов в Excel, проверка дублей контрагентов и регистрационных номеров. Каждая возможность активируется отдельным флажком в режиме предприятия — включается только то, что нужно конкретной организации. Список функций расширяется с каждым релизом — текущая версия 2.1.0. Режим AddOn: типовая конфигурация не модифицируется, обновления ДО ставятся штатно, дополнительные лицензии и внешние компоненты не требуются. Внедрение силами администратора — около часа.

30000 руб.

09.07.2026 1397 1 0

Заполнение формул в файлах Excel (кроссплатформенное решение)

Загрузка и выгрузка в Excel Универсальные функции Разработчик 1С:Предприятие 8 Россия Бесплатно (free)

Описанный ниже подход позволяет в три шага заполнять формулы в Excel файлы, вне зависимости от ОС сервера (MS Windows Server или Linux). Подход подразумевает отказ от работы с COM-объектом в пользу работы через "объектную модель документа" (DOM).

30.10.2025 8735 Abysswalker 11

Отключение уведомления "Расширение конфигурации неактивно"

Универсальные функции Работа с интерфейсом Разработчик 1С:Предприятие 8 Бесплатно (free)

Порой необходимо временно отключить расширение 1С, не удаляя его, чтобы не потерять данные. Но в этом случае при каждом запуске всем будет лезть уведомление о неактивном расширении, хотя очевидно, это техническая информация, которой не стоит лишний раз пугать пользователей.

14.05.2025 14471 DeerCven 16

В помощь разработчику: преобразование табличного документа в запрос

Инструментарий разработчика Универсальные функции Запросы Разработчик 1С:Предприятие 8 1C:Бухгалтерия 1С:Бухгалтерия 3.0 1С:Зарплата и Управление Персоналом 3.x Бесплатно (free)

Внешняя обработка для создания запроса на основании табличных данных.

22.07.2024 11946 276 ixijixi 10

Загрузка табличного документа в таблицу значений. Пять строк кода, которые изменили мир

Универсальные функции Разработчик 1С:Предприятие 8 1C:Бухгалтерия Бесплатно (free)

Благодаря этим пяти строчкам можно больше не заморачиваться с загрузкой из внешних файлов. Пользуюсь везде, всегда и постоянно.

21.05.2024 68728 dimanich70 87

181

Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Разработчик 1С:Предприятие 8 1C:Бухгалтерия Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024 9283 7 John_d 13

GUID в 1С 8.3

Универсальные функции Разработчик Стажер 1С:Предприятие 8 1C:Бухгалтерия Бесплатно (free)

Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.

12.02.2024 85776 atdonya 31

Переоткрытие внешних обработок

Универсальные функции Разработчик 1С:Предприятие 8 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023 13473 ke.92@mail.ru 18

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. Yashazz 4931 04.06.19 14:20 Сейчас в теме

Можно подробнее? Вы динамически строите граф.схему с помощью DOM?

2. botokash 403 04.06.19 14:31 Сейчас в теме

(1) Построение схемы происходит штатными командами платформы для работы с графической схемой. С помощью DOM я лишь анализирую состав схемы, могу получать все ее элементы и связи, а так же сохранять графическую схему в XML строку и в обратную сторону получать объект графической схемы из XML строки.

3. Yashazz 4931 04.06.19 17:01 Сейчас в теме

1. Ценность идеи исходной статьи - в возможности модифицировать схему. Платформа просто не имеет штатных команд такого рода. Какие команды вы имеете в виду?
2. Зачем использовать DOM для чтения состава, если как раз это платформа позволяет сделать удобно и просто? Изврата ради?

4. botokash 403 04.06.19 18:55 Сейчас в теме

(3) По первому вопросу конкретизируйте, о каких командах вы говорите? Я говорил о стандартной командной панели, которая генерируется платформой для элемента формы графической схемы. Модифицируйте ими схему как хотите.
По второму вопросу, DOM позволяет как и читать, так и менять схему программно, причем одновременно и без переключения на другой объект. При этом прочитать данных об элементах схемы в DOM можно гораздо больше. Никакого изврата тут не вижу.

7. Yashazz 4931 05.06.19 11:05 Сейчас в теме

(4) Насчёт команд понял, ценность этого фрагмента стремится к нулю, т.к. это штатный инструмент платформы и вставить его куда надо - минутное дело. Что умеет DOM, я прекрасно знаю; я вот пытаюсь понять - вы-то его применяете для модификации схемы или только для чтения?

8. botokash 403 05.06.19 11:24 Сейчас в теме

(7) Пример модификации есть, обратите внимание на приложенный код. Я показываю пример работы с графической схемой полностью через DOM, как чтения, так и модификации. Как программно добавить элементы на схему - ссылка указана, разобраться в коде на пол часа работы.

10. Yashazz 4931 05.06.19 13:05 Сейчас в теме

(8) Уважаемый, я о том, как добавлять программно, задолго до вас несколько готовых разработок сделал)) Которые кстати сказать на ИС лежат.

В приложенном документе я вижу 2 вызова функций из неведомого модуля, а что там и как - я не телепат, чтоб понять. Ну хорошо, значит, меняете схему через DOM. Ну что ж, как вариант. Я в каком-то из решений года 2-3 назад тоже так делал, и должен сказать, что бывают случаи, когда обратное построение схемы из xml, валидного с точки зрения DOM, не прокатывает. Не жрёт его сериализатор 1С почему-то. Поэтому будьте внимательны и не позиционируйте решение как универсальное, там случаются подводные камни, особенно с элементом "Точка выбора варианта".

11. botokash 403 05.06.19 13:42 Сейчас в теме

(10) "Неведомый" модуль так же приложен в статье кодом, без скачивания) Ни в коем разе не позиционирую свою статью как готовое решение. По факту есть лишь заготовка общего модуля и пару примеров работы с ним. Как мне кажется, тому кто ищет конкретный ответ на вопрос как, этого должно хватить что бы понять принцип и уже самому создавать свои нетленки)

9. botokash 403 05.06.19 11:35 Сейчас в теме

(8) Конкретизирую про модификацию, имеем исходную графическую схему "ГрафическаяСхема"

// 1. Получили ДокументDOM
ДокументDOM = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьDOMГрафическойСхемы(ГрафическаяСхема); // 
// 2. ...
// свой код чтения и модификации
// 3. получаем обратно графическую схему из ДокументDOM, PROFIT!!!
ГрафическаяСхема = УниверсальныеКартыМаршрутовКлиентСервер.ПолучитьГрафическуюСхемуИзDOM(ДокументDOM);

5. arsvlg 05.06.19 10:10 Сейчас в теме

Интересно. Спасибо за статью. Попробую.
Единственное, нужно поправить скриншот структуры справочника. В табличной части отображены не все реквизиты.

6. botokash 403 05.06.19 10:38 Сейчас в теме

(5) "ТипЭлементаПредставление" и "Наименование" являются реквизитами формы, добавлены к табличной части. Обратите внимание на их цвет в дереве реквизитов формы. Так что скриншот структуры справочника верный)

12. xioxao 05.06.19 21:48 Сейчас в теме

(6) Блин супер интересная разработка... Жаль что не хватает стартмани скачать) как наколочу обязательно зацеплю и потестю) Автору респект, за нестандартные решения, механизмами 1с)

13. botokash 403 06.06.19 03:26 Сейчас в теме

(12) В публикации весь код приведен полностью, даже скачивать не надо. Но если так нужна конфигурация, напишите в личку, отправлю на почту.

14. ntemny 63 06.06.19 14:53 Сейчас в теме

Тему с подменой карты маршрута БП не разовьете? Не совсем понял, как это можно сделать у стандартных БП платформы.

15. botokash 403 06.06.19 16:58 Сейчас в теме

(14) Когда получится что-то рабочее - обязательно поделюсь, конечно.

16. ntemny 63 06.06.19 18:13 Сейчас в теме

(15)Ну хотя бы в каком направлении копать напишите. Как у БП можно поменять карту маршрута не в конфигураторе?

17. botokash 403 07.06.19 12:40 Сейчас в теме

(16) В том то и дело, что нельзя. Буду пытаться делать некий имитатор, который будет создавать БП, но переход по карте маршрута обрабатывать самостоятельно.

18. Бубузяка 62 09.06.19 16:50 Сейчас в теме

Автору, спасибо. Это то, что мне давно было нужно! Видимо, фантазии и знаний о ДокументеДОМ не хватало. Много информации для применения на практике. Материал статьи (картинки и код) достаточен для повторения и последующего изучения.

19. botokash 403 09.06.19 16:58 Сейчас в теме

(18) Большое спасибо, рад что кому-то полезно.

20. Maystrenko_Ivan 18.07.23 21:01 Сейчас в теме

Добрый день.
Пришлите, пожалуйста, исходный код.
Попытался полностью восстановить исходную разработку, но, на этапе сохранения\записи что-то напутал. Происходит очистка полей...

21. botokash 403 19.07.23 05:50 Сейчас в теме

(20) Отписался в личку

22. men260181 22 16.04.24 06:12 Сейчас в теме

Очень классный пример работы со схемой! Ищу способ выстраивания точек маршрута по порядку от старта до завершения.
Хотел уточнить у автора: в объекте Dom они случайно не в порядке следования маршрута, может платформа при сериализации их поставила в порядке следования точек?

Для отправки сообщения требуется регистрация/авторизация

Автор:

Владислав Кашин (botokash)

Рейтинг: 403

Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.

Публикация:

№ 1071785

Создание 04.06.19 12:45

Обновление 04.06.19 12:45

Статистика:

Просмотры 11933

Загрузки 19

Рейтинг 51

Комментарии 22

Характеристики:

Код открыт Да

Рубрики Универсальные функции

Кому Разработчик

Тип файла Конфигурация (md, cf)

Платформа 1С:Предприятие 8

Конфигурация Универсальные

Операционная система Не имеет значения

Страна Не имеет значения

Отрасль Не имеет значения

Налоги Не имеет значения

Вид учета Не имеет значения

Доступ к файлу Абонемент ($m)

Работа с графической схемой в объектной модели DOM

Файлы

См. также

Журнал

База знаний

Лаборатория

Анализ & Управление

Сопровождение 1С

Корпоративные решения

Обучение

Маркетплейс

Проектный офис

Мероприятия

Видеозаписи

Биржа заказов

Форум

Мерч

О компании