Перенос контактной информации из 2.0 в 3.0

Структура КИ старого формата.

Общие для всех типов КИ:

Тип - ПеречислениеСсылка.ТипыКонтактнойИнформации - Сам тип КИ.

Вид - СправочникСсылка.ВидыКонтактнойИнформации - Вид КИ, может быть создано сколь угодно.

Представление - Строка - Представление адреса строкой. Например, "658702, Алтайский край, Каменский р-н, Камень-на-Оби г, Плотинная ст, Николаева ул, дом № 89, кв. 186" или "+7 (123) 65-41, доб. 25-26".

КИ типа Адрес:
Поле1 - Строка - Индекс, т.е. "658702".
Поле2 - Строка - Регион, т.е. "Алтайский край".
Поле3 - Строка - Район региона, т.е. "Каменский р-н".
Поле4 - Строка - Город, т.е. "Камень-на-Оби г".
Поле5 - Строка - Населенный пункт, т.е. "Плотинная ст".
Поле6 - Строка - Улица, т.е. "Николаева ул".
Поле7 - Строка - Номер дома, т.е. "89".
Поле8 - Строка - Номер корпуса, т.е. "".
Поле9 - Строка - Номер квартиры, т.е. "186".
Поле10 - Строка - Так и не понял, зачем это поле, как бы ни старался заполнять адрес, так и не заполняется :)

КИ типа Телефон:

Поле1 - Строка - Код страны, т.е. "+7".
Поле2 - Строка - Код города, т.е. "123".
Поле3 - Строка - Сам номер, т.е. "65-41".
Поле4 - Строка - Внутренний (добавочный) номер, т.е. "25-26".

Если номер заполнен одной строкой, будет заполнено одно из вышеперечисленных полей.

Остальные поля особого смысла не имеют, с той лишь оговоркой, что переносить их все же нужно:

Комментарий - Строка - Собственно, комментарий.

ЗначениеПоУмолчанию - Булево - Нет необходимости переносить.

ТипДома - ПеречислениеСсылка.ТипыДомов - Нам нужно строковое представление поля.

ТипКорпуса - ПеречислениеСсылка.ТипыКорпусов - Нам нужно строковое представление поля.

ТипКвартиры - ПеречислениеСсылка.ТипыКвартир - Нам нужно строковое представление поля.

Структура КИ нового формата:

Структура табличной части объекта, у которого есть КИ:

Тип - ПеречислениеСсылка.ТипыКонтактнойИнформации
Вид - СправочникСсылка.ВидыКонтактнойИнформации
Представление - Строка
ЗначенияПолей - Строка - Строка XDTO
Страна - Строка
Регион - Строка
Город - Строка
АдресЭП - Строка
ДоменноеИмяСервера - Строка
НомерТелефона - Строка
НомерТелефонаБезКодов - Строка
ВидДляСписка - СправочникСсылка.ВидыКонтактнойИнформации
Значение - Строка - Строка JSON

Рассмотрим структуру реквизита "Значение" более подробно. Вся информация хранится в виде строковых представлений.

В общем случае для поля есть три характеризующих значения, их имена формируются следующим образом:

*ИмяПоля* - само поле
*ИмяПоля*Type - сокращение, например, "г.", "с.", "ул.", "край" и т.п.
*ИмяПоля*id - уникальный идентификатор по адресному классификатору.
    
Общие для любого типа КИ
    
value - Представление   
comment - Комментарий
type - Тип КИ
    
Поля для типа "Адрес":
country - Страна    
countryCode - код страны
addressType - Тип адреса, если заполняется автоматически из адресного классификатора - "Административно-территориальный",
                    если заполнен вручную, но не одной строкой - "Муниципальный", если одной строкой - "ВСвободнойФорме".

Если тип адреса задан в свободной форме, все поля, расположенные ниже, не заполняются.

ZIPcode - индекс   
area - Регион страны (как субъект РФ)      
areaType 
city - Город       
cityType   
street - Улица      
streetType  
    
если есть модуль РаботаСАдресамиКлиентСервер:  
    id - уникальный идентификатор              
    areaCode         
    areaId            
    district - Район
    districtType     
    districtId        
    munDistrict - Муниципальный район (только если тип адреса - Муниципальный)    
    munDistrictType   
    munDistrictId   
    cityId            
    settlement - Поселение (только если тип адреса - Муниципальный)     
    settlementType   
    settlementId     
    cityDistrict - Внутригородской район   
    cityDistrictType
    cityDistrictId   
    territory - Территория (только если тип адреса - Муниципальный)      
    territoryType    
    territoryId      
    locality - Населенный пункт        
    localityType     
    localityId       
    streetId -        
    houseType - тип дома        
    houseNumber - номер дома     
    houseId          
    buildings - тип корпуса, массив с полями type, number
    apartments - тип квартиры, массив с полями type, number

    Поля ниже заполняются только при заполнении адреса по классификатору:
        codeKLADR        
        oktmo            
        okato            
        asInDocument     
        ifnsFLCode       
        ifnsULCode       
        ifnsFLAreaCode   
        ifnsULAreaCode   
        stead            
        steadId          
Значения для всех полей - строковые, однако, поля buildings и apartments заполняются в виде массива следующим образом:
"buildings": [
    {
    "type": "Корпус", // Тип корпуса
    "number": "1" // Номер корпуса
    }

 
Поля для типов "Телефон" и "Факс":
countryCode - код страны
areaCode - код города
number - номер
extNumber - добавочный номер
            
Поля для типа "ВебСтраница":
name

// Таблица, в которой хранится КИ в старом формате
// Тип - ТаблицаЗначений или любая другая подобная коллекция, для которой доступен обход коллекции
//		 посредством оператора Для каждого … Из … Цикл и обращение к элементу через "." 
//
ТаблицаСтараяКИ = ПолучитьСтаруюКИ();

// Для того, чтобы не выполнять запрос в цикле, сразу запомним данные основной страны
//
НаименованиеОсновнойСтраны = "";
КодОсновнойСтраны = "";

Если Метаданные.ОбщиеМодули.Найти("РаботаСАдресамиКлиентСервер") <> Неопределено Тогда
	
	ОсновнаяСтрана = РаботаСАдресамиКлиентСервер.ОсновнаяСтрана();
	
	РеквизитыСтраны = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(ОсновнаяСтрана, "Наименование, Код");
	
	НаименованиеОсновнойСтраны = СокрЛП(РеквизитыСтраны.Наименование);
	КодОсновнойСтраны = РеквизитыСтраны.Код;
	
КонецЕсли;

Для каждого Строка Из ТаблицаСтараяКИ Цикл
	
	// Объект, который мы будем заполнять
	// Тип - СправочникОбъект
	//
	ЗаполняемыйОбъект = Справочники.Партнеры.НайтиПоНаименованию("Тестов Тест Тестович").ПолучитьОбъект();
	
	// "Конвертация" вида КИ (для примера). 
	// Для реальной работы необходимо убрать запрос из цикла, т.е. в начале получить
	// старую КИ, затем конвертировать из старых видов КИ в новые, а уже затем
	// запускать данный алгоритм, либо на этом моменте Строка.Вид должен иметь нужное значение
	//
	Если Строка.Вид = "Адрес для информирования физ. лица" Тогда
		
		ВидКИ = Справочники.ВидыКонтактнойИнформации.НайтиПоНаименованию(
			"Юридический адрес",
			,
			Справочники.ВидыКонтактнойИнформации.СправочникПартнеры);
			
	ИначеЕсли Строка.Вид = "Адрес проживания физ. лица" Тогда
		ВидКИ = Справочники.ВидыКонтактнойИнформации.АдресПартнера;
	ИначеЕсли Строка.Вид = "Контактн телефон кандидата" Тогда
		
		ВидКИ = Справочники.ВидыКонтактнойИнформации.НайтиПоНаименованию(
			"Контактный телефон кандидата",
			,
			Справочники.ВидыКонтактнойИнформации.СправочникПартнеры);
			
	ИначеЕсли Строка.Вид = "Телефон физ.лица домашний" Тогда
		ВидКИ = Справочники.ВидыКонтактнойИнформации.ТелефонПартнера;
	ИначеЕсли Строка.Вид = "Email физ. лица" Тогда
		ВидКИ = Справочники.ВидыКонтактнойИнформации.EmailПартнера;
	КонецЕсли; 
	
	
	// Собственно, вот и основной алгоритм
	//
	СтрокаКИ = Новый Структура;
		
	СтрокаКИ.Вставить("Вид", ВидКИ);

	// Для данного модуля установлено повторное использование возвращаемых значений, поэтому
	// этот запрос в цикле не так страшен.
	//
	СтрокаКИ.Вставить("Тип", УправлениеКонтактнойИнформациейСлужебныйПовтИсп.ТипВидаКонтактнойИнформации(СтрокаКИ.Вид));	
		
	СтрокаКИ.Вставить("Представление", Строка.Представление);
	СтрокаКИ.Вставить("Комментарий",   Строка.Комментарий);
		
	Если СтрокаКИ.Тип = Перечисления.ТипыКонтактнойИнформации.Адрес Тогда
			
		СтрокаКИ.Вставить("Индекс",			 Строка.Поле1);	
		СтрокаКИ.Вставить("Регион",			 Строка.Поле2);
		СтрокаКИ.Вставить("Район",			 Строка.Поле3);
		СтрокаКИ.Вставить("Город",			 Строка.Поле4);
		СтрокаКИ.Вставить("НаселенныйПункт", Строка.Поле5);
		СтрокаКИ.Вставить("Улица",			 Строка.Поле6);
		СтрокаКИ.Вставить("Дом",			 Строка.Поле7);
		СтрокаКИ.Вставить("Корпус",			 Строка.Поле8);
		СтрокаКИ.Вставить("Квартира",		 Строка.Поле9);
			
		СтрокаКИ.Вставить("ТипДома",	 ""); 
		СтрокаКИ.Вставить("ТипКорпуса",	 ""); 
		СтрокаКИ.Вставить("ТипКвартиры", ""); 
			
		Если ЗначениеЗаполнено(СтрокаКИ.Дом) Тогда
			СтрокаКИ.ТипДома = Строка.ТипДома;
		КонецЕсли;
			
		Если ЗначениеЗаполнено(СтрокаКИ.Корпус) Тогда
			СтрокаКИ.ТипКорпуса = Строка.ТипКорпуса;
		КонецЕсли;
			
		Если ЗначениеЗаполнено(СтрокаКИ.Квартира) Тогда
			СтрокаКИ.ТипКвартиры = Строка.ТипКвартиры;
		КонецЕсли;
			
	ИначеЕсли СтрокаКИ.Тип = Перечисления.ТипыКонтактнойИнформации.Телефон Тогда
			
		СтрокаКИ.Вставить("КодСтраны",		 Строка.Поле1);
		СтрокаКИ.Вставить("КодГорода",		 Строка.Поле2);
		СтрокаКИ.Вставить("НомерТелефона",	 Строка.Поле3);
		СтрокаКИ.Вставить("Добавочный",		 Строка.Поле4);
			
	ИначеЕсли СтрокаКИ.Тип = Перечисления.ТипыКонтактнойИнформации.АдресЭлектроннойПочты Тогда	
		СтрокаКИ.Вставить("АдресЭП", Строка.Представление);		
	КонецЕсли;
		
	ПреобразуемоеЗначение = СтрокаКИ;
		
	Если СтрокаКИ.Тип = Перечисления.ТипыКонтактнойИнформации.Адрес Тогда
			
		// Для корректного преобразования в JSON необходимо, чтобы адрес был в виде строки 
		//
		ПреобразуемоеЗначение = "";
			
		Для каждого ЭлементСтруктуры Из СтрокаКИ Цикл
				
			Если НЕ ЗначениеЗаполнено(ЭлементСтруктуры.Значение) Тогда
				Продолжить;	
			КонецЕсли;     
				
			ПреобразуемоеЗначение = ПреобразуемоеЗначение + ЭлементСтруктуры.Ключ + "=" + ЭлементСтруктуры.Значение + Символы.ПС;	
				
		КонецЦикла;
			
	КонецЕсли;

	КонтактнаяИнформацияJSON = УправлениеКонтактнойИнформацией.КонтактнаяИнформацияВJSON(ПреобразуемоеЗначение, СтрокаКИ.Вид);
	
	// Добавляем КИ в объект. Процедура имеет четыре параметра, четвертый и пятый не указываем, т.к. устраивает их
	// значения по умолчанию.
	//
	// Параметры типовой процедуры БСП (из описания самой процедуры):
	//  СсылкаИлиОбъект          - Произвольный - ссылка или объект владельца содержащего контактную информацию.
	//                                            Для ссылки после добавления контактной информации владелец будет записан.
	//                                            Если передан объект, то контактная информация будет добавлена без записи.
	//                                            Для сохранения изменений объект необходимо будет записать отдельно.
	//  ЗначениеИлиПредставление - Строка - представление, JSON или XML соответствующее XDTO-пакету КонтактнаяИнформация
	//                                      или Адрес.
	//  ВидКонтактнойИнформации  - СправочникСсылка.ВидыКонтактнойИнформации - Вид добавляемой контактной информации.
	//  Дата                     - Дата    - дата, с которой будет действовать запись контактной информации.
	//                                       Требуется для контактной информации, у которой хранится история изменений.
	//                                       Если значение не указано, то принимается текущая дата сеанса.
	//  Замещать                 - Булево - если Истина(по умолчанию), то будет заменена вся контактная информация по
	//                                      переданному виду контактной информации.
	//                                      Если Ложь, то запись будет добавлена. Если вид контактной информации не разрешает
	//                                      ввод нескольких значений, а контактная информация объекта уже содержит запись,
	//                                      то запись не будет добавлена.
	//
	УправлениеКонтактнойИнформацией.ДобавитьКонтактнуюИнформацию(ЗаполняемыйОбъект, КонтактнаяИнформацияJSON, СтрокаКИ.Вид); 		
	
	// Поскольку в качестве первого параметра мы передавали объект, а не ссылку, необходимо записать объект
	//
	ЗаполняемыйОбъект.Записать();

КонецЦикла; 

В обработке необходимо указать ссылку на объект, в который загружается КИ, а также указать саму КИ.

Для удобства и ускорения загрузки КИ можно воспользоваться табличным документом.

Для этого можно в консоли запросов получить данные, вывести их в табличный документ, а затем копипастом вставить в обработку. На вкладке "Контактная информация" нажать кнопку "Заполнить из табличного документа" и вручную указать те виды КИ, которые не нашлись по наименованию.

После того, как заполняемый объект выбран и табличная часть заполнена, необходимо нажать кнопку "Загрузить контактную информацию", после чего КИ будет добавлена в выбранный объект.