Возможно использовать эту заготовку в обработках, где требуется подбор элементов справочников пользователем. Существующий стандартный способ из конфигурации мне показался громоздким, и я решил написать свой "мини". Результатом выбора является таблица значений со ссылкой на подобранные объекты. Элементы справочника не повторяются, даже если пользователь выбирает их несколько раз.
Для элемента формы, отвечающего за правило подбора заполняем его "список значений для выбора" необходимыми вариантами как на рисунке 1. Устанавливаем событие "ПриИзменении" для этого элемента, устанавливаем событие "ПередОткрытием" для всей формы, вставляем этот код и всё.
Благодарю за внимание!
перем ПредыдущаяПараПравил;
Процедура КнопкаВыполнитьНажатие(Кнопка)
ТаблицаКонтрагенты = ПолучитьТаблицуЭлементовИзПоляФормы("Контрагенты", Истина);
Для каждого СтрокаТаблицы Из ТаблицаКонтрагенты Цикл
Сообщить(СтрокаТаблицы.Ссылка.Наименование);
ОбработкаПрерыванияПользователя();
КонецЦикла;
ТаблицаНоменклатура = ПолучитьТаблицуЭлементовИзПоляФормы("Номенклатура");
Для каждого СтрокаТаблицы Из ТаблицаНоменклатура Цикл
Сообщить(СтрокаТаблицы.Ссылка.Наименование);
ОбработкаПрерыванияПользователя();
КонецЦикла;
КонецПроцедуры
Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)
УстановитьПравилоПодбораВПолеФормы(ЭлементыФормы.ПравилоКонтрагенты.Значение, "Контрагенты");
УстановитьПравилоПодбораВПолеФормы(ЭлементыФормы.ПравилоНоменклатура.Значение, "Номенклатура");
КонецПроцедуры
Процедура ПравилоКонтрагентыПриИзменении(Элемент)
УстановитьПравилоПодбораВПолеФормы(Элемент.Значение, "Контрагенты");
КонецПроцедуры
Процедура ПравилоНоменклатураПриИзменении(Элемент)
УстановитьПравилоПодбораВПолеФормы(Элемент.Значение, "Номенклатура");
КонецПроцедуры
//Правило выбора элементов из справочника в поле формы
Процедура УстановитьПравилоПодбораВПолеФормы(ЗначениеПравила, НазваниеСправочника)
ЭлементыФормы[НазваниеСправочника].Доступность = Истина;
Если ЗначениеПравила = "Равно" ИЛИ ЗначениеПравила = "НеРавно" Тогда
ЭлементыФормы[НазваниеСправочника].ВыборГруппИЭлементов = ИспользованиеГруппИЭлементов.ГруппыИЭлементы;
ЭлементыФормы[НазваниеСправочника].ОграничениеТипа = Новый ОписаниеТипов("СправочникСсылка." + НазваниеСправочника);
Если ПредыдущаяПараПравил <> "РавноНеРавно" Тогда
ЭлементыФормы[НазваниеСправочника].Значение = Справочники[НазваниеСправочника].ПустаяСсылка();
КонецЕсли;
ПредыдущаяПараПравил = "РавноНеРавно";
ИначеЕсли ЗначениеПравила = "ВГруппе" ИЛИ ЗначениеПравила = "НеВГруппе" Тогда
ЭлементыФормы[НазваниеСправочника].ВыборГруппИЭлементов = ИспользованиеГруппИЭлементов.Группы;
ЭлементыФормы[НазваниеСправочника].ОграничениеТипа = Новый ОписаниеТипов("СправочникСсылка." + НазваниеСправочника);
Если ПредыдущаяПараПравил <> "ВГруппеНеВГруппе" Тогда
ЭлементыФормы[НазваниеСправочника].Значение = Справочники[НазваниеСправочника].ПустаяСсылка();
КонецЕсли;
ПредыдущаяПараПравил = "ВГруппеНеВГруппе";
ИначеЕсли ЗначениеПравила = "ВСписке" ИЛИ ЗначениеПравила = "НеВСписке" Тогда
ЭлементыФормы[НазваниеСправочника].ВыборГруппИЭлементов = ИспользованиеГруппИЭлементов.ГруппыИЭлементы;
ЭлементыФормы[НазваниеСправочника].ОграничениеТипа = Новый ОписаниеТипов("СписокЗначений");
Иначе
ЭлементыФормы[НазваниеСправочника].Доступность = Ложь;
ЭлементыФормы[НазваниеСправочника].ОграничениеТипа = Новый ОписаниеТипов("СправочникСсылка." + НазваниеСправочника);
ЭлементыФормы[НазваниеСправочника].Значение = Справочники[НазваниеСправочника].ПустаяСсылка();
КонецЕсли;
ЭлементыФормы[НазваниеСправочника].Значение = ЭлементыФормы[НазваниеСправочника].ОграничениеТипа.ПривестиЗначение(ЭлементыФормы[НазваниеСправочника].Значение);
КонецПроцедуры
//Возвращает таблицу выбранных элементов справочника с колонкой "Ссылка"
Функция ПолучитьТаблицуЭлементовИзПоляФормы(НазваниеСправочника, ВключатьГруппы = Ложь)
ИсходнаяТаблица = Новый ТаблицаЗначений();
ИсходнаяТаблица.Колонки.Добавить("КолонкаЭлементов", Новый ОписаниеТипов("СправочникСсылка." + НазваниеСправочника));
ЗначениеПравила = ЭлементыФормы["Правило" + НазваниеСправочника].Значение;
Если ЗначениеПравила = "Равно" ИЛИ ЗначениеПравила = "ВГруппе" Тогда
Если ЭлементыФормы[НазваниеСправочника].Значение = Справочники[НазваниеСправочника].ПустаяСсылка() Тогда
ВыборВключаетЭлементы = Ложь;
Иначе
ВыборВключаетЭлементы = Истина;
КонецЕсли;
ИначеЕсли ЗначениеПравила = "НеРавно" ИЛИ ЗначениеПравила = "НеВГруппе" Тогда
ВыборВключаетЭлементы = Ложь;
ИначеЕсли ЗначениеПравила = "ВСписке" Тогда
ВыборВключаетЭлементы = Истина;
ИначеЕсли ЗначениеПравила = "НеВСписке" Тогда
Если ЭтаФорма[НазваниеСправочника].Количество() = 0 Тогда
ВыборВключаетЭлементы = Истина;
Иначе
ВыборВключаетЭлементы = Ложь;
КонецЕсли;
Иначе
ВыборВключаетЭлементы = Истина;
КонецЕсли;
Если ТипЗнч(ЭлементыФормы[НазваниеСправочника].Значение) = Тип("СписокЗначений") Тогда
Для Каждого текСтрока Из ЭлементыФормы[НазваниеСправочника].Значение Цикл
табСтрока = ИсходнаяТаблица.Добавить();
табСтрока.КолонкаЭлементов = текСтрока.Значение;
КонецЦикла;
Иначе
табСтрока = ИсходнаяТаблица.Добавить();
табСтрока.КолонкаЭлементов = ЭлементыФормы[НазваниеСправочника].Значение;
КонецЕсли;
Запрос = Новый Запрос;
Запрос.Текст = "
|ВЫБРАТЬ * ПОМЕСТИТЬ ИсходнаяТаблица ИЗ &ИсходнаяТаблица КАК ИсходнаяТаблица
|;
|ВЫБРАТЬ
| Ссылка
|ИЗ
| Справочник." + НазваниеСправочника + "
|ГДЕ
| " + ?(ВключатьГруппы, "", " НЕ ЭтоГруппа И ") + "
| Ссылка " + ?(ВыборВключаетЭлементы, "", "НЕ") + " В ИЕРАРХИИ (ВЫБРАТЬ КолонкаЭлементов ИЗ ИсходнаяТаблица)
|";
Запрос.УстановитьПараметр("ИсходнаяТаблица", ИсходнаяТаблица);
Возврат Запрос.Выполнить().Выгрузить();
КонецФункции
