Приемы работы с СКД: выгрузка данных справочников и документов в линейном виде в табличный документ

Создаем новую внешнюю обработку и пустую форму обработки.

Создаем следующий список реквизитов формы:

У реквизитов ОбъектВыгрузки, Таблица и ТипОбъекта устанавливаем проверку заполнения Выдавать ошибку

ТипОбъекта - перетаскиваем на форму одноименный реквизит, РежимВыбораИзСписка = Истина, в СписокВыбора добавляем 2 значения - "Справочники" и "Документы" (пердствление - по вкусу)

ОбъектВыгрузки - перетаскиваем на форму одноименный реквизит, РежимВыбораИзСписка = Истина

НастройкиКомпоновщикаНастройкиОтбор - перетаскиваем на форму НастройкиКомпоновщика.Настройки.Отбор, добавляем как поле:

НастройкиКомпоновщикаНастройкиПорядок - перетаскиваем на форму НастройкиКомпоновщика.Настройки.Порядок как поле

ТипДокумента - перетаскиваем на форму одноименный реквизит, РежимВыбораИзСписка = Истина

ГруппаГоризонтальная - обычная группа, ОтображатьЗаголовок = Ложь, Группировка - Горизонтальная всегда, Отображение - Нет; в эту группу добавим таблицу с доступными полями и таблицу выгружаемых данных:

• НастройкиКомпоновщикаНастройкиВыборДоступныеПоляВыбора - перетаскиваем НастройкиКомпоновщика.Настройки.Выбор.ДоступныеПоляВыбора:

• Таблица - перетаскиваем на форму одноименную таблицу значений вместе с колонками

Добавляем команду формы Выгрузить для выгрузки данных в файл и вносим ее на командную панель формы.

В итоге должен получиться примерно следующий интерфейс:

 У формы создаем единственный обработчик - для события ПриСозданииНаСервере. В этом обработчике будем заполнять список выбора элемента ТипДокумента

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Для Каждого ТекТип Из ТипФайлаТабличногоДокумента Цикл
		Элементы.ТипДокумента.СписокВыбора.Добавить(ТекТип);
	КонецЦикла;
	
	ТипДокумента = ТипФайлаТабличногоДокумента.XLSX;
	
КонецПроцедуры

Команда у нас одна - Выгрузить. Данная команда должна сформировать табличный документ и предложить пользователю сохранить его в файл, доступный с клиентского компьютера пользователя

&НаКлиенте
Асинх Процедура Выгрузить(Команда)
	
	ОчиститьСообщения();
	
	Если Не ПроверитьЗаполнение() Тогда
		Возврат;
	КонецЕсли;
	
	Состояние("Подготовка табличного документа...");
	ТабДок = СформироватьТабличныйДокументНаСервере();
	
	Если ТабДок = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	Расширение 			= Строка(ТипДокумента);
	Режим 				= РежимДиалогаВыбораФайла.Сохранение;
	Диалог 				= Новый ДиалогВыбораФайла(Режим);
	Диалог.Фильтр 		= Расширение+"|*."+Расширение;
	Диалог.Заголовок 	= "Выберите файл для сохранения";
	Результат 			= Ждать Диалог.ВыбратьАсинх();
	
	Если Результат = Неопределено Тогда
		
		Сообщение 		= Новый СообщениеПользователю;
		Сообщение.Текст = "Данные не записаны: не выбран файл для записи!";
		Сообщение.Сообщить();
		
		Возврат;
		
	КонецЕсли;

	Попытка
		
		ТабДок.Записать(Результат[0], ТипДокумента);
		ОбщегоНазначенияКлиент.СообщитьПользователю("Данные успешно записаны в файл "+Результат[0]);
		
	Исключение
		
		Инфо 	= ИнформацияОбОшибке();
		Причина = ПодробноеПредставлениеОшибки(Инфо);
		ОбщегоНазначенияКлиент.СообщитьПользователю("Не удалось записать данные в файл "+Результат[0]+": "+Причина);
		
	КонецПопытки;
	
КонецПроцедуры

&НаСервере
Функция СформироватьТабличныйДокументНаСервере()
	
    // Получаем из временного хранилища схему компоновки данных
	СхемаОтбор 						= ПолучитьИзВременногоХранилища(АдресСКД);

    // Получаем текущие настройки компоновщика
	Настройки 						= НастройкиКомпоновщика.ПолучитьНастройки();
    // В структуру добавляем группировку "Детальные записи" и в выбранные поля группировки автополе
	ДетальныеЗаписи 				= Настройки.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));
	ДетальныеЗаписи.Использование 	= Истина;
	АвтоПоле 						= ДетальныеЗаписи.Выбор.Элементы.Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));
	АвтоПоле.Использование 			= Истина;
	
	Настройки.Выбор.Элементы.Очистить();
	
    // Из таблицы добавляем выбранные поля
	Для Каждого Строка Из Таблица Цикл
		
		Если Строка.ИмяРеквизита = Неопределено Или Не ЗначениеЗаполнено(Строка.ИмяКолонки) Тогда
			Продолжить;
		КонецЕсли;
		
        // Ищем доступное поле компоновки по идентификатору из колонки ИмяРеквизита
		ДоступноеПоле = НастройкиКомпоновщика.Настройки.ДоступныеПоляВыбора.ПолучитьОбъектПоИдентификатору(Строка.ИмяРеквизита);
		
		Если ДоступноеПоле = Неопределено Тогда
			Продолжить;
		КонецЕсли;
		
		НовПоле 				= Настройки.Выбор.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
		НовПоле.Поле 			= ДоступноеПоле.Поле;
		НовПоле.Использование 	= Истина;
        // В качестве заголовка устанавливаем значение из колонки ИмяКолонки
		НовПоле.Заголовок 		= Строка.ИмяКолонки;
		
	КонецЦикла;
	
    // Скрываем вывод настроенных отборов, устанавливаем макет оформления (без него не видна сетка ячеек) и расположение полей в отдельных колонках
	Настройки.ПараметрыВывода.УстановитьЗначениеПараметра("ВыводитьОтбор", 			ТипВыводаТекстаКомпоновкиДанных.НеВыводить);
	Настройки.ПараметрыВывода.УстановитьЗначениеПараметра("МакетОформления", 		"Античный"); 
	Настройки.ПараметрыВывода.УстановитьЗначениеПараметра("РасположениеРеквизитов", РасположениеРеквизитовКомпоновкиДанных.Отдельно); 
				
	Результат 			= Новый ТабличныйДокумент;
    КомпоновщикМакета 	= Новый КомпоновщикМакетаКомпоновкиДанных;
    // В компоновщик макета передаем схему и настройки с отбором, сортировкой и структурой вывода
    МакетКомпоновки 	= КомпоновщикМакета.Выполнить(СхемаОтбор, Настройки);
    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(МакетКомпоновки);
	
    // Выводим данные в табличный документ
    ПроцессорВывода 	= Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(Результат);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);
	
	Результат.ОтображатьСетку 	= Истина;
	Результат.Защита 			= Ложь;
	Результат.ТолькоПросмотр 	= Ложь;
	
	Возврат Результат;
	
КонецФункции

 Добавляем функцию СведенияОВнешнейОбработке для возможности загрузки обработки в базу 1С:

Функция СведенияОВнешнейОбработке() Экспорт

	Сведения = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке();	
	Сведения.Вставить("Вид", ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка());
	Сведения.Вставить("Версия", Метаданные().Комментарий);
	Сведения.Вставить("Наименование", Метаданные().Синоним);
	Сведения.Вставить("БезопасныйРежим", Ложь);
	
	
	НоваяКоманда = Сведения.Команды.Добавить();	
	НоваяКоманда.Идентификатор = "ОткрытьФорму";	
	НоваяКоманда.Представление = Сведения.Наименование;
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
	НоваяКоманда.ПоказыватьОповещение = Ложь;
	
	Возврат Сведения;             

КонецФункции

 Любая конфигурация на управляемых формах с платформой 8.3.18 и выше (в обработке использованы новые методы Асинх).