Зарисовки на тему оформления кода HTTP-сервиса 3. Провайдер данных

Функция ЗадачаСотрудникаПоСсылке(Значение) Экспорт

    Возврат Документы.ЗадачаСотрудника.ПолучитьСсылку(Значение);
КонецФункции

Функция ЗадачаСотрудникаПоНомеру(Значение) Экспорт

    Возврат Документы.ЗадачаСотрудника.НайтиПоНомеру(Значение);
КонецФункции

Функция ПользовательПустаяСсылка() Экспорт

    Возврат Справочники.Пользователи.ПустаяСсылка()
КонецФункции

Функция ОбъектУдален(Значение) Экспорт

    Возврат Значение.ПометкаУдаления;
КонецФункции

Функция АдресБазыВИнтернете() Экспорт

    Возврат Константы.АдресПубликацииИнформационнойБазыВИнтернете.Получить();
КонецФункции

Функция СписокЗадачВыгрузка(НастройкиПолученияЗадач, ФильтрЗадач, ЗадачНаСтраницу) Экспорт
    
    // на основе настроек формируем запрос-пакет для реализации пагинации и накладываем фильтр
    Запрос = НовыйЗапросПакетСпискаЗадачСПагинацией(НастройкиПолученияЗадач, ФильтрЗадач, ЗадачНаСтраницу);
    
    // к пакету добавляем запрос-выборку с необходимым набором данных
    Запрос.Текст = Запрос.Текст + ";" + Символы.ПС +
        "ВЫБРАТЬ
        |   ЗадачаСотрудника.Ссылка КАК Ссылка,
        |   ПРЕДСТАВЛЕНИЕ(УНИКАЛЬНЫЙИДЕНТИФИКАТОР(ЗадачаСотрудника.Ссылка)) КАК УникальныйИдентификатор,
        |   ЗадачаСотрудника.Номер КАК Номер,
        |   ЗадачаСотрудника.Содержание КАК Содержание,
        |   ЗадачаСотрудника.Приоритет КАК Приоритет,
        |   ПРЕДСТАВЛЕНИЕ(УНИКАЛЬНЫЙИДЕНТИФИКАТОР(ЗадачаСотрудника.Исполнитель)) КАК Исполнитель,
        |   ПРЕДСТАВЛЕНИЕ(УНИКАЛЬНЫЙИДЕНТИФИКАТОР(ЗадачаСотрудника.Автор)) КАК Автор
        |ИЗ
        |   Документ.ЗадачаСотрудника КАК ЗадачаСотрудника
        |       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_ДанныеДляВозврата КАК ВТ_ДанныеДляВозврата
        |       ПО (ВТ_ДанныеДляВозврата.Ссылка = ЗадачаСотрудника.Ссылка)";
    
    Возврат Запрос.Выполнить().Выгрузить()
КонецФункции

Функция НовыеНастройкиПолученияЗадач() Экспорт
    
    Результат = Новый Структура;
    Результат.Вставить("СпособПагинации");
    Результат.Вставить("НомерСтраницы");
    Результат.Вставить("Лимит");
    Результат.Вставить("ДоКурсора");
    Результат.Вставить("ПослеКурсора");
    
    Возврат Результат;
КонецФункции

Функция НовыйФильтрЗадач() Экспорт
    
    Результат = Новый Структура;
    Результат.Вставить("ДатаНачала");
    Результат.Вставить("ДатаОкончания");
    Результат.Вставить("ИдентификаторИсполнителя");
    Результат.Вставить("ИдентификаторАвтора");
    
    Возврат Результат;
КонецФункции

// константы для настроек
Функция СпособПагинацииСтраницы() Экспорт
    
    Возврат "Страницы"
КонецФункции

Функция СпособПагинацииКурсор() Экспорт
    
    Возврат "Курсор"
КонецФункции

Функция НовыйЗапросПакетСпискаЗадачСПагинацией(Пагинация, Фильтр, ЗадачНаСтраницу)
    
    // Подготавливаем запрос-пакет с минимальным набором данных - ссылка
    // - применяем фильтр на оператор фильтра схемы
    
    Запрос = Новый Запрос;
    СхемаЗапроса = Новый СхемаЗапроса;
    
    ПорядокПоВозрастанию = НаправлениеПорядкаСхемыЗапроса.ПоВозрастанию;
    ПорядокПоУбыванию = НаправлениеПорядкаСхемыЗапроса.ПоУбыванию;
    
    ОператорДляФильтра = Неопределено;
    
    Если Пагинация.СпособПагинации = СпособПагинацииКурсор() Тогда
        
        // Пагинация курсором, порядок по ссылке
        // Направление порядка определяется, наличием параметра after - прямой, или его отсутствием - по убыванию
        // Оператор схемы также используется для фильтра
        
        ПоВозрастанию = ЗначениеЗаполнено(Пагинация.ПослеКурсора);
        
        Отбор = СтрШаблон("УНИКАЛЬНЫЙИДЕНТИФИКАТОР(ЗадачаСотрудника.Ссылка) %1= &Курсор", ?(ПоВозрастанию, ">", "<"));
        Курсор = ?(ПоВозрастанию, Пагинация.ПослеКурсора, Пагинация.ДоКурсора);
        Направление = ?(ПоВозрастанию, ПорядокПоВозрастанию, ПорядокПоУбыванию);
        
        Запрос.Текст =
            "ВЫБРАТЬ ПЕРВЫЕ 20
            |   ЗадачаСотрудника.Ссылка КАК Ссылка
            |ПОМЕСТИТЬ ВТ_ДанныеДляВозврата
            |ИЗ
            |   Документ.ЗадачаСотрудника КАК ЗадачаСотрудника";
        
        СхемаЗапроса.УстановитьТекстЗапроса(Запрос.Текст);
        
        ЗапросПакет = СхемаЗапроса.ПакетЗапросов[0];
        ОператорДляФильтра = ЗапросПакет.Операторы[0];
        ОператорДляФильтра.КоличествоПолучаемыхЗаписей = Пагинация.Лимит;
        
        ОператорДляФильтра.Отбор.Добавить(Отбор);
        Запрос.УстановитьПараметр("Курсор", Новый УникальныйИдентификатор(Курсор));
        
        ЭлементПорядка = ЗапросПакет.Порядок.Добавить("ЗадачаСотрудника.Ссылка");
        ЭлементПорядка.Направление = Направление;
    
    ИначеЕсли Пагинация.СпособПагинации = СпособПагинацииСтраницы() Тогда
        
        // Пагинация страницами, прямой порядок по ссылке
        // Выборка из двух вложенных запросов
        // Первый вложенный - выбирает limit * page записей - прямой порядок, содержит оператор для фильтра
        // Второй вложенный - выбирает limit записей - обратный порядок
        // Выборка - возвращает прямой порядок
        
        Запрос.Текст = 
            "ВЫБРАТЬ ПЕРВЫЕ 20
            |   Порция.Ссылка КАК Ссылка
            |ПОМЕСТИТЬ ВТ_ДанныеДляВозврата
            |ИЗ
            |   (ВЫБРАТЬ ПЕРВЫЕ 20
            |       ПолнаяПорция.Ссылка КАК Ссылка
            |   ИЗ
            |       (ВЫБРАТЬ ПЕРВЫЕ 120
            |           ЗадачаСотрудника.Ссылка КАК Ссылка
            |       ИЗ
            |           Документ.ЗадачаСотрудника КАК ЗадачаСотрудника) КАК ПолнаяПорция) КАК Порция";
        
        СхемаЗапроса.УстановитьТекстЗапроса(Запрос.Текст);
        
        ЗапросПакет = СхемаЗапроса.ПакетЗапросов[0]; 
        
        Прямой = ЗапросПакет.Операторы[0];
        Прямой.КоличествоПолучаемыхЗаписей = Пагинация.Лимит;
        ЭлементПорядка = ЗапросПакет.Порядок.Добавить("Ссылка");
        ЭлементПорядка.Направление = ПорядокПоВозрастанию;
        
        ЗапросОбратныйПорядок = Прямой.Источники[0].Источник.Запрос; 
        
        Обратный = ЗапросОбратныйПорядок.Операторы[0];
        Обратный.КоличествоПолучаемыхЗаписей = ЗадачНаСтраницу;
        ЭлементПорядка = ЗапросОбратныйПорядок.Порядок.Добавить("Ссылка");
        ЭлементПорядка.Направление = ПорядокПоУбыванию;
        
        ЗапросПрямойПорядок = Обратный.Источники[0].Источник.Запрос;
        
        ОператорДляФильтра = ЗапросПрямойПорядок.Операторы[0];
        ОператорДляФильтра.КоличествоПолучаемыхЗаписей = Пагинация.Лимит * Пагинация.НомерСтраницы;
        ЭлементПорядка = ЗапросПрямойПорядок.Порядок.Добавить("Ссылка");
        ЭлементПорядка.Направление = ПорядокПоВозрастанию;
    КонецЕсли;
    
    ПрименитьФильтрЗадач(Запрос, Фильтр, ОператорДляФильтра);
    
    Запрос.Текст = СхемаЗапроса.ПолучитьТекстЗапроса();
    Возврат Запрос
КонецФункции

Процедура ПрименитьФильтрЗадач(Запрос, Фильтр, Оператор)
    
    Если Оператор = Неопределено Тогда Возврат КонецЕсли;
    
    Если ЗначениеЗаполнено(Фильтр.ДатаНачала) Тогда
        
        Оператор.Отбор.Добавить("ЗадачаСотрудника.Дата >= &ДатаНачала");
        Запрос.УстановитьПараметр("ДатаНачала", Фильтр.ДатаНачала);
    КонецЕсли;
    
    Если ЗначениеЗаполнено(Фильтр.ДатаОкончания) Тогда
        
        Оператор.Отбор.Добавить("ЗадачаСотрудника.Дата <= &ДатаОкончания");
        Запрос.УстановитьПараметр("ДатаОкончания", Фильтр.ДатаОкончания);
    КонецЕсли;
    
    Если ЗначениеЗаполнено(Фильтр.ИдентификаторИсполнителя) Тогда
        
        Оператор.Отбор.Добавить("УНИКАЛЬНЫЙИДЕНТИФИКАТОР(ЗадачаСотрудника.Исполнитель) = &ИдентификаторИсполнителя");
        Запрос.УстановитьПараметр("ИдентификаторИсполнителя", Новый УникальныйИдентификатор(Фильтр.ИдентификаторИсполнителя));
    КонецЕсли;
    
    Если ЗначениеЗаполнено(Фильтр.ИдентификаторАвтора) Тогда
            
        Оператор.Отбор.Добавить("УНИКАЛЬНЫЙИДЕНТИФИКАТОР(ЗадачаСотрудника.Автор) = &ИдентификаторАвтора");
        Запрос.УстановитьПараметр("ИдентификаторАвтора", Новый УникальныйИдентификатор(Фильтр.ИдентификаторАвтора));
    КонецЕсли;
КонецПроцедуры

Функция СписокЗадачКоличество(Фильтр) Экспорт
    
    Запрос = Новый Запрос;
    СхемаЗапроса = Новый СхемаЗапроса;
    
    Запрос.Текст =
        "ВЫБРАТЬ
        |   КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ЗадачаСотрудника.Ссылка) КАК КоличествоЗадач
        |ИЗ
        |   Документ.ЗадачаСотрудника КАК ЗадачаСотрудника";
    
    СхемаЗапроса.УстановитьТекстЗапроса(Запрос.Текст);
    
    ЗапросПакет = СхемаЗапроса.ПакетЗапросов[0];
    ОператорДляФильтра = ЗапросПакет.Операторы[0];
    
    // Метод показан в предыдущем примере
    ПрименитьФильтрЗадач(Запрос, Фильтр, ОператорДляФильтра);
    
    Запрос.Текст = СхемаЗапроса.ПолучитьТекстЗапроса();
    
    РезультатЗапроса = Запрос.Выполнить();
    Если РезультатЗапроса.Пустой() Тогда Возврат 0 КонецЕсли;
    
    Выборка = РезультатЗапроса.Выбрать();
    Выборка.Следующий();
    
    Возврат Выборка.КоличествоЗадач;
КонецФункции

Функция ФайлыЗадачВыборка(Ссылки) Экспорт
    
    Запрос = Новый Запрос;
    Запрос.Текст = 
        "ВЫБРАТЬ
        |   ЗадачаСотрудникаПрисоединенныеФайлы.Ссылка КАК Ссылка,
        |   ПРЕДСТАВЛЕНИЕ(УНИКАЛЬНЫЙИДЕНТИФИКАТОР(ЗадачаСотрудникаПрисоединенныеФайлы.Ссылка)) КАК УникальныйИдентификатор,
        |   ЗадачаСотрудникаПрисоединенныеФайлы.ВладелецФайла КАК ВладелецФайла,
        |   ЗадачаСотрудникаПрисоединенныеФайлы.Наименование КАК Наименование,
        |   ЗадачаСотрудникаПрисоединенныеФайлы.Расширение КАК Расширение
        |ИЗ
        |   Справочник.ЗадачаСотрудникаПрисоединенныеФайлы КАК ЗадачаСотрудникаПрисоединенныеФайлы
        |ГДЕ
        |   ЗадачаСотрудникаПрисоединенныеФайлы.ВладелецФайла В(&Ссылки)";
    
    Запрос.УстановитьПараметр("Ссылки", Ссылки);
    
    Возврат Запрос.Выполнить().Выбрать();
КонецФункции

#Область ОбращенияКПодсистемам

Функция ЗаблокированоОбновлением() Экспорт
    
    Возврат ОбновлениеИнформационнойБазы.НеобходимоОбновлениеИнформационнойБазы()
КонецФункции

Функция ТаблицаЗначенийВМассив(Данные) Экспорт

    Возврат ОбщегоНазначения.ТаблицаЗначенийВМассив(Данные)
КонецФункции

#КонецОбласти

Функция ОписаниеФайла(Файл) Экспорт

    Возврат РаботаСФайлами.ДанныеФайла(Файл)
КонецФункции

Функция ВладелецФайла(Файл) Экспорт

    Возврат ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Файл, "ВладелецФайла")
КонецФункции

Процедура ЗаданиеПолучитьРеквизиты(Ссылка, Статус, Результат) Экспорт

    Реквизиты = ОбщегоНазначения.ЗначенияРеквизитовОбъекта(Ссылка, "Статус,Результат");
    
    Статус = Реквизиты.Статус;
    Если Статус = Перечисления.СтатусЗаданияОчередиОбработкиЗадач.Выполнено Тогда
        
        Результат = Реквизиты.Результат.Получить();
    КонецЕсли;
КонецПроцедуры

Функция ЗадачаСотрудникаПараметрыЗаполнения() Экспорт

    Результат = Новый Структура;
    Результат.Вставить("Дата", ТекущаяДатаСеанса());
    Результат.Вставить("Проект", Справочники.Проекты.Основной);
    Результат.Вставить("Приоритет", Перечисления.ПриоритетЗадачи.ПустаяСсылка());
    Результат.Вставить("Содержание", "");
    Результат.Вставить("Исполнитель", Справочники.Пользователи.ПустаяСсылка());
    Результат.Вставить("Автор", Справочники.Пользователи.ПустаяСсылка());
    
    Возврат Результат
КонецФункции

// и использовать для создания объекта
Процедура СоздатьЗадачуСотрудника(ПараметрыЗаполнения, РезультатНомер, Отказ) Экспорт

    ДокОбъект = Документы.ЗадачаСотрудника.СоздатьДокумент();
    ДокОбъект.Заполнить(ПараметрыЗаполнения);
    
    Если Не ДокОбъект.ПроверитьЗаполнение() Тогда 
        
        Отказ = Истина;
        Возврат
    КонецЕсли;
    
    ДокОбъект.Записать();
    
    РезультатНомер = ДокОбъект.Номер
КонецПроцедуры