Настройка начальной страницы в интерфейсе версии 8.5

Начальная страница - это окно клиентского приложения:

• Окно автоматически открывается при начале работы системы
• В окне открывается форма (такси список форм)
• Окно невозможно закрыть, все открытые в окне формы - невозможно закрыть
• Окно имеет заголовок: "Начало" (такси "Начальная страница")
• Окно имеет свойство "НачальнаяСтраница" = Истина

Где хранятся настройки начальной страницы ?

• Хранилище системных настроек с ключом объекта "Общее/НастройкиНачальнойСтраницы"
• Преднастроенные из конфигуратора: Свойства конфигурации --> Рабочая область начальной страницы

Рабочая область начальной страницы

• Конфигуратор --> Свойства конфигурации --> Рабочая область начальной страницы 
•  

   Пример: Рабочая область начальной страницы - Управление нашей фирмой, редакция 3.0 (3.0.13.374) 

  

• Левая и правая колонки со списком форм для интерфейса версия 8.5 - представляют собой единой список форм, где пользователю отображается первая по порядку, доступная по пользовательской видимости для ролей текущего пользователя
• В левой и правой колонках: свойство "Высота"  для интерфейса версия 8.5 не используется
• Свойство "Шаблон начальной страницы" для интерфейса версия 8.5 не используется
• Свойство "Отображение командного интерфейса основного раздела" для интерфейса версия 8.5 не используется

Алгорим определения списка форм для текущего пользователя

1. Платформа ищет настройки в Хранилище системных настроек c ключом объекта "Общее/НастройкиНачальнойСтраницы" и отбором по текущему пользователю
2. Если настройки выше не найдены: платформа ищет настройки по умолчанию в Хранилище системных настроек с ключом объекта "Общее/НастройкиНачальнойСтраницы"
3. Если настройки выше не найдены: используются преднастроенные из конфигуратора: Свойства конфигурации --> Рабочая область начальной страницы

//примеры работают для обоих интерфейсов: версия 8.5 и такси

//после изменения настроек текущего пользователя или настроек умолчанию:
//для обновления начальной страницы в текущем сеансе пользователя - необходимо вызвать процедуру глобального контекста
ОбновитьИнтерфейс();

//пример №1: установить форму начальной страницей для определенного пользователя	   
НачальнаяСтраница = Новый НастройкиНачальнойСтраницы;
СоставФорм = Новый СоставФормНачальнойСтраницы;
СоставФорм.ЛеваяКолонка.Добавить("Справочник.Склады.ФормаСписка");
НачальнаяСтраница.УстановитьСоставФорм(СоставФорм); 
ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиНачальнойСтраницы",,НачальнаяСтраница,,"<ИмяПользователяИБ>");

//пример №2: установить форму начальной страницей по умолчанию для всех пользователей	   
НачальнаяСтраница = Новый НастройкиНачальнойСтраницы;
СоставФорм = Новый СоставФормНачальнойСтраницы;
СоставФорм.ЛеваяКолонка.Добавить("Справочник.Склады.ФормаСписка");
НачальнаяСтраница.УстановитьСоставФорм(СоставФорм); 
ХранилищеСистемныхНастроек.СохранитьНастройкуПоУмолчанию("Общее/НастройкиНачальнойСтраницы",НачальнаяСтраница);

//пример №3: очистить форму на начальной странице для определенного пользователя
НачальнаяСтраница = Новый НастройкиНачальнойСтраницы;
СоставФорм = Новый СоставФормНачальнойСтраницы;
НачальнаяСтраница.УстановитьСоставФорм(СоставФорм); 
ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиНачальнойСтраницы",,НачальнаяСтраница,,"<ИмяПользователяИБ>"); 

//пример №4: установить стандартные настройки начальной страницы для определенного пользователя
НачальнаяСтраница = Новый НастройкиНачальнойСтраницы;
СоставФорм = НачальнаяСтраница.ПолучитьСоставФорм();
НачальнаяСтраница.УстановитьСоставФорм(СоставФорм); 
ХранилищеСистемныхНастроек.Сохранить("Общее/НастройкиНачальнойСтраницы",,НачальнаяСтраница,,"<ИмяПользователяИБ>");   

//пример №5: прочитать настройки начальной страницы для определенного пользователя 
НачальнаяСтраница = ХранилищеСистемныхНастроек.Загрузить("Общее/НастройкиНачальнойСтраницы",,,"<ИмяПользователяИБ>");  
Если НачальнаяСтраница = Неопределено Тогда
	Сообщить("У пользователя нет сохраненных настроек начальной страницы");
Иначе
	СоставФорм = НачальнаяСтраница.ПолучитьСоставФорм();
	Для Каждого тИмяФормыСтрокой Из СоставФорм.ЛеваяКолонка Цикл 
		Сообщить("ЛеваяКолонка: " + тИмяФормыСтрокой);
	КонецЦикла;
	Для Каждого тИмяФормыСтрокой Из СоставФорм.ПраваяКолонка Цикл 
		Сообщить("ПраваяКолонка: " + тИмяФормыСтрокой);
	КонецЦикла; 
КонецЕсли;

//пример №6: прочитать настройки по умолчанию 
НачальнаяСтраница = ХранилищеСистемныхНастроек.ЗагрузитьНастройкуПоУмолчанию("Общее/НастройкиНачальнойСтраницы");
Если НачальнаяСтраница = Неопределено Тогда
	Сообщить("Нет сохраненых настроек начальной страницы по умолчанию для всех пользователей");
Иначе
	СоставФорм = НачальнаяСтраница.ПолучитьСоставФорм();
	Для Каждого тИмяФормыСтрокой Из СоставФорм.ЛеваяКолонка Цикл 
		Сообщить("ЛеваяКолонка: " + тИмяФормыСтрокой);
	КонецЦикла;
	Для Каждого тИмяФормыСтрокой Из СоставФорм.ПраваяКолонка Цикл 
		Сообщить("ПраваяКолонка: " + тИмяФормыСтрокой);
	КонецЦикла; 
КонецЕсли;

Изменение начальной страницы пользователем:

• Программно: в процедуре МодульПриложения.ПриНачалеРаботыСистемы() может находится программный код, который перезаписывает настройки начальной страницы для текущего пользователя
• Программно: во время сеанса пользователя, в любой момент, можно программно изменить настройки, после вызвать процедуру ОбновитьИнтерфейс() - которая обновит начальная страницу
• Интерактивно: пользователь может выбрать форму через стандартную форму Сервис и Настройки --> Выбор начальной страницы (Настройка начальной страницы). В этом случае, при редактировании автоматически создается настройка в хранилище системных настроек с ключом объекта "Общее/НастройкиНачальнойСтраницы" для текущего пользователя

Какие формы можно добавить на начальную страницу ?

• Интерактивно через "Выбор начальной страницы" пользователь может выбрать форму из ограниченного списка, заданного в конфигураторе: Свойства конфигурации --> Рабочая область начальной страницы
• Программно: можно установить любую форму любого объекта метаданных (внешние отчеты и обработки не поддерживаются)
• Имя формы указывается строкой
• Например: "Справочник.Склады.ФормаСписка" или "Справочник.Склады.Форма.ДругаяФорма"
• Если строка не является именем формы, то она игнорируется
• Передать параметры в форму - невозможно, указывается только имя формы

Как скрыть начальную страницу ?

• Интерфейс такси программно или интерактивно очистить список форм из левой и правой колонок, после чего окно "Начальная страница" будет автоматически закрыто
• Интерфейс такси запустить 1С:Предприятие с параметром запуска /DisableHomePageForms
• Интерфейс версия 8.5 нет способа скрыть окно начальной страницы. Если программно или интерактивно очистить список форм, тогда в окно начальной страницы автоматически будет загружена встроенная форма "G5HomePlaceholder.lf" 
   

   Показать скриншоты (начальная страница без выбранной формы, кнопка "Очистить")

   

• Интерфейс версия 8.5 если в конфигураторе, Свойства конфигурации --> Рабочая область начальной страницы, очистить список форм, тогда у пользователя не будет возможности интерактивного изменения начальной страницы --> исчезнет пункт меню "Выбор начальной страницы", но тем не менее окно "Начало" все равно откроется со встроенной формой "G5HomePlaceholder.lf", но уже без гиперссылки "Выбор начальной страницы" 
   

   Показать скриншоты (начальная страница с пустым списком доступных к выбору форм)

   

   

МЕНЕДЖЕР ОТКРЫТЫХ ФОРМ (СКАЧАТЬ БЕСПЛАТНО)

Интерфейс версия 8.5 (Платформа 8.5.1.1343 Управление нашей фирмой 3.0.13.374)

•  

   выбрать форму начальной страницей в один клик / очистить начальную страницу

  

•  

   отредактировать начальную страницу у определеного пользователя / установить настройку по умолчанию / удалить настройку пользователя / скопировать настройку списку пользователей

  

Интерфейс такси

•  

   добавить форму на начальную страницу /  очистить начальную страницу

  

•  

   отредактировать начальную страницу у определеного пользователя / скопировать настройку списку пользователей / удалить настройку пользователя