В типовой конфигурации на счете 90.07 изначально нет субконто "Номенклатурные группы". Таким образом при директ-костинге суммы со счета 26 списываются на счет 90.07 (по субсчету вида налогообложения) без распределения по номенклатурным группам.
1. Добавим на 26 счет субконто "Номенклатурные группы".
2. Изменим алгоритмы закрытия счета 26.
В 1С БП релиз 3.0 все затраты, подлежащие распределению, собираются воедино.
Далее к ним применяются правила распределения в строго заданном порядке.
Можно добавлять свои и переопределять существующие правила.
В правилах определяется база распределения, счета для отбора расходов и многое другое.
Изменим существующую процедуру ОбщийМодуль.ПравилаРаспределенияРасходов.ДобавитьПравилоДиректКостинг()
Процедура ДобавитьПравилоДиректКостинг(ПравилаРаспределения, Период, Организация)
// Списываем расходы на продажу (на финансовый результат)
Правило = ПравилаРаспределения.Добавить();
Правило.Имя = "ДиректКостинг";
Правило.Наименование = НСтр("ru = 'Списать расходы на результат текущего периода методом ""Директ-костинг""'");
Правило.СодержаниеПроводки = НСтр("ru = 'Закрытие счетов косвенных расходов'");
// Отбор источника
Правило.ОтборРасходов = Новый Структура;
СчетаРасходовНаУправление = Новый Массив;
СчетаРасходовНаУправление.Добавить(ПланыСчетов.Хозрасчетный.ОбщехозяйственныеРасходы);
Правило.ОтборРасходов.Вставить("Счет", БухгалтерскийУчет.ПолучитьМассивСчетовССубсчетами(СчетаРасходовНаУправление));
Правило.Действие = "РаспределитьНаСубконто";
ПоляПриемника = Новый Структура;
ПоляПриемника.Вставить("Субконто1");
Правило.ПоляПриемника=ПоляПриемника;
Правило.ПоляИсточника.Вставить("ВидДеятельности", "ВидДеятельности");
ТекстЗапроса =
"ВЫБРАТЬ РАЗЛИЧНЫЕ
| Хозрасчетный.Ссылка КАК Счет
|ПОМЕСТИТЬ ВТ_СчетаВыручки
|ИЗ
| ПланСчетов.Хозрасчетный КАК Хозрасчетный
|ГДЕ
| (Хозрасчетный.Ссылка В ИЕРАРХИИ (ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Выручка))
| ИЛИ Хозрасчетный.Ссылка В ИЕРАРХИИ (ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Продажи_НДС)))
|
|ИНДЕКСИРОВАТЬ ПО
| Счет
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ЗНАЧЕНИЕ(Перечисление.ВидыДеятельностиДляНалоговогоУчетаЗатрат.ОсновнаяСистемаНалогообложения) КАК ВидДеятельности,
| &ПустоеПодразделение КАК Подразделение,
| ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.Продажи_РасходыНаПродажуНеЕНВД) КАК Счет,
| ХозрасчетныйОбороты.Субконто1 КАК Субконто1,
| НЕОПРЕДЕЛЕНО КАК Субконто2,
| НЕОПРЕДЕЛЕНО КАК Субконто3,
| ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка) КАК Номенклатура,
| ЕСТЬNULL(ХозрасчетныйОбороты.СуммаОборотКт, 0) - ЕСТЬNULL(ХозрасчетныйОбороты.СуммаОборотДт, 0) КАК База
|ПОМЕСТИТЬ БазаРаспределения_СписатьРасходыТекущегоПериода
|ИЗ
| РегистрБухгалтерии.Хозрасчетный.Обороты(
| &НачалоПериода,
| &КонецПериода,
| ,
| Счет В
| (ВЫБРАТЬ
| ВТ_СчетаВыручки.Счет
| ИЗ
| ВТ_СчетаВыручки),
| ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.НоменклатурныеГруппы),
| Организация = &Организация,
| ,
| ) КАК ХозрасчетныйОбороты
|
|ИНДЕКСИРОВАТЬ ПО
| ВидДеятельности
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТ_СчетаВыручки";
Правило.БазаРаспределения.Вставить("Имя", "БазаРаспределения_СписатьРасходыТекущегоПериода");
Правило.БазаРаспределения.Вставить("ТекстЗапроса", ТекстЗапроса);
КонецПроцедуры
Аналогично решается закрытие субсчетов 44 счета (расходы на продажу) на 90.08 счет.
Сам алгоритм приведен в прикрепленном файле.
Вступайте в нашу телеграмм-группу Инфостарт
