Вывод отладочных сообщений HTTP Сервиса с помощью ChromeLogger

Публикация № 705818

Разработка - Практика программирования

ChromeLogger отладка http сервис base64

22
Разработка для 1C для вывода отладочной информации с помощью ChromeLogger. Есть вопросы к знатокам.

Существует ряд средств для отладки веб-приложений, которые выводят сообщения сформированные на стороне сервера в консоль браузера. 

Рассмотрим как работает одно из таких средств - ChromeLogger (https://craig.is/writing/chrome-logger/techspecs).

На стороне сервера в процессе формирования ответа добавляется заголовок X-ChromeLogger-Data. Значение заголовка формируется так:

1. Формируем json строку вида:

data = {
    "version": "0.2", // версия модуля, который формирует отладочную информацию
    "request_uri": "/", // ресурс
    "columns": ["label", "log", "backtrace", "type"], // перечень колонок
    "rows": [ // массив строк, соответствующих колонкам
        [
            'метка',
            'сообщение/описание/представление объекта',
            'стек вызова',
            'тип отладочного сообщения'
        ]
    ]
}

2. Кодируем строку в UTF8

3. Кодируем строку в Base64

На стороне клиента в браузере Google Chrome установленное расширение Chrome Logger разбирает данный заголовок и выводит информацию в консоль.

 

А теперь реализуем это для 1С

Разработка производится на 8.3.10.2505, УНФ 1.6.12.4. Модули входят в состав расширения. Конфигурация с поддержки не снята.

Нам необходимо где-то хранить информацию, я выбрал ХранилищеОбщихНастроек. Может быть есть лучше вариант?

функция Отладка(Данные, Метка="", Трассировка="", Тип="") экспорт
	ТекущиеДанные = ОбщегоНазначения.ХранилищеОбщихНастроекЗагрузить("ChromeLogger", "ChromeLogger");
	
	если НЕ ЗначениеЗаполнено(ТекущиеДанные) тогда
		ТекущиеДанные = новый ТаблицаЗначений();
		ТекущиеДанные.Колонки.Добавить("log");
		ТекущиеДанные.Колонки.Добавить("label");
		ТекущиеДанные.Колонки.Добавить("backtrace");
		ТекущиеДанные.Колонки.Добавить("type");
	конецесли;

	Запись = ТекущиеДанные.Добавить();	
	Запись.log = Данные;
	Запись.label = Метка;
	Запись.backtrace = Трассировка;
	Запись.type = Тип;
	
	ОбщегоНазначения.ХранилищеОбщихНастроекСохранить("ChromeLogger", "ChromeLogger", ТекущиеДанные);
конецфункции

Теперь сформируем заголовок.

Формируем json строку.

функция СформироватьChromeLoggerJson()
	Таблица = ОбщегоНазначения.ХранилищеОбщихНастроекЗагрузить("ChromeLogger", "ChromeLogger");	
	
	если НЕ ЗначениеЗаполнено(Таблица) ИЛИ Таблица.Количество() = 0 тогда
		возврат неопределено;
	конецесли;
	
	Запись = новый ЗаписьJSON();
	Запись.УстановитьСтроку();
	
	Структура = Новый Структура();
	Структура.Вставить("version", "4.0");
	
	Колонки = Новый Массив();
	Колонки.Добавить("label");
	Колонки.Добавить("log");
	Колонки.Добавить("backtrace");
	Колонки.Добавить("type");	
	
	Структура.Вставить("columns", Колонки);	
	
	Строки = новый Массив();	
	для каждого строка из Таблица цикл
		Значения = Новый Массив();
		Значения.Добавить(КодироватьВUnicodeEscape(строка.label));
		
		//Значения.Добавить(строка.log);				
		Значения.Добавить(КодироватьВUnicodeEscape(строка.log));
		
		Значения.Добавить(КодироватьВUnicodeEscape(строка.backtrace));
		Значения.Добавить(КодироватьВUnicodeEscape(строка.type));
		
		Строки.Добавить(Значения);
	конеццикла;	
	
	Структура.Вставить("rows", Строки);	
	Структура.Вставить("request_uri", "/");
	
	ЗаписатьJSON(Запись, Структура);
	
	Таблица.Очистить();
	
	возврат Запись.Закрыть();		
конецфункции

Все национальные символы должны быть кодированы с помощью escape-последовательностей \uhhhh, где hhhh — шестнадцатеричное число из четырех цифр. Для этого была написана, как быстрое решение, функция КодироватьВUnicodeEscape. Можно ли это сделать "красивее", и желательно по максимум штатными средствами?

функция КодироватьВUnicodeEscape(Строка) 
	Уникод = новый Массив();
	Уникод.Добавить("\u0410");
	Уникод.Добавить("\u0430");
	Уникод.Добавить("\u0411");
	Уникод.Добавить("\u0431");
	Уникод.Добавить("\u0412");
	Уникод.Добавить("\u0432");
	Уникод.Добавить("\u0413");
	Уникод.Добавить("\u0433");
	Уникод.Добавить("\u0414");
	Уникод.Добавить("\u0434");
	Уникод.Добавить("\u0415");
	Уникод.Добавить("\u0435");
	Уникод.Добавить("\u0401");
	Уникод.Добавить("\u0451");
	Уникод.Добавить("\u0416");
	Уникод.Добавить("\u0436");
	Уникод.Добавить("\u0417");
	Уникод.Добавить("\u0437");
	Уникод.Добавить("\u0418");
	Уникод.Добавить("\u0438");
	Уникод.Добавить("\u0419");
	Уникод.Добавить("\u0439");
	Уникод.Добавить("\u041a");
	Уникод.Добавить("\u043a");
	Уникод.Добавить("\u041b");
	Уникод.Добавить("\u043b");
	Уникод.Добавить("\u041c");
	Уникод.Добавить("\u043c");
	Уникод.Добавить("\u041d");
	Уникод.Добавить("\u043d");
	Уникод.Добавить("\u041e");
	Уникод.Добавить("\u043e");
	Уникод.Добавить("\u041f");
	Уникод.Добавить("\u043f");
	Уникод.Добавить("\u0420");
	Уникод.Добавить("\u0440");
	Уникод.Добавить("\u0421");
	Уникод.Добавить("\u0441");
	Уникод.Добавить("\u0422");
	Уникод.Добавить("\u0442");
	Уникод.Добавить("\u0423");
	Уникод.Добавить("\u0443");
	Уникод.Добавить("\u0424");
	Уникод.Добавить("\u0444");
	Уникод.Добавить("\u0425");
	Уникод.Добавить("\u0445");
	Уникод.Добавить("\u0426");
	Уникод.Добавить("\u0446");
	Уникод.Добавить("\u0427");
	Уникод.Добавить("\u0447");
	Уникод.Добавить("\u0428");
	Уникод.Добавить("\u0448");
	Уникод.Добавить("\u0429");
	Уникод.Добавить("\u0449");
	Уникод.Добавить("\u042a");
	Уникод.Добавить("\u044a");
	Уникод.Добавить("\u042b");
	Уникод.Добавить("\u044b");
	Уникод.Добавить("\u042c");
	Уникод.Добавить("\u044c");
	Уникод.Добавить("\u042d");
	Уникод.Добавить("\u044d");
	Уникод.Добавить("\u042e");
	Уникод.Добавить("\u044e");
	Уникод.Добавить("\u042f");
	Уникод.Добавить("\u044f");	
	
	РусскиеБуквы = Новый Массив();
	РусскиеБуквы.Добавить("А");
	РусскиеБуквы.Добавить("а");
	РусскиеБуквы.Добавить("Б");
	РусскиеБуквы.Добавить("б");
	РусскиеБуквы.Добавить("В");
	РусскиеБуквы.Добавить("в");
	РусскиеБуквы.Добавить("Г");
	РусскиеБуквы.Добавить("г");
	РусскиеБуквы.Добавить("Д");
	РусскиеБуквы.Добавить("д");
	РусскиеБуквы.Добавить("Е");
	РусскиеБуквы.Добавить("е");
	РусскиеБуквы.Добавить("Ё");
	РусскиеБуквы.Добавить("ё");
	РусскиеБуквы.Добавить("Ж");
	РусскиеБуквы.Добавить("ж");
	РусскиеБуквы.Добавить("З");
	РусскиеБуквы.Добавить("з");
	РусскиеБуквы.Добавить("И");
	РусскиеБуквы.Добавить("и");
	РусскиеБуквы.Добавить("Й");
	РусскиеБуквы.Добавить("й");
	РусскиеБуквы.Добавить("К");
	РусскиеБуквы.Добавить("к");
	РусскиеБуквы.Добавить("Л");
	РусскиеБуквы.Добавить("л");
	РусскиеБуквы.Добавить("М");
	РусскиеБуквы.Добавить("м");
	РусскиеБуквы.Добавить("Н");
	РусскиеБуквы.Добавить("н");
	РусскиеБуквы.Добавить("О");
	РусскиеБуквы.Добавить("о");
	РусскиеБуквы.Добавить("П");
	РусскиеБуквы.Добавить("п");
	РусскиеБуквы.Добавить("Р");
	РусскиеБуквы.Добавить("р");
	РусскиеБуквы.Добавить("С");
	РусскиеБуквы.Добавить("с");
	РусскиеБуквы.Добавить("Т");
	РусскиеБуквы.Добавить("т");
	РусскиеБуквы.Добавить("У");
	РусскиеБуквы.Добавить("у");
	РусскиеБуквы.Добавить("Ф");
	РусскиеБуквы.Добавить("ф");
	РусскиеБуквы.Добавить("Х");
	РусскиеБуквы.Добавить("х");
	РусскиеБуквы.Добавить("Ц");
	РусскиеБуквы.Добавить("ц");
	РусскиеБуквы.Добавить("Ч");
	РусскиеБуквы.Добавить("ч");
	РусскиеБуквы.Добавить("Ш");
	РусскиеБуквы.Добавить("ш");
	РусскиеБуквы.Добавить("Щ");
	РусскиеБуквы.Добавить("щ");
	РусскиеБуквы.Добавить("Ъ");
	РусскиеБуквы.Добавить("ъ");
	РусскиеБуквы.Добавить("Ы");
	РусскиеБуквы.Добавить("ы");
	РусскиеБуквы.Добавить("Ь");
	РусскиеБуквы.Добавить("ь");
	РусскиеБуквы.Добавить("Э");
	РусскиеБуквы.Добавить("э");
	РусскиеБуквы.Добавить("Ю");
	РусскиеБуквы.Добавить("ю");
	РусскиеБуквы.Добавить("Я");
	РусскиеБуквы.Добавить("я");	
	
	для индекс = 0 по РусскиеБуквы.Количество()-1 цикл
		Строка = СтрЗаменить(Строка, РусскиеБуквы.Получить(индекс), Уникод.Получить(индекс));
	конеццикла;	
	
	возврат Строка;
конецфункции

Далее необходимо кодировать получившееся в utf8, после в base64. Можно ли это сделать без всяких временных файлов?

функция КодироватьВUTF8ИBase64(Строка)
    ВременныйФайл = ПолучитьИмяВременногоФайла();

    Запись = Новый ЗаписьТекста(ВременныйФайл, КодировкаТекста.UTF8);
    Запись.Записать(Строка);
    Запись.Закрыть();
    
    ДвоичныеДанные = Новый ДвоичныеДанные(ВременныйФайл);
    Результат = Base64Строка(ДвоичныеДанные);    
    УдалитьФайлы(ВременныйФайл);
	
	возврат Результат;
конецфункции

Собираем все вместе

функция СформироватьЗаголовокДляChromeLogger()
	json = СформироватьChromeLoggerJson();
	
	если НЕ ЗначениеЗаполнено(json) тогда
		возврат неопределено;
	конецесли;	

	json = СтрЗаменить(json, "\\u", "\u");
	Результат = КодироватьВUTF8ИBase64(json);	
	Результат = СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(Результат, " ", ""), Символы.ПС, ""), Символ(20), ""), Символ(13), "");	
	Результат = Прав(Результат, СтрДлина(Результат)-4);
	
	возврат Результат;
конецфункции

На последнем шаге добавляем заголовок к ответу

функция Ответ(ДанныеJSON) экспорт		
	Ответ = Новый HTTPСервисОтвет(200);
	Ответ.Заголовки.Вставить("Content-Type", "application/json; charset=UTF-8");
	
	ЗаголовокДляChromeLogger = СформироватьЗаголовокДляChromeLogger();
	если ЗначениеЗаполнено(ЗаголовокДляChromeLogger) тогда
		Ответ.Заголовки.Вставить("X-ChromeLogger-Data", ЗаголовокДляChromeLogger);				
	конецесли;
	
	ОбщегоНазначения.ХранилищеОбщихНастроекСохранить("ChromeLogger", "ChromeLogger", неопределено);
	
	Ответ.УстановитьТелоИзСтроки(ДанныеJSON, КодировкаТекста.UTF8, ИспользованиеByteOrderMark.НеИспользовать);	
	Возврат Ответ;	
конецфункции

Таким образом, при вызове в коде функции <ОбщийМодуль>.Отладка("Привет infostart.ru!"); в консоли браузера увидим наше сообщение.

 

В процессе реализации у меня возникли следующие вопросы:

1. Где лучше хранить отладочную информацию (функция Отладка), в случае использования расширений конфигурации?

2. Как "красиво" и правильно закодировать строку в unicode escape-последовательности (функция КодироватьВUnicodeEscape) штатными средствами?

3. Можно ли кодировать строку в base64 штатными средствами без временных файлов?

 

Спасибо. Надеюсь, кому-нибудь мой опыт будет полезен.

 

Обновление №1

Спасибо всем за ответы. 

Переписаны функции 
- КодироватьВUTF8ИBase64 
- КодироватьВUnicodeEscape 
- СформироватьChromeLoggerJson 

// Наименование модуля
// ХромЛогер

// Получить данные отладки
//
// Возвращаемое значение:
// Массив
//
функция ПолучитьДанныеОтладки()
	возврат ОбщегоНазначения.ХранилищеОбщихНастроекЗагрузить("ChromeLogger", "ChromeLogger");
конецфункции

// Установить данные отладки
//
// Параметры:
// Значение - Массив
//
процедура УстановитьДанныеОтладки(Значение)
	ОбщегоНазначения.ХранилищеОбщихНастроекСохранить("ChromeLogger", "ChromeLogger", Значение);
конецпроцедуры	

// Удалить все данные отладки
//
процедура УдалитьДанныеОтладки()
	ОбщегоНазначения.ХранилищеОбщихНастроекСохранить("ChromeLogger", "ChromeLogger", неопределено);
конецпроцедуры	

////////////////////////////////////////////////////////
////////////////////////////////////////////////////////

// Добавляет отладочное сообщение
//
// Параметры:
// Данные - Строка, или Объект
// Метка - Строка
// Трассировка - Строка
// Тип - Строка - возможные значения: log, warn, error, info, group, groupEnd, groupCollapsed, table
//
процедура Отладка(Данные, Метка="", Трассировка="", Тип="") экспорт
	ТекущиеДанные = ПолучитьДанныеОтладки();
	
	если НЕ ЗначениеЗаполнено(ТекущиеДанные) тогда
		ТекущиеДанные = новый Массив();
	конецесли;
	
	СтрокаДанные = новый Массив();
	СтрокаДанные.Вставить(0, Данные);
	СтрокаДанные.Вставить(1, Метка);
	СтрокаДанные.Вставить(2, Трассировка);
	СтрокаДанные.Вставить(3, Тип);
	
	ТекущиеДанные.Добавить(СтрокаДанные);
	
	УстановитьДанныеОтладки(ТекущиеДанные);
конецпроцедуры

// Кодирует строку в UTF8, затем в BASE64
//
// Параметры:
// Строка - Строка, которую необходимо закодировать
//
// Возвращаемое значение:
// Строка - строка в BASE64
//
функция КодироватьВUTF8ИBase64(Строка)
	// Совет http://forum.infostart.ru/forum9/topic181969/message1888978/#message1888978
	Поток = Новый ПотокВПамяти;
	
	ЗаписьДанных = Новый ЗаписьДанных(Поток, КодировкаТекста.UTF8,,,,ложь);
	ЗаписьДанных.ЗаписатьСимволы(Строка);
	ЗаписьДанных.Закрыть();
	
	ДвоичныеДанные = Поток.ЗакрытьИПолучитьДвоичныеДанные();
	Результат = Base64Строка(ДвоичныеДанные);
	
	возврат Результат;
конецфункции	

// Преобразовывает число в шестнадцатеричное представление
//
// Параметры:
// Значение - Число
//
// Возвращаемое значение:
// Строка - шестнадцатеричное представление
//
функция ЧислоВHex(Значение)
	Результат = "";
	
	Пока Значение > 0 Цикл
		Результат = Сред("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ", Значение%16 + 1, 1) + Результат;
		Значение = Цел(Значение/16) ;
	КонецЦикла;
	
	Возврат Результат;
конецфункции

// Кодирует строку с использованием escape-последовательностей
//
// Параметры:
// Строка - Строка, которую необходимо преобразовать
//
// Возвращаемое значение:
// Строка - преобразованная строка
//
функция КодироватьВUnicodeEscape(Строка) 
	Результат = "";
	для индекс = 1 по СтрДлина(Строка) цикл		
		Символ = Сред(Строка, индекс, 1);
		КодСимвола = КодСимвола(Символ);
		если КодСимвола > 127 тогда
			Символ = "\u" + Прав("0000" + ЧислоВHex(КодСимвола), 4);
		конецесли;
		
		Результат = Результат + Символ;
	конеццикла;	
	
	возврат Результат;
конецфункции	

// Вспомогательная фукнция для ЗаписатьJSON() в СформироватьChromeLoggerJson()
//
Функция ПреобразованиеJSON(Знач Свойство, Значение, ДопПараметры, Отказ) Экспорт
	// Совет http://forum.infostart.ru/forum9/topic181969/message1888986/#message1888986
	ТипЗначения = ТипЗнч(Значение);
	
	Если ТипЗначения = Тип("ТаблицаЗначений") Тогда
		
		мКолонки = Новый Массив;
		
		Для Каждого Колонка ИЗ Значение.Колонки Цикл
			мКолонки.Добавить(Колонка.Имя);
		КонецЦикла;
		
		СтрКолонки = СтрСоединить(мКолонки, ",");
		
		Массив = Новый Массив;
		
		Для Каждого СтрокаТЗ ИЗ Значение Цикл
			Структура = Новый Структура(СтрКолонки);
			ЗаполнитьЗначенияСвойств(Структура, СтрокаТЗ, СтрКолонки);
			Массив.Добавить(Структура);
		КонецЦикла;
		
		Возврат ПерекодироватьВсеСтрокиВМассивеВUnicodeEscape(Массив);
		
	ИначеЕсли ТипЗначения = Тип("Дата") Тогда
		
		Если НачалоДня(Значение) = '00010101' Тогда
			Возврат Формат(Значение, "ДФ=HH:mm:ss");
		Иначе
			Возврат Формат(Значение, "ДФ='dd.MM.yyyy HH:mm:ss'"); //Игнорим настройки системы
		КонецЕсли;
		
	Иначе
		
		возврат КодироватьВUnicodeEscape(Строка(Значение)); // рискнем и преобразуем в строку
		
	КонецЕсли;
	
КонецФункции

// Перекодирует все строки в массиве (рекурсивно)
//
// Параметры:
// МассивЗначений - Массив
//
// Возвращаемое значение:
// Массив - с перекодированными строками
//
функция ПерекодироватьВсеСтрокиВМассивеВUnicodeEscape(МассивЗначений)
	если ЗначениеЗаполнено(МассивЗначений) И МассивЗначений.Количество() > 0  тогда
		для индекс = 0 по МассивЗначений.Количество()-1 цикл
			Элемент = МассивЗначений.Получить(индекс);
			если ТипЗнч(Элемент) = Тип("Строка") тогда
				МассивЗначений.Установить(индекс, КодироватьВUnicodeEscape(элемент));
			иначеесли ТипЗнч(Элемент) = Тип("Массив") тогда
				МассивЗначений.Установить(индекс, ПерекодироватьВсеСтрокиВМассивеВUnicodeEscape(элемент));
			конецесли;
		конеццикла;	
	конецесли;
	
	возврат МассивЗначений;
конецфункции	

// Сформировать json строку для заголовка ChromeLogger'а
// 
// Возвращаемое значение:
// Строка - JSON
//
функция СформироватьChromeLoggerJson()
	ТекущиеДанные = ПолучитьДанныеОтладки();
	
	если НЕ ЗначениеЗаполнено(ТекущиеДанные) ИЛИ ТекущиеДанные.Количество() = 0 тогда
		возврат неопределено;
	конецесли;
	
	Запись = новый ЗаписьJSON();
	Запись.УстановитьСтроку();
	
	Структура = Новый Структура();
	Структура.Вставить("version", "1.0");
	
	Колонки = Новый Массив();
	Колонки.Добавить("label");
	Колонки.Добавить("log");
	Колонки.Добавить("backtrace");
	Колонки.Добавить("type");	
	
	Структура.Вставить("columns", Колонки);		
	Структура.Вставить("rows", ПерекодироватьВсеСтрокиВМассивеВUnicodeEscape(ТекущиеДанные));	
	Структура.Вставить("request_uri", "/");
	
	ЗаписатьJSON(Запись, Структура,,"ПреобразованиеJSON", ХромЛогер);
	
	УдалитьДанныеОтладки();
	
	возврат Запись.Закрыть();		
конецфункции

// Сформировать заголовок X-ChromeLogger-Data
//
// Возвращаемое значение:
// Строка - BASE64
//
функция СформироватьЗаголовокДляChromeLogger() Экспорт
	json = СформироватьChromeLoggerJson();
	
	если НЕ ЗначениеЗаполнено(json) тогда
		возврат неопределено;
	конецесли;	
	
	json = СтрЗаменить(json, "\\u", "\u");
	Результат = КодироватьВUTF8ИBase64(json);	
	Результат = СтрЗаменить(СтрЗаменить(СтрЗаменить(СтрЗаменить(Результат, " ", ""), Символы.ПС, ""), Символ(20), ""), Символ(13), "");	
	
	возврат Результат;
конецфункции

Пример использования

функция Ответ(ДанныеJSON) экспорт		
	Ответ = Новый HTTPСервисОтвет(200);
	Ответ.Заголовки.Вставить("Content-Type", "application/json; charset=UTF-8");
	
	ЗаголовокДляChromeLogger = ХромЛогер.СформироватьЗаголовокДляChromeLogger();
	если ЗначениеЗаполнено(ЗаголовокДляChromeLogger) тогда
		Ответ.Заголовки.Вставить("X-ChromeLogger-Data", ЗаголовокДляChromeLogger);
	конецесли;
	
	Ответ.УстановитьТелоИзСтроки(ДанныеJSON, КодировкаТекста.UTF8, ИспользованиеByteOrderMark.НеИспользовать);	
	Возврат Ответ;	
конецфункции

 

22

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. Bassgood 937 27.11.17 18:30 Сейчас в теме
Можно ли это сделать "красивее", и желательно по максимум штатными средствами?

РусскиеБуквыСтрокой = "А,Б,В,Г,Д";
РусскиеБуквы = СтроковыеФункцииКлиентСервер.РазложитьСтрокуВМассивПодстрок(РусскиеБуквыСтрокой, ",");

Процедуру разложения строки в массив можете выдернуть из БСП и прописать в ней добавление еще букв нижнего регистра, либо дополнить массив букв уже после его формирования, как то так ;)
3. PerlAmutor 45 27.11.17 18:54 Сейчас в теме
(1) Это можно сделать тоже штатными средствами:
РусскиеБуквыСтрокой = "А,Б,В,Г,Д";
РусскиеБуквы = СтрРазделить(РусскиеБуквыСтрокой,",", Ложь));
4. Bassgood 937 27.11.17 19:16 Сейчас в теме
(3) Можно и так, но на ранних версих 8.3 и ниже не взлетит - этот метод в платформе еще не был реализован.
6. ArchLord42 68 27.11.17 19:34 Сейчас в теме
(1) у автора 8.3.10 там и СтрРазделить можно юзать уже давно
7. ArchLord42 68 27.11.17 19:35 Сейчас в теме
(6) Пока писал уже написали за меня)
2. PerlAmutor 45 27.11.17 18:52 Сейчас в теме
3. Можно ли кодировать строку в base64 штатными средствами без временных файлов?

Сам не пробовал, но связка из этих двух функций глобального контекста в 8.3.11, вероятно может это сделать:
ПолучитьБуферДвоичныхДанныхИзСтроки
ПолучитьBase64СтрокуИзБуфераДвоичныхДанных
5. PerlAmutor 45 27.11.17 19:21 Сейчас в теме
Для функции "КодироватьВUnicodeEscape" данные я бы поместил либо в текстовый макет, либо в двоичный макет, в формате JSON. Соответственно перед вызовом функции хорошо бы эти данные вытащить и подготовить, а не делать этого на лету. Макет хранить в обработке расширения можно.
В 8.3.11 расширения позволяют перехватить УстановкуПараметровСеанса (на выбор, до или после родного обработчика) и создавать прямо в расширении свои Регистры сведений.
8. ArchLord42 68 27.11.17 19:36 Сейчас в теме
получение base64 строки без временных файлов

ТестоваяСтрока = "<<JSON>>>";
	
Поток = Новый ПотокВПамяти;

ЗаписьДанных = Новый ЗаписьДанных(Поток, КодировкаТекста.UTF8,,,,Ложь);
ЗаписьДанных.ЗаписатьСимволы(ТестоваяСтрока);
ЗаписьДанных.Закрыть();

ДД = Поток.ЗакрытьИПолучитьДвоичныеДанные();
Base64Строка = Base64Строка(ДД);
Показать


Странно, у меня на платформе 8.3.10.2466 вылетает ошибка:
Некорректные символы в заголовке HTTP: [X-ChromeLogger-Data: e31zYWRhc2Rhc2Rhc2Rhc2RzZGZnLC5kZnNiZmRuYmxrbmRzZmxrYm5zc3Nzc3Nz c3Nzc3Nzcw==]

чет не кушает base64
9. ArchLord42 68 27.11.17 19:55 Сейчас в теме
Сколько публикаций не видел по HTTP сервисами, ни разу не видел, чтобы юзали 3,4,5 параметры у функции "ПреобразоватьJSON", а их использование может сэкономить приличное количество строк кода и инкапсулировать все преобразования данных, которая 1Ска не может сделать автоматом, достаточно накидать функцию наподобие этой:

Функция ПреобразованияJSON(Свойство, Значение, ДопПараметры, Отказ) Экспорт
	ТипЗначения = ТипЗнч(Значение);
	
	Если ТипЗначения = Тип("ТаблицаЗначений") Тогда
		
		мКолонки = Новый Массив;
		
		Для Каждого Колонка ИЗ Значение.Колонки Цикл
			мКолонки.Добавить(Колонка.Имя);
		КонецЦикла;
		
		СтрКолонки = СтрСоединить(мКолонки, ",");
		
		Массив = Новый Массив;
		
		Для Каждого СтрокаТЗ ИЗ Значение Цикл
			Структура = Новый Структура(СтрКолонки);
			ЗаполнитьЗначенияСвойств(Структура, СтрКолонки);
			Массив.Добавить(Структура);
		КонецЦикла;
		
		Возврат Массив;
		
	ИначеЕсли ЭтоСсылка(Значение) Тогда
		
		Возврат XMLСтрока(Значение);
		
	ИначеЕсли ТипЗначения = Тип("Дата") Тогда
		
		Если НачалоДня(Значение) = '00010101' Тогда
			Возврат Формат(Значение, "ДФ=HH:mm:ss");
		Иначе
			Возврат Формат(Значение, "ДФ='dd.MM.yyyy HH:mm:ss'"; //Игнорим настройки системы
		КонецЕсли;
		
	Иначе
		
		Отказ = Истина;
		
	КонецЕсли;
	
КонецФункции
Показать


и подставить нужные параметры в функцию ЗаписатьJSON
10. MOPC 22 28.11.17 07:38 Сейчас в теме
Большое спасибо всем за советы.

Добавил обновление!
11. Dementor 584 29.11.17 20:38 Сейчас в теме
А можете привести пример использования такой доработки?

Если нужна отладка в процессе разработки, то включаем в конфигураторе автоподключение отладки веб/http-сервисов и наслаждаемся просмотром значений всех переменных и стеком вызовов.
Если нужно решать какую-то проблему связанную с рабочим использованием, то мне кажется более простым способом делать в ключевых точках записи в журнал регистрации с нужным тегом, а потом анализировать накопленные логи.

В вашем решении много кода и установка стороннего расширения в браузере. В чем же преимущества? Да и многопользовательская одновременная работа не очень продумана - под одним пользователем с долгой операцией логи накопятся, а другой клиент с быстрым запросом их прочитает и обнулит для первого пользователя.
12. MOPC 22 30.11.17 02:28 Сейчас в теме
(11) Да, совершенно верно. Можно использовать штатную отладку.
Это все лишь еще один из способов...

А пример использования - только на этапе разработки и если вы работаете в паре с веб-разработчиком, который знает, допустим только javascript/angular, и ему (разработчику) нужна какая то доп.информация.
Dementor; +1 Ответить
13. Dementor 584 30.11.17 12:35 Сейчас в теме
(12) О, про работу в паре с веб-мастером, у которого нет доступа к серверу 1С, я как-то не подумал.
Оставьте свое сообщение

См. также

Агрегатные функции СКД, о которых мало кто знает 315

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    9379    ids79    42       

Три костыля. Сказ про фокусы в коде 121

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    7526    YPermitin    67       

Отслеживание выполнения фонового задания 133

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    7836    ids79    14       

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив 239

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    9730    ids79    22       

Фоновое выполнение кода в 1С - это просто 117

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    9543    avalakh    21       

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты 125

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    8801    ids79    6       

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ 134

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Инструментарий разработчика Практика программирования Разработка

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    8302    ids79    24       

"Меньше копипаста!", или как Вася универсальную процедуру писал 170

Статья Программист Стажер Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    6089    SeiOkami    48       

Создание отчетов с помощью СКД - основные понятия и элементы 188

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    16896    ids79    16       

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017 174

Статья Программист Нет файла v8 v8::Запросы Бесплатно (free) Практика программирования Разработка

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    11272    dmurk    134       

Регистры накопления. Структура хранения в базе данных 173

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    16882    YPermitin    27       

Выполнение внешней обработки в фоновом задании 147

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Подробное описание подхода к созданию длительной операции на основе внешней обработки. Реализация протестирована на 1С 8.3.12.1714 (x64).

11.05.2019    9527    Eret1k    22       

Выгрузка документа по условию 5

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    4658    m-rv    2       

Как прикрутить ГУИД к регистру сведений 23

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8 Разработка

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    7174    m-rv    16       

О расширениях замолвите слово... 193

Статья Программист Стажер Нет файла v8 Бесплатно (free) Практика программирования Разработка

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    16049    ellavs    122       

Git-репозитории для 1С-кода (опыт использования при небольших проектах) 199

Статья Программист Стажер Нет файла v8 Windows Бесплатно (free) Практика программирования Разработка

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    12492    ellavs    83       

Трюки с внешними источниками данных 164

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    12589    YPermitin    52       

Возможности типовых шаблонов ограничения доступа на уровне записей (RLS) 162

Статья Программист Нет файла v8 v8::Права Бесплатно (free) Практика программирования БСП (Библиотека стандартных подсистем) Роли и права

Краткий обзор применения типовых шаблонов ограничения доступа на уровне записей в конфигурациях, созданных на базе БСП: #ПоЗначениям, #ПоНаборамЗначений, #ПоЗначениямРасширенный, #ПоЗначениямИНаборамРасширенный

03.02.2019    15096    ids79    9       

EnterpriseData – часть 2. Процесс выгрузки данных 126

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Основные этапы выгрузки данных через ED, обработчики событий выгрузки, правила обработки данных, правила конвертации объектов, конвертация свойств первого и второго этапов, процедуры БСП, используемые при выгрузке данных, структура «КомпонентыОбмена».

26.12.2018    12475    ids79    27       

Новый подход к обмену данными EnterpriseData 202

Статья Программист Нет файла v8 v8::УФ Россия Бесплатно (free) Практика программирования Обмен через XML

Хочу предложить Вашему вниманию цикл статей, посвященных обмену данными через универсальный формат (EnterpriseData или ED).

14.12.2018    20997    ids79    72       

EnterpriseData - пример доработки правил конвертации без использования КД 3.0 в расширении конфигурации 117

Статья Программист Нет файла v8 v8::УФ БП3.0 УТ11 Россия Windows Бесплатно (free) Практика программирования Обмен через XML

В статье подробно описан реальный пример доработки обмена данными через EnterpriseData (универсальный формат обмена) между конфигурациями УТ 11.4 и Бухгалтерия 3.0

16.11.2018    18517    ids79    20       

Программное заполнение пользовательских параметров и отборов СКД 135

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Публикация представляет из себя краткие примеры того, как можно заполнять параметры СКД программно так, чтобы все параметры и отборы были доступны в быстрых настройках и в обычных (типовых) настройках параметров и отборов СКД.

13.11.2018    19140    Unk92    18       

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С 125

Статья Программист Нет файла v8 v8::blocking 1cv8.cf Бесплатно (free) Математика и алгоритмы Практика программирования

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    20579    ids79    40       

Вспомогательные инструкции в коде 1С 104

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    20235    tormozit    100       

Произвольный код в фоновом режиме 163

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Задача: реализовать выполнение произвольного кода в фоновом режиме без изменения конфигурации, т.е. во внешней обработке.

03.09.2018    14396    nikita0832    41       

Основные понятия и механизмы оптимизации клиент-серверного взаимодействия в 1C 144

Статья Программист Нет файла v8 Россия Бесплатно (free) Математика и алгоритмы Практика программирования

У многих начинающих 1С программистов часто возникают вопросы про клиент-серверное взаимодействие в 1С и чтобы разобраться в непростых механизмах платформы, необходимо понять, что же такое контекст, для чего предназначены директивы компиляции, что представляют собой контекстные/внеконтекстные вызовы и как наиболее оптимально описывать прикладные задачи в модулях управляемых форм.

23.08.2018    20892    Rain88    42       

Повышаем эффективность разработки правил обмена 122

Статья Программист Нет файла v8 КД ОС Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8

Как повысить скорость и качество разработки правил обмена? Как вести групповую разработку правил обмена? Как облегчить сопровождение правил обмена после передачи в эксплуатацию? Об этом и многом другом вы можете узнать из этой статьи.

25.06.2018    19127    olegtymko    43       

Введение в механизм представлений в ЗУП ред. 3 152

Статья Программист Нет файла v8 v8::СПР ЗУП3.x Бесплатно (free) Практика программирования

В нашей организации на первом же телефонном собеседовании на должность разработчика по ЗУП ред. 3 вас обязательно спросят о том, что такое "Представления".

04.06.2018    24100    xrrg    82       

Как сделать запрос на изменение данных 75

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    21029    m-rv    21       

Строим графы средствами 1С (без GraphViz) 42

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Множество статей на Инфостарте описывают, как работать с компонентой GraphViz, чтобы построить ориентированный граф. Но практически нет материалов, как работать с такими графами средствами 1С. Сегодня я расскажу, как красиво строить графы с минимальным пересечением. Нам этот метод пригодился для отрисовки алгоритмов в БИТ.Финансе, т.к. типовой механизм не устраивал. Еще это может быть полезно для визуализации различных зависимостей: расчета себестоимости, графы аффилированности компаний и т.д. Надеюсь, эта статья поможет сделать мир 1С красивее и гармоничней:) Итак, поехали...

23.05.2018    16804    slozhenikin_com    19       

Распределение расходов пропорционально продажам 9

Статья Программист Пользователь Нет файла v8 v8::ОУ УТ10 УУ Финансовый учет и бюджетирование (FRP) Учет доходов и расходов Бесплатно (free) Практика программирования

Финансовая модель. Распределение административных расходов по подразделениям пропорционально продажам за месяц. Дополнительные реквизиты против бизнес-процессов!

13.05.2018    11207    Rustig    9       

Просмотр временных таблиц запроса в отладчике без изменения кода 126

Статья Программист Нет файла v8 v8::Запросы 1cv8.cf Бесплатно (free) Практика программирования

Данный способ можно использовать для просмотра содержимого временных таблиц запросов (менеджеров временных таблиц) без внесения изменений в код.

24.04.2018    23962    avfed@rambler.ru    19       

Минимализмы 3 350

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Универсальные функции

Очередная серия "минимализмов" [http://infostart.ru/public/306536/, https://infostart.ru/public/460935/]. Также, как и в предыдущих статьях, здесь приведена подборка коротких оригинальных авторских решений некоторых задач. Ранее эти решения были разбросаны по моим комментариям к чужим публикациям.

19.02.2018    35274    ildarovich    44       

Этюды по программированию. Взаимодействие с Microsoft Word 108

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Часто приходится заниматься созданием сложных документов Word с таблицами, вложенными фрагментами, хитрым оформлением и прочими радостями жизни. Это - попытка как-то структурировать полученный опыт, чтобы не приходилось перерывать ворох старых обработок в поисках крупиц истины. Надеюсь, эта статья будет полезна и Вам.

11.12.2017    25683    milkers    23       

Метод формирования движений в типовых регистрах нетиповыми регистраторами 31

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    21170    itriot11    34       

1С: Конвертация данных 3. Инструкции и примеры. EnterpriseData (универсальный формат обмена) 717

Статья Программист Нет файла v8 КД Бесплатно (free) Перенос данных из 1C8 в 1C8 Практика программирования Обмен через XML

Что такое КД3? Как начать использовать? Полезные дополнения к документации. Что нужно исправить в типовых обработках и конфигурации. Как изменить правила обмена не снимая конфигурацию с поддержки. Как отлаживать правила обмена?

19.11.2017    136456    MaxS    251       

Заполнение данных по ИНН контрагента с помощью альтернативного сервиса огрн.онлайн 131

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Код для заполнения данных по ИНН контрагента из ЕГРЮЛ с сайта огрн.онлайн.

01.11.2017    22481    slava_1c    49       

Программные перечисления, ч.2: приемы кэширования при разработке 65

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования

Все знают, что такое кэш, и зачем он нужен. Но в 1С разработчик обычно использует кэширование только на уровне конфигурации, а в какой-нибудь обработке скорее ломает голову над запросом - как получить все данные за один заход... Хочется рассказать о том, как можно добиться хороших результатов с стратегией "разделяй и властвуй".

30.10.2017    20912    unichkin    17       

Разбираемся с настройками компоновки данных 159

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Краткая шпаргалка по программной работе с настройками СКД

29.10.2017    23859    json    9       

Работа с Excel 287

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Загрузка и выгрузка в Excel

Собрал различные полезности для работы с Excel из 1С. Иногда приходится форматировать документ Excel программно из 1С. Так вот, чтобы не искать постоянно на просторах интернета как сделать левое выравнивание в ячейке Excel из 1С и т.п. решил опубликовать это...

23.10.2017    24278    arakelyan    39       

Добавление команд печати в конфигурациях на БСП 2.4.3 (в частности, в самописных документах в Бухгалтерии 3.0 после релиза 3.0.52.35) 143

Статья Программист Нет файла v8 v8::БУ БП3.0 Россия Бесплатно (free) Печатные формы документов Практика программирования БСП (Библиотека стандартных подсистем)

В статье https://infostart.ru/public/237013/ пользователя nick max рассматривался список действий для подключения команд печати в Бухгалтерии 3.0, работающей на БСП 2.3.6. В новом релизе Бухгалтерии 3.0.52.35 от 15.09.2017г. стала использоваться БСП 2.4.3, из-за чего произошли изменения в процедурах общих модулей, связанных с механизмом печати, и в процедурах их вызова в формах документов и в формах списков. Рассмотрим их.

18.09.2017    46335    bugtester    43       

Отказ от работы с временными файлами при работе с двоичными данными или Потоки как простая замена ADODB.Stream и временным файлам 126

Статья Программист Нет файла v8 Россия Бесплатно (free) Практика программирования

В платформе начиная с версии 3.8.9 (как я понял по документации) появился расширенный функционал средств работы с двоичными данными. Если раньше простой и очевидный способ преобразования данных строился на использовании временных файлов, то теперь благодаря новым средствам можно уйти от их использования.

12.09.2017    18062    vardeg    31