Счета учета расчетов с контрагентами по видам договоров в 1С:Бухгалтерия предприятия

21.06.21

В статье описана реализация решения, которое позволяет в конфигурации "1С:Бухгалтерия предприятия 3.0" указывать счета учета расчетов с контрагентами по видам договоров. Реализуется с помощью незначительного изменения типовой конфигурации (добавление нового измерения ВидДоговора в типовой регистр) и нескольких изменений в расширении конфигурации.

В типовых конфигурациях "1С:Бухгалтерия предприятия 3.0" доступна настройка счетов учета расчетов с контрагентами только в разрезе организаций, контрагентов, договоров и вида расчетов.

Данное решение с настройкой по видам договора работает в сочетаниях со всеми типовыми вышеупомянутыми настройками. Предполагается указание либо конкретного договора (типовая логика), либо указание вида договора (аналогичная типовой, но не по конкретному договору, а по выбранному виду договора).

Краткая инструкция по реализации решения:

В основной конфигурации требуется добавить в РегистрСведений.СчетаУчетаРасчетовСКонтрагентами измерение "GV_ВидДоговора" (Тип ПеречислениеСсылка.ВидыДоговоровКонтрагентов).

В расширении переопределяется соответствующий метод общего модуля основной конфигурации, а также дополняются процедуры формы записи и формы списка регистра сведений (программный вывод нового измерения на формы). Для расширения необходимо отключить безопасный режим.

Проверено на:
1С:Предприятие 8.3 (8.3.15.1830)
Бухгалтерия предприятия КОРП, редакция 3.0 (3.0.77.106 - 3.0.81.30)

Пошаговая инструкция по реализации решения с пояснениями:

1. Добавление в РегистрСведений.СчетаУчетаРасчетовСКонтрагентами измерения "GV_ВидДоговора" в основной конфигурации.

К сожалению, добавление измерений в регистры сведений в расширениях на момент написания статьи недоступно, поэтому добавить измерение необходимо в основной кофигурации, предварительно изменив настройку поддержки регистра на "Редактируется с сохранением поддержки".

2. Переопределение метода общего модуля БухгалтерскийУчетПереопределяемый.ПолучитьСчетаРасчетовСКонтрагентом() в расширении.

Последующие действия совершаются в расширении.

Для расширения должен быть отключен Безопасный режим.

В расширение добавляется общий модуль БухгалтерскийУчетПереопределяемый, где переопределяется функция (Вместо)

ПолучитьСчетаРасчетовСКонтрагентом(Знач Организация, Знач Контрагент, Знач Договор) Экспорт

За основу, конечно, взята исходная функция. Принцип ее работы прост: запросы к регистру сведений, ранжированные по степени точности удовлетворения заданным условиям подбора счетов. Возвращается структура с самыми "близкими" подходящими счетами. Фактически все несколько сложнее, но упрощенно принцип подбора можно представить так: сначала пытаемся найти настройки для конкретного договора, если таковой не найден, то для контрагента, затем для организации и вида расчетов.

В регистре предполагается указание либо конкретного договора (типовая логика), либо указание вида договора. Если не найдены настройки для выбранного договора, то ищутся настройки для вида выбранного договора. Дополненная функция работает в сочетаниях со всеми типовыми настройками (организация, контрагент, вид расчетов) кроме договора (это взаимоисключающие настройки). В функции сохранена исходная приоритетность результатов. В основе - исходная функция, дополненная запросами с подбором по виду договора и параметрами запросов ВидДоговора и ПустойВидДоговора.

Код общего модуля БухгалтерскийУчетПереопределяемый в расширении:

//( GV - 30.05.2020 - Функция дополнена подбором счетов учета по виду договора (добавленное нетиповое измерение регистра).
	// Отборы запросов типовой конфигурации:
	//	1	Организация	        Контрагент		Договор (НЕ Пустой)
	//	2+	Организация		Контрагент		ГруппаДоговоров		ВидРасчетов
	//	3	Организация		Контрагент		ПустойДоговор		ВидРасчетов
	//	4+	Организация		ГруппаКонтрагентов	ПустойДоговор		ВидРасчетов
	//	5	Организация		ПустойКонтрагент	ПустойДоговор		ВидРасчетов
	//	6+	ПустаяОрганизация	Контрагент		ГруппаДоговоров		ВидРасчетов
	//	7	ПустаяОрганизация	Контрагент		ПустойДоговор		ВидРасчетов
	//	8+	ПустаяОрганизация	ГруппаКонтрагентов	ПустойДоговор		ВидРасчетов
	//	9	Организация		Контрагент		ПустойДоговор		ПустойВидРасчетов
	//	10	Организация		ПустойКонтрагент	ПустойДоговор		ПустойВидРасчетов
	//	11	ПустаяОрганизация	ПустойКонтрагент	ПустойДоговор		ВидРасчетов
	//	12	ПустаяОрганизация	ПустойКонтрагент	ПустойДоговор		ПустойВидРасчетов
	//
	// Итоговые дополненные запросы:
	//	1	Организация		Контрагент		Договор (НЕ Пустой)
	//	2+	Организация		Контрагент		ГруппаДоговоров		ВидРасчетов
	//	3GV	Организация		Контрагент		                        ВидРасчетов		ВидДоговора
	//	3	Организация		Контрагент		ПустойДоговор		ВидРасчетов		ПустойВидДоговора
	//	4GV	Организация		ГруппаКонтрагентов	                        ВидРасчетов		ВидДоговора
	//	4+	Организация		ГруппаКонтрагентов	ПустойДоговор		ВидРасчетов		ПустойВидДоговора
	//	5GV	Организация		ПустойКонтрагент	                        ВидРасчетов		ВидДоговора
	//	5	Организация		ПустойКонтрагент	ПустойДоговор		ВидРасчетов		ПустойВидДоговора
	//	6+	ПустаяОрганизация	Контрагент		ГруппаДоговоров		ВидРасчетов
	//	7GV	ПустаяОрганизация	Контрагент		                        ВидРасчетов		ВидДоговора
	//	7	ПустаяОрганизация	Контрагент		ПустойДоговор		ВидРасчетов		ПустойВидДоговора
	//	8GV	ПустаяОрганизация	ГруппаКонтрагентов	                        ВидРасчетов		ВидДоговора
	//	8+	ПустаяОрганизация	ГруппаКонтрагентов	ПустойДоговор		ВидРасчетов		ПустойВидДоговора
	//	9GV	Организация		Контрагент		                        ПустойВидРасчетов	ВидДоговора
	//	9	Организация		Контрагент		ПустойДоговор		ПустойВидРасчетов	ПустойВидДоговора
	//	10GV    Организация		ПустойКонтрагент	                        ПустойВидРасчетов	ВидДоговора
	//	10	Организация		ПустойКонтрагент	ПустойДоговор		ПустойВидРасчетов	ПустойВидДоговора
	//	11GV    ПустаяОрганизация	ПустойКонтрагент	                        ВидРасчетов		ВидДоговора
	//	11	ПустаяОрганизация	ПустойКонтрагент	ПустойДоговор		ВидРасчетов		ПустойВидДоговора
	//	12GV    ПустаяОрганизация	ПустойКонтрагент	                        ПустойВидРасчетов	ВидДоговора
	//	12	ПустаяОрганизация	ПустойКонтрагент	ПустойДоговор		ПустойВидРасчетов	ПустойВидДоговора

// Функция возвращает возможные счета учета расчетов с контрагентом
//
// Параметры:
//  Организация - по которой выполняется поиск
//  Контрагент  - по которому выполняется поиск
//  Договор     - по которому выполняется поиск
//
// Возвращаемое значение:
//  Структура - структура содержащая счета учета расчетов
// 
&Вместо("ПолучитьСчетаРасчетовСКонтрагентом")
Функция GV_ПолучитьСчетаРасчетовСКонтрагентом(Знач Организация, Знач Контрагент, Знач Договор)

	Результат = Новый Структура("СчетРасчетов, 
	                            |СчетАвансов,
	                            |СчетРасчетовПокупателя, 
	                            |СчетАвансовПокупателя, 
	                            |СчетРасчетовПоПретензиям,
	                            |СчетРасчетовСКомитентом,
	                            |СчетУчетаТары,
	                            |СчетУчетаТарыПокупателя");

	Если ТипЗнч(Договор) = Тип("ПеречислениеСсылка.ВидыРасчетовПоДоговорам") Тогда
		ВидРасчетовПоДоговору = Договор;
		Договор = ПолучитьПустоеЗначениеДоговора();
	Иначе
		ВидРасчетовПоДоговору = ОпределениеВидаРасчетовПоПараметрамДоговора(Договор);
	КонецЕсли;

	СписокГруппКонтрагентов = ОбщегоНазначенияБПВызовСервера.ПолучитьСписокВышеСтоящихГрупп(Контрагент);
	
	СписокГруппДоговоров = ОбщегоНазначенияБПВызовСервера.ПолучитьСписокВышеСтоящихГрупп(Договор);
	
	//( GV
	Если ТипЗнч(Договор) = Тип("СправочникСсылка.ДоговорыКонтрагентов")
		И Договор <> Справочники.ДоговорыКонтрагентов.ПустаяСсылка() Тогда
		ВидДоговора = Договор.ВидДоговора;
	Иначе
		ВидДоговора = Перечисления.ВидыДоговоровКонтрагентов.ПустаяСсылка();
	КонецЕсли;
	//) GV
	
	Запрос = Новый Запрос();
	Запрос.УстановитьПараметр("Организация",       Организация);
	Запрос.УстановитьПараметр("Контрагент",        Контрагент);
	Запрос.УстановитьПараметр("Договор",           Договор);
	Запрос.УстановитьПараметр("ВидРасчетов",       ВидРасчетовПоДоговору);
	Запрос.УстановитьПараметр("ПустаяОрганизация", Справочники.Организации.ПустаяСсылка());
	Запрос.УстановитьПараметр("ПустойКонтрагент",  Справочники.Контрагенты.ПустаяСсылка());
	Запрос.УстановитьПараметр("ПустойДоговор",     ПолучитьПустоеЗначениеДоговора());
	Запрос.УстановитьПараметр("ПустойВидРасчетов", Перечисления.ВидыРасчетовПоДоговорам.ПустаяСсылка());
	//( GV
	Запрос.УстановитьПараметр("ВидДоговора", ВидДоговора);
	Запрос.УстановитьПараметр("ПустойВидДоговора", Перечисления.ВидыДоговоровКонтрагентов.ПустаяСсылка());
	//) GV
	
	//	1	Организация			Контрагент			Договор (НЕ Пустой)
	Индекс = 1;
	
	ТекстЗапроса = 
	"ВЫБРАТЬ
	|	" + Индекс + " КАК Приоритет,
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	
	|	Организация = &Организация И
	|	Контрагент  = &Контрагент И
	|	Договор     = &Договор И НЕ &Договор = &ПустойДоговор
	|";
	
	Индекс = Индекс + 1;
	
	//	2+	Организация			Контрагент			ГруппаДоговоров		ВидРасчетов
	Для Каждого ГруппаДоговоров Из СписокГруппДоговоров Цикл
		
		Запрос.УстановитьПараметр("ГруппаДоговоров" + Индекс, ГруппаДоговоров);
		
		ТекстЗапроса = ТекстЗапроса + "
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	" + Индекс + ",
		|	СчетУчетаРасчетовСПоставщиком,
		|	СчетУчетаАвансовВыданных,
		|	СчетУчетаРасчетовСПокупателем,
		|	СчетУчетаАвансовПолученных,
		|	СчетРасчетовПоПретензиям,
		|	СчетУчетаРасчетовСКомитентом,
		|	СчетУчетаРасчетовПоТареСПоставщиком,
		|	СчетУчетаРасчетовПоТареСПокупателем
		|
		|ИЗ
		|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
		|
		|ГДЕ
		|	ВидРасчетовПоДоговору = &ВидРасчетов И
		|	Организация           = &Организация И
		|	Контрагент            = &Контрагент И
		|	Договор               = &ГруппаДоговоров" + Индекс + "
		|";
		
		Индекс = Индекс + 1;
	
	КонецЦикла;
	
	//	3GV	Организация			Контрагент			ВидДоговора			ВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ВидРасчетов И
	|	Организация = &Организация И
	|	Контрагент  = &Контрагент И
	|	GV_ВидДоговора     = &ВидДоговора
	|";
	
	Индекс = Индекс + 1;
	
	//	3	Организация			Контрагент			ПустойДоговор		ВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ВидРасчетов И
	|	Организация = &Организация И
	|	Контрагент  = &Контрагент И
	|	GV_ВидДоговора        = &ПустойВидДоговора И
	|	Договор     = &ПустойДоговор
	|";
	
	Индекс = Индекс + 1;
	
	//	4GV	Организация			ГруппаКонтрагентов	ВидДоговора			ВидРасчетов
	Для Каждого ГруппаКонтрагентов Из СписокГруппКонтрагентов Цикл
		
		Запрос.УстановитьПараметр("ГруппаКонтрагентов" + Индекс, ГруппаКонтрагентов);
		
		ТекстЗапроса = ТекстЗапроса + "
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	" + Индекс + ",
		|	СчетУчетаРасчетовСПоставщиком,
		|	СчетУчетаАвансовВыданных,
		|	СчетУчетаРасчетовСПокупателем,
		|	СчетУчетаАвансовПолученных,
		|	СчетРасчетовПоПретензиям,
		|	СчетУчетаРасчетовСКомитентом,
		|	СчетУчетаРасчетовПоТареСПоставщиком,
		|	СчетУчетаРасчетовПоТареСПокупателем
		|
		|ИЗ
		|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
		|
		|ГДЕ
		|	ВидРасчетовПоДоговору = &ВидРасчетов И
		|	Организация           = &Организация И
		|	Контрагент            = &ГруппаКонтрагентов" + Индекс + " И
		|	GV_ВидДоговора               = &ВидДоговора
		|";
		
		Индекс = Индекс + 1;
	
	КонецЦикла;
	
	//	4+	Организация			ГруппаКонтрагентов	ПустойДоговор		ВидРасчетов
	Для Каждого ГруппаКонтрагентов Из СписокГруппКонтрагентов Цикл
		
		Запрос.УстановитьПараметр("ГруппаКонтрагентов" + Индекс, ГруппаКонтрагентов);
		
		ТекстЗапроса = ТекстЗапроса + "
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	" + Индекс + ",
		|	СчетУчетаРасчетовСПоставщиком,
		|	СчетУчетаАвансовВыданных,
		|	СчетУчетаРасчетовСПокупателем,
		|	СчетУчетаАвансовПолученных,
		|	СчетРасчетовПоПретензиям,
		|	СчетУчетаРасчетовСКомитентом,
		|	СчетУчетаРасчетовПоТареСПоставщиком,
		|	СчетУчетаРасчетовПоТареСПокупателем
		|
		|ИЗ
		|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
		|
		|ГДЕ
		|	ВидРасчетовПоДоговору = &ВидРасчетов И
		|	Организация           = &Организация И
		|	Контрагент            = &ГруппаКонтрагентов" + Индекс + " И
		|	GV_ВидДоговора        = &ПустойВидДоговора И
		|	Договор               = &ПустойДоговор
		|";
		
		Индекс = Индекс + 1;
	
	КонецЦикла;
	
	//	5GV	Организация			ПустойКонтрагент	ВидДоговора			ВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ВидРасчетов И
	|	Организация           = &Организация И
	|	Контрагент            = &ПустойКонтрагент И
	|	GV_ВидДоговора               = &ВидДоговора
	|";
	
	Индекс = Индекс + 1;
	
	//	5	Организация			ПустойКонтрагент	ПустойДоговор		ВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ВидРасчетов И
	|	Организация           = &Организация И
	|	Контрагент            = &ПустойКонтрагент И
	|	GV_ВидДоговора        = &ПустойВидДоговора И
	|	Договор               = &ПустойДоговор
	|";
	
	Индекс = Индекс + 1;
	
	//	6+	ПустаяОрганизация	Контрагент			ГруппаДоговоров		ВидРасчетов
	Для Каждого ГруппаДоговоров Из СписокГруппДоговоров Цикл
		
		Запрос.УстановитьПараметр("ГруппаДоговоров" + Индекс, ГруппаДоговоров);
		
		ТекстЗапроса = ТекстЗапроса + "
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	" + Индекс + ",
		|	СчетУчетаРасчетовСПоставщиком,
		|	СчетУчетаАвансовВыданных,
		|	СчетУчетаРасчетовСПокупателем,
		|	СчетУчетаАвансовПолученных,
		|	СчетРасчетовПоПретензиям,
		|	СчетУчетаРасчетовСКомитентом,
		|	СчетУчетаРасчетовПоТареСПоставщиком,
		|	СчетУчетаРасчетовПоТареСПокупателем
		|
		|ИЗ
		|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
		|
		|ГДЕ
		|	ВидРасчетовПоДоговору = &ВидРасчетов И
		|	Организация           = &ПустаяОрганизация И
		|	Контрагент            = &Контрагент И
		|	Договор               = &ГруппаДоговоров" + Индекс + "
		|";
		
		Индекс = Индекс + 1;
	
	КонецЦикла;
	
	//	7GV	ПустаяОрганизация	Контрагент			ВидДоговора			ВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ВидРасчетов И
	|	Организация = &ПустаяОрганизация И
	|	Контрагент  = &Контрагент И
	|	GV_ВидДоговора     = &ВидДоговора
	|";
	
	Индекс = Индекс + 1;
	
	//	7	ПустаяОрганизация	Контрагент			ПустойДоговор		ВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ВидРасчетов И
	|	Организация = &ПустаяОрганизация И
	|	Контрагент  = &Контрагент И
	|	GV_ВидДоговора        = &ПустойВидДоговора И
	|	Договор     = &ПустойДоговор
	|";
	
	Индекс = Индекс + 1;
	
	//	8GV	ПустаяОрганизация	ГруппаКонтрагентов	ВидДоговора			ВидРасчетов
	Для Каждого ГруппаКонтрагентов Из СписокГруппКонтрагентов Цикл
		
		Запрос.УстановитьПараметр("ГруппаКонтрагентов" + Индекс, ГруппаКонтрагентов);
		
		ТекстЗапроса = ТекстЗапроса + "
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	" + Индекс + ",
		|	СчетУчетаРасчетовСПоставщиком,
		|	СчетУчетаАвансовВыданных,
		|	СчетУчетаРасчетовСПокупателем,
		|	СчетУчетаАвансовПолученных,
		|	СчетРасчетовПоПретензиям,
		|	СчетУчетаРасчетовСКомитентом,
		|	СчетУчетаРасчетовПоТареСПоставщиком,
		|	СчетУчетаРасчетовПоТареСПокупателем
		|
		|ИЗ
		|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
		|
		|ГДЕ
		|	ВидРасчетовПоДоговору = &ВидРасчетов И
		|	Организация           = &ПустаяОрганизация И
		|	Контрагент            = &ГруппаКонтрагентов" + Индекс + " И
		|	GV_ВидДоговора               = &ВидДоговора
		|";
		
		Индекс = Индекс + 1;
	
	КонецЦикла;
	
	//	8+	ПустаяОрганизация	ГруппаКонтрагентов	ПустойДоговор		ВидРасчетов
	Для Каждого ГруппаКонтрагентов Из СписокГруппКонтрагентов Цикл
		
		Запрос.УстановитьПараметр("ГруппаКонтрагентов" + Индекс, ГруппаКонтрагентов);
		
		ТекстЗапроса = ТекстЗапроса + "
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	" + Индекс + ",
		|	СчетУчетаРасчетовСПоставщиком,
		|	СчетУчетаАвансовВыданных,
		|	СчетУчетаРасчетовСПокупателем,
		|	СчетУчетаАвансовПолученных,
		|	СчетРасчетовПоПретензиям,
		|	СчетУчетаРасчетовСКомитентом,
		|	СчетУчетаРасчетовПоТареСПоставщиком,
		|	СчетУчетаРасчетовПоТареСПокупателем
		|
		|ИЗ
		|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
		|
		|ГДЕ
		|	ВидРасчетовПоДоговору = &ВидРасчетов И
		|	Организация           = &ПустаяОрганизация И
		|	Контрагент            = &ГруппаКонтрагентов" + Индекс + " И
		|	GV_ВидДоговора        = &ПустойВидДоговора И
		|	Договор               = &ПустойДоговор
		|";
		
		Индекс = Индекс + 1;
	
	КонецЦикла;
	
	//	9GV	Организация			Контрагент			ВидДоговора			ПустойВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ПустойВидРасчетов И
	|	Организация           = &Организация И
	|	Контрагент            = &Контрагент И
	|	GV_ВидДоговора               = &ВидДоговора
	|";
	
	Индекс = Индекс + 1;
	
	//	9	Организация			Контрагент			ПустойДоговор		ПустойВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ПустойВидРасчетов И
	|	Организация           = &Организация И
	|	Контрагент            = &Контрагент И
	|	GV_ВидДоговора        = &ПустойВидДоговора И
	|	Договор               = &ПустойДоговор
	|";
	
	Индекс = Индекс + 1;
	
	//	10GVОрганизация			ПустойКонтрагент	ВидДоговора			ПустойВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ПустойВидРасчетов И
	|	Организация           = &Организация И
	|	Контрагент            = &ПустойКонтрагент И
	|	GV_ВидДоговора               = &ВидДоговора
	|";
	
	Индекс = Индекс + 1;
	
	//	10	Организация			ПустойКонтрагент	ПустойДоговор		ПустойВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ПустойВидРасчетов И
	|	Организация           = &Организация И
	|	Контрагент            = &ПустойКонтрагент И
	|	GV_ВидДоговора        = &ПустойВидДоговора И
	|	Договор               = &ПустойДоговор
	|";
	
	Индекс = Индекс + 1;
	
	//	11GVПустаяОрганизация	ПустойКонтрагент	ВидДоговора			ВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ВидРасчетов И
	|	Организация           = &ПустаяОрганизация И
	|	Контрагент            = &ПустойКонтрагент И
	|	GV_ВидДоговора               = &ВидДоговора
	|";
	
	Индекс = Индекс + 1;
	
	//	11	ПустаяОрганизация	ПустойКонтрагент	ПустойДоговор		ВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ВидРасчетов И
	|	Организация           = &ПустаяОрганизация И
	|	Контрагент            = &ПустойКонтрагент И
	|	GV_ВидДоговора        = &ПустойВидДоговора И
	|	Договор               = &ПустойДоговор
	|";
	
	Индекс = Индекс + 1;
	
	//	12GVПустаяОрганизация	ПустойКонтрагент	ВидДоговора			ПустойВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ПустойВидРасчетов И
	|	Организация           = &ПустаяОрганизация И
	|	Контрагент            = &ПустойКонтрагент И
	|	GV_ВидДоговора               = &ВидДоговора
	|";
	
	Индекс = Индекс + 1;
	
	//	12	ПустаяОрганизация	ПустойКонтрагент	ПустойДоговор		ПустойВидРасчетов
	ТекстЗапроса = ТекстЗапроса + "
	|ОБЪЕДИНИТЬ ВСЕ
	|
	|ВЫБРАТЬ
	|	" + Индекс + ",
	|	СчетУчетаРасчетовСПоставщиком,
	|	СчетУчетаАвансовВыданных,
	|	СчетУчетаРасчетовСПокупателем,
	|	СчетУчетаАвансовПолученных,
	|	СчетРасчетовПоПретензиям,
	|	СчетУчетаРасчетовСКомитентом,
	|	СчетУчетаРасчетовПоТареСПоставщиком,
	|	СчетУчетаРасчетовПоТареСПокупателем
	|
	|ИЗ
	|	РегистрСведений.СчетаУчетаРасчетовСКонтрагентами
	|
	|ГДЕ
	|	ВидРасчетовПоДоговору = &ПустойВидРасчетов И
	|	Организация           = &ПустаяОрганизация И
	|	Контрагент            = &ПустойКонтрагент И
	|	GV_ВидДоговора        = &ПустойВидДоговора И
	|	Договор               = &ПустойДоговор
	|
	|УПОРЯДОЧИТЬ ПО
	|	Приоритет
	|";
	
	Запрос.Текст = ТекстЗапроса;
	
	Выборка = Запрос.Выполнить().Выбрать();

	Если Выборка.Следующий() Тогда

		Результат.СчетРасчетов              = Выборка.СчетУчетаРасчетовСПоставщиком;
		Результат.СчетАвансов               = Выборка.СчетУчетаАвансовВыданных;
		Результат.СчетРасчетовПокупателя    = Выборка.СчетУчетаРасчетовСПокупателем;
		Результат.СчетАвансовПокупателя     = Выборка.СчетУчетаАвансовПолученных;
		Результат.СчетРасчетовПоПретензиям  = Выборка.СчетРасчетовПоПретензиям;
		Результат.СчетРасчетовСКомитентом   = Выборка.СчетУчетаРасчетовСКомитентом;
		Результат.СчетУчетаТары             = Выборка.СчетУчетаРасчетовПоТареСПоставщиком;
		Результат.СчетУчетаТарыПокупателя   = Выборка.СчетУчетаРасчетовПоТареСПокупателем;
	КонецЕсли;

	Возврат Результат;
	
КонецФункции

//) GV - 30.05.2020 - Функция дополнена подбором счетов учета по виду договора (добавленное нетиповое измерение регистра).

3. Программный вывод на форму записи регистра сведений поля ввода "Вид договора" и определение процедур GV_ДоговорПриИзмененииПосле() и GV_ВидДоговораПриИзмененииПосле в расширении.

Также в расширение добавляется сам регистр сведений СчетаУчетаРасчетовСКонтрагентами, все его измерения, все ресурсы, а также ФормаЗаписи и ФормаСписка.

В форме записи необходимо определить процедуру GV_ПриСозданииНаСервереПосле(), в которой программно выводится поле ввода "Вид договора". Кроме этого на форму необходимо добавить процедуры GV_ДоговорПриИзмененииПосле() и GV_ВидДоговораПриИзмененииПосле(), в которых пользователю сообщается о том, что необходимо указывать либо конкретный договор, либо вид договора, а одновременное указание и того и другого не предполагается.

Код модуля формы записи регистра сведений СчетаУчетаРасчетовСКонтрагентами в расширении:

//( GV - 28.05.2020 - Вывод на форму и связанные процедуры по нетиповому добавленному измерению регистра GV_ВидДоговора
&НаКлиенте
Процедура GV_ВидДоговораПриИзмененииПосле(Элемент)
	Если ЗначениеЗаполнено(Запись.GV_ВидДоговора) И ЗначениеЗаполнено(Запись.Договор) Тогда
		Запись.Договор = Неопределено;
		ОбщегоНазначенияКлиент.СообщитьПользователю("Предполагается указание либо вида договора, либо конкретного договора. Поле ""Договор"" очищено.", , "Договор", "Запись");
	КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура GV_ДоговорПриИзмененииПосле(Элемент)
	Если ЗначениеЗаполнено(Запись.GV_ВидДоговора) И ЗначениеЗаполнено(Запись.Договор) Тогда
		Запись.GV_ВидДоговора = Неопределено;
		ОбщегоНазначенияКлиент.СообщитьПользователю("Предполагается указание либо конкретного договора, либо вида договора. Поле ""Вид договора"" очищено.", , "GV_ВидДоговора", "Запись");
	КонецЕсли;
КонецПроцедуры

&НаСервере
Процедура GV_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	
	ПолеВвода = Элементы.Вставить("GV_ВидДоговора", Тип("ПолеФормы"), , Элементы.Договор);
	ПолеВвода.Заголовок = "Вид договора";
	ПолеВвода.Вид = ВидПоляФормы.ПолеВвода;
	
	//Установка связи элемента с данными
	ПолеВвода.ПутьКДанным = "Запись.GV_ВидДоговора";
	
	//Можно добавить обработчик события
	//См. синтакс-помощник чтобы узнать список событий
	// Интерфейс (управляемый) -> Поле формы -> ПолеФормы -> События
	// а так же остальные варианты расширения поля формы в зависимости от вида кнопки
	// Интерфейс (управляемый) -> Поле формы -> Расширение поля ввода -> События
	// и прочее
	ПолеВвода.УстановитьДействие(
		"ПриИзменении", 		    //Имя события
		"GV_ВидДоговораПриИзмененииПосле"); //Имя процедуры обработчика
	
КонецПроцедуры
//) GV - 28.05.2020 - Вывод на форму и связанные процедуры по нетиповому добавленному измерению регистра GV_ВидДоговора

4. Программный вывод на форму списка регистра сведений колонки "Вид договора" в расширении.

В расширении на форме списка регистра сведений СчетаУчетаРасчетовСКонтрагентами определяется процедура GV_ПриСозданииНаСервереПосле(), в которой программно выводится колонка "Вид договора".

Код модуля формы списка регистра сведений СчетаУчетаРасчетовСКонтрагентами в расширении:

//( GV - 28.05.2020 - Вывод на форму и связанные процедуры по нетиповому добавленному измерению регистра GV_ВидДоговора
&НаСервере
Процедура GV_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	Поле = Элементы.Вставить("GV_ВидДоговора", Тип("ПолеФормы"), Элементы.Список, Элементы.Договор);
	Поле.Заголовок = "Вид договора";
	Поле.Вид = ВидПоляФормы.ПолеНадписи;
	
	//Установка связи элемента с данными
	Поле.ПутьКДанным = "Список.GV_ВидДоговора";

КонецПроцедуры
//) GV - 28.05.2020 - Вывод на форму и связанные процедуры по нетиповому добавленному измерению регистра GV_ВидДоговора

+1 –

См. также

SALE! 10%

Перенос данных и обмен из УТ 10.3 в УТ 11 / КА 2 / ERP 2. Переносятся документы, справочники и остатки

Перенос данных 1C Взаиморасчеты Оптовая торговля Логистика, склад и ТМЦ Файловый обмен (TXT, XML, DBF), FTP Системный администратор Программист Платформа 1С v8.3 1С:Управление торговлей 10 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Управленческий учет Платные (руб)

Можно проверить до покупки, оставьте заявку! Воспользовались более 268 компаний! Перенос данных из УТ 10.3 в УТ 11 | из УТ 10.3 в КА 2 | из УТ 10.3 в ERP. Предлагаем качественное и проверенное временем решение для перехода с УТ 10.3. Можно перенести начальные остатки, нормативно-справочную информацию и все возможные документы. При выгрузке можно установить отбор по периоду, организациям и складам. При выходе новых релизов конфигураций 1C оперативно выпускаем обновление переноса данных.

~~55778~~ 50200 руб.

24.04.2015 194992 150 243

280

УТ 11, КА 2, ERP 2: Настраиваемые под каждую организацию печать и подпись ответственных лиц в печатных формах (ТОРГ-12, Счёт-фактура, УПД, УКД, Заказ клиента, Акт сверки, М-15 и др.)

Печатные формы Взаиморасчеты Оптовая торговля Производство готовой продукции (работ, услуг) Акт сверки Бухгалтер Пользователь Оперативный учет Управляемые формы 1С:Управление торговлей 11 Россия Бухгалтерский учет Управленческий учет Платные (руб)

Задайте для каждой организации свою печать и для каждого физического лица свою подпись. Выберите в документе печатную форму "... с печатью и подписью" - и автоматически сформируется табличный документ с печатью и подписями той организации и ответственных лиц, которые указаны в документе.

14400 руб.

13.03.2018 60751 207 76

120

"Акты сверки +" Групповая подготовка и рассылка актов сверки для Бухгалтерии 3.0.

Взаиморасчеты Email рассылки Акт сверки Бухгалтер Пользователь Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Бухгалтерский учет Платные (руб)

Внешняя обработка для Бухгалтерии 3.0 - позволяет автоматически формировать документы «Акт сверки расчетов» с контрагентами за выбранный период с последующей фоновой отправкой на почту контрагента.

3000 руб.

25.11.2020 24501 238 8

205

Рассылка по электронной почте и автоматическое формирование актов сверки взаиморасчетов для КА 2.5(2.4), УТ 11

Email рассылки Взаиморасчеты Мастера заполнения Акт сверки Бухгалтер Пользователь Платформа 1С v8.3 Бухгалтерский учет 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Бухгалтерский учет Управленческий учет Платные (руб)

Расширение для автоматического формирования актов сверки по контрагентам/партнерам, а также для массовой рассылки печатных форм акта взаиморасчетов пользователям на их электронный адрес.

9600 руб.

01.06.2020 32051 74 51

Дебиторская задолженность по срокам долга в 1С

Взаиморасчеты Бухгалтер Пользователь Платформа 1С v8.3 1С:Комплексная автоматизация 1.х 1С:Управление торговлей 10 1С:Управление производственным предприятием 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Бухгалтерский учет Управленческий учет Платные (руб)

Один из лучших вариантов отчета по дебиторской задолженности в 1С. Отображает сроки возникновения задолженности, просроченной задолженности с точностью до регистратора, а также многое другое, вне зависимости от объекта расчетов (УТ 11.3, 11.4, 11.5, КА 2.4, 2.5, ERP 2.4, 2.5), состояния флажка По документам расчета ( УТ 10, КА 1.1, УПП 1.3) в договоре. Группирует задолженность по интервалам. Имеет большое количество настроек. Не требует доработок конфигурации. Не требует перепроведения документов.

15120 руб.

28.09.2012 97020 593 283

145

"Расчет и начисление пени" для 1С:БП 3.0 (8.3 Бухгалтерия)

Взаиморасчеты Бухгалтер Бухгалтерский учет 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Платные (руб)

Расширение позволяет гибко настроить расчет и начисление пени в 1С в организации. Представлена в двух вариантах исполнения: как расширение и как обработка.

7200 руб.

18.10.2017 39150 73 46

Платежный календарь полного цикла в 1С 8.3 Бухгалтерия Предприятия — Анализ движения денежных средств

Учет доходов и расходов Взаиморасчеты БДР, БДДС Бухгалтер Пользователь Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Комплексная автоматизация 2.х Управленческий учет Платные (руб)

Мы доработали типовой платежный календарь, добавив в него планируемые постоянные расходы. Теперь можно видеть картину денежных средств в совокупности с текущей динамикой ожидаемых поступлений и расходов. Отчет позволяет увидеть остатки денежных средств в кассе и банке, их движение в разрезе статей ДДС с возможностью выбрать любой период (день, неделя, месяц). Данный отчет подходит для всех основных конфигураций линейки продуктов 1С:Предприятие 8.3 (8.3.18.1289): 1С:Бухгалтерия предприятия, редакция 3.0 (3.0.77.95), 1С:Управление торговлей, 1С:Комплексная автоматизация 2 (2.4.11.67), Объединенное решение: Модуль 1С:CRM 3 (3.0.21.3) +1С:ERP Управление предприятием 2 (2.4.13.111). Также есть возможность адаптации отчета под другие конфигурации. Мобильное приложение работает как на Android, так и на IOS.

2880 руб.

16.03.2021 22140 13 13

Автоматическое формирование и отправка счетов, актов, счетов-фактур и актов сверки для БП 3.0

Email рассылки Документооборот и делопроизводство (СЭД) Взаиморасчеты Акт сверки Бухгалтер Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Бухгалтерский учет Платные (руб)

Данная обработка позволяет сократить объем ручных операций, выполняемых ежемесячно бухгалтером или его помощником за счет автоматизации систематического процесса.

7800 руб.

12.02.2019 33115 115 24