Программное копирование узла/строки дерева значений на управляемой форме (УФ, ДанныеФормыДерево, ДанныеФормыЭлементДерева) в вариантах на клиенте и на сервере

11.01.21

Разработка - Универсальные функции

1С при интерактивном копировании строки дерева значений в управляемой форме копирует только саму строку, без его всех вложенных узлов/строк, жаль - решим! А также найдем способ передачи ДанныеФормыЭлементДерева с клиента на сервер при вставке дерева из другого элемента справочника.

Мы столкнулись с этой задачкой на следующем кейсе: пользователю в подсистеме EDIbot (конструктор веб приложений, nocode CMS, B2B порталов на 1С) было необходимо быстро вставлять готовые преформы (блоки/компоненты) в структуру страницы, а также копировать существующие преформы для возможности изменения. Структура веб страницы в подсистеме EDIbot реализована как дерево значений, и интерактивное копирование платформой 1С копирует только строчку, без вложенных в нее узлов/строк/блоков. Поэтому было решено сделать отдельные кнопки (команды), которые позволяют выполнять копирование и подбор готовых преформ со всеми вложенными узлами/строками. 

Итак, вот видео с примером работы пользователя по результату выполненной модификации:

Описание: пользователь создает личный кабинет B2B портала из готовых преформ/блоков - шапки, слайдера акций (по овощам) и меню, потом добавляет еще один слайдер, изменяет источник данных - по фруктам. 

 

Давайте разберемся, как подобное сделать Вам в своих конфигурациях. 

Рассмотрим первый пример - копирование в дереве значений на управляемой форме (ДанныеФормыДерево).

Для начала получим активную строку/узел (ДанныеФормыЭлементДерева), на которой пользователь нажал кнопку "Копировать". 

СтрокаТЧ = Элементы.СтруктураСтраницы.ТекущиеДанные;

Копировать будем в родителя текущего узла, поэтому получим родителя текущего узла/строки и опишем это в коде:

Куда = СтрокаТЧ.ПолучитьРодителя();
Если Куда=Неопределено Тогда
   Куда = СтруктураСтраницы;
КонецЕсли;	

Теперь можем вызвать нашу функцию, которая на клиенте скопирует выбранную пользователем строку в родителя:

&НаКлиенте
Функция СкопироватьУзелДерева(Узел, Куда)
	
	Если Куда=Неопределено Тогда
		Возврат Неопределено;			
	КонецЕсли;
	
	НоваяСтрока = Куда.ПолучитьЭлементы().Добавить();	
	
	ЗаполнитьЗначенияСвойств(НоваяСтрока, Узел);

	Для Каждого Элемент Из Узел.ПолучитьЭлементы() Цикл
		
		СкопироватьУзелДерева(Элемент, НоваяСтрока);
		
	КонецЦикла;
	
	Возврат НоваяСтрока.ПолучитьИдентификатор();
КонецФункции

&НаКлиенте
Процедура СкопироватьУзелСтруктуры(Команда)
		
	СтрокаТЧ = Элементы.СтруктураСтраницы.ТекущиеДанные;
	
	Если СтрокаТЧ=Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	Куда = СтрокаТЧ.ПолучитьРодителя();
	Если Куда=Неопределено Тогда
		Куда = СтруктураСтраницы;
	КонецЕсли;	
	
	ИдентификаторНовойСтроки = СкопироватьУзелДерева(СтрокаТЧ, Куда);
	Если НЕ ИдентификаторНовойСтроки=Неопределено Тогда
		Элементы.СтруктураСтраницы.ТекущаяСтрока = ИдентификаторНовойСтроки;
	КонецЕсли;	

КонецПроцедуры

 

 

Итак, первый пример мы решили, переходим ко второму - подбор и вставка узлов из другого элемента справочника. Тут сложность в том, что дерево значений хранится в реквизите элемента с типом ХранилищеЗначения, придется его получить на сервере и там же добавить в дерево значений формы (ДанныеФормыДерево) нашу структуру, решить проблему передачи ДанныеФормыЭлементДерева с клиента на сервер. 

По команде нашей кнопки открывается выбор страницы, с которой мы хотим скопировать структуру:

&НаКлиенте
Процедура ПодобратьУзелСтраницы(Команда)
	
	ОбработкаВыбораСтраницы = Новый ОписаниеОповещения("ОбработкаВыбораСтраницы", ЭтотОбъект);
	ОткрытьФорму("Справочник._ВебАппСтраницы.ФормаВыбора",,,,,,ОбработкаВыбораСтраницы);
	
КонецПроцедуры

По завершению выбора будет вызвана процедура:

&НаКлиенте 
Процедура ОбработкаВыбораСтраницы(СтраницаСсылка, ДополнительныеПараметры) экспорт
	
	Если СтраницаСсылка=Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	СтрокаТЧ = Элементы.СтруктураСтраницы.ТекущиеДанные;
	
	Если СтрокаТЧ=Неопределено Тогда
		
		Строки = СтруктураСтраницы.ПолучитьЭлементы();
		
		Если Строки.Количество()=0 Тогда			
			СтрокаТЧ = Строки.Добавить();
			СтрокаТЧ.Тип = ПредопределенноеЗначение("Перечисление._ВебАппСтруктураСтраницы.Корень");
		ИначеЕсли Строки.Количество()>0 Тогда	
			СтрокаТЧ = Строки[0];	
		КонецЕсли;	
		
	КонецЕсли;
	
	ИдентификаторНовойСтроки = ДобавитьУзлыСтраницы(СтраницаСсылка, СтрокаТЧ.ПолучитьИдентификатор());
	Если НЕ ИдентификаторНовойСтроки=Неопределено Тогда
		Элементы.СтруктураСтраницы.ТекущаяСтрока = ИдентификаторНовойСтроки;
	КонецЕсли;	

	
КонецПроцедуры	

Как видно, мы всегда предполагаем, что у нашего дерева есть корневая строка (root) и если её нет, то мы её добавляем. 

Внутри идет вызов процедуры ДобавитьУзлыСтраницы, которая объявлена в контексте сервера, т.е. мы уходим с клиента на сервер и вот тут хитрость - мы не можем передать на сервер ДанныеФормыЭлементДерева, как в первом примере - получим ошибку:

Ошибка отображения типов: Отсутствует отображение для типа 'ДанныеФормыЭлементДерева' по причине: Ошибка передачи данных между клиентом и сервером. Значение недопустимого типа. по причине: Ошибка преобразования данных XDTO: Запись значения свойства 'param': форма: Элемент имя: http://v8.1c.ru/8.2/managed-application/modules}param по причине: Ошибка отображения типов: Отсутствует отображение для типа 'ДанныеФормыЭлементДерева'

поэтому, мы будем передавать не сам тип ДанныеФормыЭлементДерева, а числовой идентификатор элемента в ДанныеФормыДерево. 

 

Функция ДобавитьУзлыСтраницы довольно простая, ее задача получить из хранилища значений дерево значений и вызвать уже серверную функцию по копированию структуры, куда передать ДанныеФормыЭлементДерева, получив его по числовому идентификатору. 

&НаСервере
Функция ДобавитьУзлыСтраницы(СтраницаСсылка, ИдентификаторРодителя)
	
	СтруктураВыбраннойСтраницы = СтраницаСсылка.СтруктураСтраницы.Получить();
	
	Если ТипЗнч(СтруктураВыбраннойСтраницы)=Тип("ДеревоЗначений") И СтруктураВыбраннойСтраницы.Строки.Количество()>0 Тогда
		Возврат СкопироватьУзелДереваСервер(СтраницаСсылка, СтруктураВыбраннойСтраницы.Строки[0].Строки, СтруктураСтраницы.НайтиПоИдентификатору(ИдентификаторРодителя));
	КонецЕсли;	

	Возврат Неопределено;
КонецФункции	

 

Интересно, да? ДанныеФормыЭлементДерева есть и в контексте Сервера и в контекста Клиента, но передать его с клиента на сервер напрямую мы не можем, поэтому делаем это через идентификатор.

 

Теперь осталось описать функцию по копированию узлов дерева значений (СтрокаДереваЗначений) в наше дерево значений формы (ДанныеФормыДерево) 

&НаСервере
Функция СкопироватьУзелДереваСервер(СтраницаСсылка, Узел, Куда)
	
	ИдентификаторНовойСтроки = Неопределено;
	Для Каждого Элемент Из Узел Цикл
		
		НоваяСтрока = Куда.ПолучитьЭлементы().Добавить();	
		
		Если ИдентификаторНовойСтроки=Неопределено Тогда
			ИдентификаторНовойСтроки = НоваяСтрока.ПолучитьИдентификатор();	
		КонецЕсли;
		
		ЗаполнитьЗначенияСвойств(НоваяСтрока, Элемент);
		
		СкопироватьУзелДереваСервер(СтраницаСсылка, Элемент.Строки, НоваяСтрока);
				
	КонецЦикла;
	
	Возврат ИдентификаторНовойСтроки;
КонецФункции

 

В итоге мы с Вами решили обе задачки по копированию, разобрались с работой ДанныеФормыДерево, передачей с клиента на сервер ДанныеФормыЭлементДерева - пользователь может копировать и вставлять/подбирать нужные ему блоки страницы веб приложения.

 

Надеюсь, моя публикация была Вам полезна и сэкономит Ваше время, ссылка на все публикации SizovE, например, в публикации

Отображение и редактирование в дереве большого количества настроек/параметров/опций программы, конфигурации, документа, справочника - без программного создания элементов формы мной были рассмотрены и другие решения/ситуации по работе с деревьями значений на форме. 

Подписывайтесь на мой канал (наверху), будет много интересного бесплатного контента :)

 

См. также

Загрузка табличного документа в таблицу значений. Пять строк кода, которые изменили мир

Универсальные функции Программист Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Благодаря этим пяти строчкам можно больше не заморачиваться с загрузкой из внешних файлов. Пользуюсь везде, всегда и постоянно.

21.05.2024    3057    dimanich70    74    

62

Вставляем картинку из буфера обмена (платформа 1С 8.3.24)

Универсальные функции Программист Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Задача: вставить картинку из буфера обмена на форму средствами платформы 1С.

1 стартмани

18.03.2024    3108    3    John_d    11    

57

GUID в 1С 8.3 - как с ними быть

Универсальные функции Программист Стажер Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пришлось помучиться с GUID-ами немного, решил поделиться опытом, мало ли кому пригодится.

12.02.2024    6060    atdonya    22    

53

Переоткрытие внешних обработок

Универсальные функции Программист Платформа 1С v8.3 Бесплатно (free)

На заключительных этапах, когда идет отладка или доработка интерфейса, необходимо много раз переоткрыть внешний объект. Вот один из способов автоматизации этого.

30.11.2023    4412    ke.92@mail.ru    16    

64

Валидация JSON через XDTO (включая массивы)

WEB-интеграция Универсальные функции Механизмы платформы 1С Программист Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

При работе с интеграциями рано или поздно придется столкнуться с получением JSON файлов. И, конечно же, жизнь заставит проверять файлы перед тем, как записывать данные в БД.

28.08.2023    10190    YA_418728146    7    

147

Печать непроведенных документов для УТ, КА, ERP. Настройка печати по пользователям, документам и печатным формам

Пакетная печать Печатные формы Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Россия Абонемент ($m)

Расширение для программ 1С:Управление торговлей, 1С:Комплексная автоматизация, 1С:ERP, которое позволяет распечатывать печатные формы для непроведенных документов. Можно настроить, каким пользователям, какие конкретные формы документов разрешено печатать без проведения документа.

2 стартмани

22.08.2023    2478    34    progmaster    8    

4

Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 1С:Розница 2 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    16689    148    sapervodichka    112    

132
Комментарии
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
1. idjumatov 17 28.10.22 13:06 Сейчас в теме
Всё бы хорошо, но когда я использую данные текущей строки в другом поле формы, при программном добавлении строки не удастся её заполнить. Метод
ЗаполнитьЗначенияСвойств(НоваяСтрока, Узел);

выдаст ошибку
Нельзя изменять поле, содержащее объект данных формы

Копирование строки дерева стандартными средствами (не программно), никаких проблем не вызывает. Проблема в том, что при этом не копируются дочерние узлы. Решения пока не нашёл, костылей хотелось бы избежать.
Оставьте свое сообщение