- Первый шаг, доработка непосредственно пакета XDTO, добавление в него описания нового документа, для этого:
1.1 Заимствуем пакет "ExchangeMessage" со всеми типами, это именно надо делать сначала, так как на втором этапе добавляется основной пакет xdto в котором есть ссылки на "ExchangeMessage", если его не будет, они соответственно очистятся
1.2 Копируем пакет xdto необходимой версии, именно копируем, а не заимствуем (в заимствованном пакете нельзя добавлять новые типы),после чего я сменил версию, пространство имен пакета, ниже поясню, для чего.
1.3 Описываем сам новый документ, как это сделать уже рассказано не раз, да и делалось это просто по аналогии с типовыми документами пакета, так что примеры перед глазами.
2 . Второй шаг Доработка плана обмена
2.1 Заимствуем план обмена "СинхронизацияДанныхЧерезУниверсальныйФормат"
2.2 добавляем в реквизит "ВерсияФорматаОбмена" нашу новую версию (пусть это будет версия 1.11), это просто список выбора который можно доработать через форму или событие создания формы. Через новую версию сделано чтоб можно было указывать какую версию формата использовать (этим и обусловлено изменение пространства имен), чтоб была возможность быстро переключиться на стандартный формат при необходимости.
2.3 Дорабатываем процедуру модуля менеджера "ПриПолученииНастроек"
&ИзменениеИКонтроль("ПриПолученииНастроек")
Процедура ДРП_ПриПолученииНастроек(Настройки)
Настройки.ИмяКонфигурацииИсточника = ОбщегоНазначенияБП.ИмяКонфигурацииИсточника();
Настройки.ЭтоПланОбменаXDTO = Истина;
Настройки.ПредупреждатьОНесоответствииВерсийПравилОбмена = Ложь;
Настройки.ФорматОбмена = "http://v8.1c.ru/edi/edi_stnd/EnterpriseData";
ВерсииФормата = Новый Соответствие;
ВерсииФормата.Вставить("1.3", МенеджерОбменаЧерезУниверсальныйФормат13);
ВерсииФормата.Вставить("1.4", МенеджерОбменаЧерезУниверсальныйФормат13);
ВерсииФормата.Вставить("1.5", МенеджерОбменаЧерезУниверсальныйФормат13);
ВерсииФормата.Вставить("1.6", МенеджерОбменаЧерезУниверсальныйФормат13);
ВерсииФормата.Вставить("1.7", МенеджерОбменаЧерезУниверсальныйФормат13);
ВерсииФормата.Вставить("1.8", МенеджерОбменаЧерезУниверсальныйФормат13);
#вставка
ВерсииФормата.Вставить("1.11", МенеджерОбменаЧерезУниверсальныйФормат13);
#КонецВставки
Настройки.ВерсииФорматаОбмена = ВерсииФормата;
Настройки.ПланОбменаИспользуетсяВМоделиСервиса = Истина;
Настройки.Алгоритмы.ПриПолученииВариантовНастроекОбмена = Истина;
Настройки.Алгоритмы.ПриПолученииОписанияВариантаНастройки = Истина;
Настройки.Алгоритмы.ПредставлениеОтбораИнтерактивнойВыгрузки = Истина;
Настройки.Алгоритмы.НастроитьИнтерактивнуюВыгрузку = Истина;
КонецПроцедуры
2.4 Расширить состав плана обмена новым документом
2.5 Отключаем авторегистрацию, заимствуем подписку на событие "СинхронизацияДанныхЧерезУниверсальныйФорматРегистрацияДокумента" и добавляем в источник наш новый документ, чтоб изменения документа попадали в обмен.
3. Третий шаг доработка общего модуля "ОбменДаннымиXDTOСервер"
3.1 в данному модуле дорабатывается только одна процедура "ВерсииФорматаОбмена"
&ИзменениеИКонтроль("ВерсииФорматаОбмена")
Функция ДРП_ВерсииФорматаОбмена(Знач УзелИнформационнойБазы)
ВерсииФорматаОбмена = Новый Соответствие;
ИмяПланаОбмена = "";
Если ЗначениеЗаполнено(УзелИнформационнойБазы) Тогда
ИмяПланаОбмена = ОбменДаннымиПовтИсп.ПолучитьИмяПланаОбмена(УзелИнформационнойБазы);
ВерсииФорматаОбмена = ОбменДаннымиСервер.ЗначениеНастройкиПланаОбмена(ИмяПланаОбмена, "ВерсииФорматаОбмена");
Иначе
ОбменДаннымиПереопределяемый.ПриПолученииДоступныхВерсийФормата(ВерсииФорматаОбмена);
КонецЕсли;
Если ВерсииФорматаОбмена.Количество() = 0 Тогда
Если ЗначениеЗаполнено(УзелИнформационнойБазы) Тогда
ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
НСтр("ru = 'Не заданы версии формата обмена.
|Имя плана обмена: %1
|Процедура: ПолучитьВерсииФорматаОбмена(<ВерсииФорматаОбмена>)'"),
ИмяПланаОбмена);
Иначе
ВызватьИсключение НСтр("ru = 'Не заданы версии формата обмена.
|Процедура: ОбменДаннымиПереопределяемый.ПриПолученииДоступныхВерсийФормата(<ВерсииФорматаОбмена>)'");
КонецЕсли;
КонецЕсли;
Результат = Новый Соответствие;
Для Каждого Версия Из ВерсииФорматаОбмена Цикл
Результат.Вставить(СокрЛП(Версия.Ключ), Версия.Значение);
КонецЦикла;
#вставка
Результат.Вставить("1.11", МенеджерОбменаЧерезУниверсальныйФормат13);
#КонецВставки
Возврат Результат;
КонецФункции
4. Четвертый шаг - доработка общего модуля "ОбменДаннымиПереопределяемый"
Здесь также изменяется только одна процедура "ПриПолученииДоступныхВерсийФормата"
&После("ПриПолученииДоступныхВерсийФормата")
Процедура ДРП_ПриПолученииДоступныхВерсийФормата(ВерсииФормата)
ВерсииФормата.Вставить("1.11", МенеджерОбменаЧерезУниверсальныйФормат13);
КонецПроцедуры
5. Пятый шаг - доработка модуля "МенеджерОбменаЧерезУниверсальныйФормат13"
Разработка модуля для нового документа делалась через КД 3.0, на эту тему есть статьи, (вот одна из них //infostart.ru/1c/articles/695523/), и по объему потянет на отдельную статью, если все-таки будет интересно, дайте знать в комментариях.
6. Шестой шаг - проверка результата
6.1 переключаем узел синхронизации на новый формат
6.2 получаем в итоге следующий файл обмена
Необходимый результат достигнут).
Если тема будет актуальной, в продолжении напишу доработки на стороне базы приемника (УНФ), там тоже есть небольшие нюансы.
Всем спасибо за прочтение.
Продолжение
Добавление нового документа в формат обмена EnterpriseData (получение)
