Функция получения даты из текста по форматной строке

Публикация № 200111 08.09.13

Разработка - Инструментарий разработчика

Преобразует текст в дату при условии наличия форматной строки

Несколько громоздская, но полезная функция.

Добавил распознование строковых месяцев, но только на русском языке.

Очень красивое решение предоставил ildarovich, советую использовать сразу его код:

Функция СтрокаВДату(Знач ФорматДаты, Знач Дано, Ошибка = Ложь) Экспорт 
	Попытка 
		ё = Формат('00010101', "ДФ=" + ФорматДаты) // - необязательная проверка первого правильности параметра 
	Исключение 
		Ошибка = Истина; 
		Возврат '00010101' 
	КонецПопытки; 
	Ч = Новый Соответствие; 
	Для ё = 1 По СтрДлина(ФорматДаты) + 7 Цикл 
		Ч[Сред(ФорматДаты + "dMyHhms", ё, 1)] = 0	// - инициализация частей даты 
	КонецЦикла; 
	Для ё = 1 По 12 Цикл 
		Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMММ"), Формат(ё, "ЧЦ=4; ЧВН=")); // - замена названий месяцев числами 
		Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMМ" ), Формат(ё, "ЧЦ=3; ЧВН=")) 
	КонецЦикла; 
	Для ё = 1 По СтрДлина(ФорматДаты) Цикл 
		Ч[Сред(ФорматДаты, ё, 1)] = 10 * Ч[Сред(ФорматДаты, ё, 1)] + Найти("123456789", Сред(Дано, ё, 1)); // - накопление частей даты 
		Ошибка = Ошибка ИЛИ Найти("dMyHhms", Сред(ФорматДаты, ё, 1)) И НЕ Найти("0123456789", Сред(Дано, ё, 1)) // - необязательная проверка на цифры 
	КонецЦикла; 
	Ч["y"] = Ч["y"] + ?(Ч["y"] < 50, 2000, ?(Ч["y"] < 100, 1900, 0)); // - дополнение двух цифр года до четырех 
	Попытка 
		Возврат Дата(Ч["y"], Ч["M"], Ч["d"], Ч["H"] + Ч["h"], Ч["m"], Ч["s"]) 
	Исключение 
		Ошибка = Истина; 
		Возврат '00010101' 
	КонецПопытки 
КонецФункции

Моя функция:

Функция ПолучитьДатуИзТекста(Текст,ФорматнаяСтрока) Экспорт
	Перем Значение;
	
	ПустаяДата = '00010101';
	Год = 1; Месяц=1; День = 1; час = 0; Мин=0; Сек=0;
	тмпТекст = Текст;
	ЗначащиеСимволы = "dMyHhms";
	СтрокаПараметра = "";
	ФорматнаяСтрока = СокрЛП(ФорматнаяСтрока)+" ";
	ПредСимв = Лев(ФорматнаяСтрока,1);
	Для к=1 по СтрДлина(ФорматнаяСтрока) Цикл
		Симв = Сред(ФорматнаяСтрока,к,1);
		Если ПредСимв<>Симв Тогда
			Если Найти(ЗначащиеСимволы,ПредСимв)>0 Тогда
				//ЭтоПараметр
				Если СтрДлина(СтрокаПараметра)=2 Тогда
					Попытка
						Значение = Число(Лев(тмпТекст,2));
					Исключение
						#Если Клиент Тогда
							Предупреждение("Не удалось выполнить преобразование!");
						#КонецЕсли
						Возврат ПустаяДата;
					КонецПопытки;
					
					тмпТекст = Сред(тмпТекст,3);
				ИначеЕсли СтрокаПараметра="yyyy" Тогда
					Попытка
						Значение = Число(Лев(тмпТекст,4));
					Исключение
						#Если Клиент Тогда
							Предупреждение("Не удалось выполнить преобразование!");
						#КонецЕсли
						Возврат ПустаяДата;
					КонецПопытки;
					тмпТекст = Сред(тмпТекст,5);
				ИначеЕсли СтрДлина(СтрокаПараметра)=1 Тогда
					дл = "";
					Попытка
						Значение = Число(Лев(тмпТекст,2));
					Исключение
						Попытка
							Значение = Число(Лев(тмпТекст,1));
							дл=1;
						Исключение
							#Если Клиент Тогда
								Предупреждение("Не удалось выполнить преобразование!");
							#КонецЕсли
							Возврат ПустаяДата;
						КонецПопытки;
					КонецПопытки;
					
					Если дл="" Тогда
						Если (СтрокаПараметра = "d" и Значение>31)ИЛИ(СтрокаПараметра = "M" и Значение>12)ИЛИ(СтрокаПараметра = "H" и Значение>23)
							ИЛИ(СтрокаПараметра = "h" и Значение>12)ИЛИ(СтрокаПараметра = "m" и Значение>59)ИЛИ(СтрокаПараметра = "s" и Значение>59) Тогда
							Попытка
								Значение = Число(Лев(тмпТекст,2));
								дл=2;
							Исключение
								#Если Клиент Тогда
									Предупреждение("Не удалось выполнить преобразование!");
								#КонецЕсли
								Возврат ПустаяДата;
							КонецПопытки;
						Иначе
							Попытка
								Значение = Число(Лев(тмпТекст,1));
								дл=1;
							Исключение
								#Если Клиент Тогда
									Предупреждение("Не удалось выполнить преобразование!");
								#КонецЕсли
								Возврат ПустаяДата;
							КонецПопытки;
						КонецЕсли;	
					КонецЕсли;	
					
					тмпТекст = Сред(тмпТекст,дл+1);
				ИначеЕсли СтрокаПараметра="MMM" или СтрокаПараметра="MMMM" Тогда
					Значение = 0;
					Для м=1 по 12 Цикл
						ТекстМесяца = Сред(Формат(Дата(2000,м,1),"ДФ=d."+СтрокаПараметра),3);
						Если Найти(тмпТекст,ТекстМесяца)>0 Тогда
							Значение = м;
							Прервать;
						КонецЕсли;
					КонецЦикла;
					Если Значение = 0 Тогда
						#Если Клиент Тогда
							Предупреждение("Не удалось выполнить преобразование!");
						#КонецЕсли
						Возврат ПустаяДата;
					КонецЕсли;
					тмпТекст = Сред(тмпТекст,СтрДлина(ТекстМесяца)+1);
				Иначе
					#Если Клиент Тогда
						Предупреждение("Не верный формат даты или форматной строки!");
					#КонецЕсли
					Возврат ПустаяДата;
				КонецЕсли;
				
				//Установим параметры
				Если ПредСимв = "d" Тогда
					День = Значение;
				ИначеЕсли ПредСимв = "M" Тогда
					Месяц = Значение;
				ИначеЕсли ПредСимв = "y" Тогда
					Если СтрокаПараметра = "yy" Тогда
						ТекВек = 100*Цел(Год(ТекущаяДата())/100);
						год = ?(Значение>=Год(ТекущаяДата())-текВек+50,ТекВек-100,ТекВек)+Значение;
					Иначе
						Год = Значение;
					КонецЕсли;
				ИначеЕсли ПредСимв = "H" Тогда
					час = Значение;
				ИначеЕсли ПредСимв = "h" Тогда
					час = Значение;
					#Если Клиент Тогда
						Сообщить("Вычисление часа не гарантировано.");
					#КонецЕсли
				ИначеЕсли ПредСимв = "m" Тогда
					Мин = Значение;
				ИначеЕсли ПредСимв = "s" Тогда
					Сек = Значение;
				КонецЕсли;
				
			Иначе
				//Это Разделитель
				тмпТекст = Сред(тмпТекст,СтрДлина(СтрокаПараметра)+1);
			КонецЕсли;
			СтрокаПараметра = Симв;
		Иначе
			СтрокаПараметра=СтрокаПараметра+Симв;
		КонецЕсли;
		ПредСимв = Симв;
	КонецЦикла;
	Возврат Дата(Год,Месяц,День,час,Мин,Сек);
КонецФункции		

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Поручик 4535 09.09.13 01:35 Сейчас в теме
(0) Вместо Предупреждение() лучше использовать Сообщить().
26. Eremkin 03.09.20 11:00 Сейчас в теме
(1)Вместо Сообщить() лучше использовать Новый СообщениеПользователю()
2. kapustinag 09.09.13 08:36 Сейчас в теме
(0) Вот в этом месте нужно более интеллектуально:
Если СтрокаПараметра = "yy" Тогда
Год = 2000+Значение;

Если Значение="99", то год должен быть 1999, а если ="13", то год 2013. Часто применяют сравнение с 50. Если значение меньше 50, то считаем нынешний век, а если больше - двадцатый век. Впрочем, это уже зависит от смысла ожидаемых данных. Может быть, на Ваших данных именно Ваше условие правильное.
6. Crazy Professor 22 24.09.13 08:58 Сейчас в теме
(2) kapustinag,
Кстати да, но я не знаю по какому принципу 1с сама это дело конвертирует у меня переключает на прошлый век с 30 включительно, но я не уверен, что это как-то зависит от текущей даты.

Сделал так:

ТекВек = 100*Цел(Год(ТекущаяДата())/100);
год = ?(Значение>=Год(ТекущаяДата())-текВек+50,ТекВек-100,ТекВек)+Значение;
3. ildarovich 7358 09.09.13 17:19 Сейчас в теме
В статье Выразить строку как число и строку как дату в запросе показано, как тоже самое можно сделать в запросе. Ну а данное решение нужно сократить раз в десять - объем кода не соответствует сложности решаемой задачи.
7. Crazy Professor 22 24.09.13 09:07 Сейчас в теме
(3) ildarovich,
Предложите готовое решение, пожалуйста - я с радостью его применю для своих целей.
Статья занятная, но не уверен, что универсальное решение будет менее громоздким чем обычный код. Однако, для больших объемов данных применение запроса может увеличить производительность.
11. ildarovich 7358 25.09.13 00:42 Сейчас в теме
(7) Вот готовое решение
//
Функция СтрокаВДату(Знач ФорматДаты, Знач Дано, Ошибка = Ложь) Экспорт
    Попытка 
        ё = Формат('00010101', "ДФ=" + ФорматДаты) // - необязательная проверка первого правильности параметра
    Исключение
        Ошибка = Истина;
        Возврат '00010101'
    КонецПопытки;
    Ч = Новый Соответствие;
    Для ё = 1 По СтрДлина(ФорматДаты) + 7 Цикл
        Ч[Сред(ФорматДаты + "dMyHhms", ё, 1)] = 0	// - инициализация частей даты
    КонецЦикла;
    Для ё = 1 По 12 Цикл
        Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMММ"), Формат(ё, "ЧЦ=4; ЧВН=")); // - замена названий месяцев числами
        Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMМ" ), Формат(ё, "ЧЦ=3; ЧВН="))
    КонецЦикла;
    Для ё = 1 По СтрДлина(ФорматДаты) Цикл
        Ч[Сред(ФорматДаты, ё, 1)] = 10 * Ч[Сред(ФорматДаты, ё, 1)] + Найти("123456789", Сред(Дано, ё, 1)); // - накопление частей даты
        Ошибка = Ошибка ИЛИ Найти("dMyHhms", Сред(ФорматДаты, ё, 1)) И НЕ Найти("0123456789", Сред(Дано, ё, 1)) // - необязательная проверка на цифры
    КонецЦикла;
    Ч["y"] = Ч["y"] + ?(Ч["y"] < 50, 2000, ?(Ч["y"] < 100, 1900, 0)); // - дополнение двух цифр года до четырех
    Попытка  
        Возврат Дата(Ч["y"], Ч["M"], Ч["d"], Ч["H"] + Ч["h"], Ч["m"], Ч["s"])
    Исключение
        Ошибка = Истина;
        Возврат '00010101'
    КонецПопытки
КонецФункции
//
Показать
ELInfinito; Simonov_NPM; rise; Valkiriyaaaa; Crazy Professor; bulpi; +6 Ответить
12. Crazy Professor 22 02.10.13 10:02 Сейчас в теме
(11) ildarovich,
Ну да, я ламмер, очень изящно - преклоняю колено.
15. kuzyara 1195 30.08.16 06:24 Сейчас в теме
(12) код (11) с ошибками.
Январь прописью не проходит, зачем-то "h" парсит и т.д.
13. Crazy Professor 22 02.10.13 10:03 Сейчас в теме
(11) ildarovich,
Можно вынести в шапку с указанием авторства? Вдруг кому нужно будет.
14. ildarovich 7358 02.10.13 11:05 Сейчас в теме
(13) Да, конечно, пожалуйста. Только просьба стандартные отступы восстановить (они пропали при вставке кода в комментарий).
25. rise 12.07.19 10:56 Сейчас в теме
(11) Круто, но к сожалению некорректно обрабатывает форматы "d" и "M", когда число знаков переменное. d.M.yyyy дает 12.7.2019

И в этой строке кажется надо в формат числа добавить ЧГ=0
Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMММ"), Формат(ё, "ЧЦ=4; ЧВН="));
4. spetzpozh 10.09.13 14:35 Сейчас в теме
Сообщить(), если учитывать рекомендации 1С, использовать не стоит вообще никогда :) СообщениеПользователю есть.
5. diver.sun 21 11.09.13 11:13 Сейчас в теме
Почитал, подумал, написал свой вариант, жутко не экономично, но зато абсолютно универсально
Процедура КнопкаВыполнитьНажатие(Кнопка)
	лФорматнаяСтрока = "Л=en; ДФ='yyyy МММ dd HH/mm/s'";
	лСтрокаДаты = "2013 Sep 11 09/58/5";
	
	
	лМассивДатНачальный = Новый Массив;
	лМассивДатНачальный.Добавить(1900);
	лМассивДатНачальный.Добавить(1);
	лМассивДатНачальный.Добавить(1);
	лМассивДатНачальный.Добавить(0);
	лМассивДатНачальный.Добавить(0);
	лМассивДатНачальный.Добавить(0);

	
	лДиапазонГода = ВернутьДиапазонЗначимыхЗначений(0,1999,2001,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,0,1900,2100,лФорматнаяСтрока,лДиапазонГода,лСтрокаДаты);
	
	лДиапазонМесяца = ВернутьДиапазонЗначимыхЗначений(1,1,12,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,1,1,12,лФорматнаяСтрока,лДиапазонМесяца,лСтрокаДаты);
	
	лДиапазонДаты = ВернутьДиапазонЗначимыхЗначений(2,1,31,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,2,1,31,лФорматнаяСтрока,лДиапазонДаты,лСтрокаДаты);
	
	лДиапазонЧаса = ВернутьДиапазонЗначимыхЗначений(3,0,23,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,3,0,23,лФорматнаяСтрока,лДиапазонЧаса,лСтрокаДаты);
	
	лДиапазонМинуты = ВернутьДиапазонЗначимыхЗначений(4,0,59,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,4,0,59,лФорматнаяСтрока,лДиапазонМинуты,лСтрокаДаты);
	
	лДиапазонСекунды = ВернутьДиапазонЗначимыхЗначений(5,0,59,лФорматнаяСтрока);
	ПодобратьЗначение(лМассивДатНачальный,5,0,59,лФорматнаяСтрока,лДиапазонСекунды,лСтрокаДаты);
	
	РезДата = Дата(лМассивДатНачальный[0],лМассивДатНачальный[1],лМассивДатНачальный[2],лМассивДатНачальный[3],лМассивДатНачальный[4],лМассивДатНачальный[5]);	
КонецПроцедуры

Процедура ПодобратьЗначение(пМассивПараметровДаты,лНомерПараметра,пСтарт,пСтоп,пФорматнаяСтрока,пСтрПоложения,пРазбираемаяСтрока)
	Если пСтрПоложения.С = -1 Тогда
		Возврат;
	КонецЕсли;
	Для Ном = пСтарт по пСтоп Цикл
		пМассивПараметровДаты[лНомерПараметра] = Ном;
		лДата = Дата(пМассивПараметровДаты[0],пМассивПараметровДаты[1],пМассивПараметровДаты[2],пМассивПараметровДаты[3],пМассивПараметровДаты[4],пМассивПараметровДаты[5]);
		лСтрПредставленияДаты = Формат(лДата,пФорматнаяСтрока);
		Если Сред(пРазбираемаяСтрока,пСтрПоложения.С,пСтрПоложения.По-пСтрПоложения.С+1) = Сред(лСтрПредставленияДаты,пСтрПоложения.С,пСтрПоложения.По-пСтрПоложения.С+1) Тогда
			Прервать;
		КонецЕсли;
	КонецЦикла;
КонецПроцедуры

Функция ВернутьДиапазонЗначимыхЗначений(лНомерПараметра,пСтарт,пСтоп,пФорматнаяСтрока)
	лМассивПараметров = Новый Массив;
	лМассивПараметров.Добавить(1900);
	лМассивПараметров.Добавить(1);
	лМассивПараметров.Добавить(1);
	лМассивПараметров.Добавить(0);
	лМассивПараметров.Добавить(0);
	лМассивПараметров.Добавить(0);
	лДатаНачальная = Дата(лМассивПараметров[0],лМассивПараметров[1],лМассивПараметров[2],лМассивПараметров[3],лМассивПараметров[4],лМассивПараметров[5]);
	лСтрПредставление = Формат(лДатаНачальная,пФорматнаяСтрока);
	
	лСтрРазностная = Новый Структура("С,ПО",10000,-1);
	
	Для лНом = пСтарт по пСтоп Цикл
		лМассивПараметров[лНомерПараметра] = лНом;
		лСтрНовая = Формат(Дата(лМассивПараметров[0],лМассивПараметров[1],лМассивПараметров[2],лМассивПараметров[3],лМассивПараметров[4],лМассивПараметров[5]),пФорматнаяСтрока);
		Если лСтрПредставление <> лСтрНовая Тогда
			СтрРазличий = ВернутьСтрРазличияВСтроках(лСтрПредставление,лСтрНовая);
			лСтрРазностная.С = Мин(лСтрРазностная.С,СтрРазличий.С);
			лСтрРазностная.ПО = Макс(лСтрРазностная.ПО,СтрРазличий.ПО);
		КонецЕсли;
	КонецЦикла;
	Если лСтрРазностная.С = 10000 Тогда
		лСтрРазностная.С = -1;
	КонецЕсли;
	Возврат лСтрРазностная; 
КонецФункции

Функция ВернутьСтрРазличияВСтроках(пСтрока1,пСтрока2)
	пПервыйРазличныйСимвол = -1;
	пПоследнийРазличныйСимвол = -1;
	Для Ном = 1 по СтрДлина(пСтрока1) Цикл
		Если Сред(пСтрока1,Ном,1) =  Сред(пСтрока2,Ном,1) И пПервыйРазличныйСимвол <> -1 Тогда
			пПоследнийРазличныйСимвол = Ном - 1;
			Прервать;
		ИначеЕсли Сред(пСтрока1,Ном,1) <>  Сред(пСтрока2,Ном,1) И пПервыйРазличныйСимвол = -1 Тогда
			пПервыйРазличныйСимвол = Ном;
		КонецЕсли;
	КонецЦикла;
	Если пПоследнийРазличныйСимвол = -1 Тогда
		пПоследнийРазличныйСимвол = СтрДлина(пСтрока1);
	КонецЕсли;
	Возврат Новый Структура("С,ПО",пПервыйРазличныйСимвол,пПоследнийРазличныйСимвол);
	
КонецФункции
Показать
8. Crazy Professor 22 24.09.13 09:37 Сейчас в теме
(5) diver.sun,
Чего-то я не понял как эта обработка должна отрабатывать при изменении порядка элементов форматной строки или вообще при исчезновении некоторых (например такой "yyMMdd", из данных с которыми я работаю). Но идея занятная - от обратного. В упрощенном варианте можно было перебирать все значения с точностью до секунды от -50 до +50 лет от текущей даты и искать подходящее через запрос :).
9. diver.sun 21 24.09.13 10:43 Сейчас в теме
Тогда она не находит позиции старта стопа изменяемого значения.
10. Crazy Professor 22 24.09.13 10:58 Сейчас в теме
(9) diver.sun, твой метод дал идею по распознаванию месяцев строкового формата.
16. Xershi 1257 20.04.18 16:46 Сейчас в теме
Кому интересно повозиться сервер вернул дату формата: "Tue, 10 Oct 2017 15:25:00 +0300".
Форматная строка выходит "Л=en; ДФ='ddd, dd MMM yyyy HH:mm:ss'" плюс часовой пояс.
17. smaharbA 08.11.18 17:14 Сейчас в теме
(16)
"Tue, 10 Oct 2017 15:25:00 +0300"


Пока СтрНайти(Стр,"  ")>0 Цикл
	Стр=СтрЗаменить(Стр,"  ","");
КонецЦикла;
МассивДаты=СтрРазделить(Стр," ");
Для ч=1 По 12 Цикл
	Стр=Прав("0"+ч,2);
	Если ВРег(МассивДаты[2])=ВРег(Формат(Дата("2018"+Стр+"01000000"),"Л=en; ДФ='MMM'")) Тогда
		Сообщить(Дата(МассивДаты[3]+Стр+МассивДаты[1]+СтрЗаменить(МассивДаты[4],":",""))+(60*60*5));
		Возврат;
	КонецЕсли;
КонецЦикла;
Показать
18. spacecraft 08.11.18 17:18 Сейчас в теме
(17)
Пока СтрНайти(Стр," ")>0 Цикл
Стр=СтрЗаменить(Стр," ","");
КонецЦикла;
МассивДаты=СтрРазделить(Стр," ");

Вот это можно описать одной строкой:
МассивДаты=СтрРазделить(Стр," ", Ложь);
19. smaharbA 14.11.18 15:57 Сейчас в теме
Можно, но лучче заменять все двойные пробелы на один.
20. spacecraft 14.11.18 16:40 Сейчас в теме
21. dobrynin.i.s 92 19.11.18 02:42 Сейчас в теме
функцию привожу из https://infostart.ru/public/886103/

Функция ПолучитьДатуВремяИзСтроки(ДатаВремя) Экспорт
	
	Результат = Неопределено;
	ДатаВремя = СтрЗаменить(ДатаВремя, "-", "");
	ДатаВремя = СтрЗаменить(ДатаВремя, ":", "");
	Если СтрДлина(ДатаВремя) - Найти(ДатаВремя, " ") = 5 Тогда // время в формате Ч:ММ:СС
		ДатаВремя = СтрЗаменить(ДатаВремя, " ", "0");
	ИначеЕсли Найти(ДатаВремя, "T") > 0 Тогда //время в формате ГГГГММДДTЧЧММСС
		ДатаВремя = СтрЗаменить(ДатаВремя, "T", "");
	Иначе // время в формате ЧЧ:ММ:СС
		ДатаВремя = СтрЗаменить(ДатаВремя, " ", "");
	КонецЕсли;
	
	ОписаниеТипа = Новый ОписаниеТипов("Дата");
	Результат = ОписаниеТипа.ПривестиЗначение(ДатаВремя);  // дата и время в виде "ГГГГММДДЧЧММСС"
	Если Не ЗначениеЗаполнено(Результат) Тогда
		Результат = ОписаниеТипа.ПривестиЗначение(Лев(ДатаВремя, 8));  // только дата "ГГГГММДД"
	КонецЕсли;

	Возврат Результат;
	
КонецФункции
Показать
22. user1040271 23.11.18 11:50 Сейчас в теме
(21)
Что-то не уверен, что эта функция универсальна, поскольку не задается ожидаемый формат.
Как он интерпретирует 11.11.11? Или 11.11 или 11?
Думаю, что она работает только с фиксированными форматами, используемыми в конкретно той задаче для работы с http
23. dobrynin.i.s 92 25.11.18 03:00 Сейчас в теме
(22)
в коде есть пояснения

11.11 или 11 - это вообще не даты.
11.11 ещё можно догадатся что 11.11.2018 - текущий год (2018), а
11 - что такое год , месяц, день или секунда
24. user1040271 26.11.18 10:25 Сейчас в теме
(23)
Об этом и речь - только по данным не всегда можно точно определить формат, особенно по единичному элементу этих данных.
Если есть ограниченный набор вариантов - то тут, конечно, не проблема: в коде отработать исключения (убрать "Т", например). Уверен, что большинство тут решало такие задачи в ходе своей практики.
Но универсальные методы на то и универсальные, что бы не привязываться к конкретным случаям.
Оставьте свое сообщение

См. также

Аналог PIVOT в запросе 1С (как выполнить транспонирование таблицы в запросе 1С) Промо

Практика программирования v8 Бесплатно (free)

В статье показывается простой метод реализации аналога оператора PIVOT в запросе 1С без использования соединений.

12.12.2020    4167    Eugen-S    23    

Что за ? в коде, или Секретный оператор в 1С

Практика программирования v8 Платформа 1C v8.2 Платформа 1С v8.1 1cv8.cf Бесплатно (free)

Инкремент, модуль и прочая магия, которая скрыта под символом "?"

21.10.2021    5699    SeiOkami    33    

Полезные примеры СКД, ч.2

Практика программирования v8 v8::СКД Бесплатно (free)

Еще несколько примеров решения задач в СКД.

06.04.2021    10301    Neti    8    

Неочевидные нюансы записи управляемой формы

Практика программирования v8 v8::УФ Платформа 1C v8.2 1cv8.cf Бесплатно (free)

Разберем несколько нюансов записи управляемой формы.

02.04.2021    12179    SeiOkami    54    

Использование классов .Net в 1С для новичков Промо

Практика программирования Разработка внешних компонент Универсальные функции v7.7 v8 Бесплатно (free)

Руководство для новичков. Написав статью http://infostart.ru/public/238584/, я понял, что многие не понимают того, что написано. Поэтому в этой статье постараюсь более подробно остановиться на азах и без кода на вражеском языке (C#)

27.01.2016    85333    Serginio    115    

Обзор полезных методов БСП 3.1.4

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Бесплатно (free)

Библиотека стандартных подсистем (далее - БСП) является частью любой типовой конфигурации, поэтому умение применять готовые процедуры и функции повышает качество разработки и избавляет от написания лишнего кода. К сожалению, не у всех есть время и упорство овладеть всей документацией, поэтому я собрал воедино наиболее популярный функционал.

25.03.2021    38517    rayastar    51    

Звуковое управление в 1С 8.3

Практика программирования v8 1cv8.cf Бесплатно (free)

В данной статье описано создание библиотеки для звукового управления (выполнение команд голосом) для платформы 1С 8.3. Задача была поставлена так, чтобы модуль функционировал непосредственно на клиенте 1С, осуществляя управление формами, и взаимодействовал с интерфейсом.

16.03.2021    6998    velemir    33    

Serverless (Faas) в 1С. Создание и вызов Yandex Cloud Functions

Универсальные функции Практика программирования v8 Бесплатно (free)

"Я не могу просто взять и скопировать код с гитхаба", "у нас 1С микросервисами окружена", "возможностей мало" - частые фразы 1С разработчиков. которым не хватает возможностей платформы в современном мире. Faas, конечно, история не новая, но нас сдерживало 152ФЗ и задержки по пингам. Для того, чтобы действительно использовать в 1С код, к примеру, на Python, надо было приложить усилия. Теперь всё намного проще - берём и используем.

28.12.2020    8708    comol    31    

Использование программных перечислений, ч.1: строковые константы Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Часто ли у вас возникает необходимость в коде выполнять сравнение на строку?

10.12.2016    40971    unichkin    74    

Базовые вещи БСП, которые облегчат жизнь программисту 1С

Практика программирования БСП (Библиотека стандартных подсистем) v8 1cv8.cf Россия Бесплатно (free)

В данной публикации я опишу полезные процедуры и функции модуля общего назначения библиотеки стандартных подсистем, обязательные к использованию любым программистом 1С.

30.08.2020    19722    quazare    34    

Форма выбора (подбор) в управляемых формах

Практика программирования v8 v8::УФ 1cv8.cf Россия Бесплатно (free)

Разбор небольших примеров того, как правильно открывать форму выбора (подбора) в управляемых формах, не прибегая к модальным окнам.

08.05.2020    74696    user5300    19    

Вспомогательные инструкции в коде 1С Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Помогаем редактору кода 1С помогать нам писать и анализировать код.

15.10.2018    35926    tormozit    106    

Программная работа с настройками СКД

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Нюансы программной работы с настройками системы компоновки данных в отчетах и динамических списках. Обзор всех видов настроек компоновки. Что в каких случаях правильно применять. В качестве примера рассмотрена работа с отборами и группировками.

27.01.2020    63999    ids79    26    

[СКД] Программное создание схемы компоновки данных

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Сделаем отчет на СКД полностью программно, без использования макета "схема компоновки данных".

15.01.2020    42806    John_d    22    

Последовательности событий при проведении документа 1С. Шпаргалка + про формы + про расширения

Практика программирования v8 Россия Бесплатно (free)

Собрал информацию о событиях/подписках/расширениях в одном месте.

30.12.2019    34486    kuzyara    38    

Оформление и рефакторинг сложных логических выражений Промо

Практика программирования v8 Россия Бесплатно (free)

В сложных логических выражениях нередко самому автору спустя какое-то время тяжело разобраться, не говоря уже о других программистах. Предлагаемая методика позволяет повысить наглядность таких выражений путем оформления в виде И-ИЛИ дерева и одновременно выполнять их рефакторинг.

20.09.2012    82709    tormozit    131    

30 задач. Странных и не очень

Практика программирования v8 Бесплатно (free)

30 задач на знание языка программирования 1С и некоторого поведения платформы. Маленьких. Странных и не очень.

02.12.2019    23917    YPermitin    62    

Как передать IP адрес, который вызвал HTTP запрос в 1C (для веб-сервера Apache)

Практика программирования v8 Бесплатно (free)

Столкнулся с задачей получения IP адреса, который вызывает http сервис 1С. Итак, решение:

22.11.2019    12160    Sibars    19    

Полезные процедуры и функции для программиста

Практика программирования Универсальные функции v8 1cv8.cf Россия Бесплатно (free)

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    39326    HostHost    41    

Запись значения в поле ввода/формы со срабатыванием события ПриИзменении Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Иногда возникает необходимость после записи значения в какое либо поле ввода/формы вызвать для него обработчик события ПриИзменении, а о вызове самого события приходится только мечтать. В этой статье приводится программный способ вызова этого события.

11.07.2007    54181    tormozit    51    

Таблица значений. Нюансы

Практика программирования v8 Бесплатно (free)

Обзор некоторых аспектов использования общеизвестного инструмента 1С.

01.10.2019    52245    Yashazz    56    

[Шпаргалка] Программное создание элементов формы

Практика программирования Работа с интерфейсом v8 1cv8.cf Бесплатно (free)

Программное создание практически всех популярных элементов формы.

06.09.2019    99604    rpgshnik    75    

Агрегатные функции СКД, о которых мало кто знает

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    76436    ids79    56    

Как сделать из &НаКлиентеНаСервереБезКонтекста почти &НаКлиентеНаСервере Промо

Практика программирования v8 1cv8.cf Россия Бесплатно (free)

Как сделать метод формы, доступный на клиенте и на сервере одновременно, и сохранить при этом удобство разработки

10.09.2017    50943    tormozit    74    

Регистры бухгалтерии. Общая информация

Практика программирования Математика и алгоритмы v8 v8::БУ БУ Бесплатно (free)

Общая информация о внутреннем устройстве регистров бухгалтерии.

05.09.2019    45873    YPermitin    25    

Три костыля. Сказ про фокусы в коде

Практика программирования v8 Бесплатно (free)

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    30066    YPermitin    81    

Отслеживание выполнения фонового задания

Практика программирования Универсальные функции Разработка v8 1cv8.cf Бесплатно (free)

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    44734    ids79    22    

Выгрузка документа по условию Промо

Практика программирования Разработка v8 Бесплатно (free)

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    17939    m-rv    3    

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    148869    ids79    75    

Фоновое выполнение кода в 1С - это просто

Практика программирования v8 1cv8.cf Бесплатно (free)

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    59687    avalakh    26    

Разбираемся с параметрами редактирования СКД

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Связь по типу, Параметры выбора, Связи параметров выбора

31.07.2019    41065    json    17    

Как прикрутить ГУИД к регистру сведений Промо

Практика программирования Перенос данных из 1C8 в 1C8 Разработка v8 Бесплатно (free)

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    23235    m-rv    18    

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    103680    ids79    16    

Управление качеством кода

Математика и алгоритмы Рефакторинг и качество кода SonarQube EDT v8 Бесплатно (free)

О SonarQube, АПК, EDT. Какие преимущества дает их использование. Для каких команд подходит.

22.07.2019    19385    Stepa86    40    

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ

Инструментарий разработчика Практика программирования v8 v8::СКД Бесплатно (free)

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    47912    ids79    27    

Как сделать запрос на изменение данных Промо

Практика программирования v8 v8::Запросы 1cv8.cf Бесплатно (free)

В статье приведены особенности внутренней архитектуры и примеры работы с расширением языка запросов 1С.

01.06.2018    36663    m-rv    23    

Регистры сведений. За кулисами

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Небольшие заметки по внутреннему устройству регистров сведений.

09.07.2019    33600    YPermitin    14    

"Меньше копипаста!", или как Вася универсальную процедуру писал

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    22453    SeiOkami    53    

Работа с настройками системы компоновки данных

Практика программирования v8 v8::СКД 1cv8.cf Бесплатно (free)

Варианты отчетов, работа с настройками вариантов: структура группировок, поля отчета, отборы, сортировка, условное оформление, другие настройки, настройки отображения диаграмм.

02.07.2019    82868    ids79    18    

Метод формирования движений в типовых регистрах нетиповыми регистраторами Промо

Практика программирования v8 1cv8.cf Бесплатно (free)

Вариант решения задач с проведением по типовым регистрам нетиповыми регистраторами. Зачем - чтобы при сравнении конфигурации не обращать внимание на свойства регистров и исключить вероятность допущения горькой оплошности при обновлении информационных баз, заменив типы регистраторов основной конфигурации типами конфигурации поставщика. Для программных продуктов, имеющих в своем составе метаданных документ "Корректировка регистров"("Корректировка записей регистров").

05.12.2017    30710    itriot11    34    

Создание отчетов с помощью СКД - основные понятия и элементы

Практика программирования Математика и алгоритмы v8 v8::СКД Бесплатно (free)

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    75210    ids79    28    

Регистры накопления. Структура хранения в базе данных

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    62904    YPermitin    31    

О расширениях замолвите слово...

Практика программирования Разработка v8 Бесплатно (free)

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    42331    ellavs    131    

Git-репозитории для 1С-кода (опыт использования при небольших проектах)

Практика программирования v8 Бесплатно (free)

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    31839    ellavs    90    

Трюки с внешними источниками данных

Практика программирования Разработка v8 1cv8.cf Бесплатно (free)

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    40912    YPermitin    53    

Ошибки при работе с хранилищем конфигурации и способы их решения

Практика программирования v8 Бесплатно (free)

В статье собраны наиболее распространенные ошибки при работе с хранилищем конфигурации и способы их обхода и решения.

01.03.2019    65813    Смешной 1С    33    

Разработка и сценарное тестирование с Vanessa-ADD. Отчетность Allure. Автоматизация запуска сценариев

Практика программирования BDD/TDD-тестирование, Vanessa v8 Россия Бесплатно (free)

Формируем отчетность о результатах выполнения сценариев. Автоматизируем запуск.

26.02.2019    28296    Vladimir Litvinenko    28