Ладно, если это были рядовые пользователи, на которых можно было найти управу. Но в большинстве своём это были ТОП-менеджеры или приближенные к ним, которым отказать было ну никак нельзя. А уж если это «тело» имеет доступ к «хозяину», тот тут точно надо бежать «сломя голову» и выполнять это поручение. Итальянской забастовкой точно отделаться не получится, а вариант с увольнением вовсе не вариант.
Ну так вот. Во время очередного приезда «хозяина», а приезд «хозяина» ничего хорошего не сулит и означает только одно, что всем и вся будет роздано «на орехи».
И вот в очередной приезд «хозяина», назовём его Иван Иванович, приехал на предприятие и начал совершать обход владений своих. В очередной раз его так допекли, то он уже ругался не просто матом и грозил всем «всеми карами небесными», но и перешел к активным действиям. Он начал тыкать пальцем в сотрудника и говорить, что сотрудник уволен. Но этого ему было мало. Он понимал, что пока суть да дело может случится так, что это увольнение может «замылиться» и сотрудника могут в итоге не уволить. А он жаждал крови, причем здесь и сейчас. Поэтому тут же развернувший к своему секретарю, отдал ей приказ, что мол быстро мне в рамках автоматизации сделайте так, чтобы я мог лично увольнять сотрудников при помощи смартфона здесь и сейчас. Сделаю небольшое отступление. Иван Иванович категорически на дух не переносит компьютеры, причем в любом их виде. Будь то стационарный ПК или ноутбук. Работал он либо с последнего iPhone, либо с яблочного планшета. Бумажные варианты тоже «шли лесом». За бумажный вариант он готов был «убить на месте» подателя сего.
Естественно, что после обхода секретарь «хозяина» вызвала к себе директора по IT и озвучила задачу самого главного на предприятии. Директор по IT тут же взял под козырек и вызвал к себе программиста и пересказал всё, что ему было передано. Фраза была довольно простая: - «Надо сделать!»
Когда программист 1С отошел от шока, а работал он в этой организации меньше месяца, и сузить свои глаза от размера ленинского рубля хотя бы до трехкопеечной монеты, после чего попытался задать хоть какие-то наводящие вопросы, типа, а в какой базе это надо реализовывать. На что получил ответ, что давай делай быстрее, а то мало никому не покажется.
В итоге программист 1С отправился ваять.
Поскольку самой главное программой на предприятие был Документооборот, реализация данного функционала решено было реализоваться там. Да, на предприятии были базы ЗУП и Бухгалтерия, но они держались особняком. Все бизнес-процессы протекали именно в Документообороте.
Итак. Если открыть документооборот на компьютере, то мы наблюдаем вот такую начальную страницу.
А если Документооборот открывать со смартфона или с планшета, то начальная страница будет выглядеть вот так.
Так как «хозяин» компьютером не пользовался, то, значит, надо остановиться на мобильном варианте, для смартфона или для планшета. Понятно, что слишком много и долго, «хозяин» нажимать ничего не будет. Ему нужен «автомат Калашникова», который работает безотказно и в любое время суток.
Было решено разместить на Рабочем столе для мобильного приложения еще один виджет, который будет находится вверху. На этом виджете будет присутствовать картинка человека с крестом, который будет символизировать увольнение и название «Экстренное увольнение».
Далее по задумке, как только нажимается эта кнопка, то возникает следующее окно, в котором и будет происходить непосредственное увольнение. Предположительно оно должно выглядеть следующим образом. Указывается сотрудник и нажимается кнопка «Уволить». И всё.
ФИО сотрудника можно выбирать из списка, начав вводить первые буквы, или непосредственно из самого справочника.
После того, как кнопка «Уволить» будет нажата, внизу появится сообщение «Сотрудник уволен».
А в Документообороте будет создан соответствующий документ (элемент справочника «ДокументыПредприятия»), по которому данное увольнение пойдет по исполнителям.
В принципе, любой, кто работал с Документооборотом, может представить и понять этот механизм работы. Думаю, что всем понятно, что при нажатии на кнопку «Уволить» происходит программное создание элемента справочника «ДокументыПредприятия». После чего происходит заполнение необходимых реквизитов в этом справочнике, и идет отправка его по исполнителям.
Вот так, кратенько, можно обрисовать теорию.
А теперь приступает непосредственно к реализации. Делалось это следующим образом.
Для начала был запущен конфигуратор Документооборота, и там создал расширение. Думаю, что никому не надо объяснять, почему расширение, а не основная конфигурация использовались для создания этого функционала. В дальнейшем надо Документооборот постоянно обновлять с выходом новых релизов, поэтому основную конфигурацию ни в коем случае не снимаем с поддержки. По стандарту фирмы 1С все доработки должны вестись в расширении или при помощи дополнительных обработок.
В новом расширении загрузил из Интернета картинку «человечка с крестом». «Общие» – «Общие картинки» – «КартинкаЭкстренноеУвольнение».
Была скопирована роль «БазовыеПраваБСП» из основной конфигурации в расширение через команду «Добавить в расширение».
Также через команду «Добавить в расширение» была скопирована общая форма «РабочийСтол».
Для этой формы была созданная команда «ЭкстренноеУвольнение» и прописан для неё следующий код.
&НаКлиенте
Процедура СЧ_ЭкстренноеУвольнениеПосле(Команда)
ОткрытьФорму("Обработка.СЧ_ЭкстренноеУвольнение.Форма.ФормаЭлемента",,ЭтаФорма,,,,,РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
КонецПроцедуры
По этому коду открывается новая форма в которой и будет происходить непосредственное удаление сотрудника. Этой формы еще нет, но мы её обязательно создадим позднее.
После чего эту команду размещаю на форме. Самое главное не забыть в свойства для отображения выбрать «Картинка и текст» и подгрузить нашу ранее загруженную картинку человека.
Там же в свойствах кнопки меняю цвет фона, цвет текста, шрифт и высоту этой кнопки, как показано на скриншоте ниже.
Затем мы должны учесть, видимость этой кнопки. Эта кнопка должна быть видима только в мобильном приложении! Поэтом при открытии пишем следующий код.
&НаКлиенте
Процедура СЧ_ПриОткрытииПосле(Отказ)
Элементы.ЭкстренноеУвольнение.Видимость = Ложь;
#Если МобильноеПриложениеКлиент или МобильныйКлиент Тогда
Если ПроверкаДоступаКЭкстренномуУдалениюСотрудников() Тогда
Элементы.ЭкстренноеУвольнение.Видимость = Истина;
КонецЕсли;
#КонецЕсли
КонецПроцедуры
&НаСервере
Функция ПроверкаДоступаКЭкстренномуУдалениюСотрудников()
ПолученноеЗначение = Ложь;
Запрос = Новый Запрос;
Запрос.УстановитьПараметр("ТекущийПользователь", Пользователи.ТекущийПользователь());
Запрос.Текст = "ВЫБРАТЬ
| СЧ_Топы_ЭкстренноеУвольнение.ПользователиТопы КАК ПользователиТопы
|ИЗ
| РегистрСведений.СЧ_Топы_ЭкстренноеУвольнение КАК СЧ_Топы_ЭкстренноеУвольнение
|ГДЕ
| СЧ_Топы_ЭкстренноеУвольнение.ПользователиТопы = &ТекущийПользователь
| И СЧ_Топы_ЭкстренноеУвольнение.ПользователиТопы.ПометкаУдаления = Ложь";
Результат = Запрос.Выполнить().Выбрать();
Если Результат.Следующий() Тогда
ПолученноеЗначение = Истина;
КонецЕсли;
Возврат ПолученноеЗначение;
КонецФункции
Если внимательно посмотреть на вышеуказанный код, то на сервере идет обращение к регистру сведений «СЧ_Топы_ЭкстренноеУвольнение», который также будет создан чуть позднее.
На этом работа с общей формой «Рабочий стол» завершена.
Переходим теперь к созданию регистра сведений, который у нас будет непериодическим и независимым. Назовем его «СЧ_Топы_ЭкстренноеУвольнение». У него будет единственное измерение «ПользователиТОПы». В этот регистр мы будем помещать тех людей, которые могут выполнить экстренное увольнение. Это будет правильным решением, так как позволяет быстро расширить или сузить круг таких лиц в реальном времени. Если это делать в коде, то каждый раз надо выгонять пользователей. Вот поэтому пришлось создавать этот регистр сведений. Код здесь никакой писать не надо. Надо только указать Подсистему и права для роли «БазовыеПраваБСП».
Далее переходим к последнему объекту, который нам надо создать в этом расширении. Это обработка «СЧ_ЭкстренноеУвольнение». Сразу указываем подсистему и права для роли «БазовыеПраваБСП». В качестве данных указываем два реквизита: «Сотрудник» и «ВидДокумента».
Реквизит «Сотрудник» имеет тип данных «СправочникСсылка.Сотрудники», а Реквизит «ВидДокумента» имеет тип данных «СправочникСсылка.ВидыДокументов».
Затем создаем форму элемента обработки и размещаем реквизиты на форме и добавляем еще команду «КомандаУволить» и декорацию в качестве надписи, которая будет отображать информацию, что сотрудник уволен.
И в итоге на форме обработки это будет следующим образом.
В качестве обработки кода, для кнопки «Уволить» будет применен следующий код.
&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
ВидДокумента = Справочники.ВидыДокументов.НайтиПоНаименованию("Экстренное увольнение");
КонецПроцедуры
&НаКлиенте
Процедура КомандаУволить(Команда)
Если Не ЗначениеЗаполнено(Объект.Сотрудник) Тогда
Сообщить("Не указан сотрудник для увольнения!");
Возврат;
КонецЕсли;
Док_ЭкстренноеУвольнение = СоздатьДокументЭкстренноеУвольнение();
Если Док_ЭкстренноеУвольнение = Неопределено Тогда
Сообщить("Документ не был создан!");
Возврат;
КонецЕсли;
ПараметрыФормы = Новый Структура("Ключ", Док_ЭкстренноеУвольнение);
МояФорма = ПолучитьФорму("Справочник.ДокументыПредприятия.Форма.ФормаЭлемента", ПараметрыФормы);
МояФорма.ДействияЗаполнитьДляМобильногоПриложения();
МояФорма.ОбновитьОтображениеДанных();
МояФорма.НТ_ДействияОтправить();
Элементы.Декорация1.Заголовок = "Сотрудник уволен!..";
КонецПроцедуры
&НаСервере
Функция СоздатьДокументЭкстренноеУвольнение()
ДокЭкстренноеУвольнение = Справочники.ДокументыПредприятия.СоздатьЭлемент();
ДокЭкстренноеУвольнение.ВидДокумента = Справочники.ВидыДокументов.НайтиПоНаименованию("Экстренное увольнение");
ДокЭкстренноеУвольнение.ДатаНачалаДействия = ТекущаяДата();
ДокЭкстренноеУвольнение.ДатаСоздания = ТекущаяДата();
ДокЭкстренноеУвольнение.Заголовок = "Увольнение сотрудника: " + Строка(Объект.Сотрудник);
ДокЭкстренноеУвольнение.Наименование = "Увольнение сотрудника: " + Строка(Объект.Сотрудник);
ДокЭкстренноеУвольнение.Комментарий = "Экстренное увольнение.";
ДокЭкстренноеУвольнение.Важность = ПредопределенноеЗначение("Перечисление.ВариантыВажностиОбъектов.Обычная");
ДокЭкстренноеУвольнение.НеДействует = Ложь;
ДокЭкстренноеУвольнение.Бессрочный = Ложь;
ДокЭкстренноеУвольнение.ПодписанВсеми = Ложь;
ДокЭкстренноеУвольнение.Подразделение = ОпределитьПодразделение();
ДокЭкстренноеУвольнение.ФормаДокумента = ПредопределенноеЗначение("Перечисление.ВариантыФормДокументов.Бумажная");
ДокЭкстренноеУвольнение.КоличествоЛистов = 1;
ДокЭкстренноеУвольнение.ЛистовВПриложениях = 1;
ДокЭкстренноеУвольнение.Подготовил = Пользователи.ТекущийПользователь();
ДокЭкстренноеУвольнение.Ответственный = Пользователи.ТекущийПользователь();
ДокЭкстренноеУвольнение.Записать();
Возврат ДокЭкстренноеУвольнение.Ссылка;
КонецФункции
Функция ОпределитьПодразделение()
Возврат Справочники.СтруктураПредприятия.НайтиПоНаименованию("Администрация");
КонецФункции
Код довольно несложный. Сначала «ПриСозданииНаСервере» определятся вид документов, который ранее был созданный в Документообороте «Экстренное увольнение».
После чего, когда нажимается кнопка «Уволить». Если вдруг забыли указать сотрудника, то программа прекратить выполнение дальнейшего кода и выдаст информацию о том, что не указали сотрудника для увольнения.
Если сотрудник был указан, то выполнится создание элемента справочника, которое будет выполняться на сервере. При этом заполнятся все перечисленные реквизиты в коде, и элемент справочника будет записан.
Если запись произошла, то на клиенте обратимся к форме этого объекта и выполним процедуры.
МояФорма.ДействияЗаполнитьДляМобильногоПриложения();
МояФорма.ОбновитьОтображениеДанных();
МояФорма.НТ_ДействияОтправить()
И в конце на форме появится надпись «Сотрудник уволен!..».
Если запустить Документооборот на ПК, то там увидим сформированный документ, который уже запущен на исполнителей.
Так как база у нас была уже опубликована на веб-сервере, то осталось только запустить программу на смартфоне (планшете) и посмотреть, как это всё выполняется. Покажу это просто скриншотами.
Когда этот функционал был показан «хозяину», то он сначала офигел и единственной фразой его было: «Вы что, ребята, шуток не понимаете!». Но потом настолько проникся и тут же уволил одного сотрудника, со словами: — «Как давно я мечтал это сделать!».
И тут же по предприятию пошел слух, что теперь хозяин не только может грозиться уволить, но и реально может уволить любого сотрудника при помощи своего смартфона простым нажатием кнопки. Поэтому бояться теперь надо еще больше, ведь за воротами стоит целая толпа страждущих на замену!
За этот функционал мне выписали огромную премию, на которую я мог теперь спокойно не работать и ждать пенсию, что было, конечно же, шуткой. Я просто продолжил работать дальше, ведь впереди было внедрение ERP, но это уже совершенно другая история, о которой я, может быть, расскажу через некоторое время.
P.S. Данная статья была мною опубликована для коллег, особенно начинающих, чтобы они имели хоть небольшое представление о том, что их ждет на работе программистом 1С. Отнеситесь это как к шутливому рассказу, хотя в каждой шутке есть доля правды.
Всем всего наилучшего и терпения!
Вступайте в нашу телеграмм-группу Инфостарт