Цикл ввода данных, пример решения

Публикация № 535155 12.07.16

Разработка - Универсальные функции

8.3 ввод данных

Отказ от модальности создает проблему организации последовательного ввода данных в рамках одной пользовательской операции. Цепочки процедур, обрабатывающих введенные данные и вызывающие следующий диалог - головная боль даже для самостоятельной поддержки или изменения логики ввода, не говоря о том уже, чтобы разбираться в чужом коде. Предлагаемое решение является некой заготовкой и может быть любым образом улучшено.

Данная тема уже обсуждалась //infostart.ru/public/305935/, но, столкнувшись с проблемой в реальной разработке, я решил изобретать свой "велосипед" =)

Основной целью являлось:

  • создание некого общего модуля, который будет отвечать непосредственно за организацию и контроль цикла ввода данных;
  • возможность запустить цикл на любое количество итерации обращений к пользователю и обработать результ ввода в 2 процедуры.
Начнем с разбора общего модуля "ВводДанныхКлиент":
//_____________________________________________________________
#Область ПрограммныйИнтерфейс

// Шаблон структуры, описывающий каждую итерацию ввода данных 
// 
&НаКлиенте
Функция ПолучитьШаблонОжидаемогоВвода() Экспорт
	
	Результат = Новый Структура;
	
	Результат.Вставить("Ключ", "");
	Результат.Вставить("Владелец", Неопределено);
	Результат.Вставить("ОбработчикВвода", "");
	
	Результат.Вставить("СписокЗначений", Новый СписокЗначений);
	
	Результат.Вставить("ОткрываемаяФорма", "");
	Результат.Вставить("ПараметрыФормы", Новый Структура);
	
	Результат.Вставить("ЧислоДлина", 0);
	Результат.Вставить("ЧислоТочность", 0);
	
	Результат.Вставить("Подсказка", "");
	Результат.Вставить("ПроизвольныйПараметр", Неопределено);
	
	Результат.Вставить("РежимДиалогаВопрос", РежимДиалогаВопрос.ДаНет);
	
	Результат.Вставить("Обязательный", Ложь);
	Результат.Вставить("ФлагЗавершения", Ложь);
	Результат.Вставить("ПостОбработка", Ложь);
	Результат.Вставить("Результат", Неопределено);
	
	Возврат Результат
	
КонецФункции

// Главная процедура. Является как и стартом цикла, так и обработкой каждой последующей итерации
//
// 	- ТочкаВозврата 		: структура, определяющая объект и имя его экспортной процедуры, 
//							куда передаются итоги ввода данных
// 	- МассивОжидаемогоВвода : массив структур из функции "ПолучитьШаблонОжидаемогоВвода", 
//							определяет действия и их поряд по вводу данных
// 	- СквозныеДанные		: служебная Структура("ФлагЗавершения, Ключ, Результат, ТочкаВозврата, МассивОжидаемогоВвода"), 
//							через нее возврат введенных в цикл 
//
&НаКлиенте
Процедура ЗапуститьЦикл(ТочкаВозврата, МассивОжидаемогоВвода, СквозныеДанные = Неопределено) Экспорт
	
	// проверка возврата в цикл после ввода данных
	Если СквозныеДанные <> Неопределено Тогда
		
		// запищем результат
		Для Каждого ОбработкаВвода Из МассивОжидаемогоВвода Цикл
			
			Если ОбработкаВвода.Ключ = СквозныеДанные.Ключ Тогда
				
				Если ОбработкаВвода.Обязательный И СквозныеДанные.Результат = Неопределено Тогда
					ОбработкаВвода.ФлагЗавершения = Ложь;
				Иначе
					
					ОбработкаВвода.ФлагЗавершения = СквозныеДанные.ФлагЗавершения;
					ОбработкаВвода.Результат = СквозныеДанные.Результат;
				
				КонецЕсли;
				
				Прервать;
				
			КонецЕсли; 
			
		КонецЦикла;
		
	КонецЕсли; 
	
	ВводЗакончен = Истина;
	
	// поиск и запуск следующей итерации ввода данных
	Для Каждого ОбработкаВвода Из МассивОжидаемогоВвода Цикл
		
		Если ОбработкаВвода.ФлагЗавершения И НЕ ОбработкаВвода.ПостОбработка Тогда
			Продолжить;
		ИначеЕсли ОбработкаВвода.ФлагЗавершения И ОбработкаВвода.ПостОбработка Тогда
			
			Выполнить("ТочкаВозврата.Объект." + ТочкаВозврата.ИмяПроцедуры + "(МассивОжидаемогоВвода)");
			Возврат;
			
		КонецЕсли;
		
		ВводЗакончен = Ложь;
		
		СквозныеДанные = Новый Структура("ФлагЗавершения, Ключ, Результат, ТочкаВозврата, МассивОжидаемогоВвода");
		
		СквозныеДанные.ФлагЗавершения = Ложь;
		СквозныеДанные.Ключ = ОбработкаВвода.Ключ;
		СквозныеДанные.Результат = Неопределено;
		СквозныеДанные.ТочкаВозврата = ТочкаВозврата;
		СквозныеДанные.МассивОжидаемогоВвода = МассивОжидаемогоВвода;
		
		Если ОбработкаВвода.ОбработчикВвода = "ВыборИзФормы" Тогда
			ВыборИзФормы(ОбработкаВвода.ОткрываемаяФорма, ОбработкаВвода.ПараметрыФормы, ОбработкаВвода.Владелец, СквозныеДанные);
		ИначеЕсли ОбработкаВвода.ОбработчикВвода = "ВыборИзСписка" Тогда
			ВыборИзСписка(ОбработкаВвода.СписокЗначений, ОбработкаВвода.Владелец, СквозныеДанные);
		ИначеЕсли ОбработкаВвода.ОбработчикВвода = "ВводСтроки" Тогда
			ВводСтроки(ОбработкаВвода.Подсказка, СквозныеДанные);
		ИначеЕсли ОбработкаВвода.ОбработчикВвода = "ВводЧисла" Тогда
			ВводЧисла(ОбработкаВвода.Подсказка, ОбработкаВвода.ЧислоДлина, ОбработкаВвода.ЧислоТочность, СквозныеДанные);
		ИначеЕсли ОбработкаВвода.ОбработчикВвода = "ОтветНаВопрос" Тогда
			ОтветНаВопрос(ОбработкаВвода.Подсказка, ОбработкаВвода.РежимДиалогаВопрос, СквозныеДанные);
		КонецЕсли;
		
		Прервать;
		
	КонецЦикла;
	
	// если все то возвращаем в точку возврата все введенные данные
	Если ВводЗакончен Тогда
		Выполнить("ТочкаВозврата.Объект." + ТочкаВозврата.ИмяПроцедуры + "(МассивОжидаемогоВвода)");	
	КонецЕсли; 
	
КонецПроцедуры

#КонецОбласти 

//_____________________________________________________________
#Область Диалоги

// Тут довольно все очевидно, обработка необбходимости вода данных
// с шаблонным возвратом в цикл

&НаКлиенте
Процедура ВыборИзФормы(ОткрываемаяФорма, ПараметрыФормы, Владелец, СквозныеДанные)
	
	ОписаниеОповещения = Новый ОписаниеОповещения("ВыборИзФормы_Завершение", ЭтотОбъект, СквозныеДанные);
	
	ОткрытьФорму(ОткрываемаяФорма, ПараметрыФормы, Владелец, , , , ОписаниеОповещения, РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
	
КонецПроцедуры

&НаКлиенте
Процедура ВыборИзСписка(СписокВыбора, Владелец, СквозныеДанные)
	
	ПараметрыФормы = Новый Структура("СписокВыбора", СписокВыбора);
	
	ОписаниеОповещения = Новый ОписаниеОповещения("ВыборИзСписка_Завершение", ЭтотОбъект, СквозныеДанные);
	
	ОткрытьФорму("ОбщаяФорма.ФормаВыбораИзСписка", ПараметрыФормы, Владелец, , , , ОписаниеОповещения, РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);
		
КонецПроцедуры

&НаКлиенте
Процедура ВводСтроки(Подсказка, СквозныеДанные)
	
	ОписаниеОповещения = Новый ОписаниеОповещения("ВводСтроки_Завершение", ЭтотОбъект, СквозныеДанные);
	
	ПоказатьВводСтроки(ОписаниеОповещения, "", Подсказка);
	
КонецПроцедуры

&НаКлиенте
Процедура ВводЧисла(Подсказка, Длина, Точность, СквозныеДанные)
	
	ОписаниеОповещения = Новый ОписаниеОповещения("ВводЧисла_Завершение", ЭтотОбъект, СквозныеДанные);
	
	ПоказатьВводЧисла(ОписаниеОповещения, 0, Подсказка, Длина, Точность);
	
КонецПроцедуры

&НаКлиенте
Процедура ОтветНаВопрос(Подсказка, Кнопки, СквозныеДанные)
	
	ОписаниеОповещения = Новый ОписаниеОповещения("ОтветНаВопрос_Завершение", ЭтотОбъект, СквозныеДанные);
	
	ПоказатьВопрос(ОписаниеОповещения, Подсказка, Кнопки);
	
КонецПроцедуры

#КонецОбласти 

//_____________________________________________________________
#Область ОбработкиОповещений

// Закрывашки наших диалогов

&НаКлиенте
Процедура ВыборИзФормы_Завершение(ВыбЗнач, СквозныеДанные) Экспорт
	
	СквозныеДанные.Результат = ВыбЗнач;
	СквозныеДанные.ФлагЗавершения = Истина;
	
	ЗапуститьЦикл(СквозныеДанные.ТочкаВозврата, СквозныеДанные.МассивОжидаемогоВвода, СквозныеДанные);
	
КонецПроцедуры

&НаКлиенте
Процедура ВыборИзСписка_Завершение(ВыбЗнач, СквозныеДанные) Экспорт
	
	СквозныеДанные.Результат = ВыбЗнач;
	СквозныеДанные.ФлагЗавершения = Истина;
	
	ЗапуститьЦикл(СквозныеДанные.ТочкаВозврата, СквозныеДанные.МассивОжидаемогоВвода, СквозныеДанные);
	
КонецПроцедуры
 
&НаКлиенте
Процедура ВводСтроки_Завершение(ВведеннаяСтрока, СквозныеДанные) Экспорт
	
	СквозныеДанные.Результат = ВведеннаяСтрока;
	СквозныеДанные.ФлагЗавершения = Истина;
	
	ЗапуститьЦикл(СквозныеДанные.ТочкаВозврата, СквозныеДанные.МассивОжидаемогоВвода, СквозныеДанные);
	
КонецПроцедуры 

&НаКлиенте
Процедура ВводЧисла_Завершение(ВведеннаяСтрока, СквозныеДанные) Экспорт
	
	СквозныеДанные.Результат = ВведеннаяСтрока;
	СквозныеДанные.ФлагЗавершения = Истина;
	
	ЗапуститьЦикл(СквозныеДанные.ТочкаВозврата, СквозныеДанные.МассивОжидаемогоВвода, СквозныеДанные);
	
КонецПроцедуры 

&НаКлиенте
Процедура ОтветНаВопрос_Завершение(Ответ, СквозныеДанные) Экспорт
	
	СквозныеДанные.Результат = Ответ;
	СквозныеДанные.ФлагЗавершения = Истина;
	
	ЗапуститьЦикл(СквозныеДанные.ТочкаВозврата, СквозныеДанные.МассивОжидаемогоВвода, СквозныеДанные);
	
КонецПроцедуры 

#КонецОбласти 

Теперь расмотрим живой пример изспользования данного модуля. 

Решим следующую задачу: при выборе товара в корзину нужно сразу запросить необходимое количество, спросить о необходимости поставить товар в резерв и, если будет положительный ответ, то дать выбрать место размещения товара.

Получаем следующие итерации ввода:

  • ввести число;
  • диалог вопроса;
  • если на диалог был ответ да, то выбрать ссылку.

Приступим.

&НаКлиенте
Процедура ТоварыПриИзменении(Элемент)
	
	// Товар был добавлен в корзину. 
	// Запросим необходимые данные.
	ЗапроситьДанные();
	
КонецПроцедуры

// Можно считать шаблоном. Обязательно экспортная, т.к. тут же происходит 
// пост-обработка итерации ввода данных (если была включена такая опция).
//
// - МассивОжидаемогоВвода   : 	параметр как флаг, либо это первый запуск, 
//								либо пост-обработка, либо завершение цикла
//
&НаКлиенте
Процедура ЗапроситьДанные(МассивОжидаемогоВвода = Неопределено) Экспорт
		
	// возврат происходит в эту же процедуру 
	ТочкаВозврата = Новый Структура("ИмяПроцедуры, Объект");
	
	ТочкаВозврата.ИмяПроцедуры = "ЗапроситьДанные";
	ТочкаВозврата.Объект = ЭтотОбъект;
	
	// проверка параметра
	Если МассивОжидаемогоВвода = Неопределено Тогда
		
		// первый запуск
		МассивОжидаемогоВвода = Новый Массив;
		
		// ожидаем ввода количества
		НовыйВводДаных = ВводДанныхКлинет.ПолучитьШаблонОжидаемогоВвода();
		
		НовыйВводДаных.Ключ = "КоличествоТовара";
		НовыйВводДаных.Владелец = ЭтаФорма;
		НовыйВводДаных.ОбработчикВвода = "ВводЧисла"; // наш тип обработчика
		НовыйВводДаных.ЧислоДлина = 5;
		
		МассивОжидаемогоВвода.Добавить(НовыйВводДаных);
		
		// спрашиваем
		НовыйВводДаных = ВводДанныхКлинет.ПолучитьШаблонОжидаемогоВвода();
		
		НовыйВводДаных.Ключ = "Вопрос";
		НовыйВводДаных.Владелец = ЭтаФорма;
		НовыйВводДаных.ПостОбработка = Истина; // признак пост-обработки перед следующим диалогом
		НовыйВводДаных.ОбработчикВвода = "ОтветНаВопрос";
		
		МассивОжидаемогоВвода.Добавить(НовыйВводДаных);
		
		// запускаем цикл	
		ВводДанныхКлинет.ЗапуститьЦикл(ТочкаВозврата, МассивОжидаемогоВвода);
		
	Иначе
		
		// цикл нам вернул данные, проверим что это: завершение либо пост-обработка 
		ВводЗакончен = Истина;
		ВводОтменен = Ложь;
		
		Для Каждого ОбработкаВвода Из МассивОжидаемогоВвода Цикл
			
			Если ОбработкаВвода.ФлагЗавершения И ОбработкаВвода.ПостОбработка Тогда
				
				ВводЗакончен = Ложь;
				
				Если ОбработкаВвода.Ключ = "Вопрос" Тогда
					
					// если ответили "Да" то добавим еще итерацию ввода данных
					Если ОбработкаВвода.Результат = КодВозвратаДиалога.Да Тогда
						
						// выбрать склад
						НовыйВводДаных = ВводДанныхКлинет.ПолучитьШаблонОжидаемогоВвода();
						
						НовыйВводДаных.Ключ = "Склад";
						НовыйВводДаных.Владелец = ЭтаФорма;
						НовыйВводДаных.Подсказка = "Наименование области";
						НовыйВводДаных.ОбработчикВвода = "ВводСтроки";
						
						МассивОжидаемогоВвода.Добавить(НовыйВводДаных);
						
					КонецЕсли;
					
					ОбработкаВвода.ПостОбработка = Ложь; // признак завершения пост-обработки
					
				КонецЕсли;
				
			ИначеЕсли ОбработкаВвода.ФлагЗавершения И НЕ ОбработкаВвода.ПостОбработка Тогда
				
				ВводОтменен = (ОбработкаВвода.Результат = Неопределено);	 
				Продолжить;
				
			КонецЕсли; 
			
		КонецЦикла;
		
		Если ВводОтменен Тогда
			Возврат;
		КонецЕсли;
		
		Если ВводЗакончен Тогда
			
			// завершим
			ЗапроситьДанные_ОбработкаВвода(МассивОжидаемогоВвода);
			
		Иначе
			
			// продолжим	
			ВводДанныхКлинет.ЗапуститьЦикл(ТочкаВозврата, МассивОжидаемогоВвода);
	
		КонецЕсли;
	
	КонецЕсли; 
		
КонецПроцедуры

&НаКлиенте
Процедура ЗапроситьДанные_ОбработкаВвода(МассивОжидаемогоВвода)
	// тут уже делаем с результатом ввода что хотим...	
КонецПроцедуры

Собственно все =)  Надеюсь данный пример раскрывает простоту использованиях представленного модуля.

Вот несколько примеров из рабочего проекта.

Пример выбора из произвольной формы

Пример вариативности диалога

Данная разработка представляется как есть. Можете дорабатывать как угодно для своих нужд. Всем успехов!

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. Diversus 2291 13.07.16 12:34 Сейчас в теме
(0) Этот способ не будет работать в web-клиенте.
Вы используете процедуру Выполнить(...) на клиенте.
2. botokash 377 13.07.16 12:49 Сейчас в теме
(1) Diversus, Вы правы. Но веб-клиент не требовался поэтому как есть. На ум только приходит сделать #Если ВебКлиент Тогда и для него делать тоже самое через сервер. Может у кого еще какие идеи будут, что бы оставаться только в рамках клиента.
3. botokash 377 13.07.16 13:10 Сейчас в теме
В принципе можно попробовать сделать через Оповестить(). Если запуск цикла происходит в общем модуле то подключать процедуру возврата как обработчик оповещения, а если в форме - то через стандартную ОбработкаОповещения().
4. Сурикат 379 14.07.16 08:36 Сейчас в теме
Очень сильно радует появление таких статей на ИС=) Не обработок за стартмани, а аля библиотек =)

Не думали, что заполнение структуры "НовыйВводДаных" удобно оберточку в виде процедуры сделать. Чисто из-за подсказок, вы свой код хорошо знаете, а просто пользователям библиотеки придется скакать в общий модуль смотреть как параметры называются =)
5. botokash 377 14.07.16 09:07 Сейчас в теме
(4) Сурикат, была такая мысль, но каюсь - не было времени довести до ума.
(1) Diversus, идею вызовов через Оповестить() реализовал и проверил. Использованию в веб-клиенте быть =) Скоро выложу в этой же публикации, нужно еще пример актуализировать.
6. starik-2005 2832 17.07.16 11:42 Сейчас в теме
Не совсем понял, что за проблемы появляются при отказе от модальности? Чем они отличаются от проблем при ее использовании?
Оставьте свое сообщение

См. также

Расширение: Быстрые отборы через буфер [Alt+C] Копировать список, [Alt+V] Вставить список, [Ctrl+C] Копировать из файлов

Универсальные обработки Инструментарий разработчика Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Копирует в буфер значения из списков, из ячеек отчетов, таблиц, настроек списков, других отборов и вставляет в выбранную настройку отбора. Работает с Объект не найден. Работает как в одной так и между разными базами 1С. Использует комбинации [Alt+C] Копировать список, [Alt+V] Вставить список. Также для копирования данных используется стандартная [Ctrl+C] (например из открытого xls, mxl, doc и т.п. файла скопировать список наименований)

1 стартмани

13.10.2022    11858    89    sapervodichka    92    

114

Система контроля ведения учета [БСП]

Универсальные функции Механизмы типовых конфигураций БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данном материале рассмотрим типовой алгоритм подсистемы контроля учета БСП в конфигурациях на примерах.

18.07.2022    5509    quazare    8    

101

Хитрости СКД. Часть 3

СКД Универсальные функции Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Бесплатно (free)

Столкнулся с тем, что мне приходится писать гору отчетов. Во многих приходится использовать повторяющиеся приемы. Решил написать шпаргалку, которая, надеюсь пригодится не только мне. В этой статье: Объединение ячеек в отчете только на определенном уровне иерархии, Постобработка итогов в табличном документе, Скрытие колонок в зависимости от количества месяцев в периоде.

28.05.2022    6678    milkers    11    

87

Базовые принципы работы с регламентными заданиями подсистем БСП

Универсальные функции БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В очередной публикации рассмотрим некоторые базовые приемы работы с регламентными заданиями в рамках библиотеки стандартных подсистем

22.05.2022    9463    quazare    25    

54

Модули общего назначения - готовые полезные функции и процедуры конфигураций на БСП

Универсальные функции БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

В данной статье я рассматриваю несколько полезных "классических" функций и процедур для работы с данными, которые уже встроены в БСП и готовы к использованию.

25.04.2022    10205    quazare    11    

130

Полезный код для программистов 1С (часть 3). Подготовка печатных форм + подсистема Управление печатью (БСП)

БСП (Библиотека стандартных подсистем) Универсальные функции Платформа 1С v8.3 Бесплатно (free)

Мы все любим 1С, не так ли? Вот дает 1С прекрасный механизм возможности модификации макетов печатных форм в БСП. А из всех рекомендаций это получение макета и заполнение параметров областей. И вы спросите: "А что не так... ты печатные формы накодить не можешь без указаний сверху?". Да вот в том то и дело, что я могу все. А вот пользователям от такого механизма пользы 0, если из всех доступных изменений остаются только шрифты, да текст произвольный накинуть. А ведь можно больше, надо только соблюдать несколько правил при подготовке печатных форм...

07.03.2022    9896    vandalsvq    0    

56

Конвертируем печатную форму pdf в картинку (jpg, gif, png и прочие) на сервере

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Была поставлена интересная задача конвертировать печатную форму в файл картинку. По условию задачи клиенту на почту нужно присылать только файл картинку (jpg, gif).

22.12.2021    6371    John_d    25    

46

Несколько простых приемов для удобной работы в конфигураторе

Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Бесплатно (free)

Простая и удобная среда разработки 1С:Предприятия позволяет практически любому человеку начать работать под капотом 1С - в конфигураторе. Время идет, новички становятся программистами, специалистами, а об удобных приемах работы узнают годами, по ходу своего карьерного пути. А здорово было бы, если бы все знали удобные приемы в начале своего пути? Эти несколько приемов будут полезны новичкам, так как они затрагивают ту область работы, с которой приходится сталкиваться в начале карьеры.

12.11.2021    13619    acces969    95    

142

Добавление электронной подписи в документ PDF

Универсальные функции Платформа 1С v8.3 1С:Бухгалтерия 3.0 Абонемент ($m)

Как добавить подпись прямо в файл PDF, чтобы не нужно было файлы подписи передавать отдельно.

1 стартмани

26.08.2021    15836    37    fotov    19    

41

Из Word в табличный документ

Универсальные функции Платформа 1С v8.3 Платформа 1C v8.2 Бесплатно (free)

Быстро и просто: текст, списки, таблицы. Готовый код

18.08.2021    4772    Yashazz    6    

64

Префиксация объектов - полезный типовой функционал БСП

Универсальные функции БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Россия Бухгалтерский учет Управленческий учет Бесплатно (free)

В данной публикации предлагаю рассмотреть основные типовые возможности библиотеки стандартных подсистем (БСП), касаемые префиксации объектов конфигураций.

21.06.2021    10949    quazare    4    

61

Модель запроса

Универсальные функции Платформа 1С v8.3 Запросы Конфигурации 1cv8 Россия Абонемент ($m)

Работа с текстом запроса напрямую не позволяет просто обратиться к определенному полю, таблице или условию. Однако, работая со схемой, можно добавить к существующему условию новое или вообще включить его в состав другой группы. Как ни странно, в типовых решениях часто можно встретить код работы с текстом запроса наряду с использование схемы. Возможно появление удобной библиотеки или нового объектного подхода позволит отказаться от работы с текстом совсем, а код построения запроса будет аутентичен исходному запросу, но без избыточности и доступный для простой модификации.

1 стартмани

01.03.2021    5210    kalyaka    26    

47

Сохранение настроек

Универсальные функции БСП (Библиотека стандартных подсистем) Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Делюсь еще одним не самым очевидным способом хранения настроек в базах на БСП без доработки конфигурации. Весь код в статье.

22.11.2020    9866    ixijixi    8    

67

Произвольные колонтитулы и повтор шапки таблицы в табличном документе (функция)

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

Пример рекурсивной функции, при помощи которой в табличный документ можно выводить верхний или нижний колонтитулы с произвольным содержимым, а также делать повтор шапки таблицы (или таблиц, если их несколько).

07.10.2020    13574    ellavs    7    

39

Лайфхаки для разработчиков 1С. Часть 1

Универсальные функции Механизмы платформы 1С Платформа 1С v8.3 Россия Бесплатно (free)

Собрали 20 лайфхаков, которые используют наши программисты при работе с 1С. Формы, контрагенты, СКД, процедуры, глюки платформы и многое другое. В этой статье публикуем первую часть.

30.09.2020    9687    Neti    47    

69

Самый простой парсинг и обработка веб-страниц в 1С

WEB-интеграция Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Рассмотрим самый простой парсинг веб-страниц средствами платформы 1С и еще некоторые полезные приемы работы с веб-страницами.

07.08.2020    25002    Infostart    30    

146

Полезные встроенные функции для работы с печатными формами и не только на УТ 11.4 и БП 3.0 (сравнение)

Универсальные функции Платформа 1С v8.3 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 Россия Бесплатно (free)

В данном обзоре приведу примеры встроенных используемых функций для работы с печатными формами на примерах конфигураций Управление торговлей 11.4 и Бухгалтерия 3.0.

10.07.2020    15196    quazare    7    

93

Форма выбора (подбор) в управляемых формах

Универсальные функции Работа с интерфейсом Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Россия Бесплатно (free)

Разбор небольших примеров того, как правильно открывать форму выбора (подбора) в управляемых формах, не прибегая к модальным окнам.

08.05.2020    179605    user5300    40    

290

Получаем уровень группировки ячейки табличного документа

Универсальные функции Платформа 1С v8.3 Бесплатно (free)

Табличные документы отчетов часто формируются с разными уровнями группировок и иногда требуется определить номер уровня ячейки. Предлагаю свои функции, которые позволяют определить, как горизонтальный, так и вертикальный уровень группировки любой ячейки табличного документа.

23.03.2020    8786    maxx    16    

57

Дополнительные функции для 1С:Документооборот

Универсальные функции Платформа 1С v8.3 1С:Документооборот Управленческий учет Абонемент ($m)

В данной публикации я хочу поделиться расширением, которое содержит дополнительные функции (доработки) для 1С:Документооборот.

1 стартмани

24.01.2020    30054    215    pavelpribytkin96    47    

56

Сходство Джаро - Винклера. Нечеткое сравнение строк

Универсальные функции Платформа 1С v8.3 Россия Бесплатно (free)

В области информатики и статистики сходство Джаро - Винклера представляет собой меру схожести строк для измерения расстояния между двумя последовательностями символов. В публикации рассмотрены некоторые особенности алгоритма, и представлен вариант его реализации на языке 1С.

25.12.2019    11323    brooho    21    

170

Автоматическое создание связанного объекта в базе 1С: Документооборот через бесшовную интеграцию

Универсальные функции Механизмы типовых конфигураций Платформа 1С v8.3 1С:Документооборот 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Зарплата и Управление Персоналом 3.x Бесплатно (free)

При настройке бесшовной интеграции с базой документооборота часто возникает задача - пользователи просят автоматически создавать связанный объект в базе документооборота по некоторому условию. В данной публикации я хочу поделиться своим решением данной задачи.

23.12.2019    6157    pavelpribytkin96    3    

39

Быстрое создание наполненных коллекций

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Разберем самые частые способы создания коллекции, значения которой известны заранее. И сравним скорость их выполнения.

28.10.2019    9153    SeiOkami    69    

68

Преобразование XML в таблицу значений или иной объект 1С методом XSL преобразования

Универсальные функции Файловый обмен (TXT, XML, DBF), FTP Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Сразу открою интригу, напрямую прочитать XML, не содержащий объект 1С, не удастся. Статья раскрывает способы привести XML к формату, который возможно прочитать средствами платформы.

24.10.2019    21376    kraspila    33    

58

Обертка функций Excel на русском. Ускорение процесса разработки.

Загрузка и выгрузка в Excel Универсальные функции Платформа 1С v8.3 Бесплатно (free)

Устали переключаться с русского на английский и обратно при работе с таблицами Excel из 1С? Сборка наиболее необходимых функций и методов работы с Excel, обернутых в функции 1С на русском языке.

24.10.2019    8950    DmitryKotov    6    

56

Вывод QR-кода типовыми средствами.

Сканер штрих-кода Универсальные функции Платформа 1С v8.3 1С:Комплексная автоматизация 1.х 1С:Управление торговлей 10 1С:Управление производственным предприятием Абонемент ($m)

Вывод QR-кода типовыми средствами. На данный момент очень часто нужно вывести в печатную форму QR-код. Показываю как на примере типового кода из УТ11 это сделать. Можно использовать в любых конфигурациях с обычными формами.

1 стартмани

21.10.2019    66356    137    Емельянов Алексей    57    

51

Методика независимой системы "Подписки на события"

Универсальные функции Платформа 1С v8.3 1С:Управление производственным предприятием Бесплатно (free)

В этой небольшой статье я хочу вам предложить пошаговое описание разработки системы управления "Подписками на события" для документов. Цель разработки - возможность управления подписками в вашей конфигурации, не прибегая к программированию через конфигуратор. Думаю, будет полезно и интересно!

17.10.2019    18796    aximo    35    

72

Полезные процедуры и функции для программиста

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Россия Бесплатно (free)

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    48003    HostHost    41    

284

Документ на документ. Автоматическое создание связанных документов

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Пример решения простой и распространенной задачи - автоматическое создание документа на основании другого документа.

16.09.2019    19513    Infostart    36    

75

"Хочу универсально!" [Часть 1]

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Бесплатно (free)

Сентябрьская серия статей про то, как начинающий разработчик Вася проходит путь от простой задачки к созданию своего механизма. На этот раз - открытие значения из текущей колонки.

02.09.2019    11648    SeiOkami    35    

76

Запуск фонового задания во внешней обработке. Отключение предупреждений защиты от опасных действий в фоновом задании

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Как запустить фоновое задание из модуля внешней обработки используя БСП. Как отключить безопасный режим и сообщения защиты от опасных действий независимо от профиля безопасности пользователя в фоновом задании во внешней обработке.

2 стартмани

24.08.2019    24692    BenGunn    29    

132

10 способов получить модуль числа (а может, и больше)

Математика и алгоритмы Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Пишем функцию вычисления модуля числа. Сколько способов существует? Давайте посчитаем!

1 стартмани

11.07.2019    26728    sam441    38    

56

Реализуем Стек, Очередь и Приоритетную очередь в 1С

Математика и алгоритмы Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Россия Бесплатно (free)

В статье рассматриваются способы реализации таких абстрактных структур данных, как стек, очередь и приоритетная очередь, используя готовые типы данных 1С. Выявляются "узкие" места, сложные моменты в реализации и сравнивается скорость работы.

24.06.2019    19652    RonX01    70    

88

Экспортные процедуры и функции общих модулей БП 3.0, ЗУП 3.1, УТ 11

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Россия Абонемент ($m)

Таблицы экспортных процедур и функций общих модулей конфигураций БП КОРП 3.0, ЗУП КОРП 3.1, УТ 11 + обработка по формированию такой таблицы из любой конфигурации.

14.06.2019    19210    35    SanchoD    33    

42

Работа с графической схемой в объектной модели DOM

Универсальные функции Платформа 1С v8.3 Управляемые формы Абонемент ($m)

Пример кода для работы с графической схемой в объектной модели DOM, платформа 8.3.12.

1 стартмани

04.06.2019    8876    botokash    19    

51

Создание внешней печатной формы в формате документа Word

Адаптация типовых решений Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

В статье написано, как создать внешнюю печатную форму (для конфигураций с БСП) в формате Word.

1 стартмани

17.05.2019    40551    ВикторП    28    

68

Программное формирование картинки в 1С:Предприятие 8.3.9 (ПотокВПамяти / ЗаписьДанных)

Универсальные функции Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

В статье представлен код программного формирования картинки (двоичные данные) без всяких внешних компонент, без формирования строки Base64, используя лишь встроенные механизмы 1С предприятие 8.3.9 (объекты ПотокВПамяти и ЗаписьДанных). Сам по себе код формирования картинки не несёт ничего нового. Всё описано в википедии. Захотелось попробовать новые методы, но никак не доходитили руки. В приложении обработка практически с этим же кодом.

1 стартмани

16.05.2019    13924    yku    11    

67