Расширения конфигурации и РИБ, друзья или враги? Или как мы передаем расширения подчиненным РИБ узлам

Публикация № 705498

Разработка - Обмен данными 1С - Распределенная БД (УРИБ, УРБД)

РИБ расширение конфигурации обновление расширения

Читая комментарии к курсу касательно новых возможностей расширений конфигурации, которые привнес релиз 8.3.11, на одном из известных сайтов с курсами, я обратил внимание, что коллегам приходится отказываться от расширений из-за решения перейти на РИБ. Мы сами относительно недавно начали переходить на РИБ, и мы также активно пользуемся расширениями и в этой статье я хотел бы рассказать, как мы решили эту проблему.

Компания, в которой я в данный момент работаю, решила активно пользоваться расширениями, начиная с 8.3.8 для облегчения обновления 1С Розница, вынеся в расширения большую часть интерфейсных и не только модификаций. До недавнего времени, вся наша филиальная сеть магазинов работала напрямую через веб-сервер, но из-за того что покрытие интернетом не везде хорошее, стали постепенно задумываться о разворачивании РИБ узлов в таких проблемных магазинах и тут же встал вопрос, "Что делать с расширением?" и так как мы сделали обмен через веб-сервис, решили "А почему бы не передавать расширение узлу через веб-сервис?".

Теперь я хочу представить вам то, как мы решили эту проблему.

В нашем веб-сервисе мы добавили функцию "GetExtandedConfig" с параметрами:

  • Name, Направление передачи: Входящий, Тип: string - Имя расширения
  • Hash, Направление передачи: Входящий, Тип: string - Хеш установленного расширения либо Неопределено если не установлено
  • Result, Направление передачи: Выходной, Тип: boolean - Результат операции
  • Data, Направление передачи: Выходной, Тип: ValueStorage (http://v8.1c.ru/8.1/data/core) - Двоичные данные установленного расширения центральной базы (если изменений расширения нет, то Неопределено)
  • Функция возвращает тип: string - Описание проблемы, если таковая возникла

В коде функции мы написали это:

// Соответствует операции GetExtandedConfig
Функция ПолучитьРасширениеКонфигурации(ИмяРасширения, ХешСумма, Результат, ИсхДанные)

	УстановитьПривилегированныйРежим(Истина); // Пользователь вебсервиса не полноправный пользователь, компенсируем это
	
	Если ПустаяСтрока(ИмяРасширения) Тогда
		
		Результат = Ложь;
		Возврат "Не указано имя расширения!";
		
	КонецЕсли;
	
	Расширения = РасширенияКонфигурации.Получить(Новый Структура("Имя", ИмяРасширения)); // Ищем расширение по полученному имени
	
	Если Расширения.Количество() <= 0 Тогда
		
		Результат = Ложь;
		Возврат "Расширение по указанному имени не найдено!";
		
	КонецЕсли;
	
	ТребуемоеРасширение = Расширения[0];
	
	Если ПустаяСтрока(ХешСумма) или ХешСумма <> Base64Строка(ТребуемоеРасширение.ХешСумма) Тогда // Либо первое получение, либо расширение изменилось
		
		Результат = Истина;
		ИсхДанные = Новый ХранилищеЗначения(ТребуемоеРасширение.ПолучитьДанные()); // Сжимать смысла нет, только ресурсы тратить
		Возврат "Доступно обновление расширения";
		
	КонецЕсли;
	
	Результат = Истина;
	Возврат "Нет обновлений расширения";
	
КонецФункции // ПолучитьРасширениеКонфигурации()

На "клиентской" стороне, после обмена данными через веб-сервис, проверяем, есть ли изменения в расширении и код выглядит так:

Функция ДоступнаЗащитаОтОпасныхДействий() Экспорт

	СисИнфо = Новый СистемнаяИнформация;
	Возврат ОбщегоНазначенияКлиентСервер.СравнитьВерсии(СисИнфо.ВерсияПриложения, "8.3.9.2033") >= 0;

КонецФункции // ДоступнаЗащитаОтОпасныхДействий()

Процедура ПроверитьИОбновитьРасширениеКонфигурации(ПроцессорОбмена) Экспорт

	// ПроцессорОбмена - WS-ссылка с установленным соединением
	
	ПоддержкаЗащитыОтОпасныхДействий = ДоступнаЗащитаОтОпасныхДействий(); // Проверим, поддерживает ли платформа защиту от опасных действий
	
	Попытка
		
		МассивОбновляемыхРасширений = Новый Массив;
		Расширения = РасширенияКонфигурации.Получить(); // Получаем список установленных расширений
		
		Для Каждого Расширение из Расширения Цикл
			
			МассивОбновляемыхРасширений.Добавить(Новый Структура("Имя, УникальныйИдентификатор, ХешСумма", Расширение.Имя, Расширение.УникальныйИдентификатор, Расширение.ХешСумма));
			
		КонецЦикла;
		
		Если МассивОбновляемыхРасширений.Количество() <= 0 Тогда // Если расширений в базе нет, добавляем в список "предопределенное" расширение, наше основное
			
			МассивОбновляемыхРасширений.Добавить(Новый Структура("Имя, УникальныйИдентификатор, ХешСумма", "Экстра", Неопределено, Неопределено));
			
		ИначеЕсли ОбменДаннымиСервер.ТребуетсяУстановкаОбновления() Тогда
			
			// Расширение уже есть, но сейчас требуется обновление конфигурации, по этому не будем пока обновлять расширение.
			// Сделано так, чтоб при первом запуске из начального образа базы, даже если есть изменения конфигурации,
			// расширение бы скачалось и установилось, а если расширение есть, то не качаем его пока не применим изменения.
			
		КонецЕсли;
		
		Для Каждого Расширение из МассивОбновляемыхРасширений Цикл
			
			Результат = Неопределено;
			ВходящиеДанные = Неопределено;
			
			// Делаем запрос к веб-сервису
			СообщениеОбмена = ПроцессорОбмена.GetExtandedConfig(Расширение.Имя, Base64Строка(Расширение.ХешСумма), Результат, ВходящиеДанные);
			
			Если Результат и Не ПустаяСтрока(СообщениеОбмена) Тогда
				
				// Получили положительный ответ и что не было сообщений, а так-же проверим, получили ли мы сами данные
				Если ВходящиеДанные = Неопределено Тогда
					
					Продолжить;
					
				КонецЕсли;
				
			Иначе 
				
				Сообщить("При получении обновления расширения: " + Расширение.Имя + " была получена ошибка: " + СообщениеОбмена);
				Продолжить;
				
			КонецЕсли;
			
			ДанныеРасширения = ВходящиеДанные.Получить(); // Получаем двоичные данные из хранилища значения
			
			// Получены данные расширения, обработаем
			Если Расширение.УникальныйИдентификатор = Неопределено Тогда // Расширение ещё не установлено
				
				РасширениеВБазе = РасширенияКонфигурации.Создать(); // Создаем новое расширение
				РасширениеВБазе.БезопасныйРежим = Ложь;
				
				Если ПоддержкаЗащитыОтОпасныхДействий Тогда
					
					РасширениеВБазе.ЗащитаОтОпасныхДействий.ПредупреждатьОбОпасныхДействиях = Ложь; // Отключаем защиту от опасных действий если поддерживается
					
				КонецЕсли;
				
			Иначе // Получаем уже установленное расширинение старой версии
				
				Раширения = РасширенияКонфигурации.Получить(Новый Структура("УникальныйИдентификатор", Расширение.УникальныйИдентификатор));
				
				Если Расширения.Количество() > 0 Тогда
					
					РасширениеВБазе = Расширения[0];
					
				КонецЕсли;
				
			КонецЕсли;
			
			Если РасширениеВБазе = Неопределено Тогда
				
				Сообщить("При обновлении раширения произошла ошибка, не удалось получить расширение: " + Расширение.Имя);
				Продолжить;
				
			КонецЕсли;
			
			// Проверим, можно ли без ошибок применить расширение
			ОшибкиВРасширении = РасширениеВБазе.ПроверитьВозможностьПрименения(ДанныеРасширения); // Возвращает ИнформацияОПроблемеПримененияРасширенияКонфигурации
			
			Если ОшибкиВРасширении.Количество() > 0 Тогда
				
				Сообщить("При проверке расширения " + Расширение.Имя + ", возникли ошибки:");
				
				// Покажем полный список ошибок
				Для Каждого Ошибка из ОшибкиВРасширении Цикл
					
					Сообщить("(" + Ошибка.Важность + ") " + Расширение.Имя + ": " + Ошибка.Описание);
					
				КонецЦикла;
				
				// Не будем его устанавливать
				Продолжить;
				
			КонецЕсли;
			
			// Всё хорошо! Обновляем расширение!
			РасширениеВБазе.Записать(ДанныеРасширения);
			Сообщить("Успешно обновлено расширение: " + Расширение.Имя + ", получена версия: " + РасширениеВБазе.Версия);
			
		КонецЦикла;
		
	Исключение
		
		Сообщить("Ошибка в процедуре обновления расширения: " + ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
		
	КонецПопытки;
	
КонецПроцедуры

Вот и всё! Но, как и в каждой бочке, и тут есть ложка дёгтя, о чем и хотелось отдельно упомянуть.

Проблемы механизма

Одна из главных проблем механизма, это то что он не связан тесно с передачей изменений конфигурации, а работает параллельно с ним и в связи с чем может возникнуть ситуация когда к примеру ещё не передан новый предопределенный элемент (Справочника, ПВХ и пр.), а обновленное расширение к нему уже обращается, и контроль "применимости" расширения не видит этой проблемы. Но я думаю, что это не существенная проблема, учитывая, сколько данный механизм решает проблем, да и после получения узлом недостающих данных, проблема уходит.

Заключение

Данный механизм не претендует на какую-либо уникальность, скорей желание показать, что и такую задачу можно разрешить достаточно простым способом. Также я хотел бы сказать, что этот механизм был сделан в спешке из-за наступления дедлайна на пятки и стоило добавить контроль минимальной версии конфигурации для того чтобы не возникло ситуации описанной выше да и качество кода оставляет желать лучшего.

Будут вопросы, обращайтесь!

PS: Если вы используете обмен через файлы (в той или иной вариации), то вы можете при отправке данных центральной базе, добавлять информацию о хеше установленного расширения, а центральной проверять эту добавку и по мимо полезных данных обмена, выгружать расширение актуальной версии. Практически так-же как и БСП добавляет свои данные в сообщение обмена. Ознакомится с примерами дополнения сообщения обмена своими данными, можно ознакомится в статье: https://its.1c.ru/db/metod8dev#content:2278:hdoc Кстати, 8.3.12 делает именно так, она передает полностью расширение, а не изменившуюся часть.

Специальные предложения

Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. aspirator23 437 26.11.17 09:51 Сейчас в теме
РИБ и расширения - больная тема. В узлах они точно должны быть, если курс взят на расширения. Вероятно их все же включат в обмены. Но когда это произойдет неизвестно.
2. markers 250 26.11.17 12:18 Сейчас в теме
(1) Возможно-возможно и хоть и расширения сами по себе очень легкие (наше весит порядка 1.2 мб), но всё-же хотелось бы чтобы передавалась разница, а не целиком расширение. Но ждать когда это чудо произойдет, мы не можем. Тем-более мы всё ещё сидим на 8.3.8 ибо пока не можем перейти на более новые версии (не работает механизм авто установки новой версии тонкого клиента, скачивает и потом не устанавливает, а точек у нас много), хотя хотелось бы, в 8.3.9 и в 8.3.10 очень много вкусного есть, не говоря уже о 8.3.11
3. aspirator23 437 26.11.17 15:52 Сейчас в теме
(2) В 8.3.12 расширения через РИБ скорее всего не будет. Следовательно минимум год выкручиваться придется альтернативными способами.
4. markers 250 17.01.18 09:43 Сейчас в теме
(3) К слову, таки добавили
5. aspirator23 437 17.01.18 13:01 Сейчас в теме
9. wolder 111 11.02.20 04:32 Сейчас в теме
(5) А что толку то. Я вообще не хотел использовать расширения в узлах РИБ, на типовой УТ 11.4 но при синхронизации программа писала на существование расширений не участвующих в обмене РИБ (так как расширения имеют модификации и новые реквизиты справочников и документом)пришлось снимать с поддержки УТ и ставить галочку обмена в планеОбмена.СНастройками, так же поставил галочку на "Используется в распределенной ИБ" каждого расширения, сформировал базу узла, пошел обмен между узлом и ЦБ, а как только стал вносить изменения в расширения ЦБ, обмен вновь стал ругаться.
История описана вот тут: https://xn----1-bedvffifm4g.xn--p1ai/news/2018-04-19-transfer-of-extensions-to-peripheral-nodes/?comments#comment-821091
Так, что не на много все изменилось, да "косметические" расширения может и будут без проблем мигрировать, а вот с модификацией типовых объектов уже нет.
6. astrallight 06.08.18 05:06 Сейчас в теме
Хорошие новости! "Реализована возможность использования расширений конфигурации в распределенной информационной базе. Для плана обмена реализовано свойство ВключатьРасширенияКонфигурации.
Для расширения конфигурации реализованы свойства ИспользуетсяВРаспределеннойИнформационнойБазе и ГлавныйУзел. Источник: http://downloads.v8.1c.ru/content//Platform/8_3_12_1567/
misha226; +1 Ответить
7. psamt1k 11.06.19 08:19 Сейчас в теме
1. Дико извиняюсь за поднятие старой темы, но

ПоддеРжкаЗащитыОтОпасныхДействий

2. Спасибо, за механизм. Очень помогает (количество РИБ - порядка 10)
8. markers 250 11.06.19 11:47 Сейчас в теме
(7) Спасибо за замечание, у меня такое бывает ;) И хорошо что кому-то принес пользу ;)
10. wolder 111 11.02.20 06:32 Сейчас в теме
По своему опыту расскажу, что:
Имеем УТ 11.4.11.63 ЦБ была типовая :) так как для планаОбмена.СОтборами пришлось ставить галочку "Включать расширения конфигурации" и на самих расширениях ставить галочки "Используется в распределенной ИБ", только тогда удалось сформировать файл базы данных узла. Обмен между ЦБ и узлом пошел, всё хорошо, в узле есть расширения.
Но на этом проблема не закончилась, так как понятное дело, что в ЦБ придется делать модификации расширений и что-то дорабатывать в них. Так и получилось, внес изменения в расширения ЦБ, сохранил, жму кнопку "Синхронизация" и она мне выдает "Ошибка чтения файла сообщения обмена: Данные принимаются от узла с другим набором расширений, меняющих структуру данных.
Необходимо произвести перенос расширений конфигурации в узел.
{Обработка.КонвертацияОбъектовРаспределенныхИнформационныхБаз.МодульОбъекта( …. . .. . ….. );
по причине:
Данные принимаются от узла с другим набором расширений, меняющих структуру данных."
Необходимо произвести перенос расширений конфигурации в узел.
———————————————————————————-
Тут я поторопился, решил выгрузить расширения из ЦБ и загрузить в узел, но как вы уже успели догадаться это не возможно, так как конфигурация узла закрыта для изменений в том числе расширений. Т.е. нельзя загрузить расширения в узел.
Выполнять танцы с бубном по снятию признака узла бд, после обновить расширения, а затем вернуть признак узла, это крайне не удобно так как периодичность внесения изменений в ЦБ расширения будет огромная.
Т.е. тут нужно сразу понять, что сообщение об ошибках обмена началось ещё со стороны ЦБ в момент синхронизации с узлом. Очевидно это та самая ошибка по контрольной сумме версий конфигурации, из-за чего становиться физически очень сложный обмен РБД при наличии расширений конфигурации и дальнейших их модификаций. Причем и при не желании переносить расширения ЦБ в узлы, нам это приходится всё равно делать этот перенос с изменением и снятием с поддержки конфигурации ЦБ и установкой в план обмена переноса расширений, так и при наличии принудительного обмена расширениями они фактически не могут мигрировать между конфигурациями ЦБ и узла, так как появляется расхождение контрольной суммы. Фатальная ситуация.

Стал курить, читать и мельком наткнулся на сообщения коллег о разности поведения механизмов обмена между нажатием кнопки "Синхронизировать" и "Выполнить сценарий".
Удалил файлы обмена старые, нажал "Выполнить сценарий" в ЦБ - всё выгрузилось, т.е. модифицированное расширение выгрузилось в файл обмена для узла, и на узле уже с надеждой жал кнопку "Выполнить сценарий" вместо "Синхронизация" и загрузилось и по журналу регистрации было написано перезагрузить базу (узла) для принятия расширений, перегрузил, ещё раз запустил, опять кнопку "Выполнить сценарий" и всё, он прошел удачно!!!!
11. markers 250 11.02.20 07:50 Сейчас в теме
(10) Вы правы, в случае добавления объектов/реквизитов в расширении, обмен в РИБ работает паршиво. Сам с этим сталкивался из-за чего возвращался к старой классической схеме изменения конфигурации. Тут совет может быть только один - не создавать объекты и реквизиты в расширении (и не делать их модификации), только расширять формы, модули и пр. в общем то, что сложней всего обновить. Реквизиты и объекты, особенно новые, не создают больших проблем при обновлении.
12. malikov_pro 602 14.11.20 20:57 Сейчас в теме
(11) Возможно ли вашу наработку оформить в виде расширения и опубликовать на github? Она частично связана с моим исследованием по доставке расширений до баз клиента (близкое к пакетнотному менеджеру). Не силен в РИБ, при этом предположу что можно организовать блокировку по получению нового пакета данных и наличия актуального расширения.
13. markers 250 15.11.20 03:41 Сейчас в теме
(12) да. С ссылкой на данную публикацию и автора. Так же скиньте потом ссылку на ваш GitHub. Спасибо!
14. malikov_pro 602 15.11.20 08:53 Сейчас в теме
(13) https://github.com/malikov-pro/1c_transfer_extention, под Apache-2.0 License
Перенес код, с обвзякой в виде сервисов и обработок буду позже разбираться, созвместно с доставкой расширения в центральную базу.
Оставьте свое сообщение

См. также

РИБ 200 узлов. Середина пути Промо

Распределенная БД (УРИБ, УРБД) v8 Розница Россия Бесплатно (free)

Между настройкой и поддержкой РИБ на 2 узла и на 10 большой разницы нет, а вот когда число удаленных точек переваливает за сотню, приходится решать уже совсем другие вопросы

25.10.2016    39976    comol    215    

Восстановление узла РИБ по магазинам на примере 1С:Розница 2.3.4

Распределенная БД (УРИБ, УРБД) v8 Розница Россия Бесплатно (free)

После очередного обновления узла РИБ столкнулся с ошибкой, РИБ перестал работать. Начитался много статей про восстановление РИБа, ни одна толково не помогла. Поэтому не мытьем, так катанием сам разобрался, как же быстро восстановить РИБ, чтобы он заработал.

15.06.2020    3988    maxon    1    

Восстановление данных 1С8 при помощи механизма РИБ

Распределенная БД (УРИБ, УРБД) Тестирование и исправление v8 Бесплатно (free)

Предлагаю сообществу способ восстановления утраченных данных из бэкапа используя механизм РИБ. Зачастую наличие бэкапа базы не позволяет просто взять и откатить состояние базы на утро или вечер предыдущего дня. Бывает так, что утерю важных данных заметили спустя 2 дня, и свежий бекап нам не поможет. Предлагаю относительно простой способ переноса определенных данных из резервной копии базы в рабочую. Не надо писать обработку по выгрузке, загрузке данных или по переносу через COM-соединение. Единственное условие: в базе должны работать обмены РИБ.

13.06.2020    1523    Vortigaunt    1    

Как мы РИБ на веб-сервисы переводили

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Россия Бесплатно (free)

Решение проблем обмена РИБ с 10+ баз с помощью веб-сервисов и базы обмена.

13.05.2020    4047    RSConsulting    22    

Обмен по расписанию типовыми средствами. Промо

Распределенная БД (УРИБ, УРБД) Обмен через XML Перенос данных из 1C8 в 1C8 v8 1cv8.cf Россия Бесплатно (free)

Часто перед интеграторами стоит задача организовать автообмен (по расписанию или при наступлении какого-либо события) данными между различными конфигурациями. В этой статье я попробую изложить простую инструкцию, как это можно сделать средствами, заложенными в типовые конфигурации 1С (ЗУП, БП, УПП и т.д.). Для обмена используется подсистема "Обмен данными" из БСП

20.06.2012    103278    kser87    52    

Установка расширений конфигурации, модифицирующих структуры данных, в фоновом задании запрещена

Распределенная БД (УРИБ, УРБД) v8 Бесплатно (free)

Вариант решения проблемы синхронизации узла при передаче изменений метаданных расширения, используемого в распределенной информационной базе.

20.02.2020    2944    fristaller    2    

И снова "Конфигурация узла распределенной ИБ не соответствует ожидаемой"

Распределенная БД (УРИБ, УРБД) Обмен данными 1С v8 Бесплатно (free)

Конфигурация узла распределенной ИБ не соответствует ожидаемой. Приведен очередной способ устранения этой ошибки, возникший не в результате сбоев в работе оборудования или при обмене, а в результате обновления платформы 1С.

05.11.2019    6300    Kobra_RU    11    

Cannot insert duplicate key. Кто виноват и что делать

Распределенная БД (УРИБ, УРБД) Тестирование и исправление v8 Бесплатно (free)

Ошибка "CANNOT INSERT DUPLICATE KEY" в базах 1С и связанная с ней "магия".

25.02.2019    22192    YPermitin    32    

Особенности обмена данными с использованием "ручной" регистрации Промо

Распределенная БД (УРИБ, УРБД) Перенос данных из 1C8 в 1C8 v8 1cv8.cf Бесплатно (free)

Эта статья рассчитана на программистов, которые используют обмен данными с помощью метода "ВыбратьИзменения" и последующую их запись. Только для планов обменов, имеющих "ручную" регистрацию.

14.01.2013    33849    logarifm    6    

РИБ и расширения

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Абонемент ($m)

Как заставить работать РИБ с расширением.

1 стартмани

20.02.2019    22481    30    RocKeR_13    44    

Как отвязать информационную базу от РИБа

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Россия Бесплатно (free)

Краткая инструкция для новичков о том, как в 2 клика отвязать информационную базу от РИБа.

03.05.2018    17376    user861285    11    

Magic Updater. Система администрирования распределенной сети 1С:РИБ

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

Обновления 1С стали для Вас адом? Каждодневная "война" за получение данных из всех торговых точек? Обмены то проходят, то не проходят? Разрушилась база, а резервной копии нет и не было? Если у Вас тоже регулярно возникают данные вопросы - найдите пару минут прочитать статью ниже.

15.08.2017    17734    comol    15    

УНФ РИБ Промо

Распределенная БД (УРИБ, УРБД) Перенос данных из 1С7.7 в 1C8.X v8 УНФ Россия Бесплатно (free)

В типовой УНФ нет РИБа. Исправляем этот недостаток, используя УТ 11 и ИТС. Статья подойдет для настойки распределенки в любой конфе на базе БСП.

16.10.2012    39882    ptkrzy    23    

Восстановление обмена в РИБ. Запущенный случай

Распределенная БД (УРИБ, УРБД) v8 Россия Бесплатно (free)

Удачная попытка восстановить обмен в РИБ при большом количестве объектов обмена и ошибках при обмене.

03.04.2017    15288    peterxx    14    

Что делать, если параметр запуска /resetmasternode приводит к вылету с дампом

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

Для тех, кто столкнулся с проблемой отключения узловой базы от главного узла через параметр запуска /ResetMasterNode.

01.04.2017    17666    therva    4    

Проблема с обновлением типовой конфигурации УТП 1.2 (Украина) в дочернем узле

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Украина Бесплатно (free)

При обновлении конфигурации в дочернем узле РБД , в случае, если обновление добавляет предопределенные элементы справочников, невозможно загрузить файл обмена стандартными средствами

15.02.2017    12938    bulpi    4    

Автоматическое обновление конфигурации в узлах РИБ Промо

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

При поднятии РИБ одна из существенных проблем – как автоматически обновлять конфигурацию на периферийных узлах? Научить простых пользователей заходить в конфигуратор довольно проблематично. Предлагаю довольно простое, на мой взгляд решение с минимальными доработками в конфигурацию.

14.07.2012    53353    fixin    75    

Конфигурация узла распределенной ИБ не соответствует ожидаемой

Распределенная БД (УРИБ, УРБД) v8 Россия Бесплатно (free)

Есть куча материалов, где описано решение возникающей ошибки при обмене с РИБ, но ни одно не помогло. Пришлось включить мозг, и, о чудо, было найдено простое решение.

26.01.2017    25049    virtmon    34    

Планы обмена. Управляемый режим блокировок

Распределенная БД (УРИБ, УРБД) v8 Бесплатно (free)

Статья о том, как устроен объект конфигурации 1С:Предприятие 8 "План обмена", в том числе на уровне СУБД SQL Server. Анализируются особенности его использования при управляемом режиме блокировок.

28.11.2016    41554    zhichkin    17    

Highload обмен данными: постановка задачи

Производительность и оптимизация (HighLoad) Распределенная БД (УРИБ, УРБД) v8 Бесплатно (free)

Цели статьи: определить, что такое "highload обмен", описать типовой сценарий обмена, сформулировать основные требования к обменам такого типа и предложить методику оценки производительности (пропускной способности).

04.11.2016    14297    zhichkin    3    

Корректное отключение от главного узла РИБ и создание самостоятельной БД. Быстрое создание/восстановление узла РИБ без выгрузки начального образа для конфигураций на основе БСП

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

В публикации описан один из способов создания тестовой БД для разработки с актуальными данными, быстрого восстановления работоспособности РИБ при "падении" одного из узлов, или "быстрого" создания/восстановления узла РИБ без выгрузки начального образа для конфигураций на основе БСП.

16.02.2016    98886    asg.aleks    12    

Автоматическое обновление конфигурации в узлах РИБ

Распределенная БД (УРИБ, УРБД) v8 Бесплатно (free)

Вариант автоматического обновления конфигурации (без участия пользователей) периферийной базы РИБ. Очень простой способ без необходимости внесения кода в конфигурацию 1С. В дополнение к публикации http://infostart.ru/public/143517/. Спасибо автору, навел на эту идею!

22.01.2016    24440    Kitri    4    

Отладка конвертации данных 2.1 в конфигурациях, построенных на БСП 2.1 (БП 3.0, УТ 11 etc.)

Практика программирования Распределенная БД (УРИБ, УРБД) Обмен через XML БСП (Библиотека стандартных подсистем) v8 1cv8.cf Бесплатно (free)

Отладка процесса выгрузки/загрузки данных при проведении синхронизации в новых конфигурациях 1С может вызвать (у меня вызвала) некоторые затруднения. О них и пойдёт речь.

29.10.2015    40339    NittenRenegade    23    

Как я восстанавливал разрушенную базу

Архивирование (backup) Распределенная БД (УРИБ, УРБД) Тестирование и исправление v8 1cv8.cf Бесплатно (free)

УТ10.3 на Платформе 8.2 на базе MSSQL была разрушена после попытки её восстановить после неудачного динамического обновления. Таблица Config целевой базы была заменена на содержимое таблицы Config от другой рабочей базы. Но на самом деле конфигурации у них существенно отличались, поэтому после таких действий целевая база рухнула окончательно. Что же делать?

21.08.2015    29894    METAL    25    

"Распил" базы "БП 3.0 ПРОФ" с дальнейшим переносом в "БП 3.0 Базовая" ОДНОЙ организации

Распределенная БД (УРИБ, УРБД) v8 Россия Бесплатно (free)

Условия: Есть "БП 3.0 ПРОФ", в которой ведется учет по трем (неважно, скольким) Организациям. Необходимо оставить учет только по одной (к примеру) организации, и при этом перенести все данные по ней в "БП 3.0. Базовая"

14.08.2015    17298    Viktor_Ermakov    10    

РИБ Бухгалтерия 3.0.39, файловый вариант базы

Распределенная БД (УРИБ, УРБД) v8 БП2.0 Россия Бесплатно (free)

Настройка обмена данных РИБ в файловом варианте базы, через планировщик задач.

18.05.2015    12507    maikl007    2    

Автоматическое обновление конфигурации периферийного узла РИБ при обмене

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

При большом количестве периферийных узлов в РИБ достаточно проблематично производить обновление конфигурации. В данной статье опишу свой опыт решения данной проблемы.

24.03.2015    29533    kondrat1C    20    

Выделение одной организации из Бухгалтерии редакция 3 через РИБ

Распределенная БД (УРИБ, УРБД) v8 БП2.0 Россия Бесплатно (free)

Выделение одной организации из Бухгалтерии редакция 3 через РИБ (например, 3.0.36.16) может привести к большим проблемам с последующими обновлением.

16.02.2015    15650    shevelyov    4    

Обмен с помощью WMI

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

Полный контроль над процессом, осуществляемый из единого центра.

10.11.2014    10466    loekyn    7    

Обмены данными и РИБ с использованием облачных сервисов

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

Проверенный на практике, простой и доступный способ настройки обменов данными без использования FTP и встроенного почтового клиента.

22.10.2014    20114    rarename    14    

Реализация обмена по организации в УТ

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

В связи с открытием филиала в другом городе возникла необходимость организации учета в конфигурации "Управление торговлей для Казахстана, ред. 3" (адаптированный аналог "Управление торговлей, ред. 11"). Как оказалось встроенного обмена по организации не оказалось, есть только "Полный". Пришлось реализовывать самому. Конечно был вариант работы через терминальное подключение и тонкий клиент, но в связи во-первых неустойчивыми каналами связи и с заделкой на будущее (большие объемы данных) решил сделать РИБ. И вот об этом моя первая статья, может поможет кому нибудь.

05.06.2014    15658    Bajo    5    

РИБ для УНФ

Распределенная БД (УРИБ, УРБД) v8 УНФ Россия Бесплатно (free)

Штатного механизма типового полного обмена (РИБ) нет. Добавляем этот функционал. Данный способ подойдет для типового релиза УНФ начиная с версии 1.4.7.37 или для конфигураций на основе БСП.

10.01.2014    30230    ZhAmAn    28    

Интерактивный счетчик объектов обмена

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

При обменах на периферийных базах счетчик обмена сделан не очень красиво – он зависает на 10% и вся загрузка не отображается на счетчике. Предлагаю методику, чтобы визуализировать прогресс загрузки/выгрузки.

16.08.2013    17305    fixin    3    

Параллельность выгрузок

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

Рассказываю свой опыт, как добился параллельности выгрузки из центральной базы РИБ сразу в 70 узлов.

15.08.2013    24909    fixin    41    

Из главного узла не загружены изменения справочника "Идентификаторы объектов метаданных"

Распределенная БД (УРИБ, УРБД) Администрирование данных 1С v8 1cv8.cf Бесплатно (free)

Данная проблема появляется регулярно на Периферийной Базе, после проведения обновления релиза ЦБ. Всем кому данная проблема неожиданно обновила вкус жизни, посвящается. Пошаговая инструкция, 100 % гарантия, никакого программирования.

09.05.2013    41383    motorkuzbassa.it    40    

МиниКейс "Закрытие месяца в УПП без остановки работы системы (Партионный учёт)"

Распределенная БД (УРИБ, УРБД) Закрытие периода Закрытие периода Закрытие периода v8 1cv8.cf БУ Бесплатно (free)

Предлагается схема закрытия месяца на предприятии с круглосуточной работой в 1С. Используются обработки, которые доступны на infostart.ru.

24.02.2013    24318    axxell    7    

Настройка филиальных баз данных

Распределенная БД (УРИБ, УРБД) Перенос данных из 1C8 в 1C8 v8 БП2.0 ЗУП2.5 УТ10 Россия Бесплатно (free)

Клиент поставил задачу реализации работы филиалов в конфигурациях "Бухгалтерия предприятия" и "Зарплата и Управление Персоналом", в которых уже давно работает центральное отделение. Главная загвоздка в том, что, несмотря на автономную работу филиалов, отчетность нужно было продолжать сдавать от юридического лица в центральном филиале. Начали продумывать варианты реализации...

29.01.2013    17706    evgant    6    

Обмен данными в распределенной базе через e-mail.

Распределенная БД (УРИБ, УРБД) WEB v8 1cv8.cf Бесплатно (free)

Если у вас нет финансов для покупки отдельного сервера под 1С или вы просто не хотите пока вкладывать денежные средства для развития этого программного продукта, но у вас есть острая необходимость в обмене данными между двумя удаленно расположенными пользователями, то в данной статье я расскажу как настроить обмен данными без финансовых вложений по средствам e-mail.

13.01.2013    48341    Klim Bassenger    34    

Исправление ошибки в РИБ (некорректные данные в базе)

Распределенная БД (УРИБ, УРБД) v8 1cv8.cf Бесплатно (free)

Если у вас выгрузились в одну из периферийных баз данные из другой – эта инструкция для вас. :) Пример из реальной практики.

27.09.2012    17837    Korolev    11    

Обмен данными по планам обмена

Распределенная БД (УРИБ, УРБД) Перенос данных из 1C8 в 1C8 v8 1cv8.cf Бесплатно (free)

В этой статье я постараюсь рассказать, как перенести механизм обмен данными из типовой конфигурации в нетиповую и создать свои планы обмена.

19.07.2012    48877    kereo    17