Консоль запросов 1С "consquery.ru"

Процедура КоманднаяПанельФормыВыгрузитьТекстЗапроса(Элемент)
	
	ТекстЗапроса = ЭтаФорма.ПолучитьТекстЗапроса(Истина) ; 
	
	ПараметрыЗапроса = кзПолучитьПараметрыЗапроса(ТекстЗапроса, True);
	
	Результат = "";
	
	//[begin] Added by Sergey. http://infostart.ru/profile/18346/
	//17.02.2012 16:53:42
	Результат = "Запрос = Новый Запрос;" + Символы.ПС;
	Результат = Результат + "Запрос.Текст = """ + Символы.ПС;
	//[end] Added 
	
	//Символ(34)  - " (кавычки)
	//Символ(13)  - cr (возврат коретки)
	Для СЦ = 1 по СтрЧислоСтрок(ТекстЗапроса) цикл
		ТекСтр = СтрЗаменить(СтрПолучитьСтроку(ТекстЗапроса,СЦ), Символ(13), ""); 
		ТекСтр = СтрЗаменить(ТекСтр,Символ(34),Символ(34) + Символ(34)); 
		Если Лев(СокрЛП(ТекСтр),1)<> "|" Тогда
			Результат = Результат + "|" + ТекСтр + Символы.ПС;
		КонецЕсли; 	
	КонецЦикла;
	Результат = Результат  + "|"";" + Символы.ПС;
	
	Если ПараметрыЗапроса <> Неопределено Тогда
		Для каждого ТекПараметрЗапроса Из кзПолучитьПараметрыЗапроса(ТекстЗапроса) Цикл
			СтрокаСПараметром = ЭтаФорма.мФормаПараметров.Параметры.Найти(ТекПараметрЗапроса.Имя, "ИмяПараметра");
			Если СтрокаСПараметром = Неопределено Тогда 
				Сообщить("Не задан параметр """ + ТекПараметрЗапроса.Имя + """");
			ИначеЕсли ТипЗнч(СтрокаСПараметром.ЗначениеПараметра) = Тип("СписокЗначений") Тогда
				ЗначениеПараметра = "кзСписок" + ТекПараметрЗапроса.Имя;
				Результат = Результат + ЗначениеПараметра + " = Новый СписокЗначений;" + Символы.ПС;
				Для каждого ТекЗначениеСписка Из СтрокаСПараметром.ЗначениеПараметра Цикл
					Результат = Результат + "кзСписок" + ТекПараметрЗапроса.Имя + ".Добавить(" + кзПодставитьПараметр(ТекЗначениеСписка.Значение) + ");" + Символы.ПС;
				КонецЦикла; 
			Иначе
				ЗначениеПараметра = кзПодставитьПараметр(СтрокаСПараметром.ЗначениеПараметра);
			КонецЕсли;
			Результат = Результат + "Запрос.УстановитьПараметр(""" + ТекПараметрЗапроса.Имя + """, " + 
				?(СтрокаСПараметром = Неопределено, "", ЗначениеПараметра) + ");" + Символы.ПС;
		КонецЦикла; 
		
		Результат = Результат + Символы.ПС;

	Конецесли;
	
	//[begin] Added by Sergey. http://infostart.ru/profile/18346/
	//17.02.2012 16:52:18
	Если Элемент.Имя = "ВыгрузитьТекстЗапроса" Тогда
		Результат = Результат + "Результат = Запрос.Выполнить();" + Символы.ПС;
		Результат = Результат + "Выборка = Результат.Выбрать();" + Символы.ПС;
		Результат = Результат + "Пока Выборка.Следующий() Цикл" + Символы.ПС;
		Результат=Результат + "КонецЦикла;"+Символы.ПС;
	ИначеЕсли Элемент.Имя = "ВыгрузитьТекстЗапросаВТЗ" Тогда
		Результат = Результат + "Результат = Запрос.Выполнить();" + Символы.ПС;
		Результат = Результат + "Выборка = Результат.Выгрузить();" + Символы.ПС;
		Результат = Результат + "Для каждого СтрокаТЗ Из Выборка Цикл" + Символы.ПС;
		Результат=Результат + "КонецЦикла;"+Символы.ПС;
	КонецЕсли;
	//[end] Added 

	Ответ = Вопрос("Скопировать в буфер?", РежимДиалогаВопрос.ДаНетОтмена);
	Если Ответ = КодВозвратаДиалога.Да Тогда
		кзСкопироватьВБуфер(ПолучитьФорму("Точка"),Результат);
	ИначеЕсли Ответ = КодВозвратаДиалога.Нет Тогда
		ТД = Новый ТекстовыйДокумент(); 
		ТД.УстановитьТекст(Результат);
		ТД.Показать(,); 
	КонецЕсли;
КонецПроцедуры