У каждого из указанных в наименовании механизмов есть свои плюсы и минусы. Данная обработка подойдет для разработчиков 1С, перед которыми стоит задача уменьшить размер БД всеми возможными способами и как можно сильнее. В рамках этой задачи можно порезать историю данных, для чего её необходимо сначала перевести в метаданные БСП.
Первый нюанс: не все виды метаданных можно хранить в БСП.
Функция ПоддержваемыеВидыМетаданных()
ВидыМетаданных = Новый Массив;
ВидыМетаданных.Добавить("Справочники");
ВидыМетаданных.Добавить("Документы");
ВидыМетаданных.Добавить("ПланыВидовХарактеристик");
ВидыМетаданных.Добавить("ПланыСчетов");
ВидыМетаданных.Добавить("ПланыВидовРасчета");
ВидыМетаданных.Добавить("БизнесПроцессы");
ВидыМетаданных.Добавить("Задачи");
Возврат ВидыМетаданных;
КонецФункции
Второй нюанс: для быстрой работы с версиями истории данных необходимо сначала её обновить.
Процедура ОбновитьИсториюТаблицы(ТекущиеМетаданные)
ИсторияДанных.ОбновитьИсторию(ОбщегоНазначенияКлиентСервер.ЗначениеВМассиве(ТекущиеМетаданные));
КонецПроцедуры
После чего внутри каждого вида метаданных обходим каждую таблицу, внутри которой обходим каждый объект, внутри которого обходим все версии по возрастанию... Мёд на глазах от вложенных циклов, но иначе никак :)
Для каждого объекта мы
1. очищаем версии в механизме БСП
2. переносим версии объекта
3. очищаем историю данных по указанному объекту
Процедура ОбработатьТекущиеДанные(Данные, Версии, СоответствиеПользователей)
ОчиститьВерсииБСП(Данные);
ПеренестиВерсии(Версии, СоответствиеПользователей);
ОчиститьВерсииИсторииДанных(Данные);
КонецПроцедуры
Процедура ОчиститьВерсииБСП(Данные)
Набор = РегистрыСведений.ВерсииОбъектов.СоздатьНаборЗаписей();
Набор.Отбор.Объект.Установить(Данные);
Набор.Записать();
КонецПроцедуры
Процедура ПеренестиВерсии(Версии, СоответствиеПользователей)
Для Каждого ТекущаяВерсия Из Версии Цикл
ПеренестиВерсию(ТекущаяВерсия, СоответствиеПользователей);
КонецЦикла;
КонецПроцедуры
Процедура ОчиститьВерсииИсторииДанных(Данные)
ИсторияДанных.УдалитьВерсии(Данные);
КонецПроцедуры
Ну и непосредственная реализация переноса версий:
Процедура ПеренестиВерсии(Версии, СоответствиеПользователей)
Для Каждого ТекущаяВерсия Из Версии Цикл
ПеренестиВерсию(ТекущаяВерсия, СоответствиеПользователей);
КонецЦикла;
КонецПроцедуры
Процедура ПеренестиВерсию(Версия, СоответствиеПользователей)
ВерсияОбъекта = ИсторияДанных.СформироватьПоВерсии(Версия.Данные, Версия.НомерВерсии);
СведенияОВерсииОбъекта = НовыеСведенияОВерсииОбъекта();
ЗаполнитьЗначенияСвойств(СведенияОВерсииОбъекта, Версия);
СведенияОВерсииОбъекта.АвторВерсии = СоответствиеПользователей.Получить(Версия.ИмяПользователя);
СведенияОВерсииОбъекта.ДатаВерсии = Версия.Дата;
// указываете любой план обмена, в составе которого отсутствует РС ВерсииОбъектов
ИмяПланаОбмена = "СинхронизацияДанныхЧерезУниверсальныйФормат";
ВерсионированиеОбъектов.СоздатьВерсиюОбъектаПоОбменуДанными(ВерсияОбъекта, СведенияОВерсииОбъекта, Истина,
ПланыОбмена[ИмяПланаОбмена].ЭтотУзел());
КонецПроцедуры
А зачем использовать обмен данными? А затем, что иного способа, где я могу заполнить версию произвольным способом, программный интерфейс версионирования объектов БСП не поддерживает. Поэтому если в Вашей конфигурации нет плана обмена СинхронизацияДанныхЧерезУниверсальныйФормат, можете выбрать любой, где в состав не входит регистр сведений ВерсииОбъектов.
Тестировал обработку на БСП 3.1.6.437. Можно использовать как интерактивно, так и в фоне (поддержана регистрация внешней обработкой).
Итоги: Фирма 1С предусмотрела переход с БСП на историю данных, а обратного перехода не предусмотрели, что и заставило меня разработать данный механизм своими силами. В холиваре, что лучше История данных или Версионирование БСП, не участвую. Каждому выгодно что-то своё. О разнице между механизмами можете почитать тут.
Проверено на следующих конфигурациях и релизах:
- 1С:Библиотека стандартных подсистем, редакция 3.1, релизы 3.1.6.437
Вступайте в нашу телеграмм-группу Инфостарт