Консоль запросов для управляемых форм 8.3

11.05.23

Разработка - Инструментарий разработчика

–

> > > > > > > > > > > > > >

Универсальная внешняя обработка для создания, редактирования и отладки запросов, с возможностью обработки таблицы результатов произвольными алгоритмами на языке 1С. Выгрузка результатов запроса в таблицу или дерево значений, включая временные таблицы и запросы пакета. Формирование запроса для консоли в отладчике, включая временные таблицы и параметры. Версия 1.1.0.93 от 07.05.2023

Скачать файлы

	Наименование	Файл	Версия	Размер
	СДРКонсольЗапросовХ – Консоль запросов для управляемых форм 8.3 .epf 232,75Kb 806	.epf	1.1.0.93	232,75Kb	806	Скачать

СДРКонсольЗапросовХ – инструмент для программиста, позволяющий создавать и отлаживать запросы для баз 1С 8.3, а также обрабатывать результаты запросов (тонкий, толстый, web клиент). Не зависит от конкретной конфигурации, никаких БСП.

Работает с современными конфигурациями 1С с запретом на использование модальности и синхронных вызовов. Для конфигураций, использующих БСП, есть возможность подключения обработки к справочнику "ДополнительныеОтчетыИОбработки".

Видео инструкции по работе с консолью можно посмотреть здесь

Если Вас заинтересовала эта обработка, то рекомендую обратить внимание на Навигатор по базе данных 1С 8.3

В плане интерфейса использована классическая схема: дерево запросов, запрос и результаты запроса.

Особенности

Работает с современными конфигурациями 1С (с запретом на использование модальности и синхронных вызовов)
Заточена на интерфейс «Такси» - мало место для работы по сравнению с неуправляемыми формами (поэтому экономим место: можно погасить дерево запросов, результаты запроса и вообще ничего лишнего стараемся не показывать)
Оптимизирован обмен данными между клиентом и сервером
Не содержит избыточного функционала, редко используемого в практической работе
Для всех форм обработки установлен вариант масштаба "Компактный". Если кому то это не нравится и хочется использовать платформенную кнопку "Изменить масштаб", то надо в конфигураторе для всех форм обработки установить вариант масштаба "Авто".

Работа с деревом запросов

Запросы хранятся в виде дерева (как обычно)
Можно сохранить или загрузить все дерево запросов (в файл или из файла)
Можно сохранить отдельную веточку запросов в файл
Можно подгрузить в отдельную ветку запросов запросы из файла
Можно копировать запросы (вместе с параметрами и таблицами МВТ) или перетаскивать их в другие ветки дерева
ВАЖНО: корень дерева не предназначен для работы с запросом

Работа с текстом запроса

Поддержка пакета запросов
Можно выполнить весь пакет, либо только выделенную часть пакета
Можно подсчитать время выполнения запросов, входящих в пакет (отдельная страница результатов "Выполнение пакета")
В поля выборки можно вставить специальное поле, чтобы вместо ссылки выводился GUID
В пакет запроса можно вставить специальный разделитель, чтобы выполнение пакета остановилось на этом месте
Выделенную часть запроса можно закомментировать, раскомментировать или преобразовать в строку для вставки в код скрипта 1С

Параметры запроса

В параметрах запроса кроме стандартных, может быть таблица значений, граница, момент времени, уникальный идентификатор
В параметре можно указать битую ссылку (ссылку не несуществующий объект)
В значение параметра можно вставить ссылку на объект
В качестве параметру можно указать выражение на языке 1С, которое будет вычисляться перед выполнением запроса
Можно скопировать выбранные параметры из одного запроса в другой
Можно редактировать таблицу значений, являющуюся параметром запроса

Таблицы МВТ

Здесь располагаются таблицы значений, которые перед выполнением запроса помещаются в менеджер временных таблиц
В основном используется при перехвате сложных запросв из отладчика
Можно скопировать выбранные таблицы из одного запроса в другой
Таблицы значений можно редактировать

Результаты запроса

Результаты запроса оформляются в виде таблицы значений или дерева значений
Временные таблицы пакета запроса также оформляются в виде таблицы значений (по желанию)
Есть возможность показывать итоги по числовым колонкам таблицы результатов или временных таблиц
Есть возможность показывать итоги для выделенных строк по числовым колонкам таблицы результатов или временных таблиц
Кликнув мышкой по ячейки результирующей таблицы значений можно открыть значение в стандартной форме (если там находится ссылка на объект)
Можно открыть значение ячейки таблицы в специальной форме, предоставляющей доступ ко всем реквизитам объекта (Редактор объектов информационной базы 8.3 – встроен в консоль запросов). Как самостоятельно встроить более новую версию "Редактора объектов" описано здесь.
В специальной форме можно открыть не только ссылочный объект, но и хранилище значения (поддерживаются массив, список значений, структура, соответствие, таблица значений, табличный и текстовый документ)
Можно загрузить таблицу результатов запроса в параметр запроса либо сохранить в файл
Можно загрузить таблицу результатов запроса в менеджер временных таблиц запроса
Можно выгрузить ссылочные объекты из произвольной колонки результатов запроса в формате XML (для последующей загрузки в базу). Для обмена данными можно использовать файлы или строку, передаваемую через буфер обмена.

Сохранение запросов из отладчика

Есть возможность остановиться в отладчике и сохранить запрос с параметрами и временными таблицами в файл, который затем можно подгрузить в консоль для отладки.
Есть возможность остановиться в отладчике и сформировать XML-представление запроса с параметрами и временными таблицами, из которго в консоли можно сформировать запрос для отладки (передается через буфер обмена без использования промежуточных файлов)
Функция общего модуля для сохранения запроса из отладчика прилагается, пример вызова: омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос, "D:\1Cv8\Запросы\000") или омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос) - формирует XML-представление запроса
В функцию сохранения запроса в качестве первого параметра можно передать Запрос или МакетКомпоновкиДанных

Функция для перехвата запроса из отладчика (актуальный текст функции приведен на закладке "Настройки" обработки)

// ---------------------------------------------------------------------
// ФУНКЦИЯ ДЛЯ ОТЛАДКИ ЗАПРОСОВ (для использования в отладчике Shift-F9)
// ---------------------------------------------------------------------

// Назначение: сохраняет объект запрос в файл или формирует XML-представление запроса для последующей отладки в консоли запросов
// Версия: 1.1.0.67 от 22.11.2020
// Параметры:
// ЗапросИлиМакетКомпоновки - объект типа Запрос или МакетКомпоновкиДанных, для которого надо сохранить описание
// ИмяФайла - имя файла, куда будет сохранено описание запроса (можно без расширения)
//            этот файл затем можно подгрузить в расширенную консоль запросов
//     ВАЖНО: если ИмяФайла равно Неопределено, то функция возвращает XML-представление запроса, которое можно через буфер обмена передать в консоль запросов
//     ВАЖНО: в качестве имени файла можно указать ЧИСЛО, сформированное обработкой СДРКонсольЗапросовХ - в этом случае запрос сохранится во временный файл
//            на сервере, который потом можно будет подгрузить в консоль
// МаксЧислоЗаписей - максимальное число записей, выгружаемых из каждой временной таблицы, при значении -1 выгружаются ВСЕ записи
// ВключатьВременныеТаблицы - если истина, то сохраняются временные таблицы из менеджера временных таблиц
//
// Пример вызова:
//    _омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос, "D:\1Cv8\Запросы\000") - сохраняет запрос в файл (НА СЕРВЕРЕ)
//    _омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос, 4055120049) - сохраняет запрос во временный файл (НА СЕРВЕРЕ), расширение файла: "4055120049-dat"
//    _омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос) - возвращает XML-представление запроса
//    _омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос,,200) - возвращает XML-представление запроса (выгружаются не больше 200 записей из каждой временной таблицы)
// Замечания:
// - ВАЖНО: функцию надо вызывать ДО ВЫПОЛНЕНИЯ запроса
// - в управляемом режиме выполняется на сервере, соответственно обращайте внимание на имя файла

Функция СохранитьЗапросДляСДРКонсолиХ(Знач ЗапросИлиМакетКомпоновки, Знач ИмяФайла = Неопределено, Знач МаксЧислоЗаписей = -1, Знач СжиматьПараметрыXML = истина, Знач ВключатьВременныеТаблицы = истина) Экспорт
	Если ТипЗнч(ЗапросИлиМакетКомпоновки) = Тип("МакетКомпоновкиДанных") Тогда
		ВключатьВременныеТаблицы = ложь;
		
		Запрос = новый Запрос(ЗапросИлиМакетКомпоновки.НаборыДанных.Получить(0).Запрос);
		Для каждого Элем из ЗапросИлиМакетКомпоновки.ЗначенияПараметров Цикл
			Запрос.Параметры.Вставить(Элем.Имя, Элем.Значение);
		КонецЦикла;
	ИначеЕсли ЗапросИлиМакетКомпоновки = Неопределено Тогда
		Запрос = новый Запрос;
	Иначе
		Запрос = ЗапросИлиМакетКомпоновки;
	КонецЕсли;
	
	СтрукЗапрос = новый Структура;
	СтрукЗапрос.Вставить("Формат", "СДРКонсольЗапросовХ");
	СтрукЗапрос.Вставить("Версия", 2);
	СтрукЗапрос.Вставить("Назначение", "Запросы");
	СтрукЗапрос.Вставить("Элементы", новый Массив);
	
	СтрукЭлемент = новый Структура;
	СтрукЭлемент.Вставить("Дети", новый Массив);
	СтрукЭлемент.Вставить("Имя", "Запрос");
	СтрукЭлемент.Вставить("Текст", Запрос.Текст);
	СтрукЭлемент.Вставить("СпособВыгрузки", 0);
	СтрукЭлемент.Вставить("Параметры", новый Массив);
	СтрукЭлемент.Вставить("МВТ", новый Массив);
	
	Если ВключатьВременныеТаблицы и Запрос.МенеджерВременныхТаблиц <> Неопределено и Запрос.МенеджерВременныхТаблиц.Таблицы <> Неопределено и Запрос.МенеджерВременныхТаблиц.Таблицы.Количество() <> 0 Тогда
		
		Если МаксЧислоЗаписей >= 0 Тогда
			пЗапрос = новый Запрос;
			пЗапрос.МенеджерВременныхТаблиц = Запрос.МенеджерВременныхТаблиц;
			пШаблонЗапроса =
			"ВЫБРАТЬ ПЕРВЫЕ " + Формат(МаксЧислоЗаписей, "ЧРГ=0;ЧН=;") + "
			|	т.*
			|ИЗ
			|	%1 КАК т
			|";
		КонецЕсли;
		
		ТекстЗапроса = "";
		Если Запрос = Неопределено Тогда
			Запрос = новый Запрос;
		КонецЕсли;
		
		Для каждого пТаблицаМВТ из Запрос.МенеджерВременныхТаблиц.Таблицы Цикл
			пРезультатЗапроса = пТаблицаМВТ.ПолучитьДанные();
			Если МаксЧислоЗаписей < 0 Тогда
				ТабРезультат = пРезультатЗапроса.Выгрузить();
			ИначеЕсли пРезультатЗапроса.Пустой() Тогда
				ТабРезультат = пРезультатЗапроса.Выгрузить();
			Иначе
				пЗапрос.Текст = СтрЗаменить(пШаблонЗапроса, "%1", пТаблицаМВТ.ПолноеИмя);
				ТабРезультат = пЗапрос.Выполнить().Выгрузить();
			КонецЕсли;
			
			пСтрук = новый Структура;
			пСтрук.Вставить("Имя", пТаблицаМВТ.ПолноеИмя);
			пСтрук.Вставить("СпецЗначение", ЗначениеВСтрокуВнутр(ТабРезультат));
			
			СтрукЭлемент.МВТ.Добавить(пСтрук);
		КонецЦикла;
	КонецЕсли;
	
	// ВАЖНО: алгоритм формирования параметров должен быть идентичен (метка:001)
	ПараметрыЗапроса = Запрос.Параметры;
	Для каждого Элем из ПараметрыЗапроса Цикл
		СтрукПараметр = новый Структура;
		СтрукПараметр.Вставить("Имя", Элем.Ключ);
		СтрукПараметр.Вставить("Значение", Элем.Значение);
		СтрукПараметр.Вставить("ЭтоСпецЗначение", ложь);
		СтрукПараметр.Вставить("СпецЗначение", "");
		СтрукПараметр.Вставить("ТипЗначения", "");
		
		Если ТипЗнч(Элем.Значение) = Тип("Массив") Тогда
			Список = новый СписокЗначений;
			Список.ЗагрузитьЗначения(Элем.Значение);
			СтрукПараметр.Значение = Список;
			
		ИначеЕсли ТипЗнч(Элем.Значение) = Тип("ФиксированныйМассив") Тогда
			Список = новый СписокЗначений;
			Список.ЗагрузитьЗначения(новый Массив(Элем.Значение));
			СтрукПараметр.Значение = Список;
			
		ИначеЕсли ТипЗнч(Элем.Значение) = Тип("Граница") Тогда
			СтрукПараметр.ЭтоСпецЗначение = истина;
			СтрукПараметр.Значение = "Граница";
			СтрукПараметр.ТипЗначения = "Граница";
			СтрукПараметр.СпецЗначение = ЗначениеВСтрокуВнутр(Элем.Значение);
			
		ИначеЕсли ТипЗнч(Элем.Значение) = Тип("ТаблицаЗначений") Тогда
			СтрукПараметр.ЭтоСпецЗначение = истина;
			СтрукПараметр.Значение = "ТаблицаЗначений";
			СтрукПараметр.ТипЗначения = "ТаблицаЗначений";
			СтрукПараметр.СпецЗначение = ЗначениеВСтрокуВнутр(Элем.Значение);
			
		ИначеЕсли ТипЗнч(Элем.Значение) = Тип("МоментВремени") Тогда
			СтрукПараметр.ЭтоСпецЗначение = истина;
			СтрукПараметр.Значение = "МоментВремени";
			СтрукПараметр.ТипЗначения = "МоментВремени";
			СтрукПараметр.СпецЗначение = ЗначениеВСтрокуВнутр(Элем.Значение);
			
		ИначеЕсли ТипЗнч(Элем.Значение) = Тип("УникальныйИдентификатор") Тогда
			СтрукПараметр.ЭтоСпецЗначение = истина;
			СтрукПараметр.Значение = Строка(Элем.Значение);
			СтрукПараметр.ТипЗначения = "УникальныйИдентификатор";
			СтрукПараметр.СпецЗначение = ЗначениеВСтрокуВнутр(Элем.Значение);
		КонецЕсли;
		
		СтрукЭлемент.Параметры.Добавить(СтрукПараметр);
	КонецЦикла;
	
	СтрукЗапрос.Элементы.Добавить(СтрукЭлемент);
	
	// преобразование запроса в строку XML
	Если ИмяФайла = Неопределено Тогда
		Попытка
			СтрукЗапросXML = новый Структура;
			СтрукЗапросXML.Вставить("СжиматьПараметрыXML", СжиматьПараметрыXML);
			СтрукЗапросXML.Вставить("Текст", СтрукЭлемент.Текст);
			
			СтрукЗапросXML.Вставить("МВТ", новый Структура);
			Для каждого Элем из СтрукЭлемент.МВТ Цикл
				ИмяПараметра = Элем.Имя;
				Если СжиматьПараметрыXML Тогда
					ЗначениеПараметра = ЗначениеИзСтрокиВнутр(Элем.СпецЗначение);
					Если ТипЗнч(ЗначениеПараметра) = Тип("ТаблицаЗначений") Тогда
						ЗначениеПараметра = новый ХранилищеЗначения(ЗначениеПараметра, новый  СжатиеДанных(9));
					КонецЕсли;
				Иначе
					ЗначениеПараметра = ЗначениеИзСтрокиВнутр(Элем.СпецЗначение);
				КонецЕсли;
				СтрукЗапросXML.МВТ.Вставить(ИмяПараметра, ЗначениеПараметра);
			КонецЦикла;
			
			СтрукЗапросXML.Вставить("Параметры", новый Структура);
			Для каждого Элем из СтрукЭлемент.Параметры Цикл
				ИмяПараметра = Элем.Имя;
				Если Элем.ЭтоСпецЗначение Тогда
					Если СжиматьПараметрыXML Тогда
						ЗначениеПараметра = ЗначениеИзСтрокиВнутр(Элем.СпецЗначение);
						Если ТипЗнч(ЗначениеПараметра) = Тип("ТаблицаЗначений") Тогда
							ЗначениеПараметра = новый ХранилищеЗначения(ЗначениеПараметра, новый  СжатиеДанных(9));
						КонецЕсли;
					Иначе
						ЗначениеПараметра = ЗначениеИзСтрокиВнутр(Элем.СпецЗначение);
					КонецЕсли;
				Иначе
					ЗначениеПараметра = Элем.Значение;
				КонецЕсли;
				СтрукЗапросXML.Параметры.Вставить(ИмяПараметра, ЗначениеПараметра);
			КонецЦикла;
			
			ЗаписьXML = новый ЗаписьXML;
			ЗаписьXML.УстановитьСтроку();
			СериализаторXDTO.ЗаписатьXML(ЗаписьXML, СтрукЗапросXML, НазначениеТипаXML.Явное);
			
			Возврат ЗаписьXML.Закрыть();
		Исключение
			Возврат ОписаниеОшибки();
		КонецПопытки;
	КонецЕсли;
	
	Если ТипЗнч(ИмяФайла) = Тип("Число") Тогда
		пРасширение = Формат(ИмяФайла, "ЧГ=0") + "-dat";
		ИмяФайла = ПолучитьИмяВременногоФайла(пРасширение);
	КонецЕсли;
	
	СтрокаДанных = ЗначениеВСтрокуВнутр(СтрукЗапрос);
	
	ТДок = новый ТекстовыйДокумент;
	ТДок.УстановитьТекст(СтрокаДанных);
	
	Если Найти(ИмяФайла, ".") = 0 Тогда
		ИмяФайла = ИмяФайла + ".dat";
	КонецЕсли;
	
	Попытка
		ТДок.Записать(ИмяФайла);
		Возврат "Ок";
	Исключение
		Возврат ОписаниеОшибки();
	КонецПопытки;
	
КонецФункции

Комментарии в тексте запроса

// Комментарий СОХРАНИТСЯ
// Комментарий СОХРАНИТСЯ

ВЫБРАТЬ
	т.Ссылка КАК Ссылка, // Комментарий НЕ СОХРАНИТСЯ
	т.Код КАК Код
ПОМЕСТИТЬ втВалюты
// Комментарий СОХРАНИТСЯ
ИЗ
	Справочник.Валюты КАК т
ГДЕ
	т.Ссылка В(&Валюты)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	т.Ссылка КАК Ссылка,
	т.Код КАК Код
ПОМЕСТИТЬ втКонтрагенты // Комментарий НЕ СОХРАНИТСЯ
// Комментарий СОХРАНИТСЯ
// Комментарий СОХРАНИТСЯ
ИЗ
	Справочник.Контрагенты КАК т
ГДЕ
	т.Ссылка В(&Контрагенты)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	т.Ссылка КАК Ссылка,
	т.Код КАК Код
ИЗ
	втКонтрагенты КАК т

Для обработки результатов запроса есть закладка «Алгоритмы»

в Web клиенте выполнить алгоритм можно только на стороне сервера
Алгоритм – это код на языке 1С
Алгоритмы хранятся в виде дерева, функционал аналогичен дереву запросов
ВАЖНО: корень дерева не предназначен для работы с алгоритмом
Алгоритмы могут выполнятся как на стороне сервера, так и на стороне клиента; имеют доступ к результатам запроса, можно указать дополнительные параметры (число, дата, ссылка и т.д.)
В консоль встроены примеры реализации алгоритмов на стороне сервера и клиента. В примере для клиента обратите внимание на строки «//--- Сервер:старт» и «//--- Сервер:финиш» - код между этими строками будет выполняться на сервере.

Видео инструкции по работе с консолью можно посмотреть здесь

Некоторые примеры скриншотов

Основное окно консоли запросов

Закладка "Настройки"

Закладка "Параметры запроса"

Вывод уникального идентификатора объекта в результатах запроса

Иллюстрация команды "Открыть объект..." в результатах запроса

Выгрузка ссылочных объектов из колонки результатов запроса в XML

Просмотр временных таблиц и запросов пакета

Выгрузка результатов в дерево значений

Перехват запроса в отладчике

Обработка результатов запроса произвольным алгоритмом

Тестирование

Платформа (8.3.11.2867, 8.3.13.1513, 8.3.15.1489), на платформах ниже 8.3.9 работать не будет
Управление холдингом, редакция 3.0 (3.0.4.4)
1С:ERP Управление предприятием 2 (2.4.10.56)

Это инструмент для программистов и продвинутых пользователей (я использую постоянно).

Если Вас заинтересовала эта обработка, то рекомендую обратить внимание на Навигатор по базе данных 1С 8.3

История изменений (2019)

Версия 1.1.0.29 от 04.03.2019

Версия 1.1.0.31 от 31.03.2019

Версия 1.1.0.33 от 21.04.2019

Версия 1.1.0.35 от 15.08.2019

Версия 1.1.0.37 от 27.08.2019

Версия 1.1.0.39 от 14.10.2019

Версия 1.1.0.41 от 26.11.2019

Версия 1.1.0.43 от 19.12.2019

Версия 1.1.0.45 от 07.02.2020

Версия 1.1.0.47 от 22.03.2020

Версия 1.1.0.49 от 23.03.2020

Версия 1.1.0.53 от 01.04.2020

Версия 1.1.0.55 от 01.05.2020

Версия 1.1.0.57 от 08.06.2020

Версия 1.1.0.59 от 10.07.2020

Версия 1.1.0.61 от 26.08.2020

Версия 1.1.0.65 от 02.11.2020

Версия 1.1.0.67 от 22.11.2020

Версия 1.1.0.68 от 05.02.2021

Версия 1.1.0.69 от 22.02.2021

Версия 1.1.0.71 от 24.06.2021

Версия 1.1.0.73 от 09.10.2021

Версия 1.1.0.77 от 02.12.2021

Версия 1.1.0.79 от 03.08.2022

Версия 1.1.0.81 от 14.09.2022

Версия 1.1.0.83 от 17.01.2023

Версия 1.1.0.87 от 12.03.2023

обновлена специальная форма объекта (Редактор объектов информационной базы 8.3), предоставляющей доступ ко всем реквизитам объектов и движениям документов
добавлена возможность формирования таблицы значений для параметров запроса или для менеджера временных таблиц из табличного документа (на закладке "Параметры запроса" и "Таблицы МВТ" появилась кнопка "Добавить таблицу из табличного документа")

Версия 1.1.0.93 от 07.05.2023

обновлена специальная форма объекта (Редактор объектов информационной базы 8.3), предоставляющей доступ ко всем реквизитам объектов и движениям документов
добавлена возможность выгрузить результаты выполнения запроса в табличный документ (см. подменю "Отчеты" на закладке "Результат запроса")

консоль запрос алгоритм обработка параметры отладка редактор объект таблица пакет результат перехват выгрузка XML СДР СДРКонсольЗапросовХ

–

См. также

INFOSTART TECH EVENT 2023, 11-13 октября, Санкт-Петербург

Инструментарий разработчика Мобильная разработка DevOps и автоматизация разработки Администрирование СУБД Мероприятия Россия Платные (руб)

XIII конференция по управлению и технологиям автоматизации учета на платформе 1С:Предприятие, которая пройдет в Санкт-Петербурге и соберет 1500 участников из разных регионов России и мира.

5100 руб.

09.12.2022 30068 11 0

433

Онлайн-интенсив "DevOps для 1С". с 4 сентября по 17 октября 2023 г.

Инструментарий разработчика DevOps и автоматизация разработки DevOps для 1С Платные (руб)

Данный онлайн-курс (интенсив) предусматривает изучение процессов, инструментов и методик DevOps, их применение при разработке на платформе 1С.

20.06.2023 9835 0 Infostart 2

121

SALE! %

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

~~12000~~ 10000 руб.

02.09.2020 93530 477 380

531

SALE! 25%

PowerTools

Инструментарий разработчика Инструменты администратора БД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Россия Платные (руб)

Универсальный инструмент программиста для администрирования конфигураций. Сборник наиболее часто используемых обработок под единым интерфейсом.

~~3600~~ 2700 руб.

14.01.2013 170203 1051 0

792

Автоматизация труда программиста. Библиотека прикладных функций

Инструментарий разработчика Платформа 1С v8.3 Платформа 1C v8.2 Платформа 1С v8.1 Конфигурации 1cv8 Платные (руб)

Программист - это человек, непрерывно принимающий решения. Написание кода не является процессом принятия решения - это всего лишь трансляция ваших желаний. Если вас периодически тяготит написание сотен строк кода ради решения задач, то прошу обратить внимание. Данный продукт позволит существенно сократить время на рутинные операции при разработке. За счет библиотечной реализации сокращается объём кода, а его читаемость повышается. К библиотеке прилагается документация API и шаблоны кода для наиболее популярных методов.

4200 руб.

16.04.2021 12508 3 9

Многопоточность. Универсальный «Менеджер потоков» 2.1

Инструментарий разработчика Платформа 1С v8.3 Конфигурации 1cv8 Россия Платные (руб)

Восстановление партий или взаиморасчетов, расчет зарплаты, пакетное формирование документов или отчетов - теперь все это стало доступнее. * Есть желание повысить скорость работы медленных алгоритмов! Но... * Нет времени думать о реализации многопоточности? * о запуске и остановке потоков? * о поддержании потоков в рабочем состоянии? * о передаче данных в потоки и как получить ответ из потока? * об организации последовательности? Тогда ЭТО - то что надо!!!

5000 руб.

07.02.2018 96488 235 97

286

Менеджер конфигураций 1С

Инструментарий разработчика Платные (руб)

Менеджер конфигураций 1С — альтернативный стартер информационных баз 1С:Предприятие.

1439 руб.

21.02.2023 5246 2 33

Все консоли запросов для 1С

Запросы Бесплатно (free)

Список всех популярных обработок.

17.03.2023 19449 kuzyara 70

147

Комментарии

В избранное Подписаться на ответы

Свернуть все

1. Perk0n 13 08.11.18 10:57 Сейчас в теме

Спасибо.

В 1С:Документооборот и БП 3.0 работает.
В ЗУПе 3.1 не работает.

Платформа: 1С:Предприятие 8.3 (8.3.13.1513)
Конфигурация: Зарплата и управление персоналом, редакция 3.1 (3.1.7.144) (http://v8.1c.ru/hrm/)
Copyright © ООО "1C-Софт", 2007-2018. Все права защищены
(http://www.1c.ru)
Режим: Серверный (сжатие: усиленное)
Приложение: Тонкий клиент
Локализация: Информационная база: русский (Россия), Сеанс: русский
Вариант интерфейса: Такси

Ошибки:
--------------------------------------------------------------------------------
08.11.2018 14:44:53
{(1, 1)}: Ожидается выражение "ВЫБРАТЬ"

При начале работы с интерактивам конструктором запросов ЗУПе. Например при раскрытии справочников.

Штука классная. Надеюсь поправите для ЗУПа.

3. ROL32 488 08.11.18 11:48 Сейчас в теме

Спасибо.

По поводу ЗУПа - для открытия конструктора используется платформенный вызов, поэтому поправить что либо проблематично.
Думаю, что ошибка вызвана или ошибкой платформы (наблюдал для ERP под 8.3.12.1685), или подпорченной струтурой хранения самой базы (проверить можно на новой пустой или демонстрационной базе ЗУП)

58. kuzyara 1766 15.03.23 10:40 Сейчас в теме

(1) проблема в пустой строке при вызове конструктора. Фиксится заменой "Новый КнострукторЗапроса(ТекстЗапроса)" на "Новый КнострукторЗапроса()" без параметра если строка пустая

Прикрепленные файлы:

2023-03-14_19-24-45.png

59. ROL32 488 16.03.23 10:13 Сейчас в теме

(58) Вы наверное используете какую то старую версию, в последних версиях консоли это исправлено

	ТекстЗапроса = _ТекстЗапроса.ПолучитьТекст();
	Если не ПустаяСтрока(ТекстЗапроса) Тогда
		Конструктор = Новый КонструкторЗапроса(ТекстЗапроса);
	Иначе
		Конструктор = Новый КонструкторЗапроса;
		пСоотв = новый Соответствие;
	КонецЕсли;

Показать

60. kuzyara 1766 16.03.23 10:45 Сейчас в теме

(59) да я про типовые, там до сих пор этот баг)

2. Evg-Lylyk 4306 08.11.18 11:17 Сейчас в теме

Посмотрите другой подобный инструмент https://infostart.ru/public/835718/

4. ROL32 488 08.11.18 11:52 Сейчас в теме

Обязательно

5. ROL32 488 05.02.19 13:45 Сейчас в теме

Странно, что так мало комментариев.
Похоже, что у тех, кто скачал все работает и их все устраивает.
А может наоборот посмотрели и сразу удалили.

6. vova-1c 153 30.03.19 11:43 Сейчас в теме

Не подключается
Конфигурация

Прикрепленные файлы:

7. vova-1c 153 30.03.19 11:43 Сейчас в теме

ошибка

Прикрепленные файлы:

8. ROL32 488 19.08.19 19:29 Сейчас в теме

(7) Почему то не было уведомления о комментарии - поэтому не отвечал, только сегодня случайно увидел

Сознательно не делал эту обработку подключаемой, если очень хочется, то в модуль объекта надо добавить экспортную функцию с именем "СведенияОВнешнейОбработке"
описание функции здесь: https://its.1c.ru/db/bsp302doc#content:2776:hdoc

9. cprit 186 26.12.19 13:03 Сейчас в теме

Добрый день!
Для обычных форм есть замечательный набор инструментов "Инструменты разработчика 1С", но его невозможно использовать в линуксе и в тонком и веб клиенте.

Поэтому мы решили собрать подобный пакет, но который будет работать только на платформенных механизмах или с использованием кроссплатформенных компонент.

Использование этого пакета инструментов хотим сделать общедоступным(OpenSource), разработку вести через гитхаб с использованием EDT.

Можем ли мы включить в этот набор обработки(или часть идей и функционала) вашей консоли запросов для управляемых форм?

На текущий момент нашли основные инструменты (консоль запросов, консоль кода, редактор реквизитов, консоль компоновки и др.) для включения в инструментарий. Сейчас занимаемся получением одобрения авторов. Часть включаем свои- редактор предопределенных, редактор констант, Групповая обработка

Ссылка на репозиторий с новыми инструментами https://github.com/cpr1c/tools_ui

12. ROL32 488 30.01.20 15:36 Сейчас в теме

(9) Добрый день!

Можем ли мы включить в этот набор обработки(или часть идей и функционала) вашей консоли запросов для управляемых форм?

не возражаю

10. lock73 106 24.01.20 10:31 Сейчас в теме

В БП 3.0.75.38 платформа 8.3.15.1830 не открывается конструктор запросов. При нажатии на кнопку "Конструктор" ничего не происходит.
Поля "ТекстЗапросв", "ОписаниеЗапроса" не редактируются.
Аналогично и для текстовых полей алгоритма.

11. lock73 106 24.01.20 10:59 Сейчас в теме

В этой конфигурации на этой платформе типовое значение режима модальности и режима синхронных вызовов - Не использовать.

13. ROL32 488 06.02.20 21:13 Сейчас в теме

(11) Почему то перстали приходить уведомления, поэтому не отвечал (случайно увидел ваше сообщение)
Вы наверное находитесь в корне дерева запросов (// КОРНЕВОЙ ЗАПРОС НЕ ИСПОЛЬЗУЕТСЯ //)
Добавьте новый запрос в дерево запросов и все получится

14. Myst_ 65 25.02.20 12:45 Сейчас в теме

Добрый день.
Ошибка при выполненнии перехваченного запроса
{(79, 2)}: Тип не может быть выбран в запросе
<<?>>ТабДанные.ТипЗначения

15. ROL32 488 15.07.20 21:14 Сейчас в теме

(14) Добрый день
Полностью переработал перехват запросов - теперь должно работать

16. stas4tor 04.08.20 13:22 Сейчас в теме

Добрый день.
Возможно ли добавить итоговое поле, для колонок где тип число, при выводе результата запроса? Очень не хватает такой мелочи.

18. ROL32 488 21.08.20 17:20 Сейчас в теме

(16) Почему то иногда мне не приходят оповещения на комментарии, поэтому сразу не отвечаю
Наверное Вы правы, итоговое поле добавлю

19. ROL32 488 26.08.20 12:43 Сейчас в теме

(16) Добрый день.
Версия 1.1.0.61 от 26.08.2020
добавлена возможность отображать итоги по числовым полям результатов запросов (для всех или выделенных строк)

17. N1ce 14.08.20 21:42 Сейчас в теме

Консоли запросов

Прикрепленные файлы:

КонсольЗапросов.epf
КонсольЗапросов_Plus.epf

20. avdol1 24.09.20 12:17 Сейчас в теме

Добрый день, как добавить строки в параметр запроса в виде таблицы значение?

Прикрепленные файлы:

21. ROL32 488 02.10.20 17:27 Сейчас в теме

(20) Добрый день
Самый простой способ сформировать таблицу в параметрах запроса следующий:
1. Создаю запрос, на пример ВЫБРАТЬ Ссылка, Наименование ИЗ Справочник.Валюты
2. Выполняю запрос в консоли
3. Результаты запроса подгружаю в параметр (это будет таблица валют)
4. После этого эту таблицу в параметрах запроса можно редактировать (добавлять, удалять, изменять строки)
5. Изменять структуру таблицы нельзя

22. Serg2000mr 164 09.11.20 02:02 Сейчас в теме

При выполнении обмена между базами часто бывает нужно загрузить параметр запроса (список или ТЗ) из файла или из буфера. Пример реализации https://infostart.ru/public/14183/ (https://github.com/lavelinevgeny/consquery).

61. ROL32 488 16.03.23 17:12 Сейчас в теме

(22) Реализоано в версии 1.1.0.87

23. Serggray 14 13.02.21 12:57 Сейчас в теме

Добрый день
Платформа 8.3.12. , УНФ 1.4 Ошибки

{ВнешняяОбработка.СДРКонсольЗапросовХ.Форма.Форма.Форма(1416,35)}: Переменная не определена (НаправлениеПоиска)
				Поз1 = СтрНайти(пСтрока, ",", <<?>>НаправлениеПоиска.СКонца);
{ВнешняяОбработка.СДРКонсольЗапросовХ.Форма.Форма.Форма(1397,54)}: Процедура или функция с указанным именем не определена (СтрНайти)
	пСтрокаОбъектНеНайден = Сред(пСтрокаОбъектНеНайден, <<?>>СтрНайти(пСтрокаОбъектНеНайден, "(") + 1);
{ВнешняяОбработка.СДРКонсольЗапросовХ.Форма.Форма.Форма(1401,8)}: Процедура или функция с указанным именем не определена (СтрНайти)
	Поз = <<?>>СтрНайти(пСтрокаОбъектНеНайден, ":");

Я так понимаю из-за включенного режима совместимости. Если дело только в этом конечно можно попробывать подправить или бесполезно ?

25. ROL32 488 14.02.21 19:24 Сейчас в теме

(23) Добрый день!
Данная обработка будет корректно работать на версии платфлормы не ниже 8.3.8 (это написано в публикации)
Функция СтрНайти появилась в версии платформы 8.3.6 (судя по Вашей ошибке у вас режим совместимости еще ниже)
Попробывать подправить можно, только этим (функция СтрНайти) правка не ограничиться

24. ROL32 488 14.02.21 19:17 Сейчас в теме

Добрый день!
Данная обработка будет корректно работать на версии платфлормы не ниже 8.3.8 (это написано в публикации)

26. sabb 18.02.21 09:25 Сейчас в теме

Добрый день!
Есть возможность выгрузки в csv файл, просто результат большой выборки по другому не получается выгрузить, зависает и падение с ошибкой "не хватает памяти".

27. ROL32 488 18.02.21 20:15 Сейчас в теме

(26) Добрый день!
Нет такой возможности нет (как то не было необходимости реализовывать)
В Вашем случае я бы воспользовался закладкой "Алгоритмы" - там можно написать любой алгоритм, с перебором строк таблицы результатов запроса.

28. roma03v1 30.04.21 11:21 Сейчас в теме

не открывается окно редактирования таблицы значений почему то.
При клике на кнопку "открыть спец.значение" открывается окошко. уазать количество строк нельзя, число не вводиться. 8.3.18.1289 Как поправить? очень нужно, поясните плз

Прикрепленные файлы:

29. ROL32 488 30.04.21 21:38 Сейчас в теме

(28) Добрый день!
Уже был такой вопрос: Ссылка

30. Hans 2 24.07.21 16:59 Сейчас в теме

Сделай что бы показывало время выполенния запросов временных таблиц. Что бы можно было узнать какая временная таблица сколько занимает времени при формировании всего запроса.

31. ROL32 488 27.07.21 11:21 Сейчас в теме

(30) Добрый день!
Запрос выполняется целиком (отправился целиком на сервер, а затем вернулся результат, см. Запрос.ВыполнитьПакет()), поэтому определить сколько времени занимал отдельный запрос из пакета не представляется возможным.

33. Hans 2 12.08.21 16:21 Сейчас в теме

(31) Можно ж по отдельности выполнять запросы пакета и счетать время.

34. ROL32 488 23.10.21 22:32 Сейчас в теме

(33) Реализоано в версии 1.1.0.73

32. Hans 2 12.08.21 16:20 Сейчас в теме

Сделай флаг автоматического сохранения запросов перед выполнением. Защита от кривых запросов, которые делаешь много времени, запускаешь и все зависает. Для меня критично, не знаю как для других.

35. ROL32 488 23.10.21 22:34 Сейчас в теме

(32) Реализоано в версии 1.1.0.73

36. Hans 2 28.11.21 12:01 Сейчас в теме

Почему параметры вывода запроса находятся на вкладке "Текст запроса"? Они интуитивно должны быть на вкладке "Результат запроса".

Сценарий такой > Сначала текст запроса, потом заполняем параметры, нажимаем Выполнить. Понимаем что нам нужны временные таблицы. Начинаем искать где эта настройка.

Прикрепленные файлы:

37. ROL32 488 28.11.21 18:05 Сейчас в теме

(36) Я так вижу мир

Обычно происходит так:
- сначала пишется текст запроса
- потом заполняются параметры
- потом выполняется запрос
- потом выполняется тюнинг запроса (работаем не вкладке "Текст зароса")

но тем не менее подумаю, возможно доработаю интерфейс

38. ВадимЛитовченко 21 18.04.22 13:34 Сейчас в теме

Не работает

Прикрепленные файлы:

39. ROL32 488 19.04.22 15:39 Сейчас в теме

(38) В описании обработки указано: "на платформах ниже 8.3.9 работать не будет"
может быть дело в этом?

40. Jimbo 9 11.08.22 08:46 Сейчас в теме

Есть ли новые функции от 20й платформы ?
как-то СокрЛП, Строка и т.д.

https://wonderland.v8.1c.ru/blog/novye-funktsii-yazyka-zaprosov-i-sistemy-komponovki-dannykh/

41. ROL32 488 11.08.22 10:54 Сейчас в теме

(40) Консоль использует платформенный конструктор запросов, поэтому все новые функции платформы для запросов должны быть доступны. Я пока не использую 20-ую платформу, поэтому не проверял

43. Jimbo 9 11.08.22 14:28 Сейчас в теме

(41) с сайта итс консоль не хавает СокрЛП, Строка - это первое что проверил

42. Evg-Lylyk 4306 11.08.22 10:57 Сейчас в теме

(40) Подавляющее число консолей вызывают конструктор платформы в тонкий конструктор запросов 1с забили добавить новые функции в редактор выражений (описывал это в статье ошибка №3)

44. Jimbo 9 11.08.22 14:32 Сейчас в теме

(42) пишем в конфигураторе или толстом запрос , копируем, в тонком вставить - и ошибка не знает тонкий СокрЛП

45. ROL32 488 11.08.22 19:54 Сейчас в теме

(44) Проверил
1С:ERP Управление предприятием 2 (2.5.7.394)
1С:Предприятие 8.3 (8.3.20.1613) Тонкий клиент

ВЫБРАТЬ ПЕРВЫЕ 10
	т.Ссылка КАК Ссылка,
	т.Наименование КАК Наименование,
	СОКРЛП(т.Наименование) КАК НаименованиеХ
ИЗ
	Справочник.Контрагенты КАК т

запрос выполняется без ошибок, конструктор запроса открывается
СОКРЛП(т.Наименование) КАК НаименованиеХ - написал руками

46. frkbvfnjh 766 09.09.22 05:22 Сейчас в теме

Попакетный запер времени есть?

47. ROL32 488 09.09.22 11:26 Сейчас в теме

(46) есть

48. Yury1001 1465 23.09.22 14:31 Сейчас в теме

Не могу вызвать конструктор для указания параметров из виртуальных таблиц.
Что не так?

Прикрепленные файлы:

49. ROL32 488 24.09.22 22:10 Сейчас в теме

(48) По фотке не очень понятно в чем проблема
вообще это это работает платформетный конструктор запросов
можно обсудить по Скайпу - буду на связи после 27.09.2022

52. user1882876 27.12.22 17:19 Сейчас в теме

(49)

Как раз хотел задать такой же вопрос но увидел, что уже задали.
Это когда пытаешься вызвать конструктор запроса для условия и задать выборку из временной таблицы.
Т.е. в условии указать ... Где Номенклатура В ( Выбрать Ссылка из Вт_номенклатура ) и вот то что скобках, сделать конструктором, как в толстом клиенте, а не руками писать.

Тоже интересует есть ли такая возможность у этой консоли? По фотке похоже, что нет?

53. ROL32 488 28.12.22 09:57 Сейчас в теме

(52) Такой возможности нет.
Консоль использует платформенный конструктор запросов.
В тонком клиенте конструктор несколько урезан (вопрос к разработчикам платформы 1С), поэтому вылетает эта ошибка.
Пока единственный выход - это запустить консоль под толстым клиентом или написать этот запрос руками.
Чтобы не писать руками, можно предварительно сформировать этот запрос отдельно в констукторе, а потом текст вставить в условие.

50. ImPenguin 35 21.10.22 08:12 Сейчас в теме

Добрый день! Очень полезный конструктор запросов, особенно радует просмотр временных таблиц и возможность в качестве параметров передавать УникальныйИдентификатор, спасибо вам.
Но вот почему-то не нашел элементарной вещи. Когда вставляешь текст запроса из конфигуратора в консоль, он содержит символы переноса строк и двойных ковычек (ведь это строка), и нет кнопки по которой можно было бы их быстро убрать... (может я просто не нашел). Поэтому вот вам небольшая команда, добавьте пожалуйста, думаю будет очень полезно.

Индекс = 1;
Пока Индекс <= _ТекстЗапроса.КоличествоСтрок() Цикл
	_ТекстЗапроса.ЗаменитьСтроку(Индекс, СтрЗаменить(_ТекстЗапроса.ПолучитьСтроку(Индекс), "|", ""));
	_ТекстЗапроса.ЗаменитьСтроку(Индекс, СтрЗаменить(_ТекстЗапроса.ПолучитьСтроку(Индекс), """""", """"));
	Индекс = Индекс + 1;
КонецЦикла;

51. ROL32 488 21.10.22 14:54 Сейчас в теме

(50) Добрый день! Спасибо за отзыв.
Такой кнопки действительно нет - не хотел нагружать интерфейс, посчитал, что нажать Ctrl+H и выполнить замену не сложно.
Может быть добавлю такую команду.
Кроме того из конструктора можно вствить запрос без не нужных символов - в конфигураторе открыть конструктор запроса, нажать кнопку Запрос и получить нормальный текст запроса.

54. Rafaraf 33 17.01.23 16:59 Сейчас в теме

Забрал, спасибо! играюсь....есть ли возможность поделиться своими алгоритмами обработки ? сюда можно скинуть )

55. ROL32 488 17.01.23 19:09 Сейчас в теме

(54) Код обработки открыт

56. Rafaraf 33 18.01.23 14:18 Сейчас в теме

(55) я имел в виду с закладки «Алгоритмы» обработки, на скриншоте у Вас есть разные варианты, хорошо бы тоже прикрепить к статье как примеры

57. ROL32 488 18.01.23 20:25 Сейчас в теме

(56) Ясно
алгоритмы всегда разные - это способ быстро поправить данные для объектов, которые вы получили запросом
для примера написания, можно нажать конпку "Пример (клиент)" или ""Пример (сервер)"

пример конкретного полезного алгоритма приложу в описании обработки позже

62. Katherine 22.03.23 12:19 Сейчас в теме

Добрый день. Олег, спасибо за ваш набор инструментов - консоль, редактор объектов, навигатор. Очень удобные инструменты, много помогают в решении "внутренних" задач.
По консоли (1.1.0.83) есть такая проблема. В Толстом клиенте при открытии запроса в конструкторе запроса нет вкладки Итоги. В Тонком клиенте все нормально. В 77 версии вкладка Итоги есть, а с 79 уже пропала.
В 87 есть Итоги в Толстом клиенте или стоит подождать исправления?

И если не сложно, добавьте пожалуйста возможность сохранить результат запроса в Excel-файл. Иногда нужно анализировать в экселе данные, а писать отчет не хочется, проще и удобнее воспользоваться консолью. :)

Прикрепленные файлы:

63. ROL32 488 22.03.23 16:29 Сейчас в теме

(62) Добрый день, спасибо за отзыв.
1. Закладка Итоги: консоль использует платформенный конструктор запросов - если он открывается в "режиме компоновки данных", то вкладка "Итоги" не видна.
Можно поправить самому: откройте обработку в конфигураторе, в модуле формы "Форма" найдите и закомментарьте строку

Конструктор.РежимКомпоновкиДанных = истина;

2. с Excel возиться не хочу, тем не менее выгрузить в Excel можно:
- результат запроса выгрузить в табличный документ (кнопка "Еще", "Вывести список")
- получившийся табличный документ можно сохранить в различном формате средствами платформы

64. Katherine 03.04.23 16:51 Сейчас в теме

Добрый день.
Олег, спасибо за опциональность режима компоновки данных в 89. Только на днях скачала 87 версию и там закомментировала строку по вашему совету. Но опция универсальнее конечно.

А о выводе списка для выгрузки в Excel почему-то не подумала ;) . Спасибо.

65. nialorg 28.04.23 07:51 Сейчас в теме

Олег, добрый день! Я бы хотел выразить свою благодарность Олегу за создание такой удивительной и полезной обработки. Это действительно помогло мне сэкономить время и улучшить мою производительность на работе. Я ценю ваш талант и профессионализм, а также вашу способность создавать такие продукты, которые вносят реальную пользу в повседневную жизнь людей. Обработка, которую вы создали, действительно стала для меня находкой, и я не представляю свою работу без нее.

Рекомендую Олега и его обработку всем, кто ищет эффективные инструменты для упрощения своей работы.

Спасибо вам, Олег, за то, что вы делаете!)

66. ROL32 488 28.04.23 11:46 Сейчас в теме

(65) Большое спасибо за отзыв!

67. qeos 115 03.05.23 17:13 Сейчас в теме

А можете переписать вывод не в таблицу, а в табличный документ?

68. ROL32 488 03.05.23 17:58 Сейчас в теме

(67) Какой вывод? Если речь идет о результатах выполнения запросов, то этого делать не буду, есть много консолей, которые представляют результаты в табличном документе - это более простой вариант, но для меня не удобный.

69. qeos 115 03.05.23 19:03 Сейчас в теме

(68)
Да, речь о результатах.
Может можно вариант соответствующий сделать в параметра вывода?

И еще было бы хорошо выводить все результаты, а не только последний.

70. ROL32 488 03.05.23 20:13 Сейчас в теме

(69) Если в параметрах вывода указать "Таблица значений + временные таблицы", то вы получите все результаты (см. закладку "Временные таблицы")

71. ROL32 488 03.05.23 20:29 Сейчас в теме

(69) Вывод результатов в таблицы для меня более предпочителен по следующим причинам:
- в таблицах данные можно сортировать, устанавливать отбор
- таблицу результат можно поместить в параметр запроса или в менеджер временных таблиц
- из таблицы можно сразу открыть ссылочный объект (для табличного документа придется делать расшифровку)
- по экспериментам для больших объемов данных работает быстрее
- чисто субъективно мне больше нравится

Хотя, возможно сделаю (когда будет время) отдельную команду для вывода всех результатов в табличный документ, в принципе это не сложно.
Пока отвечал пришла мысль когда это будет полезно.

72. pau74 82 25.07.23 10:36 Сейчас в теме

Есть ли возможность в алгоритме использовать результат запроса, выведенного в дерево значений?
В этом случае параметр ТабРезультат пустой.

73. ROL32 488 25.07.23 15:40 Сейчас в теме

(72) Попробуйте использовать параметр _ДеревоРезультатыЗапроса

74. Merkalov 8 22.09.23 03:38 Сейчас в теме

Если в пакетном запросе последним будет уничтожение временной таблицы - то в таблицу с результатом ничего не попадает. На мой взгляд было бы удобнее все же выдавать результат последнего запроса за исключением запросов на уничтожение временный таблиц.