Внешняя компонента для выполнения регулярных выражений

Рег.НайтиСовпадения("Hello world", "([A-Za-z]+)\s+([a-z]+)", Истина); // Истина -  иерархический обход

Сообщить( Рег.Количество()); // 1 - всего один результат, а не 3 
Сообщить( Рег.КоличествоВложенныхГрупп()); // 2 - две подгруппы (submatches)

//Обходим MatchCollection
Пока Рег.Следующий() Цикл
Сообщить(Рег.ТекущееЗначение); // Hello world
Сообщить(Рег.ПолучитьПодгруппу(0)); // Hello
Сообщить(Рег.ПолучитьПодгруппу(1)); // world
КонецЦикла;

	Рег = Новый("AddIn.Component.RegEx");
	Рег.ВсеСовпадения = Истина;
	Рег.Многострочный = Истина;
	Рег.IgnoreCase = Истина;
	Рег.ВызыватьИсключения = Истина;
	Рег.Шаблон = "([^\W]\w+\.(?:(?!\w )[^\s]\w+){1,})";

	СтрокаПоиска = "ВЫБОР
		|КОГДА Договор.ВидОперации = ЗНАЧЕНИЕ(Перечисление.навВидыОперацийДоговор.СоглашениеОПеременеСтороны)
		|		И НЕ Договор.ПрежнийАгент = ЗНАЧЕНИЕ(Справочник.Контрагенты.ПустаяСсылка)
		|		И НЕ Договор.АгентскийДоговорОсновной = ЗНАЧЕНИЕ(Документ.Договор.ПустаяСсылка)
		|	ТОГДА Договор.АгентскийДоговорОсновной.НомерДоговора";

		СписокГрупп = Новый СписокЗначений;
		Рег.НайтиСовпадения(СтрокаПоиска,, Ложь);
		Пока  Рег.Следующий() Цикл
			СписокГрупп.Добавить(Рег.ТекущееЗначение);
		КонецЦикла; 

SELECT
		|CASE Contract.Vid = VALUE(ENUMERATION.VidContract.Soglash)
		|		AND NOT Contract.LastAgent= VALUE(Catalog.Contragent.Empty)
		|		AND NOT Contract.ContractMain = VALUE(Doc.Contract.Empty)
		|	ТОГДА Contract.ContractMain.NumberContractа

Шаблон = "(Адаптац(ия|ию|ей) и сопровожден(ие|ия|ию) экземпляр(ов|а) Систем|Услуг( |и )по адаптации и сопровожден(ие|ия|ию)|Сопровожден(ие|ия|ию) адаптированн(ых|ого)( | Исполнителем )экземпляр(ов|а) Систем)";

ТекстДокумента = "Сопровождение адаптированных Исполнителем экземпляров Систем";

RegExp.Matches(ТекстДокумента, Шаблон);

#Область ИспользованиеКомпонентыRegEx

////////////////////////////////////////////////////////////­////////////////////////////////////////////
// Методы для работы с компонентой разбора текста регулярным выражением.
// Компонента сохранена в виде общего макета RegEx. Для ее использования, необходимо сохранить
// содержимое макета (zip-архив) в справочник ВнешниеКомпоненты.  
//
// Ссылки:
// https://infostart.ru/1c/tools/940766/
// https://github.com/alexkmbk/RegEx1CAddin/releases
////////////////////////////////////////////////////////////­/////////////////////////////////////////////

// Создает экземпляр компоненты RegEx. При необходимости, подключает компоненту.
// 
// Возвращаемое значение:
//  Произвольный - Созданная компонента.
//
Функция РегСоздать() Экспорт   
	
	// Вероятно, нужно модифицировать метод, чтобы можно было использовать асинхронное подключение на клиенте.
	
	ИмяКомпоненты = "AddIn.Component.RegEx";
	
	Попытка
		Компонента = Новый(ИмяКомпоненты);
	Исключение  
		Подключено = РегПодключитьСинхронно();
		Если Не Подключено Тогда
			ВызватьИсключение(СтрШаблон(НСтр("ru = 'Не удалось подключить компоненту %1'"), ИмяКомпоненты));
		КонецЕсли; 
		Компонента = Новый(ИмяКомпоненты);
	КонецПопытки;      
	
	Возврат Компонента;
	
КонецФункции  

Функция РегПодключитьСинхронно() Экспорт   
	#Если ТонкийКлиент Или ВебКлиент Тогда
	УстановитьВнешнююКомпоненту("ОбщийМакет.RegEx");
	#КонецЕсли
	Возврат ПодключитьВнешнююКомпоненту("ОбщийМакет.RegEx", "Component", ТипВнешнейКомпоненты.Native);
КонецФункции  

// Метод выполняет поиск в переданном тексте по переданному регулярному выражению.
//  Результатом выполнения метода будет массив результатов поиска.
//  
//  Для того, чтобы получить результаты выполнения метода (массив результатов), необходимо
//  выполнить метод Следующий/Next(), и после этого, в свойстве ТекущееЗначение/CurrentValue будет доступно
//  значение текущей подгруппы результата выполнения (текущий элемент массива результатов).
//  Идея похожа на обход результата запроса.
//  
//  Пример:
//  Рег.НайтиСовпадения("Hello world", "([A-Za-z]+)\s+([a-z]+)");
//  Пока Рег.Следующий() Цикл
//  	Сообщить(Рег.ТекущееЗначение);
//  КонецЦикла;
//
// Параметры:
//  Компонента						 - Произвольный	 - Компонента RegEx
//  ТекстДляАнализа					 - Строка		 - Анализируемый текст
//  РегулярноеВыражение				 - Строка		 - Регулярное выражение. Если не задано, то берется из свойства Шаблон.
//  ИерархическийОбходРезультатов	 - Булево		 - Определяет то, как будет осуществлен обход результатов.
//  		По умолчанию = Ложь. Если ИерархическийОбходРезультатов=Ложь, тогда каждый элемент массива результатов поиска - найденная подгруппа поиска.
//  		Если подгрупп нет, то массив будет содержать один элемент - найденную строку.
//  		Если ИерархическийОбходРезультатов=Истина, тогда, каждый элемент массива результатов поиска будет содержать
//  		только найденную строку, а значение подгруппы при их наличии, можно будет получить методом ПолучитьПодгруппу.
//
Процедура РегНайтиСовпадения(Компонента, 
		ТекстДляАнализа, РегулярноеВыражение = Неопределено, ИерархическийОбходРезультатов = Ложь) Экспорт
	Компонента.НайтиСовпадения(ТекстДляАнализа, РегулярноеВыражение, ИерархическийОбходРезультатов)
КонецПроцедуры 

// Выполняет переход к следующему найденному фрагменту - аналогично методу выборки Следующий().
//
// Параметры:
//  Компонента	- Произвольный	 - Компонента RegEx
// 
// Возвращаемое значение:
//  Булево - Удалось ли перейти к следующему найденному фрагменту.
//
Функция РегСледующий(Компонента) Экспорт
	Возврат Компонента.Следующий();
КонецФункции

// Возвращает количество результатов поиска, после выполнения метода РегНайтиСовпадения
//
// Параметры:
//  Компонента	- Произвольный	 - Компонента RegEx
// 
// Возвращаемое значение:
//  Число - Количество результатов поиска
//
Функция РегКоличество(Компонента) Экспорт 
	Возврат Компонента.Количество();
КонецФункции                        

// Возвращает количество групп (подгрупп\SubMatches) если в шаблоне были заданы группы.
//  Например, для шаблона ([A-Za-z]+)\s+([a-z]+) будет возвращено значение 2.
//  Метод возвращает значение только после выполнения метода РегНайтиСовпадения
//
// Параметры:
//  Компонента	- Произвольный	 - Компонента RegEx
// 
// Возвращаемое значение:
//  Число - количество групп
//
Функция РегКоличествоВложенныхГрупп(Компонента) Экспорт
	Возврат Компонента.КоличествоВложенныхГрупп();
КонецФункции  

// Возвращает строковое значение подгруппы из результатов поиска методом НайтиСовпадения.
//
// Параметры:
//  Компонента		 - Произвольный	 - Компонента RegEx
//  ИндексПодгруппы	 - Число		 - Задает индекс группы, который следует получить(доступны значения от 0 до КоличествоВложенныхГрупп - 1)
// 
// Возвращаемое значение:
//  Строка - Строковое значение подгруппы из результатов поиска методом РегНайтиСовпадения
//
Функция РегПолучитьПодгруппу(Компонента, ИндексПодгруппы) Экспорт
	Возврат Компонента.ПолучитьПодгруппу(ИндексПодгруппы);	
КонецФункции  

// Выполняет поиск в переданном тексте по переданному регулярному выражению.
//  Результатом выполнения метода будет строка в формате JSON представляющая собой массив структур.
//  Метод позволяет значительно быстрее получить и обработать результат поиска
//  (за счет минимизации вызовов методов через NativeAPI).
//
// Параметры:
//  Компонента			 - Произвольный	 - Компонента RegEx
//  ТекстДляАнализа		 - Строка		 - Анализируемый текст
//  РегулярноеВыражение	 - Строка		 - Регулярное выражение. Если не задано, то берется из свойства Шаблон.
// 
// Возвращаемое значение:
//  Строка - Строка в формате JSON представляющая собой массив структур
//
Функция РегНайтиСовпаденияJSON(Компонента, ТекстДляАнализа, РегулярноеВыражение = Неопределено) Экспорт
	Возврат Компонента.НайтиСовпаденияJSON(ТекстДляАнализа, РегулярноеВыражение);
КонецФункции  

// Заменяет в переданном тексте часть, соответствующую регулярному выражению, значением, переданным параметром ЗначениеДляЗамены.
//
// Параметры:
//  Компонента			 - Произвольный	 - Компонента RegEx
//  ТекстДляАнализа		 - Строка		 - Анализируемый текст
//  РегулярноеВыражение	 - Строка		 - Регулярное выражение. Если не задано, то берется из свойства Шаблон.
//  ЗначениеДляЗамены	 - Строка		 - Значение для замены
// 
// Возвращаемое значение:
//  Строка - Строка с замененными фрагментами
//
Функция РегЗаменить(Компонента, ТекстДляАнализа, РегулярноеВыражение = Неопределено, ЗначениеДляЗамены = Неопределено) Экспорт
	Возврат Компонента.Заменить(ТекстДляАнализа, РегулярноеВыражение, ЗначениеДляЗамены);
КонецФункции 

// Делает проверку на соответствие текста регулярному выражению.
//
// Параметры:
//  Компонента			 - Произвольный	 - Компонента RegEx
//  ТекстДляАнализа		 - Строка		 - Анализируемый текст
//  РегулярноеВыражение	 - Строка		 - Регулярное выражение. Если не задано, то берется из свойства Шаблон.
// 
// Возвращаемое значение:
//  Булево - Возвращает значение Истина если текст соответствует регулярному выражению
//
Функция РегСовпадает(Компонента, ТекстДляАнализа, РегулярноеВыражение = Неопределено) Экспорт
	Возврат Компонента.Совпадает(ТекстДляАнализа, РегулярноеВыражение);
КонецФункции  

// Возвращает номер версии компоненты в виде строки.
//
// Параметры:
//  Компонента	 - Произвольный	 - Компонента RegEx
// 
// Возвращаемое значение:
//  Строка - Номер версии компоненты в виде строки
//
Функция РегВерсия(Компонента) Экспорт 
	Возврат Компонента.Версия();
КонецФункции 

// Получает или устанавливает свойство компоненты.
//  Если Задано значение параметра Значение (<>Неопределено), то происходит установка значения соответствующего свойства.
//  Однако, режим можно задавать директивно, параметром УстановитьЗначение. Если передать Булево, то это явно укажет,
//  что необходимо выполнить - прочитать или установить значение.
//
// Параметры:
//  Компонента			 - Произвольный			 - Компонента RegEx
//  ИмяСвойства			 - Строка				 - Имя свойства. Варианты:
//		*ВсеСовпадения	- Булево	- Если установлено в Истина, то поиск будет выполняться по всем совпадениям, а не только по первому.
//		*Многострочный	- Булево	- Если установлено в Истина, то началом строки считаются также и символы перевода строки.
//			Значение по умолчанию: Истина.
//		*ИгнорироватьРегистр	- Булево	- Если установлено в Истина, то поиск будет осуществляться без учета регистра.
//			Значение по умолчанию: Ложь.                                                    
//		*Шаблон			- Строка	- Задает регулярное выражение которое будет использоваться при вызове методов компоненты, 
//			если в метод не передано значение регулярного выражения.  
//			Значение по умолчанию: пустая строка. 
//		*FirstIndex		- Число		- Аналог свойства FirstIndex из VBScript.RegExp. 
//			Возвращает индекс (начинается с 0) первого символа найденного текста в исходной строке.
//		*UCP			- Булево	- Свойство устанавливает флаг PCRE2_UCP в методе pcre2_compile, 
//			что включает обработку всех символов Unicode для директив \W и \w (а не только ASCII).
//			Значение по умолчанию: Ложь.
//		*ОписаниеОшибки	- Строка	- Содержит текст последней ошибки. Если ошибки не было, то пустая строка.
//			Значение по умолчанию: пустая строка.
//		*ВызыватьИсключения	- Булево	- Если установлена в Истина, то при возникновении ошибки, 
//			будет вызываться исключение, при обработке исключения, текст ошибки можно получить
//			из свойства ErrorDescription\ОписаниеОшибки. 
//		*ТекущееЗначение	- Строка	- Текущее значение найденного фрагмента при выполнении метода РегСледующий().
//  Значение			 - Произвольный, Неопределено	 - Устанавливаемое значение
//  УстановитьЗначение	 - Булево, Неопределено			 - Режим установки/чтения свойства.
// 
// Возвращаемое значение:
//  Произвольный, Неопределено - Если это установка свойства, то возвращается Неопределено.
//
Функция РегПолучитьУстановитьСвойство(Компонента, ИмяСвойства, Значение = Неопределено, УстановитьЗначение = Неопределено) Экспорт
	
	Результат = Неопределено;
	
	Если ТипЗнч(УстановитьЗначение)=Тип("Булево") Тогда
		ТребуетсяУстановитьЗначение = УстановитьЗначение;
	Иначе     
		ТребуетсяУстановитьЗначение = Значение<>Неопределено;
	КонецЕсли;

	Если ТребуетсяУстановитьЗначение Тогда 
		Компонента[ИмяСвойства] = Значение;
	Иначе 
		Результат = Компонента[ИмяСвойства];
	КонецЕсли;
	
	Возврат Результат;
	
КонецФункции

#КонецОбласти // ИспользованиеКомпонентыRegEx