Вышла версия 8.3.11 «1С:Предприятия»

Процедура ЗаполнитьСтавкуНДСТабЧасти(СтрокаТабличнойЧасти, ДокументОбъект, ВидДокумента = "") Экспорт

	ИмяТабличнойЧасти = ОбщегоНазначения.ПолучитьИмяТабличнойЧастиПоСсылкеНаСтроку(СтрокаТабличнойЧасти);
	МетаданныеДокумента = ДокументОбъект.Метаданные();
	РеквизитыТабличнойЧасти = Новый Массив;

	ОписаниеТиповТабличнаяЧастьОбработки = Новый ОписаниеТипов("ОбработкаТабличнаяЧастьСтрока.ОбработкаТабличнойЧастиТовары.Товары");
	Если ОписаниеТиповТабличнаяЧастьОбработки.СодержитТип(ТипЗнч(СтрокаТабличнойЧасти)) Тогда
		//Передана строка табличной части обработки ОбработкаТабличнойЧастиТовары
		РеквизитыТабличнойЧасти = Метаданные.Обработки.ОбработкаТабличнойЧастиТовары.ТабличныеЧасти.Товары.Реквизиты;
	Иначе
		ОписаниеТиповТабличнаяЧастьДокумента = Новый ОписаниеТипов("ДокументТабличнаяЧастьСтрока."+МетаданныеДокумента.Имя+"."+ИмяТабличнойЧасти);
		Если ОписаниеТиповТабличнаяЧастьДокумента.СодержитТип(ТипЗнч(СтрокаТабличнойЧасти)) Тогда
			//Передана строка табличной части документа ДокументОбъект
			Если МетаданныеДокумента.ТабличныеЧасти.Найти(ИмяТабличнойЧасти) <> Неопределено Тогда
				РеквизитыТабличнойЧасти = МетаданныеДокумента.ТабличныеЧасти[ИмяТабличнойЧасти].Реквизиты;
			КонецЕсли;
		КонецЕсли;
	КонецЕсли;

	//Заполнить СтавкаНДС
	Если РеквизитыТабличнойЧасти.Найти("СтавкаНДС")<>неопределено Тогда
		НеЯвляетсяРезидентом = ?(МетаданныеДокумента.Реквизиты.Найти("Контрагент") <> Неопределено И ТипЗнч(ДокументОбъект.Контрагент) = Тип("СправочникСсылка.Контрагенты"), ?(ДокументОбъект.Контрагент.НеЯвляетсяРезидентом = Истина, Истина, Ложь), Ложь);
		ЕстьДоговорКонтрагента = МетаданныеДокумента.Реквизиты.Найти("ДоговорКонтрагента") <> Неопределено;
		Если ЕстьДоговорКонтрагента Тогда
			ТекДоговорКонтрагента = ДокументОбъект.ДоговорКонтрагента;
		Иначе
			Если ТипЗнч(ДокументОбъект) = Тип("ДокументОбъект.КорректировкаЗаказаПокупателя") Тогда
				ЕстьДоговорКонтрагента = Истина;
				ТекДоговорКонтрагента = ДокументОбъект.ЗаказПокупателя.ДоговорКонтрагента;
			ИначеЕсли ТипЗнч(ДокументОбъект) = Тип("ДокументОбъект.КорректировкаЗаказаПоставщику") Тогда
				ЕстьДоговорКонтрагента = Истина;
				ТекДоговорКонтрагента = ДокументОбъект.ЗаказПоставщику.ДоговорКонтрагента;
			КонецЕсли;
		КонецЕсли;
		
		РеализацияНаЭкспорт = ?(ЕстьДоговорКонтрагента, ?(ТекДоговорКонтрагента.РеализацияНаЭкспорт = Истина, Истина, Ложь), Ложь);
		НалоговыйАгентНерезидент = ?(ЕстьДоговорКонтрагента, ?(ТекДоговорКонтрагента.УчетАгентскогоНДС = Истина И ТекДоговорКонтрагента.ВидАгентскогоДоговора = Перечисления.ВидыАгентскихДоговоров.Нерезидент, Истина, Ложь), Ложь);
		Если НеЯвляетсяРезидентом И Не НалоговыйАгентНерезидент И ВидДокумента = "Приобретение" Тогда
			СтрокаТабличнойЧасти.СтавкаНДС = Перечисления.СтавкиНДС.БезНДС;
			Возврат;
		ИначеЕсли РеализацияНаЭкспорт И ВидДокумента = "Реализация" Тогда
			СтрокаТабличнойЧасти.СтавкаНДС = Перечисления.СтавкиНДС.НДС0;
			//возможно, дальше ставка будет изменена на БезНДС, если применяется ЕНВД
		Иначе
			СтрокаТабличнойЧасти.СтавкаНДС = СтрокаТабличнойЧасти.Номенклатура.СтавкаНДС;
		КонецЕсли;
		
		ЕстьОрганизация = (НЕ МетаданныеДокумента.Реквизиты.Найти("Организация") = Неопределено);
		ЕстьСчетДоходовБУ = (РеквизитыТабличнойЧасти.Найти("СчетДоходовБУ")<>неопределено);
		ЭтоРеализация = ЕстьСчетДоходовБУ ИЛИ РеквизитыТабличнойЧасти.Найти("ПроцентСкидкиНаценки")<>неопределено;
		
		//В документах реализации, для организаций применяющих УСН устанавливать ставку "БезНДС"
		Если ЭтоРеализация Тогда
			Если ЕстьОрганизация Тогда
				УчетнаяПолитика = ОбщегоНазначения.ПолучитьПараметрыУчетнойПолитикиРегл(ДокументОбъект.Дата, ДокументОбъект.Организация);
				Если ЗначениеЗаполнено(УчетнаяПолитика) И (УчетнаяПолитика.СистемаНалогообложения = Перечисления.СистемыНалогообложения.Упрощенная
						ИЛИ УчетнаяПолитика.ПрименяетсяОсвобождениеОтУплатыНДС) Тогда
					СтрокаТабличнойЧасти.СтавкаНДС = Перечисления.СтавкиНДС.БезНДС;
					Возврат;
				КонецЕсли;
			Иначе
				УчетнаяПолитика = Неопределено;
			КонецЕсли;
			
			//В документах реализации, для ЕНВД устанавливать ставку "БезНДС"
			ЕстьСчетДоходовБУ = ?(ЕстьСчетДоходовБУ, ЗначениеЗаполнено(СтрокаТабличнойЧасти.СчетДоходовБУ), Ложь);
			Если ЕстьСчетДоходовБУ Тогда
				//Определяем вид деятельности по счету доходов
				Если НалоговыйУчетУСН.ОтноситсяКДеятельностиЕНВД(СтрокаТабличнойЧасти.СчетДоходовБУ) Тогда
					СтрокаТабличнойЧасти.СтавкаНДС = Перечисления.СтавкиНДС.БезНДС;
				КонецЕсли;
			ИначеЕсли ЕстьОрганизация И (НЕ ЕстьДоговорКонтрагента) Тогда
				//Если счет доходов не указан, для розничной продажи берем их учетной политики
				Если ЗначениеЗаполнено(УчетнаяПолитика) И (УчетнаяПолитика.РозничнаяТорговляОблагаетсяЕНВД) Тогда
					СтрокаТабличнойЧасти.СтавкаНДС = Перечисления.СтавкиНДС.БезНДС;
				КонецЕсли;
			КонецЕсли;
			
		КонецЕсли;
	КонецЕсли;

КонецПроцедуры // ЗаполнитьСтавкуНДСТабЧасти()