После того, как пересмотрел множество примеров шаблонов внешних обработок заполнения объектов, написал свою. Решил поделиться, чтобы вы могли не тратить время на проверку того, что можно передавать на сервер, где использовать РеквизитФормыВЗначение, а где КопироватьДанныеФормы :)
Задача:
1. Заполнение документа в форме, без записи.
2. Возможность отладки.
3. Минимум лишних действий.
Далее код, модуль обработки:
Функция СведенияОВнешнейОбработке() Экспорт
ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.2.2.1");
ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиЗаполнениеОбъекта();
ПараметрыРегистрации.Версия = "1.0";
ПараметрыРегистрации.Назначение.Добавить("Документ.Премия");
ПараметрыРегистрации.Наименование = НСтр("ru='Премия'");
ПараметрыРегистрации.Информация = НСтр("ru='Расчет премии'");
ПараметрыРегистрации.БезопасныйРежим = Ложь;
Команда = ПараметрыРегистрации.Команды.Добавить();
Команда.Идентификатор = "Премии";
Команда.Представление = "Рассчитать премии";
Команда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыЗаполнениеФормы();
Возврат ПараметрыРегистрации;
КонецФункции
Процедура ЗаполнитьПремии(Объект) Экспорт
Для Каждого Стр Из Объект.Начисления Цикл
Стр.Результат = 1000000;
КонецЦикла;
КонецПроцедуры
Процедура ВыполнитьКоманду(ИдентификаторКоманды, ОбъектыНазначения, ПараметрыКоманды) Экспорт
Если ИдентификаторКоманды = "Премии" Тогда
ЭтаФорма = ПараметрыКоманды.ЭтаФорма;
ЗаполнитьПремии(ЭтаФорма.Объект);
ЭтаФорма.Модифицированность = Истина;
Сообщение = Новый СообщениеПользователю();
Сообщение.Текст = НСтр("ru = 'Премии рассчитаны и заполнены'");
Сообщение.Сообщить();
КонецЕсли;
КонецПроцедуры
Процедура СведенияОВнешнейОбработке как в документации к БСП.
Здесь стоит обратить внимание на то, что при вызове функции ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке нужно указывать версию БСП, иначе будет выскакивать ошибка. Разумеется сообщение будет не о том, что этот функционал работает начиная с такой-то версии, а о том, что значение Форма не заполнено.
Заполнение Объекта вынесено в отдельную процедуру для того, чтобы была возможность вызвать её из модуля формы.
Модуль формы:
&НаСервере
Процедура ЗаполнитьНаСервере(ОбъектДокумент)
ОбработкаОбъект = РеквизитФормыВЗначение("Объект");
ОбработкаОбъект.ЗаполнитьПремии(ОбъектДокумент);
КонецПроцедуры
&НаКлиенте
Процедура Заполнить(Команда)
ПараметрыФормы = Новый Структура("Ключ", Объект.СсылкаНаДокумент);
ФормаДокумента = ПолучитьФорму("Документ.Премия.ФормаОбъекта", ПараметрыФормы);
ОбъектДокумент = ФормаДокумента.Объект;
ЗаполнитьНаСервере(ОбъектДокумент);
КопироватьДанныеФормы(ОбъектДокумент,ФормаДокумента.Объект);
ФормаДокумента.Открыть();
КонецПроцедуры
Здесь мы создаем форму существующего документа. Затем передаем копию объекта этой формы для заполнения на сервере. Форму и непосредственно объект формы на сервер передать нельзя. Копируем заполненную копию обратно в данные формы и открываем форму. В результате получаем заполненную форму документа без его записи.
Протестировано на релизе платформы 1С:Предприятие 8.3 (8.3.16.1063).
