Black Friday: Cashback 35% при покупке 1С лицензий на счет INFOSTART.RU

Произвольное закрытие 20,25,26 счетов

Публикация № 171719

Разработка - Практика программирования

28
Каждый программист сталкивался с тем, что штатными средствами распределение затрат происходит не так как требует главный бухгалтер. В этом случае приходится изменять стандартный механизм: изменять модули, создавать собственные документы, или использовать специальные обработки перед выполнением закрытия месяца, что создает сложность в обновлении. Но есть и другой подход...

В данной статье приводится пример на конфигурации "1С: Комплексная автоматизация 1.1" по созданию универсального механизма распределения затрат по 20ым счетам.

Не вдаваясь в подробности "что, как и почему?", начну с описания своих действий. Сразу замечу, что нам также необходимо добавить свои объекты в конфигруцию, но наши изменения никак не будут влиять на сложность последующего обновления конфигурации.

Первое действие: Открываем конфигуратор Smile

В конфигураторе добавляем общий модуль с специфичным названием "Алгоритм_ОбработкаПроведения". Обязательно выставляем: "Сервер" и "Привилегированный". "Сервер" - необходимо чтобы вызов нашего модуля происходил в последнюю очередь.

Добавленный общий модуль

В модуле прописываем следующий код:

/////----------------- Расчет себестоимости	+++

Процедура Алгоритм_ОбработкаПроведения_РасчетСебестоимостиВыпускаОбработкаПроведения(Источник, Отказ, РежимПроведения) Экспорт
	
	ВыбратьИВыполнитьАлгоритмыОчистки(Источник);
	
	ВыбратьИВыполнитьАлгоритмыРасчета(Источник);
	
КонецПроцедуры

Процедура ВыбратьИВыполнитьАлгоритмыОчистки(Источник)

	Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних.ХарактерЗатрат,
		|	Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних.АлгоритмБУ,
		|	Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних.АлгоритмНУ,
		|	Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних.АлгоритмБУРАУЗ
		|ИЗ
		|	РегистрСведений.Алгоритм_СпособыЗакрытияСебестоимости.СрезПоследних(&Период, ОчисткаДанных) КАК Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних";

	Запрос.УстановитьПараметр("Период", КонецМесяца(Источник.Дата));

	Результат = Запрос.Выполнить();

	ВыборкаДетальныеЗаписи = Результат.Выбрать();

	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
		////+++ Очищаем регистр бухгалтерии
		АлгоритмОчистки_СКД = ВыборкаДетальныеЗаписи.АлгоритмБУ.Получить();
		
		Для каждого АлгоритмОчистки_НаборДанных из АлгоритмОчистки_СКД.НаборыДанных Цикл
			АлгоритмОчистки_Запрос = Новый Запрос(АлгоритмОчистки_НаборДанных.Запрос);
			Для каждого АлгоритмОчистки_Праметры из АлгоритмОчистки_СКД.Параметры Цикл
				АлгоритмОчистки_Запрос.УстановитьПараметр(АлгоритмОчистки_Праметры.Имя, АлгоритмОчистки_Праметры.Значение);
			КонецЦикла;
			АлгоритмОчистки_Запрос.УстановитьПараметр("НачалоПериода", НачалоМесяца(Источник.Дата));
			АлгоритмОчистки_Запрос.УстановитьПараметр("КонецПериода", КонецМесяца(Источник.Дата));
			АлгоритмОчистки_Запрос.УстановитьПараметр("НачалоПериодаГраница", Новый Граница(НачалоМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмОчистки_Запрос.УстановитьПараметр("КонецПериодаГраница", Новый Граница(КонецМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмОчистки_Запрос.УстановитьПараметр("Регистратор", Источник.Ссылка);
			
			АлгоритмОчистки_Хозрасчетный = Источник.Движения.Хозрасчетный;
			АлгоритмОчистки_Хозрасчетный.Прочитать();
			
			АлгоритмОчистки_Выборка = АлгоритмОчистки_Запрос.Выполнить().Выбрать();
			Пока АлгоритмОчистки_Выборка.Следующий() Цикл
				НомерСтроки = АлгоритмОчистки_Выборка.НомерСтроки - 1;
				АлгоритмОчистки_Хозрасчетный.Удалить(НомерСтроки);
			КонецЦикла;
			Попытка АлгоритмОчистки_Хозрасчетный.Записать(); Исключение
				Сообщить("Ошибки в алгоритме очистки регистра",СтатусСообщения.ОченьВажное);
			КонецПопытки;
		КонецЦикла;
		////--- Очищаем регистр бухгалтерии
		
		////+++ Очищаем регистр налоговый
		АлгоритмОчистки_СКД = ВыборкаДетальныеЗаписи.АлгоритмНУ.Получить();
		
		Для каждого АлгоритмОчистки_НаборДанных из АлгоритмОчистки_СКД.НаборыДанных Цикл
			АлгоритмОчистки_Запрос = Новый Запрос(АлгоритмОчистки_НаборДанных.Запрос);
			Для каждого АлгоритмОчистки_Праметры из АлгоритмОчистки_СКД.Параметры Цикл
				АлгоритмОчистки_Запрос.УстановитьПараметр(АлгоритмОчистки_Праметры.Имя, АлгоритмОчистки_Праметры.Значение);
			КонецЦикла;
			АлгоритмОчистки_Запрос.УстановитьПараметр("НачалоПериода", НачалоМесяца(Источник.Дата));
			АлгоритмОчистки_Запрос.УстановитьПараметр("КонецПериода", КонецМесяца(Источник.Дата));
			АлгоритмОчистки_Запрос.УстановитьПараметр("НачалоПериодаГраница", Новый Граница(НачалоМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмОчистки_Запрос.УстановитьПараметр("КонецПериодаГраница", Новый Граница(КонецМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмОчистки_Запрос.УстановитьПараметр("Регистратор", Источник.Ссылка);
			
			АлгоритмОчистки_Налоговый = Источник.Движения.Налоговый;
			АлгоритмОчистки_Налоговый.Прочитать();
			
			АлгоритмОчистки_Выборка = АлгоритмОчистки_Запрос.Выполнить().Выбрать();
			Пока АлгоритмОчистки_Выборка.Следующий() Цикл
				НомерСтроки = АлгоритмОчистки_Выборка.НомерСтроки - 1;
				АлгоритмОчистки_Налоговый.Удалить(НомерСтроки);
			КонецЦикла;
			АлгоритмОчистки_Налоговый.Записать();
		КонецЦикла;
		////--- Очищаем регистр налоговый
		
		////+++ Очищаем регистр РАУЗРегл
		АлгоритмОчистки_СКД = ВыборкаДетальныеЗаписи.АлгоритмБУРАУЗ.Получить();
		
		Для каждого АлгоритмОчистки_НаборДанных из АлгоритмОчистки_СКД.НаборыДанных Цикл
			АлгоритмОчистки_Запрос = Новый Запрос(АлгоритмОчистки_НаборДанных.Запрос);
			Для каждого АлгоритмОчистки_Праметры из АлгоритмОчистки_СКД.Параметры Цикл
				АлгоритмОчистки_Запрос.УстановитьПараметр(АлгоритмОчистки_Праметры.Имя, АлгоритмОчистки_Праметры.Значение);
			КонецЦикла;
			АлгоритмОчистки_Запрос.УстановитьПараметр("НачалоПериода", НачалоМесяца(Источник.Дата));
			АлгоритмОчистки_Запрос.УстановитьПараметр("КонецПериода", КонецМесяца(Источник.Дата));
			АлгоритмОчистки_Запрос.УстановитьПараметр("НачалоПериодаГраница", Новый Граница(НачалоМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмОчистки_Запрос.УстановитьПараметр("КонецПериодаГраница", Новый Граница(КонецМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмОчистки_Запрос.УстановитьПараметр("Регистратор", Источник.Ссылка);
			
			АлгоритмОчистки_УчетЗатратРегл = Источник.Движения.УчетЗатратРегл;
			АлгоритмОчистки_УчетЗатратРегл.Прочитать();
			
			АлгоритмОчистки_Выборка = АлгоритмОчистки_Запрос.Выполнить().Выбрать();
			Пока АлгоритмОчистки_Выборка.Следующий() Цикл
				НомерСтроки = АлгоритмОчистки_Выборка.НомерСтроки - 1;
				АлгоритмОчистки_УчетЗатратРегл.Удалить(НомерСтроки);
			КонецЦикла;
			АлгоритмОчистки_УчетЗатратРегл.Записать();
		КонецЦикла;
		////--- Очищаем регистр РАУЗРегл
	КонецЦикла;

КонецПроцедуры
	
Процедура ВыбратьИВыполнитьАлгоритмыРасчета(Источник)
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
		"ВЫБРАТЬ
		|	Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних.ХарактерЗатрат,
		|	Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних.АлгоритмБУ,
		|	Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних.АлгоритмНУ,
		|	Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних.АлгоритмБУРАУЗ
		|ИЗ
		|	РегистрСведений.Алгоритм_СпособыЗакрытияСебестоимости.СрезПоследних(&Период, (НЕ ОчисткаДанных)) КАК Алгоритм_СпособыЗакрытияСебестоимостиСрезПоследних";

	Запрос.УстановитьПараметр("Период", КонецМесяца(Источник.Дата));

	Результат = Запрос.Выполнить();

	ВыборкаДетальныеЗаписи = Результат.Выбрать();

	Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
		////+++ Пишем регистр бухгалтерии
		АлгоритмЗаполнения_СКД = ВыборкаДетальныеЗаписи.АлгоритмБУ.Получить();
		
		Для каждого АлгоритмЗаполнения_НаборДанных из АлгоритмЗаполнения_СКД.НаборыДанных Цикл
			АлгоритмЗаполнения_Запрос = Новый Запрос(АлгоритмЗаполнения_НаборДанных.Запрос);
			Для каждого АлгоритмЗаполнения_Праметры из АлгоритмЗаполнения_СКД.Параметры Цикл
				АлгоритмЗаполнения_Запрос.УстановитьПараметр(АлгоритмЗаполнения_Праметры.Имя, АлгоритмЗаполнения_Праметры.Значение);
			КонецЦикла;
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("НачалоПериода", НачалоМесяца(Источник.Дата));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("КонецПериода", КонецМесяца(Источник.Дата));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("НачалоПериодаГраница", Новый Граница(НачалоМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("КонецПериодаГраница", Новый Граница(КонецМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("Регистратор", Источник.Ссылка);
			
			АлгоритмЗаполнения_Хозрасчетный = Источник.Движения.Хозрасчетный;
			АлгоритмЗаполнения_Хозрасчетный.Прочитать();
			
			АлгоритмЗаполнения_Выборка = АлгоритмЗаполнения_Запрос.Выполнить().Выбрать();
			Пока АлгоритмЗаполнения_Выборка.Следующий() Цикл
				АлгоритмЗаполнения_Запись = АлгоритмЗаполнения_Хозрасчетный.Добавить();
				ЗаполнитьЗначенияСвойств(АлгоритмЗаполнения_Запись, АлгоритмЗаполнения_Выборка);
				Для и1 = 1 по 3 Цикл
					Попытка
						Знач_Субк = АлгоритмЗаполнения_Выборка["СубконтоДт"+и1];
						СчетДт = АлгоритмЗаполнения_Выборка["СчетДт"];
						ВидСубконто = ОпределитьВидСубконто(СчетДт, Знач_Субк);
						Если не ВидСубконто = неопределено Тогда
							АлгоритмЗаполнения_Запись.СубконтоДт.Вставить(ВидСубконто, Знач_Субк);
						КонецЕсли;
					Исключение КонецПопытки;
					
					Попытка
						Знач_Субк = АлгоритмЗаполнения_Выборка["СубконтоКт"+и1];
						СчетКт = АлгоритмЗаполнения_Выборка["СчетКт"];
						ВидСубконто = ОпределитьВидСубконто(СчетКт, Знач_Субк);
						Если не ВидСубконто = неопределено Тогда
							АлгоритмЗаполнения_Запись.СубконтоКт.Вставить(ВидСубконто, Знач_Субк);
						КонецЕсли;
					Исключение КонецПопытки;
				КонецЦикла;
			КонецЦикла;
			АлгоритмЗаполнения_Хозрасчетный.Записать();
		КонецЦикла;
		////--- Пишем регистр бухгалтерии
		
		////+++ Пишем регистр налоговый
		АлгоритмЗаполнения_СКД = ВыборкаДетальныеЗаписи.АлгоритмНУ.Получить();
		
		Для каждого АлгоритмЗаполнения_НаборДанных из АлгоритмЗаполнения_СКД.НаборыДанных Цикл
			АлгоритмЗаполнения_Запрос = Новый Запрос(АлгоритмЗаполнения_НаборДанных.Запрос);
			Для каждого АлгоритмЗаполнения_Праметры из АлгоритмЗаполнения_СКД.Параметры Цикл
				АлгоритмЗаполнения_Запрос.УстановитьПараметр(АлгоритмЗаполнения_Праметры.Имя, АлгоритмЗаполнения_Праметры.Значение);
			КонецЦикла;
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("НачалоПериода", НачалоМесяца(Источник.Дата));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("КонецПериода", КонецМесяца(Источник.Дата));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("НачалоПериодаГраница", Новый Граница(НачалоМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("КонецПериодаГраница", Новый Граница(КонецМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("Регистратор", Источник.Ссылка);
			
			АлгоритмЗаполнения_Налоговый = Источник.Движения.Налоговый;
			АлгоритмЗаполнения_Налоговый.Прочитать();
			
			АлгоритмЗаполнения_Выборка = АлгоритмЗаполнения_Запрос.Выполнить().Выбрать();
			Пока АлгоритмЗаполнения_Выборка.Следующий() Цикл
				АлгоритмЗаполнения_Запись = АлгоритмЗаполнения_Налоговый.Добавить();
				ЗаполнитьЗначенияСвойств(АлгоритмЗаполнения_Запись, АлгоритмЗаполнения_Выборка);
				Для и1 = 1 по 3 Цикл
					Попытка
						Знач_Субк = АлгоритмЗаполнения_Выборка["СубконтоДт"+и1];
						СчетДт = АлгоритмЗаполнения_Выборка["СчетДт"];
						ВидСубконто = ОпределитьВидСубконто(СчетДт, Знач_Субк);
						Если не ВидСубконто = неопределено Тогда
							АлгоритмЗаполнения_Запись.СубконтоДт.Вставить(ВидСубконто, Знач_Субк);
						КонецЕсли;
					Исключение КонецПопытки;
					
					Попытка
						Знач_Субк = АлгоритмЗаполнения_Выборка["СубконтоКт"+и1];
						СчетКт = АлгоритмЗаполнения_Выборка["СчетКт"];
						ВидСубконто = ОпределитьВидСубконто(СчетКт, Знач_Субк);
						Если не ВидСубконто = неопределено Тогда
							АлгоритмЗаполнения_Запись.СубконтоКт.Вставить(ВидСубконто, Знач_Субк);
						КонецЕсли;
					Исключение КонецПопытки;
				КонецЦикла;
			КонецЦикла;
			АлгоритмЗаполнения_Налоговый.Записать();
		КонецЦикла;
		////--- Пишем регистр налоговый
		
		////+++ Пишем регистр РАУЗРегл
		АлгоритмЗаполнения_СКД = ВыборкаДетальныеЗаписи.АлгоритмБУРАУЗ.Получить();
		
		Для каждого АлгоритмЗаполнения_НаборДанных из АлгоритмЗаполнения_СКД.НаборыДанных Цикл
			АлгоритмЗаполнения_Запрос = Новый Запрос(АлгоритмЗаполнения_НаборДанных.Запрос);
			Для каждого АлгоритмЗаполнения_Праметры из АлгоритмЗаполнения_СКД.Параметры Цикл
				АлгоритмЗаполнения_Запрос.УстановитьПараметр(АлгоритмЗаполнения_Праметры.Имя, АлгоритмЗаполнения_Праметры.Значение);
			КонецЦикла;
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("НачалоПериода", НачалоМесяца(Источник.Дата));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("КонецПериода", КонецМесяца(Источник.Дата));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("НачалоПериодаГраница", Новый Граница(НачалоМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("КонецПериодаГраница", Новый Граница(КонецМесяца(Источник.Дата), ВидГраницы.Включая));
			АлгоритмЗаполнения_Запрос.УстановитьПараметр("Регистратор", Источник.Ссылка);
			
			АлгоритмЗаполнения_УчетЗатратРегл = Источник.Движения.УчетЗатратРегл;
			АлгоритмЗаполнения_УчетЗатратРегл.Прочитать();
			
			АлгоритмЗаполнения_Выборка = АлгоритмЗаполнения_Запрос.Выполнить().Выбрать();
			Пока АлгоритмЗаполнения_Выборка.Следующий() Цикл
				АлгоритмЗаполнения_Запись = АлгоритмЗаполнения_УчетЗатратРегл.Добавить();
				ЗаполнитьЗначенияСвойств(АлгоритмЗаполнения_Запись, АлгоритмЗаполнения_Выборка);
			КонецЦикла;
			АлгоритмЗаполнения_УчетЗатратРегл.Записать();
		КонецЦикла;
		////--- Пишем регистр РАУЗРегл
		
	КонецЦикла;
	
КонецПроцедуры
 
Функция ОпределитьВидСубконто(Счет, Знач_Субк) Экспорт
	
	Результат = Неопределено;
	ТипЗнчСК = ТипЗнч(Знач_Субк);
	Для каждого ВС из Счет.ВидыСубконто Цикл
		Если ВС.ВидСубконто.ТипЗначения.СодержитТип(ТипЗнчСК) Тогда
			Результат = ВС.ВидСубконто;
			Прервать;
		КонецЕсли;
	КонецЦикла;
	
	Возврат Результат;
	
КонецФункции

/////----------------- Расчет себестоимости	---

Подробные разъяснения по представленному коду давать особого смысла не вижу смысла. т.к. по окнчании статьи станет ясен каждый выполненный шаг. А что происходит в приведенном модуле примерно ясно по коду, даже на первый взгляд.

А в кратце так:

  1. Сначала ищем актуальный на текущий месяц алгоритм очистки регистров
  2. Выполняем непосредственное удаление записей по фильтру
  3. Ищем актуальный на текущий месяц алгоритм распределения
  4. Последовательно перебираем все запросы в СКД по определенному разделу учета. Производим заполнение параметров и выполнеям. Ничего осверхъестественного. Условности есть только в специфичных бухгалтерских регистрах, что видно по коду
Удобство данный схемы работы заключается в возможности отлдаки запроса в режиме предприятия через консоль. При желании можно доработать, добавив внешний источник данных и ввода произвольных дополнительных параметров.
 

Второе действие:

Добавляем подписку на событие. Источник - документ производящий стандартное распределение 20ых счетов (мой случай: "РасчетСебестоимостиВыпуска"). Событие - ОбработкаПроведения. Обработчик - указываем нашу процедуру в созданном общем модуле (Алгоритм_ОбработкаПроведения_РасчетСебестоимостиВыпускаОбработкаПроведения - точка входа).

Добавленная подписка на собтие

На текущем этапе у нас есть модуль, который срабатавает при рспределении затрат. Но так и нет механизма, который бы отработал и распределил затраты так как надо нам.

Третие действие:

Добавляем регистр сведений "Алгоритм_СпособыЗакрытияСебестоимости". Устанавливаем периодичность "Месяц", режим записи "независимый". Добавляем ресурсы "АлгоритмБУ, АлгоритмНУ, АлгоритмБУРАУЗ" тип "ХранилищеЗначения". Измерения хоть у меня и добавлены, практическое применение они не имеют. В реквизиты добавляем "Описание" - строка, "ОчисткаДанных"- булево. Собственно информация из этого регистра и будет использоваться для выполнения распределения.

Добавленный регистр сведений

Но чтоб нам было понятно что там будет храниться и как с этим работать выполним следующий шаг.

Четвертый шаг:

Добавляем форму записи для регистра сведений, примерно следующего вида (но, в принципе, у каждого человека своя фантазия Wink ):

Форма записи регистра сведений

В форме редактирование ресурсов организуем через элемент надпись с свойством гиперссылка. По нажатии на надпись выдается стандартное окно СКД, в котором и будем в последующим указывать что и как делать.

Модуль формы:

Перем ВыбраннаяСКД;

Процедура ОбработкаВыбора(ЗначениеВыбора, Источник)
	
	Если Тип(ЗначениеВыбора) = Тип("СхемаКомпоновкиДанных") Тогда
		
		Если ВыбраннаяСКД = "АлгоритмБУ" Тогда
			АлгоритмБУ = Новый ХранилищеЗначения(ЗначениеВыбора);
		ИначеЕсли ВыбраннаяСКД = "АлгоритмБУРАУЗ" Тогда
			АлгоритмБУРАУЗ = Новый ХранилищеЗначения(ЗначениеВыбора);
		ИначеЕсли ВыбраннаяСКД = "АлгоритмНУ" Тогда
			АлгоритмНУ = Новый ХранилищеЗначения(ЗначениеВыбора);
		КонецЕсли;
		
	КонецЕсли;
	
КонецПроцедуры

Процедура НадписьАлгоритмРаспределенияБУНажатие(Элемент)
	
	СКД = АлгоритмБУ.Получить();
	Если СКД = Неопределено Тогда
		СКД = Новый СхемаКомпоновкиДанных;
	КонецЕсли;
	
	ВыбраннаяСКД = "АлгоритмБУ";
	
	// Вызовем конструктор для интерактивного изменения СКД
	КонструкторСКД = Новый КонструкторСхемыКомпоновкиДанных(СКД);
	КонструкторСКД.Редактировать(ЭтаФорма);
		
КонецПроцедуры

Процедура НадписьАлгоритмРаспределенияБУРАУЗНажатие(Элемент)
	
	СКД = АлгоритмБУРАУЗ.Получить();
	Если СКД = Неопределено Тогда
		СКД = Новый СхемаКомпоновкиДанных;
	КонецЕсли;
	
	ВыбраннаяСКД = "АлгоритмБУРАУЗ";
	
	// Вызовем конструктор для интерактивного изменения СКД
	КонструкторСКД = Новый КонструкторСхемыКомпоновкиДанных(СКД);
	КонструкторСКД.Редактировать(ЭтаФорма);
		
КонецПроцедуры

Процедура АлгоритмРаспределенияНУНажатие(Элемент)
	
	СКД = АлгоритмНУ.Получить();
	Если СКД = Неопределено Тогда
		СКД = Новый СхемаКомпоновкиДанных;
	КонецЕсли;
	
	ВыбраннаяСКД = "АлгоритмНУ";
	
	// Вызовем конструктор для интерактивного изменения СКД
	КонструкторСКД = Новый КонструкторСхемыКомпоновкиДанных(СКД);
	КонструкторСКД.Редактировать(ЭтаФорма);
		
КонецПроцедуры

Ну вот вроде бы и всё, осталось сохранить конфигурацию, обновить информационную базу, и написать собственный запрос на распределение, использую всё удобство и всю мощь формирования запросов СКД Smile

СКД в режиме предприятия

Пример запроса для "Алгоритм распределения БУ":

ВЫБРАТЬ
	ХозрасчетныйОстатки.Счет КАК СчетКт,
	&Счет_90021 КАК СчетДт,
	ХозрасчетныйОстатки.Субконто1 КАК СубконтоКт1,
	ХозрасчетныйОстатки.Субконто2 КАК СубконтоКт2,
	ХозрасчетныйОстатки.Субконто2 КАК СубконтоДт1,
	ХозрасчетныйОстатки.Организация КАК Организация,
	ХозрасчетныйОстатки.СуммаОстаток КАК Сумма,
	&КонецПериода КАК Период,
	"Закрытие Выполнение услуг" КАК Содержание
ИЗ
	РегистрБухгалтерии.Хозрасчетный.Остатки(&КонецПериодаГраница, Счет В ИЕРАРХИИ (&Счет_20), , Субконто2 В ИЕРАРХИИ (&СубконтоНГ)) КАК ХозрасчетныйОстатки

В приведенном коде возможно имеются некоторые ошибки, связанные с упрощением механизма работы, т.к. пример взят из рабочей базы, где был первоначально реализован проект. Но, тем не менее, я думаю, данная статья будет всё-таки полезна и принесет свою лепту в развитие метода доработки стандартной 1С.

Всем спасибо за прочтение и внимание, и извиниюсь, что статья довльна сжата (упускаются многие моменты выбора решения применения технологий).


PS

Спасибо за оставленные комментарии, в которых обсалютно верно было замечено, что здесь приведена только реализация, а вот когда и зачем этот механизм использовать не сказано.

Мысль реализовать подобное решение возникала уже давно, но раньше хватало возможностей всё необходимое вывернуть из стандартного механизма (хотя кое-что и приходилось дописывать в модулях). Но чем дальше, тем хуже... Сейчас работаю во франчайзе, встречаются различные конторы, и ,что самое поразительное, вопрос о себестоимости встает очень часто. И часто слышу следующее: "Хорошо, стандартный механизм работает, но мы по-другому производим распределение затратных счетов, как быть?". А что самое главное, ошибки в их методике нет, просто она, в основном, ориентирована на возможность собрать данные для финансовой отчетности (рентабельности не только производства в целом, а в отдельности по каждому направлению, продукции направления в разрезе всех затрат). Еще одно важное свойство - возможность ведения НЗП даже в бухгалтерии. При этом Вы полностью самостоятельно определяете по каким правилам это всё происходит. И заметим, что если в "1С:Бухгалтеия 2.0" еще можно сделать операции вручную, то уже в комплексной, при включенном РАУЗ, распределение затрат произвольным способом не представляется возможным.

Внедряя данный механизм на предприятии, мы получили большой плюс в уходе от ручного труда: планово-экономический отдел, также как и заместители главного бухгалтера, смогли отказаться от части своих excel-документов. Что значительно повышает достоверность данных, да и время на получение этих данных значительно сократилось. А значит, данный механизм, смог повысить эффективность работы предприяти в целом.

Но, как и всегда, есть и ложка дёгтя: для настройки и правильной работы механизма требуется не просто программист 1С, а программист, который хоть что-то понимает в бухгалтерском учете. А если конфигурация будет КА или УПП, то тут еще сложнее...

28

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. Lukich66 82 01.02.13 19:29 Сейчас в теме
из анекдота. Говорят изобрели новый способ делать детей. Хм,а чем старый то плох?
В пятницу вечером оч. тяжело разбираться в тонкостях распределения с/с по 20му счету. Первое впечатление: человек Вы явно смелый и одаренный несомненно,но замахнуться на самое святое в 1с-себестоимость? Подвергнуть сомнению их методику? Кто это у Вас за главбух?
3. redwonder87 28 04.02.13 06:54 Сейчас в теме
(1) мысль реализовать подобное решение возникала уже давно, но раньше хватало возможностей всё необходимое вывернуть из стандартного механизма (хотя кое-что и приходилось дописывать в модулях). Но чем дальше, тем хуже... Сейчас работаю во франчайзе, встречаются различные конторы, и ,что самое поразительное, вопрос о себестоимости встает очень часто. И часто слышу следующее: "Хорошо, стандартный механизм работает, но мы по-другому производим распределение затратных счетов, как быть?". А что самое главное, ошибки в их методике нет, просто она, в основном, ориентирована на возможность собрать данные для финансовой отчетности (рентабельности не только производства в целом, а в отдельности по каждому направлению, продукции направления в разрезе всех затрат). Еще одно важное свойство - возможность ведения НЗП даже в бухгалтерии. При этом Вы полностью самостоятельно определяете по каким прпавилам это всё происходит.
Lukich66; +1 Ответить
5. Lukich66 82 04.02.13 12:09 Сейчас в теме
(3) redwonder87, добрый день. Пожалуй могу и согласиться с Вами. Взять хотя бы с/хозяйство- здесь незавершенки пруд пруди,схем закрытия как тетя Катя захочет. Например от затрат дойного стада нужно 10% отдать на приплод молодняка. Типовой схемой - это множественный подбор плановой стоимости выхода 11/20.01- а у Вас это чем-то можно предусмотреть? И все-таки механизм реализации довольно-таки сложен,не вникнув в него, по-легкому не внедрить( надо же еще и Бухов с ним познакомить). Кстати в 3-ей версии БП с/с поимела отличия,насколько принципиальные еще не изучали?
7. redwonder87 28 06.02.13 06:24 Сейчас в теме
(5) нет 3ью версию не смотрел. Т.е. видел интерфейс, но устанавливать и настраивать еще не приходилось.
10. ula1c 01.03.13 23:57 Сейчас в теме
(7) redwonder87, хотелось бы все-таки увидеть описания вашего примера использования произвольного закрытия, с аргументацией и доводами невозможности использования стандартного механизма.
11. redwonder87 28 05.03.13 16:39 Сейчас в теме
(10) Реальная задача:
Затраты с 25 счета должны распределиться на 20 счет по номенклатурным группам, у которых стоит свойство производственные, в статью "прямые распределяемые". После на 20 счете затраты по НГ "Проектные" должны распределиться пропорционально на НГ со свойством "проектные", а проектные НГ должны закрываться полностью только если была реализация по этой НГ. Всё остальное распределяется и закрывается по стандартной схеме, но не трогая вышеупомянутые объекты.
Вот такое вот строительство долгосрочных объектов с НЗП.
2. TODD22 18 01.02.13 19:50 Сейчас в теме
А можете рассказать чем ваш механизм выгодно отличается от механизма 1С? То есть в чём профит? А то только реализацию описали.
4. redwonder87 28 04.02.13 07:12 Сейчас в теме
(2) TODD22, исходя из предыдущего моего комментария, получаем - остаток НЗП. А также возможность распределения статей затрат по определенным номенклатурным группам в строго определенные подразделения, а не валом размазывать... А значит мы получаем не просто затраты, а корректный финансовый результат на основании которого могут работать экономисты без дополнительных трудозатрат. Также бывают ситуации, когда есть расходы по НГ, по которым нет не выпуска, не реализации. Но затраты по этой группе должны распределяться на выпуск или реализацию, да еще не прямопропорционально, а в определенной зависимости именно по подразделениям. Но это только то, с чем мне приходилось сталкиваться. Подобных задач на самом деле много, и они часто возникают, но сложность их реализации заставляет компании отказываться от автоматизации, перекладывая данные проблемы на плечи своих сотрудников (и тут появляется "всемогущий" excel).
8. Константин С. 605 15.02.13 14:05 Сейчас в теме
(2) TODD22, И еще навивает на мысль о не полном знании типового механизна. Который позволяет создать "Способ распределения" с собственным запросом. Не зачем залезать во внутрь)))
9. TODD22 18 15.02.13 17:23 Сейчас в теме
(8) часто такое встречаю... когда можно решить типовым функционалом, кто нибудь обязательно что нибудь допишет :)
Прежде чем что то дописать нужно наверное мат. часть учить... ну и не забывать мантру программиста... читать её каждый день 10 раз до начала работы: "Я не буду изобретать велосипед, я возьму готовый и согну как мне нужно" я думаю где то через неделю должно придти "просветление". А если практиковать от полугода то вполне может быть что всевышней одарит программиста лучезарной кармой.
18. Светлый ум 235 19.07.16 17:50 Сейчас в теме
(8) Константин С., Это как приведите пример если не трудно:
- куда запрос втыкать?
6. TODD22 18 05.02.13 18:15 Сейчас в теме
Также бывают ситуации, когда есть расходы по НГ, по которым нет не выпуска, не реализации.

Это скорее не правильно поставленный учёт или незнание конфигурации.
А также возможность распределения статей затрат по определенным номенклатурным группам в строго определенные подразделения, а не валом размазывать...

А типовая разве так не умеет? У затраты мы указываем подразделение и НГ. И соответствующим образом настраиваем способы распределения.
Подобных задач на самом деле много, и они часто возникают, но сложность их реализации заставляет компании отказываться от автоматизации, перекладывая данные проблемы на плечи своих сотрудников (и тут появляется "всемогущий" excel).

Скорее всего такие задачи возникают из за плохого знания теории производственного учёта и расчета СС.
И как верно подмечено "И схем закрытия "Как тетя Катя захочет".

А так разработка зачётная.
irishka77; l-Rain; Lukich66; +3 Ответить
12. WildFire 23.04.13 10:58 Сейчас в теме
Я так понимаю, эта разработка исключительно под РАУЗ? Ведь при партионке никакого закрытия затратных счетов не существует вовсе. Подписку на событие попросту не к чему цеплять и т.д.
13. Ele1234567 23.12.13 11:56 Сейчас в теме
14. soba 03.03.15 23:51 Сейчас в теме
Некоторые картинки с внешнего хостинга не отображаются. Перезалейте, пожалуйста
15. freep777 05.03.15 07:28 Сейчас в теме
Картинки не отображаются (некоторые)!
16. Swetlana 10 05.03.15 14:51 Сейчас в теме
тоже интересно было бы просмотреть полностью статью
17. Raimz 1 06.08.15 09:41 Сейчас в теме
Та же самая проблема! Перезалейте статью или линк на файл .doc ;)
Оставьте свое сообщение

См. также

Полезные процедуры и функции для программиста 160

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Практика программирования Универсальные функции

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    11493    HostHost    23       

Специальное предложение по 1С:Документооборот 8! Промо

Оперативно навести порядок в документообороте? Легко! Воспользуйтесь специальным предложением! Внедрение за 2 недели! Фиксированная цена и гарантия результата!

Перенос данных БП 3.0 => УТ 11 / КА 2 / ERP 2 (ЕРП) (перенос остатков, документов и справочной информации из "1С:Бухгалтерия предприятия 8", ред.3.0). Обновлено до БП 3.0.73.х, УТ 11.4.10.х, КА 2.4.10.х., ERP 2.4.10.х! Промо

Переносятся документы за выбранный период, справочная информация и остатки по счетам бух. учета в программу УТ 11 / КА 2 / ЕРП 2 (ERP). Переносятся все возможные виды операций ввода остатков на нужную дату. Есть отбор по периоду переноса документов и фильтр по организации, доступен выбор даты ввода остатков. Если нужно переносить что-то дополнительно, то обычно бесплатно добавляем это в перенос . Смотрите видеодемонстрацию со звуком - советами по переносу и рекомендациями настройки программ.

29700 руб.

Агрегатные функции СКД, о которых мало кто знает 353

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    15398    ids79    44       

Три костыля. Сказ про фокусы в коде 124

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    10451    YPermitin    69       

Очный семинар по регулярному менеджменту Александра Фридмана "Вы или Хаос", 12 декабря 2019 г. , Санкт-Петербург Промо

Семинар по регулярному менеджменту от Александра Фридмана для собственников, первых лиц и топов. Технология управленческого планирования, комплексного управления временем и другими ресурсами, выполнением поручений, делами, информацией, контактами (встречи-звонки-почта).

от 11000 до 29000 рублей

Отслеживание выполнения фонового задания 143

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    12581    ids79    16       

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив 261

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    17780    ids79    31       

Cashback 35% при покупке 1С лицензий на счет INFOSTART.RU с 27.11 по 04.12 Промо

Оформляете заказ на 1С лицензии или конфигурации. Получаете 35% от стоимости на счет в профиле INFOSTART.RU. Выбираете сервисы и продукты на сумму кэшбэка.

Фоновое выполнение кода в 1С - это просто 124

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    12682    avalakh    21       

Перенос документов и справочников ERP 2 / КА 2 / УТ 11 => БП 3.0 Промо

Перенос позволяет настроить собственный обмен данными между указанными программами, альтернативный предлагаемому фирмой 1С. Предоставляем техподдержку по всем вопросам данного обмена. Можем подключиться к вам удаленно для разбора ситуаций. Оперативно обновляем при выходе новых релизов 1С. Бесплатные обновления в течение полугода.

19700 руб.

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты 141

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    15934    ids79    8       

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ 155

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Инструментарий разработчика Практика программирования

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    13492    ids79    27       

Перенос данных УТ 10.3 => УТ 11 / КА 2 / ERP 2 (ЕРП 2) (документы, остатки и справочная информация из "1С:Управление торговлей, ред. 10.3" в УТ 11 / КА 2 / ERP 2). Обновлен до УТ 10.3.56.х, УТ 11.4.10.х, КА 2.4.10.х и ERP 2.4.10.х! Промо

Уже более 100 компаний приобрели перенос и выполнили переход на УТ 11 / КА 2 / ERP 2 с помощью нашей разработки! Обработка перехода с УТ 10.3 на УТ 11 / КА 2 / ERP 2 позволяет перенести не только остатки на указанную дату (как типовой перенос), но и все возможные документы за выбранный период. При выходе новых релизов этих программ оперативно выпускаем обновление обработки. Предоставляем техническую поддержку. Можем сделать бесплатный тестовый перенос!

29700 руб.

Регистры сведений. За кулисами 129

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Небольшие заметки по внутреннему устройству регистров сведений.

09.07.2019    10522    YPermitin    12       

"Меньше копипаста!", или как Вася универсальную процедуру писал 183

Статья Программист Стажер Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    9301    SeiOkami    49       

1СПАРК РИСКИ. Сервис оценки благонадежности контрагентов. Промо

СПАРК помогает предотвратить мошенничество со стороны компаний и предпринимателей, благодаря актуальным сведениям о компаниях и системе выявления факторов риска.Сервис позволяет управлять налоговыми рисками и комплексно оценивать благонадежность контрагентов.

Создание отчетов с помощью СКД - основные понятия и элементы 216

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    23610    ids79    17       

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017 179

Статья Программист Нет файла v8 v8::Запросы Бесплатно (free) Практика программирования Разработка

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    13566    dmurk    134       

Новый раздел на Инфостарте - Electronic Software Distribution Промо

Инфостарт напоминает: на нашем сайте можно купить не только ПО, связанное с 1С. В нашем арсенале – ESD-лицензии на ПО от ведущих вендоров: Microsoft, Kaspersky, ESET, Dr.Web, Аскон и другие.

  • Низкие цены, без скрытых платежей и наценок
  • Оперативная отгрузка
  • Возможность оплаты с личного счета (кешбек, обмен стартмани на рубли и т.п.)
  • Покупки идут в накопления для получения скидочных карт лояльности Silver (5%) и Gold (10%)

Регистры накопления. Структура хранения в базе данных 178

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    21007    YPermitin    27       

Выполнение внешней обработки в фоновом задании 149

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Подробное описание подхода к созданию длительной операции на основе внешней обработки. Реализация протестирована на 1С 8.3.12.1714 (x64).

11.05.2019    12909    Eret1k    23       

Перенос данных УПП 1.3 => ERP 2 (ЕРП) / УТ 11 / КА 2.х (обработка переноса документов, остатков и справочников из "1С:Управление производственным предприятием, ред. 1.3" в ERP / УТ 11 / КА 2). Обновлен до УПП 1.3.127.х, КА 2.4.10.х и ERP 2.4.10.х! Промо

Обработка позволяет переносить из УПП 1.3 в ERP 2 документы за выбранный период и остатки. Типовая обработка от фирмы 1С документы не переносит. Также исправлены ошибки типовой обработки. При выходе новых релизов обновление высылается бесплатно в течение года. Разработка будет полезна фирмам-франчайзи, которые периодически выполняют такой перенос данных для заказчиков. Вы можете один раз приобрести обработку переноса, и потом бесплатно получать обновления при выходе новых релизов конфигураций 1С.

29700 руб.

Выгрузка документа по условию 5

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    7294    m-rv    2       

Как прикрутить ГУИД к регистру сведений 23

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8 Разработка

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    9864    m-rv    16       

Подборка решений для взаимодействия со ФГИС «Меркурий» Промо

С 1 июля 2019 года все компании, участвующие в обороте товаров животного происхождения, должны перейти на электронную ветеринарную сертификацию (ЭВС) через ФГИС «Меркурий». Инфостарт предлагает подборку программ, связанных с этим изменением.

О расширениях замолвите слово... 195

Статья Программист Стажер Нет файла v8 Бесплатно (free) Практика программирования Разработка

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    18860    ellavs    125       

Git-репозитории для 1С-кода (опыт использования при небольших проектах) 202

Статья Программист Стажер Нет файла v8 Windows Бесплатно (free) Практика программирования Разработка

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    15084    ellavs    83       

Программы для исполнения 488-ФЗ: Маркировка товаров Промо

1 января 2019 года вступил в силу ФЗ от 25.12.2018 № 488-ФЗ о единой информационной системе маркировки товаров с использованием контрольных (идентификационных) знаков, который позволяет проследить движение товара от производителя до конечного потребителя. Инфостарт предлагает подборку программ, связанных с применением 488-ФЗ и маркировкой товаров.

Трюки с внешними источниками данных 166

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    15822    YPermitin    52       

Вакансия Автор новостных обзоров на тему 1С и бухучета, По совместительству Промо

Редакция Infostart.ru будет рада сотрудничеству с 1С-специалистом, умеющим и любящим излагать свои мысли в письменной форме. Если вы работали в IT-изданиях или имеете опыт ведения технологического блога/канала/группы, если сможете сделать обзор обработок из каталога infostart.ru/public/all/, то у вас большое преимущество.

Возможности типовых шаблонов ограничения доступа на уровне записей (RLS) 173

Статья Программист Нет файла v8 v8::Права Бесплатно (free) Практика программирования БСП (Библиотека стандартных подсистем) Роли и права

Краткий обзор применения типовых шаблонов ограничения доступа на уровне записей в конфигурациях, созданных на базе БСП: #ПоЗначениям, #ПоНаборамЗначений, #ПоЗначениямРасширенный, #ПоЗначениямИНаборамРасширенный

03.02.2019    19097    ids79    9