Вступление

Всех приветствую. Хочу поделиться своей обработкой для 1С, при помощи которой можно интерактивно генерировать текст запроса для получения родителей верхнего уровня иерархического (И не только!) справочника. Эта задача часто возникает, когда нужно определить корневую группу для любого элемента, независимо от глубины иерархии прямо в запросе.

Источник вдохновения

За основу бралась статья Транзитивное замыкание запросом. Отдельная благодарность автору за разрешение написания статьи, правда, руки у меня дошли только спустя год 🫠 Надеюсь, время действия разрешения не истекло.

В чем особенность

Моей задачей было сделать так, чтобы можно было удобно использовать интерактивно под различные задачи, а также добавить дополнительные возможности: 

• Поменять имена колонок 
• Задать ограничение элементов 
• Поместить результат во временную таблицу
• Получить родителей по любому реквизиту, отличному от родителя 

Использование

Откройте обработку в любой базе (но если в базе нет справочника, для которого вы пишите запрос, то текст не будет отформатирован). Заполните данные на форме, большинство из них заполнятся автоматически, при необходимости можно их поменять: 

• Имя справочника: Название справочника, для которого определяются верхние родители в иерархии.

• Максимальная длина пути: Максимальное количество уровней вложенности в иерархии справочника.

• Имя реквизита иерархии: Реквизит, определяющий иерархию, если она строится не по стандартному полю "Родитель".

• Получить родителей групп: Включать ли в результат иерархию групп (если Ложь, возвращаются родители только для элементов).

• Имя временной таблицы: Имя временной таблицы для сохранения результата; если не указано, формируется обычная выборка данных.

• Имя параметра с элементами: Если задано, родители определяются только для указанных в параметре элементов (пустое значение — параметр объявлен не будет). Пересекается с параметром "Получить родителей групп".

• Имя колонки элемент: Название колонки с элементами в результирующей выборке.

• Имя колонки родитель: Название колонки с верхними родителями в результирующей выборке.

После заполнения, нажмите кнопку "Заполнить тексты запросов". На форме заполнятся 2 (если справочник в текущей базе не найден) или 4 поля с текстами запросов:

Компактный (для конструктора) - если хотите вставить в конструктор или в консоль запросов

Компактный (для конфигуратора) - если хотите вставить сразу в модуль

А также их форматированные через схему запроса варианты.

Открытый код

Любой может что-то добавить или исправить. Если вы хотите использовать основную функцию формирования в своей конфигурации (например, для ее использования через менеджер временных таблиц), то можете скопировать код, который представлен ниже:

&НаКлиентеНаСервереБезКонтекста
// Текст запроса для получения родителей всех уровней иерархии
//
// Параметры:
//  ИмяСправочника			 - Строка - Имя справочника, внутри которого необходимо получить родителей 
//  МаксимальнаяДлинаПути	 - Число  - Максимально возможное количество уровней вложенности в справочнике
//  ИмяРеквизитаИерархии	 - Строка - Имя реквизита, на котором строится иерархия (на случай, если иерархия строится другим, отличным от родителя, реквизитом)
//  ПолучитьРодителейГрупп	 - Булево - Включить в результат запроса иерархию групп (Ложь = Получить родителей только элементов)
//  ИмяВременнойТаблицы		 - Строка - Если указано, то результат будет помещен в указанную временную таблицу, иначе будет сформирован текст с выборкой данных
//  ИмяПараметраСЭлементами	 - Строка - Если указать, то родители будут получы только у элементов из данного параметра ("" = У всех элементов). Обратите внимание, что параметр пересекается с параметром "ПолучитьРодителейГрупп"
//  ИмяКолонкиЭлемент		 - Строка - Имя колонки с элементами в результате запроса
//  ИмяКолонкиРодитель		 - Строка - Имя колонки с родителями в результате запроса
// 
// Возвращаемое значение:
//  Строка - Текст запроса, при помощи которого можно получить родителей всех уровней иерархии.
//
Функция ТекстЗапросаДляПолученияРодителейВсехУровнейИерархии(Знач ИмяСправочника, Знач МаксимальнаяДлинаПути = 8, Знач ИмяРеквизитаИерархии = "Родитель", Знач ПолучитьРодителейГрупп = Ложь,
		Знач ИмяВременнойТаблицы = "", Знач ИмяПараметраСЭлементами = "", Знач ИмяКолонкиЭлемент = "Ссылка", Знач ИмяКолонкиРодитель = "Родитель")
	
	Пролог = "ВЫБРАТЬ #ИмяРеквизитаИерархии НачалоДуги, Ссылка КонецДуги ПОМЕСТИТЬ ЗамыканияДлины1 ИЗ Справочник.#ИмяСправочника
	| ГДЕ #ИмяРеквизитаИерархии <> Значение(Справочник.#ИмяСправочника.ПустаяСсылка)
	| ОБЪЕДИНИТЬ ВЫБРАТЬ Ссылка, Ссылка ИЗ Справочник.#ИмяСправочника
	| #СтрУсловия;";
	
	СтрУсловия = ?(ПустаяСтрока(ИмяПараметраСЭлементами), "", "ГДЕ Ссылка В(&" + ИмяПараметраСЭлементами + ")");
	СтрУсловия = СтрУсловия + ?(ПолучитьРодителейГрупп, "", ?(ПустаяСтрока(СтрУсловия), "ГДЕ", " И") + " ЭтоГруппа = Ложь"); 
	
	Пролог = СтрЗаменить(Пролог, "#СтрУсловия", СтрУсловия);
	
	Рефрен = "ВЫБРАТЬ РАЗЛИЧНЫЕ ПерваяДуга.НачалоДуги, ВтораяДуга.КонецДуги ПОМЕСТИТЬ ЗамыканияДлины#2 ИЗ ЗамыканияДлины#1 КАК ПерваяДуга
	| ВНУТРЕННЕЕ СОЕДИНЕНИЕ ЗамыканияДлины#1 КАК ВтораяДуга ПО ПерваяДуга.КонецДуги = ВтораяДуга.НачалоДуги;
	| УНИЧТОЖИТЬ ЗамыканияДлины#1;";
	
	Эпилог = "ВЫБРАТЬ НачалоДуги КАК #ИмяКолонкиРодитель, КонецДуги КАК #ИмяКолонкиЭлемент" + ?(ПустаяСтрока(ИмяВременнойТаблицы), "", " ПОМЕСТИТЬ " + ИмяВременнойТаблицы) + " ИЗ ЗамыканияДлины#2 ГДЕ НачалоДуги <> КонецДуги";
	
	ТекстЗапроса = Пролог;
	ТекущаяДлинаЗамыканий = 1;
	
	Пока ТекущаяДлинаЗамыканий < МаксимальнаяДлинаПути Цикл
		ТекстЗапроса = ТекстЗапроса + СтрЗаменить(СтрЗаменить(Рефрен, "#1", Формат(ТекущаяДлинаЗамыканий, "ЧГ=0")), "#2", Формат(2 * ТекущаяДлинаЗамыканий, "ЧГ=0"));
		ТекущаяДлинаЗамыканий = 2 * ТекущаяДлинаЗамыканий;
	КонецЦикла;
	
	ТекстЗапроса = ТекстЗапроса + СтрЗаменить(Эпилог, "#2", Формат(ТекущаяДлинаЗамыканий, "ЧГ=0"));
	ТекстЗапроса = ТекстЗапроса + "; УНИЧТОЖИТЬ ЗамыканияДлины" + Формат(ТекущаяДлинаЗамыканий, "ЧГ=0");
	
	ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "#ИмяСправочника",       ИмяСправочника);
	ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "#ИмяРеквизитаИерархии", ИмяРеквизитаИерархии);
	ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "#ИмяКолонкиЭлемент",    ИмяКолонкиЭлемент);
	ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "#ИмяКолонкиРодитель",   ИмяКолонкиРодитель);
	
	Возврат ТекстЗапроса;
	
КонецФункции