Конвертация схемы XSD в модель XDTO и обратно
Интеграция - Файловый обмен (TXT, XML, DBF), FTP
Файлы
ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.
Подписка PRO — скачивайте любые файлы со скидкой до 85% из Базы знаний
Оформите подписку на компанию для решения рабочих задач
Оформить подписку и скачать решение со скидкойВы можете заказать платную доработку или адаптацию этой разработки под вашу конфигурацию на «Бирже заказов».
- 0% комиссии — оплата напрямую исполнителю;
- Исполнители любого масштаба — от отдельных специалистов до команд под проект;
- Прямой обмен контактами между заказчиком и исполнителем;
- Безопасная сделка — при необходимости;
- Рейтинги, кейсы и прозрачная система откликов.
До сих пор в платформе 1С не исправлен баг, когда после создания фабрики на основе схемы XML импортированные типы из других пространств некорректно конвертируются в простейшие типы XMLSchema. Для решения этой проблемы необходимо создавать фабрику на основе модели XDTO. Многие сервисы документооборота предоставляют схемы XML регламентированных документов.
Предлагаю обработку для получения модели xdto из схемы XML. В обработке имеется проверка на пространство имен в схеме XML, если пространство имен не заполнено, тогда оно добавляется принудительно = XSDToModel. После конвертации необходимо переименовать это пространство по умолчанию.
Обновление от 30.04.2026
Добавлена обратная конвертация модели в схему
Код модуля объекта:
#Область ОписаниеПеременных
Перем ПространствоИмен;
#КонецОбласти
#Область ПрограммныйИнтерфейс
Процедура Конвертировать() Экспорт
ЧтениеXML = Новый ЧтениеXML;
ЧтениеXML.УстановитьСтроку(XSDСхема);
ПостроительДОМ = Новый ПостроительDOM;
ДокументДОМ = ПостроительДОМ.Прочитать(ЧтениеXML);
ИнициализироватьПространствоИмен(ДокументДОМ);
ПостроительСхемXML = Новый ПостроительСхемXML;
СхемаXML = ПостроительСхемXML.СоздатьСхемуXML(ДокументДОМ);
НаборСхемXML = Новый НаборСхемXML;
НаборСхемXML.Добавить(СхемаXML);
Фабрика = Новый ФабрикаXDTO(НаборСхемXML);
ОбъектМоделиXDTO = Фабрика.ЭкспортМоделиXDTO(ПространствоИмен);
ЗаписьXML = Новый ЗаписьXML;
ЗаписьXML.УстановитьСтроку();
Фабрика.ЗаписатьXML(ЗаписьXML, ОбъектМоделиXDTO,,,, НазначениеТипаXML.Явное);
МодельXDTO = ЗаписьXML.Закрыть();
КонецПроцедуры
Процедура КонвертироватьОбратно() Экспорт
ЧтениеXML = Новый ЧтениеXML;
ЧтениеXML.УстановитьСтроку(МодельXDTO);
Модель = ФабрикаXDTO.ПрочитатьXML(ЧтениеXML);
Фабрика = Новый ФабрикаXDTO(Модель);
ПространствоИмен = Модель.package[0].targetNamespace;
НаборСхем = Фабрика.ЭкспортСхемыXML(ПространствоИмен);
Схема = НаборСхем[0];
Схема.ОбновитьЭлементDOM();
ЗаписьXML = Новый ЗаписьXML;
ЗаписьXML.УстановитьСтроку();
ЗаписьДОМ = Новый ЗаписьDOM;
ЗаписьДОМ.Записать(Схема.ДокументDOM, ЗаписьXML);
XSDСхема = ЗаписьXML.Закрыть();
КонецПроцедуры
#КонецОбласти
#Область СлужебныеПроцедурыИФункции
Процедура ИнициализироватьПространствоИмен(ДокументДОМ)
АтрибутПространстваИмен = ДокументДОМ.ПервыйДочерний.Атрибуты.ПолучитьИменованныйЭлемент(targetNamespace());
Если АтрибутПространстваИмен = Неопределено Тогда
АтрибутПространстваИмен = ДокументДОМ.СоздатьАтрибут(targetNamespace());
АтрибутПространстваИмен.Значение = ПространствоИменПоУмолчанию();
ДокументДОМ.ПервыйДочерний.Атрибуты.УстановитьИменованныйЭлемент(АтрибутПространстваИмен);
КонецЕсли;
ПространствоИмен = АтрибутПространстваИмен.Значение;
КонецПроцедуры
Функция targetNamespace()
Возврат "targetNamespace";
КонецФункции
Функция ПространствоИменПоУмолчанию()
Возврат "XSDToModel";
КонецФункции
#КонецОбласти
Код модуля формы:
#Область ОбработчикиКомандФормы
&НаКлиенте
Процедура Конвертировать(Команда)
Если Не ЗначениеЗаполнено(Объект.XSDСхема) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = НСтр("ru='Схема XSD не заполнена. Конвертация невозможна'");
Сообщение.Сообщить();
Возврат;
КонецЕсли;
КонвертироватьНаСервере();
КонецПроцедуры
&НаКлиенте
Процедура ОбратнаяКонвертация(Команда)
Если Не ЗначениеЗаполнено(Объект.МодельXDTO) Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = НСтр("ru='Модель XDTO не заполнена. Конвертация невозможна'");
Сообщение.Сообщить();
Возврат;
КонецЕсли;
КонвертироватьОбратноНаСервере();
КонецПроцедуры
#КонецОбласти
#Область СлужебныеПроцедурыИФункции
&НаСервере
Процедура КонвертироватьНаСервере()
ОбъектОбработки = РеквизитФормыВЗначение("Объект");
ОбъектОбработки.Конвертировать();
ЗначениеВРеквизитФормы(ОбъектОбработки, "Объект");
КонецПроцедуры
&НаСервере
Процедура КонвертироватьОбратноНаСервере()
ОбъектОбработки = РеквизитФормыВЗначение("Объект");
ОбъектОбработки.КонвертироватьОбратно();
ЗначениеВРеквизитФормы(ОбъектОбработки, "Объект");
КонецПроцедуры
#КонецОбласти
Проверено на следующих конфигурациях и релизах:
- Управление торговлей, редакция 11, релизы 11.5.20.58
Вступайте в нашу телеграмм-группу Инфостарт
