Недокументированное использование стандартных обработок из меню "Все функции".

09.02.18

Разработка - Механизмы платформы 1С

Рассмотрены возможности произвольного использования стандартных функций, вызываемых из меню платформы "Все функции" - "Стандартные" (Активные пользователи, Журнал регистрации, Поиск ссылок на объект, Проведение документов ...).

В платформе 1С предприятие есть очень удобные стандартные функции:

1. Активные пользователи;
2. Журнал регистрации;
3. Поиск ссылок на объект;
4. Проведение документов;
5. Удаление помеченных объектов;
6. Управление внешними источниками данных;
7. Управление итогами;
8. Управление полнотекстовым поиском;
9. Управление расширениями конфигурации;

Однако нигде не описаны варианты их использования кроме вызова из пункта "Все функции" главного меню. Поэтому иногда встречается мнение, что эти функции являются чем-то специфичным и сложным, что они вообще написаны не на 1С, а на С++ как и сама платформа. 

На самом деле технически эти функции являются самыми обычными 1С обработками, включенными в состав платформы, и ими можно пользоваться полностью аналогично любым другим привычным обработкам.

Рассмотрим несколько способов их использования на примере стандартной обработки "Поиск ссылок на объекты".

1. Вызов стандартной обработки из любого пункта меню. Обработка "Поиск ссылок на объекты" достаточно удобна и может пригодиться обычным пользователям. Однако не всегда возможно давать им доступ к меню "Все функции" из-за ограниченного уровня доступа пользователя. В этом случае можно добавить вызов обработки из стандартного меню.

Добавляем в конфигурацию новую команду и в модуле команды прописываем текст:

&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
    ПодключитьВнешнююОбработкуНаСервере();
    ОткрытьФорму("ВнешняяОбработка.StandardFindByRef.Форма");
КонецПроцедуры

&НаСервере
Процедура ПодключитьВнешнююОбработкуНаСервере()
    ВнешниеОбработки.Подключить("v8res://mngbase/StandardFindByRef.epf", "StandardFindByRef", false);
КонецПроцедуры

При выборе этой команды у пользователя запустится обработка "Поиск ссылок на объекты" из обычного меню. 

2. Подмена стандартной обработки. Допустим, по какой-то причине нас не устраивает стандартная обработка. В этом случае мы можем ее подменить любой другой. Выполняем на сервере следующий код (например в "ПриЗапуске()" конфигурации) и после этого из стандартного меню "Все функции" - "Поиск ссылок на объект" будет вызываться наша собственная внешняя либо встроенная в конфигурацию обработка. 

	ДвоичныеДанные = Новый ДвоичныеДанные("C:\ВнешняяОбработка.epf");
	АдресХранилища = ПоместитьВоВременноеХранилище(ДвоичныеДанные); 
	ВнешниеОбработки.Подключить(АдресХранилища, "StandardFindByRef", false);

3. Изменение стандартной обработки. Стандартные обработки очень удобны, однако иногда в них не хватает какой-то мелочи. Например, нам может понадобиться добавить в обработку "Поиск ссылок на объект" фильтр для поиска только по документам. Можно, конечно, написать такую же обработку самостоятельно, а можно просто взять встроенную и немного изменить. Чтобы получить встроенную в виде отдельно файла, выполняем код:

КопироватьФайл("v8res://mngbase/StandardFindByRef.epf","C:\ВнешняяОбработка.epf");

Теперь у нас есть стандартный 1С-ный файл "C:\ВнешняяОбработка.epf" с встроенной обработкой. Его можно открыть в конфигураторе и внести любые нужные изменения. В дальнейшем модифицированную обработку можно использовать просто как внешнюю либо подключить обратно вместо встроеной.

Ну и напоследок соответствие стандартных обработок внутренним адресам платформы.

1. Активные пользователи - "v8res://mngbase/StandardActiveUsers.epf";
2. Журнал регистрации - "v8res://mngbase/StandardEventLog.epf";
3. Поиск ссылок на объект - "v8res://mngbase/StandardFindByRef.epf";
4. Проведение документов - "v8res://mngbase/StandardDocumentsPosting.epf";
5. Удаление помеченных объектов - "v8res://mngbase/StandardDeleteMarkedObjects.epf";
6. Управление внешними источниками данных - "v8res://mngbase/StandardExternalDataSourcesManagement.epf";
7. Управление итогами - "v8res://mngbase/StandardTotalsManagement.epf";
8. Управление полнотекстовым поиском - "v8res://mngbase/StandardFullTextSearchManagement.epf";
9. Управление расширениями конфигурации - "v8res://mngbase/StandardExtensionsManagement.epf";
10. upd. с 8.3.11. Управление системой взаимодействия  - "v8res://mngbase/StandardECSRegister.epf"

И еще одна обработочка. Не входит в стандартные, но тоже полезна для ознакомления.

11. Конструктор запросов на управляемых формах - "v8res://mngbase/QueryWizard.epf";

Не стоит забывать, что такое использование стандартных функций является недокументированным. Т.е. на текущий момент на платформах 8.2 - 8.3.6 такие варианты вызовов работают вполне корректно. Но могут перестать работать в любой момент, поэтому злоупотреблять ими не стоит. 

Также стоит учитывать, что в официальных материалах по 1С не документирована возможность простого изменения этих обработок не случайно. Встроенные обработки разрабатываются с учетом функционала текущей платформы. Т.е. они учитывают особенности работы и ограничения той платформы, в состав которой включены. В каких-то случаях, при использовании обработки от другой платформы, могут быть ошибки. Особенно в сложных режимах, например, при удалении документов, управлении итогами или восстановлении последовательностей. Так что использовать эти обработки следует аккуратно, оценивая возможные риски.

 

Вступайте в нашу телеграмм-группу Инфостарт

Активные пользователи Журнал регистрации Поиск ссылок на объект Проведение документов Удаление помеченных объектов Управление внешними источниками данных Управление итогами Управление полнотекстовым поиском Управление расширениями конфигурации

Вы можете заказать платную адаптацию этой статьи под ваши задачи на «Бирже заказов».

  • 0% комиссии — оплата напрямую исполнителю;
  • Исполнители любого масштаба — от отдельных специалистов до команд под проект;
  • Прямой обмен контактами между заказчиком и исполнителем;
  • Безопасная сделка — при необходимости;
  • Рейтинги, кейсы и прозрачная система откликов.

См. также

Механизмы платформы 1С Разработчик Бесплатно (free)

Разберем 15 мифов о работе платформы «1С:Предприятие 8» – как распространенных, так и малоизвестных. Начнем с классики: «Код, написанный в одну строку, работает быстрее, чем многострочный». Так ли это на самом деле?

16.07.2025    45908    TitanLuchs    109    

156

Работа с интерфейсом WEB-интеграция Механизмы платформы 1С Бесплатно (free)

Веб-интерфейсы повышают качество внешнего вида приложений 1С, предсказуемы с точки зрения верстки, позволяют организовать удобные и высокопроизводительные рабочие места для пользователей. Расскажем об особенностях разработки веб-интерфейсов на React внутри 1С, двустороннем взаимодействии 1С и JavaScript, а также сборке веб-приложения в одностраничный файл.

19.06.2025    18941    zeegin    15    

64

Механизмы платформы 1С Работа с интерфейсом Разработчик Стажер 1С:Предприятие 8 Бесплатно (free)

Про ООП в 1С и о том, как сделать свой код более кратким и выразительным при помощи использования текучего интерфейса (fluent interface).

03.02.2025    26180    bayselonarrend    127    

68

Механизмы платформы 1С Разработчик 1С:Предприятие 8 Бесплатно (free)

В этой статье подробно рассматривается работа с JSON в XDTO в 1С:Предприятие. Вы узнаете, как сериализовать и десериализовать объекты XDTO в JSON, интегрировать 1С с веб-сервисами и API, а также корректно обрабатывать данные при обмене. Разбираются особенности работы с коллекциями, использование функций восстановления и частые ошибки при работе с JSON и XDTO.

30.01.2025    33560    user2122906    10    

69

Механизмы платформы 1С Файловый обмен (TXT, XML, DBF), FTP Разработчик 1С:Предприятие 8 Бесплатно (free)

Этот материал познакомит вас с механизмом XDTO (XML Data Transfer Objects) в 1С и научит эффективно использовать его возможности. Мы разберёмся, как работать с XML-схемами, создавать модели данных, манипулировать объектами XDTO, а также сериализовать и десериализовать их в XML. Вы узнаете, как использовать XDTO для интеграции с внешними системами, избегать типичных ошибок и оптимизировать код. К концу вы будете уверенно применять XDTO для решения сложных задач обмена данными и автоматизации процессов.

17.01.2025    56417    user2122906    13    

63

Механизмы платформы 1С WEB-интеграция Разработчик 1С:Предприятие 8 Бесплатно (free)

В платформе 8.3.27 появилась возможность использовать WebSocket-клиент. Давайте посмотрим, как это все устроено и чем оно нам полезно.

14.01.2025    47167    dsdred    110    

160

Механизмы платформы 1С Разработчик Стажер 1С:Предприятие 8 1C:Бухгалтерия Бесплатно (free)

Эта небольшая статья - некоторого рода шпаргалка по файловым потокам: как и зачем с ними работать, какие преимущества это дает.

23.06.2024    40717    bayselonarrend    24    

181
Комментарии
Подписаться на ответы Инфостарт бот Сортировка: Древо развёрнутое
Свернуть все
1. friend0 19.06.15 12:34 Сейчас в теме
Неожиданно. Если не секрет, то где подобную информацию можно раскопать? И можно ли еще что-то стандартное сделать нестаднартным? "Изменить форму", например.
Scaramuccia; pavlo; chebser; IvanovAV; ikekoval; Spacer; alevnev; CyberCerber; sashocq; sergpogo; Dementor; +11 – Ответить
7. ekaruk 5071 19.06.15 13:41 Сейчас в теме
(1) friend0, (4) Dementor, В официальном описании ничего этого нет.
Поэтому и "недокументированное использование".
Вытянуто из ресурсных файлов .res в поставке платформы.
Случайно наткнулась при разборе ошибок платформы.
Светлый ум; KAS1979; Somebody1; simuljakr; m_aster; wunderland; Scaramuccia; lioness3148; Gang031; IvanovAV; vitaliy1911; +11 – Ответить
128. tormozit 7394 08.05.20 18:13 Сейчас в теме
(1) Реализовать такую функциональность через документированную объектную модель управляемой формы невозможно. В частности невозможно снаружи формы получить результирующие заголовки ее полей. Поэтому такой обработки скорее всего не существует. А если она и существует, то она должна использовать какие то недокументированные возможности в объектной модели управляемой формы, которые я очень хотел бы познать.
2. AlX0id 19.06.15 12:51 Сейчас в теме
Ага, и, например, ширину панели открытых окон в такси :)
3. ZhokhovM 688 19.06.15 12:58 Сейчас в теме
Круто, спасибо. В обработке "StandardDocumentsPosting" можно вернуть закладку "Восстановление последовательностей", заменив код:
"Items.RestoreSequence.Enabled" на "True", далее изучить код для заполнения списка восстановления последовательностей.
4. Dementor 1077 19.06.15 13:07 Сейчас в теме
Автор, действительно, поделитесь методом поиска информации!
О ресурсах v8res:// в официальной документации я ничего не находил. Единственные упоминания появляются в описаниях ошибок. Но с типовыми пунктами меню сгенерировать ошибку нереально.
5. w.r. 656 19.06.15 13:18 Сейчас в теме
На глюки платформы при использовании этих функций никто не наталкивался?
6. Dementor 1077 19.06.15 13:39 Сейчас в теме
Не там искал... Оказывается это тема годичной давности с партнерского форума. Там и полный состав стандартных обработок и код для сохранения/переопределения. А так же официальная позиция компании 1С по этому поводу:

Вполне очевидно, что данная возможность не является лицензионной.

Тот факт, что стандартные обработки не предоставляются в пользовательский интерфейс - это осознанное решение. Конкретное прикладное решение опирается на некоторый конкретный и прогнозируемый (прикладным разработчиком) список функциональных возможностей. Стандартные функции развиваются синхронно с платформой, а не с прикладным решением. Поэтому пользователю, кажется, будет совершенно непонятно, почему (после обновления платформы и без обновления прикладного решения) какая-то функция внезапно поменяла свой внешний вид и предоставляемые возможности.

Кроме того, переопределение системных форм ведет к тому, что теряется некоторый пользовательский опыт, когда пользователь, переходя от одного прикладного решения к другому, внезапно для него получает совершенно другую форму с (в пределе) совершенно другим поведением и возможностями.

Также стоит отметить, что любое использование недокументированных возможностей в любой момент времени может перестать работать (описываемая возможность не является исключением).
Danil.Potapov; ikekoval; Дмитрий74Чел; +3 – Ответить
84. tailer2 13.12.16 14:55 Сейчас в теме
(6) трабл в том, что любая документированная фича в любой момент может перестать работать

в вообще, доступно и всерьез, знаете ли
ixijixi; EugeneSemyonov; Somebody1; ksely; Hobbit_Jedi; v.l.; +6 – Ответить
86. Dementor 1077 29.12.16 17:29 Сейчас в теме
(84) не нужно путать отмену документированных и недокументированных фич. Согласен, что документированные возможности тоже отменяют и изменяют, но при этом такие изменения явно документируют и о них извещают пользователей платформы (а далее это уже ваше право не читать файл V8Update.htm). Стоит отметить, что отмененные фичи в новых платформах могут продолжить работать, если для конфигурации выбрать режим совместимости с предыдущими версиями.

Недокументированные возможности могут появляться и исчезать хаотично, про их жизненный цикл никто не отчитывается и если они пропадут, то никакой режим совместимости уже не поможет.
117. Dr.Mult 20 04.12.18 17:49 Сейчас в теме
(6)
и код для сохранения/переопределения.
, конечно тут элементарный копипаст с изменением пары фраз и выдача за свой титанический труд ( цитата "Случайно наткнулась при разборе ошибок платформы. " - ха .. ха)
8. Поручик 4611 19.06.15 13:42 Сейчас в теме
Супер. Автору зачёт. Вот уж не знал. Сколько встречал вопросов, а можно ли вызвать что-то стандартное, и везде ответ - нельзя.
9. ekaruk 5071 19.06.15 13:46 Сейчас в теме
(8) Поручик, Официально это делать действительно нельзя.
Позиция 1С по поводу таких переопределений описана в (6). И в принципе я с ней согласна. Их подход правильный. Есть стандартные функции, которые зависят от релиза платформы и развиваются параллельно с ней.
Но в некоторых случаях все-таки пользоваться под свою ответственность можно.
10. bulpi 219 19.06.15 14:11 Сейчас в теме
11. ZhokhovM 688 19.06.15 14:32 Сейчас в теме
Автор, а кроме стандартных обработок есть еще другие стандартные встроенные объекты? Например, по списку внутренних идентификаторов платформы: "v8res://mngbase/" или "v8res://...".
12. ekaruk 5071 19.06.15 14:55 Сейчас в теме
(11) ZhokhovM, По обработкам вроде это все.
Есть много вшитых в ресурсы форм, но как их правильно вытащить я пока не разбиралась.
13. mburkin 11 19.06.15 15:09 Сейчас в теме
А такую штуку можно провернуть со всеми обработками или только из тех, что скрываются в пункте "Стандартные"?
14. ekaruk 5071 19.06.15 15:13 Сейчас в теме
(13) mburkin, А с какими это "со всеми"?
Насколько я знаю, других обработок в платформе нет.
На самом деле в данном случае для подключения используется стандартный метод менеджера внешних обработок ВнешниеОбработки.Подключить()
Смысл этой статьи только в определении внутренних адресов, по которым можно взять стандартные обработки.
15. МихаилМ 19.06.15 15:53 Сейчас в теме
спасибо. здорово.
16. ZOMI 400 19.06.15 17:34 Сейчас в теме
17. w.r. 656 19.06.15 17:48 Сейчас в теме
Автор, удаление пормеченных объектов разве не является обработкой конфигурации?
19. ekaruk 5071 19.06.15 17:56 Сейчас в теме
(17) w.r., Всегда есть платформенная в меню "Все функции".
Плюс дополнительно в конфигурации может быть включена обработка, адаптированная под особенности конкретной конфигурации.
Например, в УТ11, есть отдельные обработки "Удаление помеченных объектов", "Управление итогами и агрегатами", "Управление полнотекстовым поиском".
Но это именно отдельные независимые обработки.
В общем случае при наличии обработок в конфигурации лучше использовать их, а не встроенные в платформу.
18. Fragster 1168 19.06.15 17:53 Сейчас в теме
Очень хочется подменить стандартное окно полнотекстового поиска, случайно нет информации про него?
20. ekaruk 5071 19.06.15 17:58 Сейчас в теме
(18) Fragster, Насколько я понимаю, это не платформенная, а стандартная встроенная в конфигурацию обработка.
С ней можно делать все, что угодно, стандартными средствами из конфигуратора.
21. w.r. 656 19.06.15 18:12 Сейчас в теме
Автор, и еще в примере 1 ошибка ПодключитьВнешнююОбработкуНаСервере() это процедура, иначе нужно что-нибудь возвращать в функции и лучше вызывать без контекста
22. ekaruk 5071 19.06.15 19:24 Сейчас в теме
(21) w.r., Да, действительно. с точки зрения идеологии работы правильнее Процедура.
Поправила.
Хотя, как ни странно, вариант с функцией тоже работает и ошибок не выдает.
По поводу контекста, это пример для модуля команды.
В нем нет варианта директивы &НаСервереБезКонтекста.
Но при вызове из формы логичнее использовать без контекста.
23. w.r. 656 19.06.15 19:41 Сейчас в теме
(22) функция без явного указания возвращаемого значения возвращает Неопределено, вот когда вызывают процедуру, как функцию, тогда будет ошибка выполнения. Если общая команда, то логично, что всегда есть контекст, извиняюсь. Но я бы конфигурацию менять не стал без особой крайней надобности. Лучше внешняя обработка
27. w.r. 656 20.06.15 16:37 Сейчас в теме
(22) стало интересно, тут с точки зрения идеологии нужна все-таки функция, тк метод ВнешниеОбработки.Подключить возвращает имя подключенной обработки, значит можно контролировать этот процесс :
&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
    ИмяОбработки = ПодключитьВнешнююОбработкуНаСервере(); 
    Если ИмяОбработки = "StandardFindByRef" Тогда
      ОткрытьФорму("ВнешняяОбработка.StandardFindByRef.Форма");
    Иначе
      Предупреждение("Не удалось подключить внешнюю обработку!");
    КонецЕсли;
КонецПроцедуры

&НаСервере
Функция ПодключитьВнешнююОбработкуНаСервере()
    ИмяОбработки = ВнешниеОбработки.Подключить("v8res://mngbase/StandardFindByRef.epf", "StandardFindByRef", Ложь);
Возврат ИмяОбработки;
КонецФункции
Показать

Ну если не используется модальность, то показать через метод ПоказатьПредупреждение
24. Aleksey.Bochkov 3713 20.06.15 09:26 Сейчас в теме
(0) поясню минус - ИМХО, от таких возможностей больше вреда, чем пользы. По этим соображениям и не публиковал тут подобную информацию когда раскопал эту фичу.
25. ekaruk 5071 20.06.15 11:10 Сейчас в теме
(24) Aleksey.Bochkov, У меня были сомнения о том, стоит ли описывать такие вещи о работе платформы. Думаю, то что они не описаны в официальной документации от 1С это правильно.
Однако я также считаю что для правильной работы с платформой программист должен понимать, как она работает, из чего состоит программный продукт, как взаимосвязаны его части (платформа, конфигурация, информационная база), какой функционал выполняется на каком уровне, какие настройки на каком уровне настраиваются.
При возникновении проблем со стандартными механизмами, нужно иметь возможность разобраться, в чем именно проблема. Программист должен уметь понять как работает нужный функционал. Именно для того, чтобы понять, в чем именно проблема в данных в конкретнй базе. А для этого нужно иметь возможность взять эту же обработку из текущей версии платформы в виде файла и пройтись отладчиком по непонятным вещам.
Также я считаю полезной возможность делать свои обработки на базе стандартных встроенных, а не изобретать каждый раз велосипеды, которые работают каждый по-разному.
И на мой взгляд, Инфостарт именно тот ресурс, на котором должна быть подобная информация. Также как информация о внутреннней структуре .cf и .dt файлов, структуре хранения системных данных базы в SQL. Да, неправильное использование такой информации может навредить, но понимание этих вещей необходимо для правильной работы и возможности оперативно решать возникающие задачи.
IgorS; EugeneSemyonov; Mizhgan42; user1580936; rintik; MoshkovEV; Greysvandir; Elvira_Saydasheva; m_aster; Anna_arbuz; Jeka44; bulpi; Somebody1; Korolev; KolyNCo; Hobbit_Jedi; bark.722688; AllexSoft; sergathome; tgr123; ayuplotnikov; Wdivine; jif; vvp117; zuza; EVKash; IvanovAV; purgin; TeMochkiN; Maruska77; slavapil; Rjhev; alexeyplotnikov; AliceLight; Vovan58; tormozit; Sergey-MX; antonov_i; wildwilduser; chmv; alex-l19041; kinazarov; sytkosa; viking(j); [AdepT]; kentavr27; Craig; anchovy; marat_n; EduardSpb; Alexsur; Sgeor; frkbvfnjh; flexornail; Enot; v.l.; Nuobu; andrey1508; rzabolotin; invertercant; AndrewVVS; mrXoxot; sergo_722; CratosX; cefew; AlexAuto; RomaM; FullMoon; Зеленоград; 1cprogr_nsk; Corablove; FSerg; MRAK; begemot; worker1c; unichkin; +76 – Ответить
26. w.r. 656 20.06.15 15:39 Сейчас в теме
(25) Не согласен. Работа программиста прежде всего разработка. Порнимать механизмы нужно, но только касаемо части разработки. Если возникли проблемы с платформой, то лучше и правильней все-таки откатиться на предыдущую версию, где нет проблемы, и сообщить о ней разработчику, чем пытаться ее устранить самостоятельно, используя недокументируемые функции
28. tormozit 7394 20.06.15 23:48 Сейчас в теме
Интересно а внешние обработки с обычными формами там есть? Считаю было бы очень полезно в статье указать ссыдку на тему партнерского форума, где даны официальные разъяснения по этой возможности.
29. ekaruk 5071 21.06.15 00:04 Сейчас в теме
(28) tormozit, Формы обычные есть. Обработок в явном виде не видела.
Насколько я понимаю, тема имелась в виду эта. Ничего больше не встречала. https://partners.v8.1c.ru/forum/topic/1252472
Там нет особо официальных разъяснений. Основная идея: использовать функции платформы можно только из основного меню.
30. tarassov 114 22.06.15 18:01 Сейчас в теме
Очень интересная идея автора!
И чуть-чуть ее можно продолжить.
Информация о файлах v8res://mngbase/StandardActiveUsers.epf и т.п. лежит в файле mngbase_root.res
"v8res://mngbase/dcssFormModuleRus.txt"
"v8res://mngbase/searchFormModuleRus.txt"
"v8res://mngbase/FileSystemExtension.zip"
"v8res://mngbase/CryptoProtectionExtension.zip"
"v8res://mngbase/html.txt"
"v8res://mngbase/model.xdto"
Greysvandir; IvanovAV; kote; oleg-x; CSiER; newborn; kraynev-navi; serg__k; invertercant; GlukAl; frkbvfnjh; v.l.; Serj1C; +13 – Ответить
146. user958974 31.01.23 11:38 Сейчас в теме
(30)
mngbase_root.res
А чем посмотреть сожержимое этого файла?
31. mrmasson 57 23.06.15 09:10 Сейчас в теме
Ставлю жирный плюс. В УТ 11.1 в обработке поиска ссылки не объект нет справочника "Номенклатура". Благодаря Вашему способу, смогу вытянуть стандартную обработку, подправить ее и пользоваться в свое удовольствие
32. ekaruk 5071 23.06.15 10:05 Сейчас в теме
(31) mrmasson, На самом деле в Вашем случае это не обязательно.
Он там есть, просто называется "Позиция номенклатуры".
Вытягивать придется только если нужно будет какие-то еще опции в поиск добавить.
IgorS; user813055; +2 – Ответить
33. tarassov 114 23.06.15 13:12 Сейчас в теме
Попробовал, ка описано, сделать "1. Вызов стандартной обработки из любого пункта меню. "
Если вместо предлагаемого
&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
    ПодключитьВнешнююОбработкуНаСервере();
    ОткрытьФорму("ВнешняяОбработка.StandardFindByRef.Форма");
КонецПроцедуры

написать
&НаКлиенте
Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)
	
	Параметры = Новый Структура;
	Параметры.Вставить("RequiredObject", ПараметрКоманды);
	
	ПодключитьВнешнююОбработкуНаСервере();
    ОткрытьФорму("ВнешняяОбработка.StandardFindByRef.Форма", Параметры, ПараметрыВыполненияКоманды.Источник, ПараметрыВыполненияКоманды.Уникальность, ПараметрыВыполненияКоманды.Окно);
	
КонецПроцедуры
Показать


то не потребуется вручную выбирать объект. Сразу заработает поиск!
BigB; Korolev; Огонек; jONES1979; Rjhev; teflon; MalimonovDS; wolfsoft; +8 – Ответить
34. DoctorRoza 23.06.15 16:15 Сейчас в теме
Конструктор запросов порадовал! :)
35. Mortiferus 369 24.06.15 09:21 Сейчас в теме
Классно! Только сегодня думал о том, как запускать регламентным заданием перепроведение документов, чтобы самому не писать. Молодчина!
36. Zord 24.06.15 09:28 Сейчас в теме
Отлично! Спасибо большое! Я буквально на днях искал где же эти обработки зарыты!
37. Ulus 257 24.06.15 10:46 Сейчас в теме
Молодец.
Давно ее подметил.
Видно - мега спец!
Все темы - МОЩЬ!
38. Чарик 2 24.06.15 17:46 Сейчас в теме
Классная статья! И самое главная нужная! Автору респект и жирный плюс!
39. DrAku1a 1805 25.06.15 02:48 Сейчас в теме
Автору респект! Яростно плюсуем!
40. ekaruk 5071 27.06.15 09:34 Сейчас в теме
Вау.
Моя первая публикация, набравшая 200 плюсиков.
Причем ровно за неделю.
Похоже, действительно зацепила интересную тему.
Приятно :)
Greysvandir; m_aster; bark.722688; SmArtist; golcha; jONES1979; TeMochkiN; inf012; jaroslav.h; coolseo; fomaOp; sCHTASS; v.l.; Nuobu; gelhar; FindSS; ZhokhovM; +17 – Ответить
41. Yashazz 4931 30.06.15 08:11 Сейчас в теме
У меня есть ощущение, что таковое появилось недавно. Потому что я копался в 8.2.12 ровно с той же идеей, и нихрена не обрёл. Ну и в любом случае это может завтра измениться, и тогда будут грабли)

Автору за кропотливое копание в потрохах 1С - респект.
42. kuzev 48 30.06.15 13:10 Сейчас в теме
Добавлю ссылку на пост годичной давности: https://snegopat.ru/forum/viewtopic.php?f=6&t=619.
Painted; artbear; +2 – Ответить
43. Kondrat 11 02.07.15 12:39 Сейчас в теме
44. infostartfilipich 06.07.15 11:12 Сейчас в теме
Не могу открыть в Бухгалтерии 2.0 на платформе 8.2.19.116 (и клиент-сервер и файловая, код выполняется в модуле внешней обработки) - пробовал и так:
ВнешниеОбработки.Подключить("v8res://mngbase/StandardFindByRef.epf", "StandardFindByRef", false);
ВнешниеОбработки.Создать("StandardFindByRef");
и так:
ВнешниеОбработки.Создать("v8res://mngbase/StandardFindByRef.epf", false);
Ругается:
"Ошибка подключения внешних метаданных
по причине:
Файл не обнаружен 'StandardFindByRef'"
Что я не так делаю? - на платформе 8.3 работает...
45. ekaruk 5071 06.07.15 12:01 Сейчас в теме
(44) infostartfilipich, Да, у меня тоже напрямую не подключается на 8.2.19.130.
Зато подключается через промежуточный файл
КопироватьФайл("v8res://mngbase/StandardFindByRef.epf","c:/temp/StandardFindByRef.epf");
Обработка = ВнешниеОбработки.Создать("c:/temp/StandardFindByRef.epf", false);
46. infostartfilipich 06.07.15 12:06 Сейчас в теме
(45) Спасибо, понял!
Хорошо бы этот нюанс и в статью добавить...
47. ekaruk 5071 06.07.15 12:37 Сейчас в теме
(46) infostartfilipich, Да я сама не знала. Только сейчас попробовала.
Не могу понять, почему обычный вариант не работает.
Вроде должен работать аналогично.
Синтаксис команд работы с внешними обработками в 8.2 и 8.3 одинаковый.
50. V.Nikonov 141 08.07.15 23:10 Сейчас в теме
(47) Адресное пространство "v8res://mngbase..." недоступно для проводника Windows? По этой причине или требуется разрешение на запись в "v8res://mngbase..."?
51. ekaruk 5071 08.07.15 23:46 Сейчас в теме
(50) V.Nikonov, Оно не может быть доступно.
Это внутренний адрес конфигурации.
Мы туда ничего не пишем, только читаем.
48. pro1c@inbox.ru 188 07.07.15 15:09 Сейчас в теме
49. Дикий Йожыг 07.07.15 15:36 Сейчас в теме
Клева.
А есть возможность получить под обычные формы? А то выдает обработки под управляемые.
52. tormozit 7394 10.07.15 19:36 Сейчас в теме
Форма настроек динамического списка есть там?
53. Dementor 1077 11.07.15 12:09 Сейчас в теме
(52) tormozit, Нет. Только перечисленные обработки.
54. vec435 17 19.08.15 18:37 Сейчас в теме
а для 8.1 есть какая-нить инфа?
55. sashocq 195 24.08.15 11:20 Сейчас в теме
Нашёл там ещё описания форм. Есть идеи как их вытащить? Интересует диалог выбора цвета (ColorChoose.lf), хотелось бы его доработать и вставить себе в конфигурацию. Просмотрел весь код формы — не нашёл, как формируется список цветов и как они отображаются.
56. пользователь 14.09.15 15:40
Сообщение было скрыто модератором.
...
57. chmv 14.09.15 17:19 Сейчас в теме
58. superkuzja 3 18.09.15 13:10 Сейчас в теме
Евгения, подскажите как правильно получить путь к стандартной обработке. У меня при выполнении команды:
КопироватьФайл("v8res://mngbase/StandardFindByRef.epf","C:\ВнешняяОбработка.epf");
выходит ошибка:
Ошибка копирования файлов
по причине:
Каталог не обнаружен 'v8res://mngbase/StandardActiveUsers.epf'

Запускал на платформе 8.3.6.2152. Заранее - спасибо!
serega7; Hobbit_Jedi; +2 – Ответить
59. ekaruk 5071 18.09.15 13:53 Сейчас в теме
(58) superkuzja, У меня на 8.3.6.2152 обработка в файл сохраняется корректно.
Проверяла для файловой базы. Контекст выполнения &НаСервере
60. superkuzja 3 18.09.15 14:05 Сейчас в теме
(59) большое спасибо, Евгения, всё корректно отработало при изменении контекста.
61. mszsuz 349 28.09.15 07:48 Сейчас в теме
Во вложении готовая обработка для выгрузки. Поможет сэкономить немного времени.
Прикрепленные файлы:
2015-09-28 ВыгрузкаВстроенныхОтчетов.epf
AAM94; tricolor; Mimm2015; m_aster; Jeka44; BigB; Dmitry888; gea81; Simonov_NPM; Danil.Potapov; nad0_hto; BARS1969; GetNight; Rjhev; Serj1C; teflon; inanity; Lukich66; serg__k; Захаров_Николай; alex-l19041; andrew_comm; frkbvfnjh; v.l.; vserdtsov; DrAku1a; shmellevich; AndrewVVS; sergo_722; aytana; CratosX; ekaruk; +32 – Ответить
72. alex-l19041 8 15.06.16 10:22 Сейчас в теме
(61) mszsuz,

Обработка хорошая, только сразу не запустилась.
Пришлось СтрРазделить(Стр, ";", Ложь);
заменить на
ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(Стр,";");

Также процедура КаталогВыгрузкиНачалоВыбора
не сработала. Пришлось полностью переписать
73. mszsuz 349 15.06.16 11:44 Сейчас в теме
(72) Переходите на новую платформу. Сейчас уже 8.3.8. Две недели проверяю - вроде нормально работает.
androgin; +1 – Ответить
80. androgin 04.08.16 17:53 Сейчас в теме
(73) mszsuz, 2 недели?????
она с прошлого года уже ! )))))
62. boln 1044 18.01.16 15:00 Сейчас в теме
ekaruk, не в первый раз жалею, что слово "гений" не имеет женского рода :)
63. frkbvfnjh 825 22.02.16 07:05 Сейчас в теме
Я с "детства" мечтал добраться до этих обработок, чтоб хотя бы вызвать из из своего кода. Это самая качественная и нужная статья по недокументированным возможностям. Хотя не пойму, почему разработчики платформы не добавили возможность хотя бы просто вызова этих диалогов из кода, пусть даже с административными правами...
jONES1979; +1 – Ответить
64. frkbvfnjh 825 22.02.16 07:30 Сейчас в теме
Кстати, тут уже спрашивали, так что повторюсь - как добраться до обработок для обычного приложения, не управляемого? Я имею ввиду, может кто нибудь уже разобрался как до них добраться...
66. ekaruk 5071 24.02.16 22:33 Сейчас в теме
(64) frkbvfnjh, Про обычное не знаю. Теоретически это должны быть те же самые обработки.
(65) Abbra, Не совсем поняла, как скопировали. Эти обработки не являются элементами конфигурации, соответственно на них не может быть внешней ссылки. При их открытии даже звездочка неактивна. Если нужно дать на них ссылку, то я вижу только вариант встраивать их в конфигурацию.
67. Abbra 24 24.02.16 23:23 Сейчас в теме
(66) из Вашей статьи скопировал. "v8res://mngbase/StandardFindByRef.epf" )
Теперь понятно, что нельзя. Спасибо.

65. Abbra 24 24.02.16 22:26 Сейчас в теме
А нельзя ли как-нибудь эти ссылки использовать по кнопке Перейти по ссылке (Звездочка с зеленой стрелкой) для открытия обработок? Просто скопировал - не получилось.

68. AndreykO 10 11.03.16 06:47 Сейчас в теме
Спасибо. Очень помогло. Всё работает
69. anri99 16.03.16 15:38 Сейчас в теме
Отличная статья, спасибо автору, такое редко где встретишь!
alex-l19041; +1 – Ответить
70. Trise 139 07.04.16 13:17 Сейчас в теме
Надеюсь тема актуальна и развивается, найти бы стандартную форму сообщения об ошибке, в частности формы с кнопкой подробно, для создания "подписки на ошибку" и дальнейшем обработки и сбора информации, что-бы не выискивать, что пользователю там выдалось, а иметь корректно сохраненный текст ошибки, если еще и контекст удастся зацепить было бы совсем замечательно.
TreeDogNight; +1 – Ответить
71. ekaruk 5071 07.04.16 17:56 Сейчас в теме
(70) Trise, С формами так, к сожалению, не получится.
Механизм подключения внешних файлов с внутренними именами есть только для отчетов и обработок.
Формы теоретически можно вытащить, но подменить стандартные внешними нельзя.
74. blackschool 24 06.07.16 11:37 Сейчас в теме
В коде типовых конфигураций можно найти упоминание имён стандартных обработок. Например, в УТ 11.2 "StandardFindByRef".
75. ekaruk 5071 06.07.16 13:45 Сейчас в теме
(74) blackschool, Да, действительно.
Появились упоминания.
Интересно, раньше не было нигде.
76. LexSeIch 212 11.07.16 07:52 Сейчас в теме
Тема очень интересная - большое спасибо за публикацию данной статьи.
77. German_Tagil 43 11.07.16 10:03 Сейчас в теме
И все таки как быть с обычными формами?
82. Wolex 130 23.09.16 16:20 Сейчас в теме
(77) German_Tagil, учитывая, что для управляемых используется внутренний каталог v8res://mngbase/, покопайте в сторону OrdinaryApplication. что-нибудь в духе ordbase
111. ssfedkin 6 31.05.18 12:30 Сейчас в теме
Интересно, получилось у кого-нибудь для обычных форм обработки вытащить? Как в (82) не получается.
78. ZhokhovM 688 19.07.16 15:17 Сейчас в теме
Есть вопрос, как вызвать программно стандартную форму "Все функции" из внешней обработки? Мне нужно это для теста. Никто не знает?
133. M_Volkov 5 15.04.21 05:09 Сейчас в теме
(78)
как вызвать программно стандартную форму "Все функции" из внешней обработки?
Удалось? Если Да, поделись...
134. ZhokhovM 688 15.04.21 07:46 Сейчас в теме
79. jONES1979 23.07.16 19:42 Сейчас в теме
Действительно, очень любопытно, и перспективы интересные. Спасибо! :)
81. tyushin 02.09.16 04:34 Сейчас в теме
на актуальной платформе что-то не работает у меня. Ошибка "каталог v8res://mngbase/... не обнаружен"
JesteR; BigB; +2 – Ответить
83. v3rter 13.12.16 13:04 Сейчас в теме
Подскажите, пожалуйста, адрес стандартной формы формы "Редактирование списка значений".
85. JesteR 156 29.12.16 10:23 Сейчас в теме
8.3.8.2197 Попробовал вытащить Удаление помеченных, не работает, пишет "Каталог не обнаружен", видимо с момента выхода публикации 1С что-то изменили.
87. ekaruk 5071 02.01.17 23:08 Сейчас в теме
(85) Ничего не изменилось.
На 8.3.9.2016 отлично работает.
Проверьте, что код выполняется на сервере и существует каталог, в который файл копируете.
88. JesteR 156 20.01.17 12:03 Сейчас в теме
(85) (87) Извините, сам дурак. Все работает. Спасибо.
89. Probot1c 04.02.17 06:21 Сейчас в теме
Автор молодец, полезно!
90. daho 8 09.02.17 10:57 Сейчас в теме
А вот для неуправляемых форм можно выгрузить обработки?
91. German_Tagil 43 09.02.17 13:05 Сейчас в теме
92. Wolex 130 12.02.17 22:52 Сейчас в теме
(90) в (77) уже спрашивали, в (82) возможный ответ
93. daho 8 14.02.17 14:09 Сейчас в теме
(92) Да, спасибо.. Так в принципе и мыслил. Думал может кто уже наковырял. )
94. Aphanas 94 01.03.17 15:47 Сейчас в теме
Коллеги, подскажите кто знает, возможно ли выдернуть подобным образом обработку конструктора запроса?
95. mszsuz 349 05.03.17 22:34 Сейчас в теме
(94) Да. Именно она и упомянута в описании под номером 10.
96. fishca 1317 28.03.17 16:48 Сейчас в теме
97. Aprobator 21.06.17 10:07 Сейчас в теме
Обалденно, у меня просто других слов нет )
98. sss999 50 24.07.17 08:41 Сейчас в теме
Это ты сама написала?
99. vladismi 170 14.09.17 10:27 Сейчас в теме
Полезно. Запомним.
100. vs84 09.11.17 15:39 Сейчас в теме
А можно выдернуть форму поиска в динсписке, которая по Ctrl+F?
101. jif 20.11.17 17:47 Сейчас в теме
Добрый день, а которая Shift+F11 ? Спасибо
103. ekaruk 5071 11.12.17 17:21 Сейчас в теме
(101) Это уже к стандартным не относится. Про неё не знаю :(
102. b-dm 181 11.12.17 16:51 Сейчас в теме
Оригинальный и нестандартный подход.
104. JohnyDeath 302 09.02.18 08:17 Сейчас в теме
Обработку по просмотру встроенной истории из 8.3.11 никто не находил?
METAL; romankoav; +2 – Ответить
105. ekaruk 5071 09.02.18 11:07 Сейчас в теме
(104) А в каком релизе она появилась?
Вроде только "Управление системой взаимодействия" добавилось.
106. JohnyDeath 302 09.02.18 12:28 Сейчас в теме
(105) там как-то мутно. В файлике ресурсов нет прям отдельной обработки, но есть код формы (скорее всего она как бы "общая форма" получается)
Я смотрю в платформе 8.3.11.2867
107. ekaruk 5071 09.02.18 13:01 Сейчас в теме
(106) Да, похоже, это общая форма.
Называется DataHistoryVersions.lf
Где-то был пост о том, как эти формы преобразовывать в нормальный читабельный вид. Но не могу сейчас найти.
108. JohnyDeath 302 09.02.18 14:14 Сейчас в теме
(107) Если найдешь - поделись, а то мы уже начинаем свою рисовать
109. VKislitsin 1063 14.03.18 15:42 Сейчас в теме
110. ekaruk 5071 14.03.18 18:46 Сейчас в теме
(109) Да, вторая ссылка как раз оно.
Работа с формами платформы.
ZhokhovM; romankoav; +2 – Ответить
129. Leon29 13.10.20 16:11 Сейчас в теме
(104) Я искал и нашёл неожиданно для себя здесь: в конфигурации общие формы - добавить. В списке выбрать нужную форму истории, например, "Форма истории изменений истории данных" и готово.
112. RoleXX 31.05.18 17:13 Сейчас в теме
В платформе явно вшиты и обработки с обычными формами (самописная конфа на обычных формах и через меню вызываются эти обработки с обычными формами) вопрос только где их искать...
113. ekaruk 5071 04.06.18 15:12 Сейчас в теме
(112) Может, это те же самые? Не проверяла, может в этих два варианта форм.
114. Alex10166 33 24.07.18 14:54 Сейчас в теме
115. unknown181538 166 13.10.18 20:02 Сейчас в теме
С настройкой панели навигации можно что-нибудь сделать? отключить в частности?
116. unknown181538 166 13.10.18 23:27 Сейчас в теме
(115)
В ПриНачалеРаботыСистемы:
ЭА_Сервер.ПереопределитьНастройкуНавигации();



В модуле ЭА_Сервер:
Процедура ПереопределитьНастройкуНавигации()Экспорт

ДвоичныеДанные = Новый ДвоичныеДанные("C:\Database\ВнешняяОбработка1.epf");
АдресХранилища = ПоместитьВоВременноеХранилище(ДвоичныеДанные);
// так
ВнешниеОбработки.Подключить(АдресХранилища, "v8res://mngbase/dcschangesettingsstructure.epf", false);
// Или так
ВнешниеОбработки.Подключить(АдресХранилища, "8res://mngbase/dcschangesettingsstructure", false);

КонецПроцедуры


Что-то не подменяется форма
118. AlexO 136 26.01.19 14:41 Сейчас в теме
Я, ребята, может и ошибаюсь, или все эти "стандартные обработки, вшитые в платформу, и с таким трудом вытащенные" - выкладываются на диске ИТС? И их смело можно оттуда взять?
119. nomadon 369 27.01.19 07:25 Сейчас в теме
Форму блокировки приложения находили?
120. Simonov_NPM 04.09.19 08:07 Сейчас в теме
Подскажите как вытащить обработку проведения с обычной формой, вытаскиваю "StandardDocumentsPosting.epf", она на управляемых.
121. ekaruk 5071 04.09.19 09:19 Сейчас в теме
(120) Подозреваю, что она существует в платформе только в варианте на управляемых формах.
122. Simonov_NPM 04.09.19 09:43 Сейчас в теме
(121) Все верно, в файле mngbase_ru.res лежат управляемые, обычные (судя по содержимому) лежат в basicui_ru.res, вот только как их от туда вытащить. Пробовал
КопироватьФайл("v8res://basicui/StandardFindByRef.epf","C:\ВнешняяОбработка.epf");
, но там нет строк с расширением epf. Все что удалось вытащить так это форму )))
КопироватьФайл("v8res://basicui/DocumentsPostingDlg.f","D:\Новая папка\DocumentsPosting81.epf"); и все на этом.
tormozit; +1 – Ответить
123. пользователь 08.11.19 00:11
Сообщение было скрыто модератором.
...
124. TreeDogNight 22 31.01.20 15:14 Сейчас в теме
Можно ли таким образом выгрузить стандартную форму Обсуждений Системы взаимодействий?
125. andryandry 104 26.02.20 09:16 Сейчас в теме
подскажите, а как получить двоичные данные встроенной обработки? хочу заменить стандартный поиск в расширении конфигурации, предварительно сохранив в нем измененную форму обработки
126. user1279577 18.03.20 13:40 Сейчас в теме
Про обычные формы и не только есть отдельная публикация: https://infostart.ru/public/538300/
127. Trise 139 09.04.20 08:26 Сейчас в теме
Подскажите, может знает кто как вытащить форму справки... Прям так и охота туда всяких кнопочек понавтыкат=))
130. adva 45 24.12.20 16:22 Сейчас в теме
А нельзя случайно открыть программно Все функции?

p.s. Кажется нашел в ответах выше, попробую
131. androidT1C 76 25.02.21 12:46 Сейчас в теме
8.3.12

Делаю:
КопироватьФайл("v8res://mngbase/StandardECSRegister.epf", "D:\StandardECSRegister.epf");

Результат:
{ВнешняяОбработка.КопироватьФайл_v8res_mngbase.Форма.Форма.Форма(14)}: Ошибка при вызове метода контекста (КопироватьФайл)
КопироватьФайл("v8res://mngbase/StandardECSRegister.epf", "D:\StandardECSRegister.epf");
по причине:
Ошибка копирования файлов
по причине:
Каталог не обнаружен 'v8res://mngbase/StandardECSRegister.epf'

Почему? Аналогичная ошибка с StandardFindByRef и другими.
Что на клиенте, что на сервере.
132. M_Volkov 5 14.04.21 09:23 Сейчас в теме
При выборе константы из "Все функции" отрывается форма константы. Можно ли ее как-то достать, посмотреть, доработать для типа ХранилищеЗначения?
135. mszsuz 349 07.07.21 11:49 Сейчас в теме
в 8.3.20 прикрыли лавочку.
136. tormozit 7394 07.07.21 12:00 Сейчас в теме
(135) Где доказательство?
137. mszsuz 349 07.07.21 12:04 Сейчас в теме
(136) Поторопился. Просто переименовали некоторые, н-р:
StandardFindByRef -> StandardFindByReference
138. mszsuz 349 07.07.21 12:10 Сейчас в теме
StandardExtensionsManagement -> StandardConfigurationExtensionsManagement
139. Necessitudo 23.11.21 14:29 Сейчас в теме
Управление серверами - "StandartServersControl"
1c-kt; Live; +2 – Ответить
140. alexander-lubich 30 31.05.22 00:04 Сейчас в теме
Файл не обнаружен 'v8res://mngbase/StandardActiveUsers.epf' ресурс не найден платформа 8.3.20.1789

видимо обработки теперь называются по другому или вызывать их надо иначе
141. alexander-lubich 30 31.05.22 00:17 Сейчас в теме
(137) да , я тоже . работает в новых платформах
имя другое (Поторопился. Просто переименовали некоторые, н-р:
StandardFindByRef -> StandardFindByReference)

тут раскрыто https://infostart.ru/public/538300/
142. пользователь 04.08.22 09:49
Сообщение было скрыто модератором.
...
143. user1395119 01.09.22 13:02 Сейчас в теме
Добрый день!

Спасибо, работает.
144. user1486489 15.12.22 08:39 Сейчас в теме
Добрый день! Спасибо) Спустя столько лет все еще актуально!
145. user958974 30.01.23 17:52 Сейчас в теме
Коллеги, подскажите, а какой адресс нужно вставить в
ВнешниеОбработки.Подключить("v8res://mngbase/StandardFindByRef.epf", "StandardFindByRef", false);

Что бы таким образом открывались "Функции для технического специалиста" (Все функции)?
147. user958974 31.01.23 16:05 Сейчас в теме
Коллеги а какое наименование у "Все функции" ? Что нужно подставить в "ВнешниеОбработки.Подключить(" первым параметром , что бы подключить именно "Все функции" и потом открыть?
149. Alexwarsis 11.04.23 13:42 Сейчас в теме
// Инициализация внешнего объекта
&AtClient
Procedure Init(extObject)
HelpExtObj = extObject;
EndProcedure

А можно как-то получить extObject, никто не знает?
150. Mopo3 337 21.02.24 17:24 Сейчас в теме

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	
	СписокСтандартныхОбработок = ПолучитьСписокСтандартныхОбработок();
	
	Для Каждого СтандартнаяОбработка Из СписокСтандартныхОбработок Цикл
		
		ИмяОбработки = ПодключитьВнешнююОбработкуНаСервере(СтандартнаяОбработка.Значение, СтандартнаяОбработка.Представление);
		ФормаВнешнейОбработки = ПолучитьФорму("ВнешняяОбработка." + ИмяОбработки + ".Форма");
		
		Элементы.СтандартнаяОбрабтка.СписокВыбора.Добавить(ИмяОбработки, ФормаВнешнейОбработки.Заголовок);
		
	КонецЦикла;
	
КонецПроцедуры

&НаСервереБезКонтекста
Функция ПолучитьСписокСтандартныхОбработок()
	
	СписокСтандартныхОбработок = Новый СписокЗначений;
	
	//
	ФайлСтандартныхОбработок = НайтиФайлы(КаталогПрограммы(), "mngbase_ru.res").Получить(0);
	
	ЧтениеТекста = Новый ЧтениеТекста(ФайлСтандартныхОбработок.ПолноеИмя,,,, Ложь);
	ТекстСтандартныхОбработок = ЧтениеТекста.Прочитать();
	ЧтениеТекста.Закрыть();
	
	//
	НомерВхождения = 0;
	Последний_разделитель = Неопределено;
	
	Пока Истина Цикл
		
		НомерВхождения = НомерВхождения + 1;
		Позиция_epf = СтрНайти(ТекстСтандартныхОбработок, ".epf",,, НомерВхождения);
		
		Если Позиция_epf = 0 Тогда 
			Прервать;
		КонецЕсли;
		
		//
		Позиция_разделитель = СтрНайти(ТекстСтандартныхОбработок, Символ(0), НаправлениеПоиска.СКонца, Позиция_epf, 1);
		Позиция_слэш = СтрНайти(ТекстСтандартныхОбработок, "/",,, НомерВхождения);
		
		Если Позиция_epf > Позиция_слэш И Позиция_слэш > Позиция_разделитель Тогда 
			Прервать;
		КонецЕсли;

		//
		ИмяСтандартнойОбработки = Сред(ТекстСтандартныхОбработок, Позиция_разделитель + 1, Позиция_epf - Позиция_разделитель - 1);
		
		Если СтрЧислоСтрок(ИмяСтандартнойОбработки) > 1 Тогда 
			Прервать;
		КонецЕсли;
		
		//
		ПутьСтандартнойОбработки = СтрШаблон("v8res://mngbase/%1.epf", ИмяСтандартнойОбработки);
		
		Если СтрНайти(ТекстСтандартныхОбработок, ПутьСтандартнойОбработки) = 0 Тогда 
			ЭтаОбработкаИмеетДругойПуть = Истина;
		КонецЕсли;
		
		//
		СписокСтандартныхОбработок.Добавить(ИмяСтандартнойОбработки, ПутьСтандартнойОбработки);
		
	КонецЦикла;
	
	//
	Возврат СписокСтандартныхОбработок;
	
КонецФункции // ПолучитьСписокСтандартныхОбработок()

&НаСервереБезКонтекста
Функция ПодключитьВнешнююОбработкуНаСервере(Имя, Путь)
	
	ИмяОбработки = ВнешниеОбработки.Подключить(Путь, Имя, Ложь);
	
	Возврат ИмяОбработки;
	
КонецФункции

//
&НаКлиенте
Процедура СтандартнаяОбрабткаПриИзменении(Элемент)
	
	ОткрытьВыбраннуюФорму();
	
КонецПроцедуры

&НаКлиенте
Процедура СтандартнаяОбрабткаОткрытие(Элемент, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	ОткрытьВыбраннуюФорму();
	
КонецПроцедуры

&НаКлиенте
Процедура ОткрытьВыбраннуюФорму()
	
	ОткрытьФорму("ВнешняяОбработка." + СтандартнаяОбрабтка + ".Форма");	
	
КонецПроцедуры // ОткрытьВыбраннуюФорму()

Показать
SergMuravev; user2142141; shibudo; swimdog; vvlas; BigB; ZhokhovM; sashocq; +8 – Ответить
151. mxs89 48 17.07.24 10:48 Сейчас в теме
Приветствую.
9db1fa37-b455-4f3f-b8dd-7de0ea7d6da3: Файл не обнаружен 'v8res://mngcore/_bubbleDoublle.zip'. Ресурс не найден: src\resNative.cpp(145): Ресурс не найден"
Может кто сталкивался? Что это за ресурс?
152. script 128 27.02.26 15:35 Сейчас в теме
{ВнешняяОбработка.ВыгрузкаВстроенныхОтчетов.Форма.Форма.Форма(22)}: Error calling context method (КопироватьФайл): Error copying files: File not found 'v8res://mngbase/StandardExtensionsManagement.epf'. Resource not found
153. B2B 274 28.07.26 20:57 Сейчас в теме
(152) StandardConfigurationExtensionsManagement.epf
Для отправки сообщения требуется регистрация/авторизация