Взаимосвязь значений, типов, менеджеров, метаданных

	МоёЗначение1 = ВыбТовар; // тип значения - Тип
	
	МойТип1 = ТипЗнч(МоёЗначение1); // тип значения - Тип :)
	// или
	МойТип1 = Тип("СправочникСсылка.Номенклатура"); // тип значения - Тип
	ТипСамогоТипа = ТипЗнч(МойТип1); // для информации - не вижу прикладного смысла :)
	
	МойСправочникМенеджер1 = Справочники.Номенклатура; // тип значения - СправочникМенеджер.Номенклатура
	ТипСамогоМенеджера = ТипЗнч(МойСправочникМенеджер1); // для информации

	МойМетаОбъект1 = Метаданные.Справочники.Номенклатура; // тип значения - СправочникМенеджер.Номенклатура
	ТипСамогоМетаОбъекта = ТипЗнч(МойМетаОбъект1); // для информации
	
	
	////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
	// Преобразования
	
	// 1.1. Из значения в значение
	МоёЗначение2 = МоёЗначение1; // для простых типов и ссылок - по значению. Для объектов, таблиц знаечний и т.п. это один и тот же объект.
	
	// 1.2. Из значения тип (тривиально). Встречается постоянно.
	МойТип2 = ТипЗнч(МоёЗначение1);
	
	// 1.3. Из значения в менеджера напрямую невозможно. Только через мета-обект.
	МойСправочникМенеджер2 = Справочники[МоёЗначение1.Метаданные().Имя];
	
	// 1.4. Из значения в мета-объект. Встречается постоянно.
	МойМетаОбъект2 = МоёЗначение1.Метаданные();
	
	// 2.1. Из типа получить пустое значение. На практике, практически, не встречается.
	МояПустаяСсылка2 = Новый (МойТип1);
	
	// 2.2. Из значения тип (тривиально).
	МойТип2 = МойТип1;
	
	// 2.3. Из типа получить менеджера напрямую невозможно. Только через мета-обект.
	МойСправочникМенеджер2 = Справочники[Метаданные.НайтиПоТипу(МойТип1).Имя];
	
	// 2.4. Из типа получить мета-объект.
	МойМетаОбъект2 = Метаданные.НайтиПоТипу(МойТип1);
	
	// 3.1. Из менеджера получить пустое значение (тривиально). Встречается постоянно.
	МояПустаяСсылка2 = МойСправочникМенеджер1.ПустаяСсылка();
	// также
	//МоёЗначение2 = МойСправочникМенеджер1.НайтиПоКоду("00000000001");
	//МоёЗначение2 = МойСправочникМенеджер1.НайтиПоНаименованию("Бумага офисная", Истина);
	//МоёЗначение2 = МойСправочникМенеджер1.НайтиПоРеквизиту("1234", "Артикул");
	
	// 3.2. Из менеджера получить тип напрямую невозможно. Только через пустое значение.
	МойТип2 = ТипЗнч(МойСправочникМенеджер1.ПустаяСсылка());
	
	// 3.3. Из менеджера получить менеджера (тривиально). Не вижу прикладного смысла.
	МойСправочникМенеджер2 = МойСправочникМенеджер1;
	
	// 3.4. Из менеджера получить мета-объект напрямую невозможно. Только через пустое значение.
	МойМетаОбъект2 = МойСправочникМенеджер1.ПустаяСсылка().Метаданные();
	
	// 4.1. Из мета-объекта в значениена напрямую невозможно. Только через менеджера.
	МоёПустоеЗначение2 = Справочники[МойМетаОбъект1.Имя].ПустаяСсылка();
	
	// 4.2. Из мета-объекта в тип значения напрямую невозможно. Только через два преобразования: сначала в менеджера, потом в пустое значение.
	МойТип2 = ТипЗнч(Справочники[МойМетаОбъект2.Имя].ПустаяСсылка());
	
	// 4.3. Из мета-объекта в менеджера
	МойСправочникМенеджер2 = Справочники[МойМетаОбъект2.Имя];
	
	// 4.4. Из мета-объекта в мета-объект. Не вижу прикладного смысла.
	МойМетаОбъект2 = МойМетаОбъект1;
	
	Сообщить("Код выполнен.", СтатусСообщения.Информация);