Состав подсистемы
В подсистему входит четыре объекта конфигурации:
- Обработка.ScanDoc_СерверСканирования
- Обработка.ScanDoc_ТестСканирования
- РегистрСведений.ScanDoc_НастройкиСканирования
- Перечисление.ScanDoc_ФорматыФайлов
Обработка.ScanDoc_СерверСканирования
Экспортные процедуры
- ПодключитьКомпонентуСканирования() - подключает компоненту из макета. Подключается всегда 32 битная версия (так как толстый клиент всегда х32), хотя в поставку включена и версия х64.
- ПолучитьИмяРабочегоМеста() - формирует строку, содержащую иям рабочей станции (включая сеанс RDP), а также пользователя Windows. Используется для хранения и восстановления настроек
- ЗаполнитьНастройкиПоУмолчанию() - Заполняет обработку настройками по умолчанию.
- ЗагрузитьНастройки(), ЗаписатьНастройки() - Работа с регистром сведений с настройками
- Сканировать(ФормаВладелец) - Инициирует процесс сканирования с настройками из регистра настроек. Параметры: ФормаВладелец - Обычная форма, из которой вызывается процесс сканирования. Получает информацию об отсканированных страницах
Форма прогресса сканирования
Непосредственное взаимодействие с компонентой осуществляется через форму прогресса сканирования. Сама компонента не блокирует вызывающий ее процесс. Информация о ходе сканирования обрабатывается через ВнешнееСобытие. Перед открытием формы происходит создание экземпляра компоненты м сохранение его в глобальную переменную ДрайверСканера. Это необходимо для предотвращения потери ссылки на компоненту и уничтожения ее платформой 1С прямо в процессе сканирования.
Процедура ПередОткрытием(Отказ, СтандартнаяОбработка)
Индикатор1 = 0;
ЭлементыФормы.СканированиеНадпись.Заголовок = "Подготовка к сканированию";
ЭлементыФормы.СтраницаНадпись.Заголовок = "Страница 1";
Если Не ПодключитьКомпонентуСканирования() Тогда
Отказ = Истина;
Сообщить("Не удалось подключить компоненту сканирования");
Возврат;
КонецЕсли;
Попытка
ДрайверСканера = Новый("AddIn.allspScanDoc.allspScanDoc");
Исключение
Отказ = Истина;
Сообщить("Не удалось создать объект сканирования");
Возврат;
КонецПопытки;
УстройствоОткрыто = ДрайверСканера.ОткрытьУстройство(GUIDСканера);
Если Не УстройствоОткрыто Тогда
Отказ = Истина;
Сообщить("Не удалось создать подключиться к сканеру");
Возврат;
КонецЕсли;
ДрайверСканера.УстановитьЯркость(Яркость*100);
ДрайверСканера.УстановитьКонтраст(Контраст*100);
ДрайверСканера.УстановитьКачество(Качество);
ДрайверСканера.УстановитьЦветность(Цветность);
ДрайверСканера.УстановитьКоличествоСтраниц(КоличествоСтраниц);
Если Источник = 0 Тогда
ДрайверСканера.НачатьСканирование();
ИначеЕсли Источник = 1 Тогда
ДрайверСканера.НачатьСканированиеПодатчик();
ИначеЕсли Источник = 2 Тогда
ДрайверСканера.НачатьСканированиеСтекло();
КонецЕсли;
КонецПроцедуры
Само внешнее событие обрабатывает 3 сообщения:
Процедура ВнешнееСобытие(Источник, Событие, Данные)
Если Событие = "IT_MSG_STATUS_PERCENT" Тогда
ЭлементыФормы.СканированиеНадпись.Заголовок = "Сканирование...";
ЭлементыФормы.СтраницаНадпись.Заголовок = "Страница "+Строка(Страница);
Попытка
Индикатор1 = Число(Данные);
Исключение
КонецПопытки;
КонецЕсли;
Если Событие = "WIA_TRANSFER_MSG_END_OF_STREAM" Тогда
Если Индикатор1 <> 0 Тогда
Индикатор1 = 100;
Страница = Страница+1;
СканНачат = Истина;
ДвоичныеДанные = Новый ДвоичныеДанные(Данные);
УдалитьФайлы(Данные);
Картинка = Новый Картинка(ДвоичныеДанные);
ВладелецФормы.ОбработатьПолучениеКартинки(Картинка);
КонецЕсли;
КонецЕсли;
Если Событие = "WIA_TRANSFER_MSG_END_OF_TRANSFER" Тогда
Если СканНачат ИЛИ (Не СканНачат И ЭтотОбъект.Источник=1) Тогда
ДрайверСканера.ЗакрытьУстройство();
ЭлементыФормы.СканированиеНадпись.Заголовок = "Сохранение данных";
ВладелецФормы.СканированиеЗавершено();
Закрыть();
КонецЕсли;
КонецЕсли;
КонецПроцедуры
Событие IT_MSG_STATUS_PERCENT возникает множественно в процессе сканирования. В поле Данные процент завершения операции.
Событие WIA_TRANSFER_MSG_END_OF_STREAM возникает в конце каждой отсканированной страницы. В поле Данные путь временного файла с изображением. За удаление этого файла отвечает конфигурация. Событие вызывает экспортную процедуру ОбработатьПолучениеКартинки(Картинка) формы, указанной в процедуре Сканировать(ФормаВладелец). В качестве параметра передается объект Картинка.
Событие WIA_TRANSFER_MSG_END_OF_TRANSFER возникает при окончании передачи данных. Вызывает экспортную процедуру СканированиеЗавершено() формы, указанной в процедуре Сканировать(ФормаВладелец).
На некоторых моделях сканеров может возникаль ложое событие WIA_TRANSFER_MSG_END_OF_STREAM, если в автоподатчике нет листов. Поэтому необходима проверка того, что данные начали передаваться.
Порядок вызова собитий следующий: [[IT_MSG_STATUS_PERCENT повторяется много раз], WIA_TRANSFER_MSG_END_OF_STREAM повторяется в конце каждой страницы] WIA_TRANSFER_MSG_END_OF_TRANSFER вызывается однократно для каждого источника данных при автовыборе (зависит от модели сканера). На некоторых моделях сканеров при отсутствии источника сканирования может быть сразу вызвано событие WIA_TRANSFER_MSG_END_OF_TRANSFER .
Форма настроек
Форма осуществляет пользовательский интерфейс к регистру с настройками.
Перечисление.ScanDoc_ФорматыФайлов
Перечисление содержит значения для типов файлов. Используется в форме настройки. Обработка сканирования не реализует сохранение результатов сканирования, этим должно заниматься прикладное решение. Для многостраничных документов обработка использует экспортную процедуру ОбработатьПолучениеКартинки формы инициатора сканирования. Таким образом прикладное решение может группировать наборы страниц для последующего сохранения многостраничных документов.
РегистрСведений.ScanDoc_НастройкиСканирования
Регистр хранит информацию о настройках для каждой пары [рабочая станция]/[пользователь]. При этом в сеансе RDP [рабочая станция] идентифицируется как [имя терминального сервера]\[имя локольной станции]. Максимальные и минимальные значения для яркости/контраста, а также предопределенные значения качества и источников можно посмотреть на форме настройки.
Обработка.ScanDoc_ТестСканирования
В обработке реализовано использование подсистемы с минимальной логикой. страницы сохраняются в памяти и доступны на время работы самой обработки.
Заключение
Внимание! Компонента выпущена в бета версии, никаких гарантий на ее работу не предусмотрено, хотя в настоящее время и работает в реальных решениях. Выложена для ознакомления и применения с целью сбора отзывов. Компонента не обременена лицензионными соглашениями и предоставляется для свободного использования на свое усмотрение как есть.
Вступайте в нашу телеграмм-группу Инфостарт