Пример формирования внешнего отчета программно и в фоновом режиме

28.08.18

Разработка - Инструментарий разработчика

Пример формирования внешнего отчета программно и фоновом режиме на управляемых формах, также можно подключить его как внешний отчет.

Файлы

ВНИМАНИЕ: Файлы из Базы знаний - это исходный код разработки. Это примеры решения задач, шаблоны, заготовки, "строительные материалы" для учетной системы. Файлы ориентированы на специалистов 1С, которые могут разобраться в коде и оптимизировать программу для запуска в базе данных. Гарантии работоспособности нет. Возврата нет. Технической поддержки нет.

Наименование	Скачано	Купить файл	По подписке PRO
Пример внешнего отчета: .erf 13,18Kb 102	102	2 500 руб. Купить	1 SM Скачать

Вы можете заказать платную доработку или адаптацию этой разработки под вашу конфигурацию на «Бирже заказов».

0% комиссии — оплата напрямую исполнителю;
Исполнители любого масштаба — от отдельных специалистов до команд под проект;
Прямой обмен контактами между заказчиком и исполнителем;
Безопасная сделка — при необходимости;
Рейтинги, кейсы и прозрачная система откликов.

Этот отчет (ОСВ) был сделан для примера, так сказать показать наглядно на практике, какие есть возможности формирования отчета в платформе 1С.

На форме присутствуют 4 кнопки, которые формируют отчет тем или иным способом.

1. Сформировать - Отчет будет формироваться штатным образом, то есть стандартная команда формы "Сформировать".

2. Сформировать (программно) - Отчет будет формироваться программным образом вызывая процедуру "СформироватьОтчет" в модуле объекта. Передавая в качестве параметров "СхемуКомпоновкиДанных" и АдресХранилища куда будет помещатся результат процедуры.

3. Сформировать (длительные операции в фоне) - Отчет формируется по средствам БСП используя модули "ДлительныеОперации.ЗапуститьВыполнениеВФоне" и "ДополнительныеОтчетыИОбработки.ВыполнитьКоманду". Также как и во 2-ом способе основной процедурой обработчиком будет являтся "СформироватьОтчет" в модуле объекта. Этот способ формирования я считаю самой сложной (по крайней мере для меня), так как в свое время, чтобы релизовать этот способ у меня ушло много времени. И собственно порадило эту публикация, чтобы другие тоже не теряли время. Главным услувием является добавления отчета как внешний отчет в режиме предприятия в подсистему "ДополнительныеОтчетыИОбработки".

4. Сформировать отчет (режим компоновки в фоне) - Отчет формируется также как и первый способ, исключение лишь в том что задается режим компоновки как "РежимКомпоновкиРезультат.Фоновый".

Отчет тестировался на версия БСП - 2.2.5.32, который был в конфигурации Бухгалтерия для Казахстана ред. 3.0 релиз 3.0.9.35. Отчет можно в дальнейшем использовать для разработок новых отчетов, без добавления его в конфигурацию как объект отчет. Тем самым облегчая дальнейшее сопровождение конфигурации.

В отчете достаточно изменить Запрос СКД, в коде КлючТекущегоВарианта ну и везде где есть упоминание про "Пример отчета".

Ниже приведу весь код отчета

Модуль формы отчета:

&НаКлиенте
Перем ПараметрыОбработчикаОжидания;

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	ЭтаФорма.КлючТекущегоВарианта = "ПримерОтчета";
	Если Параметры.ДополнительнаяОбработкаСсылка = Справочники.ДополнительныеОтчетыИОбработки.ПустаяСсылка() Тогда
		// Почему то не передаются "Параметры" ДополнительнаяОбработкаСсылка, так что ищем сами
		// Если же и здесь не находит, то служебные процедуры выведут ошибки.
		ВременнаяСсылка	=	Справочники.ДополнительныеОтчетыИОбработки.НайтиПоНаименованию("Пример отчета");
		Параметры.ДополнительнаяОбработкаСсылка	= ВременнаяСсылка;	
		ОбъектСсылка = ВременнаяСсылка; 
	Иначе 
		ОбъектСсылка = Параметры.ДополнительнаяОбработкаСсылка;
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура СформироватьОтчетВФонеДлительныеОперации(Команда)
	
	ОбщегоНазначенияКлиентСервер.УстановитьСостояниеПоляТабличногоДокумента(Элементы.Результат, "ФОРМИРОВАНИЕОТЧЕТА");
	
	ОчиститьСообщения();
	
	ОтключитьОбработчикОжидания("Подключаемый_ПроверитьВыполнениеЗадания");
	
	ДлительныеОперацииКлиент.ИнициализироватьПараметрыОбработчикаОжидания(ПараметрыОбработчикаОжидания);
	
	ИнтервалПроверки = ПараметрыОбработчикаОжидания.ТекущийИнтервал;
	
	Состояние(НСтр("ru = 'Выполнение отчета...'"));
	
	СформироватьОтчетВФонеДлительныеОперацииНаСервере();
	
	Если НЕ Выполнено Тогда
		ПодключитьОбработчикОжидания("Подключаемый_ПроверитьВыполнениеЗадания", ИнтервалПроверки, Истина);
	Иначе
		ОтключитьОбработчикОжидания("Подключаемый_ПроверитьВыполнениеЗадания");
		ЗагрузитьПодготовленныеДанные()
	КонецЕсли;
	
КонецПроцедуры

&НаКлиенте
Процедура СформироватьОтчетПрограммно(Команда)
	
	СформироватьОтчетПрограммноНаСервере()
	
КонецПроцедуры

&НаСервере
Процедура СформироватьОтчетПрограммноНаСервере()
	
	ДлительныеОперации.ОтменитьВыполнениеЗадания(ИдентификаторЗадания);
	
	ИдентификаторЗадания 	= Неопределено;
	Выполнено 				= Ложь;
	АдресХранилища 			= ПоместитьВоВременноеХранилище(Неопределено, УникальныйИдентификатор);
	
	ОтчетОбъект	= РеквизитФормыВЗначение("Отчет");
	
	ПараметрыКоманды = Новый Структура;
	ПараметрыКоманды.Вставить("СхемаКомпоновкиДанных"			, ОтчетОбъект.СхемаКомпоновкиДанных);	
	ПараметрыКоманды.Вставить("НастройкиПользователя"			, Отчет.КомпоновщикНастроек.ПользовательскиеНастройки);
	
	ОбщегоНазначенияКлиентСервер.УстановитьСостояниеПоляТабличногоДокумента(Элементы.Результат, "ФОРМИРОВАНИЕОТЧЕТА");
	
	ОтчетОбъект.СформироватьОтчет(ПараметрыКоманды,АдресХранилища);
	
	ОбщегоНазначенияКлиентСервер.УстановитьСостояниеПоляТабличногоДокумента(Элементы.Результат, "НеИспользовать");
	
	ЗагрузитьПодготовленныеДанные();
	
КонецПроцедуры

&НаСервере
Процедура СформироватьОтчетВФонеДлительныеОперацииНаСервере()
	
	ДлительныеОперации.ОтменитьВыполнениеЗадания(ИдентификаторЗадания);
		
	ИдентификаторЗадания 	= Неопределено;
	Выполнено 				= Ложь;
	АдресХранилища 			= ПоместитьВоВременноеХранилище(Неопределено, УникальныйИдентификатор);
	
	ОтчетОбъект	= РеквизитФормыВЗначение("Отчет");
	
	ПараметрыКоманды = Новый Структура;
	ПараметрыКоманды.Вставить("АдресХранилища"         			, АдресХранилища);
	ПараметрыКоманды.Вставить("ДополнительнаяОбработкаСсылка" 	, ОбъектСсылка);
	ПараметрыКоманды.Вставить("СопровождающийТекст"				, НСтр("ru = 'Выполнение отчета...'"));
	ПараметрыКоманды.Вставить("ИдентификаторКоманды"			, "СформироватьОтчет");
	ПараметрыКоманды.Вставить("УникальныйИдентификатор"         , УникальныйИдентификатор);
	ПараметрыКоманды.Вставить("СхемаКомпоновкиДанных"			, ОтчетОбъект.СхемаКомпоновкиДанных);	
	ПараметрыКоманды.Вставить("НастройкиПользователя"			, Отчет.КомпоновщикНастроек.ПользовательскиеНастройки);	
	
	Попытка
		
		ЗаданиеРезультат = ДлительныеОперации.ЗапуститьВыполнениеВФоне(
			УникальныйИдентификатор,
			"ДополнительныеОтчетыИОбработки.ВыполнитьКоманду",
			ПараметрыКоманды,
			СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
				НСтр("ru = 'Выполнение дополнительного отчета или обработки ""%1"", имя команды ""%2""'"),
				Строка(ПараметрыКоманды.ДополнительнаяОбработкаСсылка),
				ПараметрыКоманды.ИдентификаторКоманды));
		
		Выполнено = ЗаданиеРезультат.ЗаданиеВыполнено;
		ВызваноИсключение = Ложь;
		
		Если Выполнено Тогда
			ЗагрузитьПодготовленныеДанные();
		Иначе
			ИдентификаторЗадания  = ЗаданиеРезультат.ИдентификаторЗадания;
		КонецЕсли;
		
	Исключение
		
		Выполнено = Ложь;
		ВызваноИсключение = Истина;
		ТекстОшибки = КраткоеПредставлениеОшибки(ИнформацияОбОшибке());
		
	КонецПопытки;
	
		
КонецПроцедуры

&НаКлиенте
Процедура СформироватьОтчетВФонеРежимКомпоновки(Команда)
	
 	ЭтаФорма.СкомпоноватьРезультат(РежимКомпоновкиРезультата.Фоновый);
	
КонецПроцедуры

&НаКлиенте
Процедура Подключаемый_ПроверитьВыполнениеЗадания()
	
	Попытка
		Если ЗаданиеВыполнено(ИдентификаторЗадания) Тогда 

			ЗагрузитьПодготовленныеДанные();
			ОбщегоНазначенияКлиентСервер.УстановитьСостояниеПоляТабличногоДокумента(Элементы.Результат, "НеИспользовать");
		
		Иначе
			ДлительныеОперацииКлиент.ОбновитьПараметрыОбработчикаОжидания(ПараметрыОбработчикаОжидания);
			ПодключитьОбработчикОжидания(
				"Подключаемый_ПроверитьВыполнениеЗадания", 
				ПараметрыОбработчикаОжидания.ТекущийИнтервал, 
				Истина);
		КонецЕсли;
	Исключение
		ОбщегоНазначенияКлиентСервер.УстановитьСостояниеПоляТабличногоДокумента(Элементы.Результат, "НеИспользовать");
		ВызватьИсключение;
	КонецПопытки;
	
КонецПроцедуры

&НаКлиенте
Процедура ЗагрузитьПодготовленныеДанныеНаКлиенте()
	
	ЗагрузитьПодготовленныеДанные();
		
КонецПроцедуры

&НаСервере
Процедура ЗагрузитьПодготовленныеДанные()

	РезультатВыполнения = ПолучитьИзВременногоХранилища(АдресХранилища);
	
	Результат = РезультатВыполнения.Результат;	

	//ДанныеРасшифровки = РезультатВыполнения.ДанныеРасшифровки;
	
	ИдентификаторЗадания = Неопределено;
	
	ОбщегоНазначенияКлиентСервер.УстановитьСостояниеПоляТабличногоДокумента(Элементы.Результат, "НеИспользовать");
	
	//ДополнительныеСвойства = Отчет.КомпоновщикНастроек.Настройки.ДополнительныеСвойства;
	
КонецПроцедуры

&НаСервереБезКонтекста
Функция ЗаданиеВыполнено(ИдентификаторЗадания)
	
	Возврат ДлительныеОперации.ЗаданиеВыполнено(ИдентификаторЗадания);
	
КонецФункции

Модуль объекта:

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда

////////////////////////////////////////////////////////////////////////////////
// ПРОГРАММНЫЙ ИНТЕРФЕЙС

#Область ПрограммныйИнтерфейс

Функция СведенияОВнешнейОбработке() Экспорт
	ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке("2.2.5.32");
	ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительныйОтчет();
	ПараметрыРегистрации.Версия = "1.0";
	ПараметрыРегистрации.Наименование = "Пример отчета";
	ПараметрыРегистрации.Информация = "Пример отчета";
	ПараметрыРегистрации.БезопасныйРежим = Ложь;
	
	
	НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
	НоваяКоманда.Представление = НСтр("ru = 'Пример отчета'");
	НоваяКоманда.Идентификатор = "СформироватьОтчет";
	НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыОткрытиеФормы();
	НоваяКоманда.ПоказыватьОповещение = Ложь;
	
	Возврат ПараметрыРегистрации;
КонецФункции

// Интерфейс для выполнения команд обработки.
Процедура ВыполнитьКоманду(ИмяКоманды,ПараметрыВыполненияКоманды) Экспорт
	
	Если ИмяКоманды = "СформироватьОтчет" Тогда
		СформироватьОтчет(ПараметрыВыполненияКоманды,ПараметрыВыполненияКоманды.АдресХранилища);
	КонецЕсли;
	
КонецПроцедуры
#КонецОбласти

Процедура СформироватьОтчет(ПараметрыОтчета,АдресХранилища) Экспорт 
	
	ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
	Результат = Новый ТабличныйДокумент;
	
	СхемаКомпоновкиДанных = ПараметрыОтчета.СхемаКомпоновкиДанных;
	//Или можно так, если схема одна. Не передавая в качестве параметров.
	//СхемаКомпоновкиДанных = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных"); 
	
	КомпоновщикНастроекДанных = Новый КомпоновщикНастроекКомпоновкиДанных;
	КомпоновщикНастроекДанных.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(СхемаКомпоновкиДанных));
	
	КомпоновщикНастроекДанных.ЗагрузитьНастройки(КомпоновщикНастроек.Настройки);//копируем настройки
	КомпоновщикНастроекДанных.ЗагрузитьПользовательскиеНастройки(ПараметрыОтчета.НастройкиПользователя);//копируем пользовательские настройки
	
	Настройки = КомпоновщикНастроекДанных.ПолучитьНастройки();
	
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных,Настройки,ДанныеРасшифровки);
	
	ВнешниеНаборыДанных = Новый Структура;// Сюда можно поместить наборы данных ТЗ
	
	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки,ВнешниеНаборыДанных,ДанныеРасшифровки);
	
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(Результат);
	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);
	
	ПоместитьВоВременноеХранилище(Новый Структура("Результат,ДанныеРасшифровки", Результат, ДанныеРасшифровки), АдресХранилища);
	
КонецПроцедуры

#КонецЕсли

Вступайте в нашу телеграмм-группу Инфостарт

Внешний отчеты и обработки ДополнительныеОтчетыИОбработки СКД Выполенение в фоне.

+20 –

См. также

Онлайн-курс «Разработка на 1С с AI-агентами»

Разработка Инструментарий разработчика Групповая разработка (Git, хранилище) Разработчик Платные (руб)

Практический курс по работе с AI-агентами для разработчиков 1С уровня middle и senior, а также тимлидов команд: от постановки задач и передачи контекста до создания расширений, интеграций, MCP-инструментов, тестов и проверки готового решения.

50000 руб.

10.09.2026 13780 124 0

Database Compression Tool: Инструмент для свертки и сжатия баз данных 1С

Инструментарий разработчика Чистка данных Свертка базы Инструменты администратора БД Системный администратор Разработчик Руководитель проекта 1С:Предприятие 8 1С:ERP Управление предприятием 2 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х 1С:Управление нашей фирмой 3.0 Россия Платные (руб)

Инструмент представляет собой обработку для проведения свёртки или обрезки баз данных. Работает на ЛЮБЫХ конфигурациях (УТ, БП, ERP, УНФ, КА и т.д.). Поддерживаются серверные и файловые базы, управляемые и обычные формы, интерфейс 8.5. Может выполнять свертку одновременно в несколько потоков, а также без непосредственного участия пользователя. Решение в Реестре отечественного ПО.

24900 руб.

20.08.2024 83377 432 171

364

Infostart Toolkit Air: Инструменты разработки в 1С:8.3 и 8.5

Инструментарий разработчика Роли и права Запросы СКД Разработчик Руководитель проекта 1С:Предприятие 8 Платные (руб)

Инструменты для разработчиков 1С 8.3 и 8.5: Infostart Toolkit. Автоматизация и ускорение разработки на управляемых формах. Легкость работы с 1С.

16500 руб.

02.09.2020 285915 1608 423

1220

Analyzer 1C — граф знаний о конфигурации 1С, подключаемый к ИИ через MCP

Инструментарий разработчика Разработка Администрирование веб-серверов Системный администратор Разработчик Аналитик Руководитель проекта 1С 8.3 Платные (руб)

Analyzer 1C сводит выгрузку 1С — основную конфигурацию и все расширения — в единый граф знаний. Любой запрос по связям за доли секунды, с пометками «Доб.» / «Заимств.» / «Переопределено». Новое в 2.0 — обновление поставки: сравнение и объединение версий деревом «как в Конфигураторе» с выгрузкой плана решений; поиск конфликтов из-за перехватов расширений и висячих ссылок; загрузка из бинарных .cf/.cfe; циклические зависимости. Плюс анализ влияния, запросы BSL, роли и RLS, граф вызовов. Минута на развёртывание через Docker без необходимости подключения к Интернет. Любая 1С:Предприятие 8.3+.

14000 руб.

17.04.2026 16914 63 62

Infostart PrintWizard (конструктор печатных форм)

Пакетная печать Печатные формы Инструментарий разработчика Разработчик 1С:Предприятие 8 Платные (руб)

Расширение для создания и редактирования печатных форм в системе 1С:Предприятие 8.3. Благодаря конструктору можно значительно снизить затраты времени на разработку печатных форм, повысить качество и прозрачность разработки, а также навести порядок в многообразии корпоративных печатных форм. Обновление версии от 21.04.26

22570 руб.

06.10.2023 44272 122 54

135

Infostart MCP: готовые MCP серверы для вайбкодинга в 1С

Инструментарий разработчика Нейросети Платные (руб)

Первые попытки разработки на 1С с использованием больших языковых моделей (LLM) могут разочаровать. LLMки сильно галлюцинируют, потому что не знают устройства конфигураций 1С, не знают нюансов синтаксиса. Но если дать им подсказки с помощью MCP, то результат получается кардинально лучше. Далее в публикации: MCP для поиска по метаданным 1С, справке синтакс-помощника и проверки синтаксиса.

15250 руб.

25.08.2025 77066 147 41

154

Pilot 1C – ИИ-помощник разработчика 1С

Разработка Инструментарий разработчика Разработчик Руководитель проекта 1С 8.3 Платные (руб)

Pilot 1C превращает задачу, поставленную обычными словами, в техническое задание, код на встроенном языке и сценарии проверки. Прежде чем что-то предложить, он сверяется с устройством вашей конфигурации через граф Analyzer 1C: существует ли объект, из чего он состоит, кто его вызывает, какие роли дают права. Чего найти не удалось – спрашивает, а не выдумывает. Готовый код проходит более полутора сотен проверок по справочнику языка и стандартам разработки, который приезжает вместе с продуктом. Модель – ваша: любой сервер, совместимый с программным интерфейсом OpenAI, в том числе локальный. Правки в конфигурацию Pilot не вносит – их применяет разработчик.

18300 руб.

11.09.2026 3798 5 0

Infostart DataFormWizard: Управление вводом данных в 1С 8.3

Инструменты администратора БД Инструментарий разработчика Роли и права Разработчик 1С:Предприятие 8 1C:Бухгалтерия Россия Платные (руб)

Расширение позволяет без изменения кода конфигурации выполнять проверки при вводе данных, скрывать от пользователя недоступные ему данные, выполнять код в обработчиках. Не изменяет данные конфигурации, легко устанавливается практически на любую конфигурацию на управляемых формах.

17000 руб.

10.11.2023 28796 103 46

107

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. shura_k 15.11.17 10:58 Сейчас в теме

пробую ваш обработку, для меня так же важно запустить отчет в фоне.
отчет сам формируется нормально, и штатными средствами и вашей процедурой СформироватьОтчетПрограммноНаСервере.
но вот с фоновом формированием - проблема.
ничего не возвращается из Временного Хранилища!
помогите пожалуйста разобраться...

Разобрался - проблемы была в Параметры.ДополнительнаяОбработкаСсылк

2. Bakytzhan_777 62 15.11.17 11:59 Сейчас в теме

(1)Рад что разобрались). Я тоже с этим сталкивался, многие часы отладки таки не дали ответа, почему ссылка пустая. Пришлось самому присваивать ссылку в "Параметры.ДополнительнаяОбработкаСсылка".

3. shura_k 15.11.17 13:10 Сейчас в теме

но в обработке есть реально две ошибки:
1. НоваяКоманда.Идентификатор = "СформироватьОтчет";
НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
у вас изначально вариант - открытиеформы, а надо вызовсерверногометода.
У вас же даже Процедура ВыполнитьКоманду для этого уже была.
2. ДлительныеОперацииКлиент.ИнициализироватьПараметрыОбработчикаОжидания(ПараметрыОбработчикаОжидания);
ТекущийИнтервал = ПараметрыОбработчикаОжидания.ТекущийИнтервал;
ПодключитьОбработчикОжидания("Подключаемый_ПроверитьВыполнениеЗадания",ТекущийИнтервал, Истина);
надо инициализировать ПараметрыОбработчикаОжидания, иначе потом в процедуре Подключаемый_ПроверитьВыполнениеЗадания будет ошибка на ТекущийИнтервал

4. Bakytzhan_777 62 15.11.17 17:00 Сейчас в теме

(3)

1. НоваяКоманда.Идентификатор = "СформироватьОтчет";
НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
у вас изначально вариант - открытиеформы, а надо вызовсерверногометода.

Если ставить "ТипКомандыВызовСерверногоМетода()" вместо "ТипКомандыОткрытиеФормы()" то форма не откроется и запуститься сразу команда по идентификатору "СформироватьОтчет".

2. ДлительныеОперацииКлиент.ИнициализироватьПараметрыОбработчикаОжидания(ПараметрыОбработчикаОжидания);
ТекущийИнтервал = ПараметрыОбработчикаОжидания.ТекущийИнтервал;
ПодключитьОбработчикОжидания("Подключаемый_ПроверитьВыполнениеЗадания",ТекущийИнтервал, Истина);
надо инициализировать ПараметрыОбработчикаОжидания, иначе потом в процедуре Подключаемый_ПроверитьВыполнениеЗадания будет ошибка на ТекущийИнтервал

Здесь все поправил.
Спасибо вам за замечания.

9. Mikhail-Kobtsev 27.08.18 16:57 Сейчас в теме

(3)

ыОбработчикаОжидания.ТекущийИ

подскажи в каком именно моменте необходимо инициализация ПараметрыОбработчикаОжидания ?

10. Bakytzhan_777 62 28.08.18 07:02 Сейчас в теме

(9) В типовых инициализируют при открытии формы. Я сделал в команде "СформироватьОтчетВФонеДлительныеОперации".

5. shura_k 15.11.17 17:43 Сейчас в теме

да, тоже до этого дошел.
в итоге сделал две команды: одну на открытие формы другую на ВызовСерверногоМетода.
потому как без первого - реально форма не открывается, а без второго не работает сформировать отчет в фоне.
я в процедуре формирования еще запихиваю тз во внешние данные.

6. cdromscsi 22.12.17 11:16 Сейчас в теме

Спасибо. Очень помог пример кода для пункта 3: Сформировать (длительные операции в фоне). Все работает.

7. Bakytzhan_777 62 19.01.18 20:35 Сейчас в теме

(6) Рад что помогла публикация)

8. MKassatkin 27.04.18 11:45 Сейчас в теме

Хороший пример! Пригодилось, спасибо!

11. Mikhail-Kobtsev 28.08.18 14:36 Сейчас в теме

спасибо автору за статью и еще за оперативный ответ :), давно хотел юзать отчеты через бсп в фоне.

12. Margo462 541 03.11.20 12:09 Сейчас в теме

Через фоновую компоновку делаю с внешним набором данных и появляется ошибка с ненайденной таблицей, а программно работает

Для отправки сообщения требуется регистрация/авторизация

Автор:

Бакытжан Ажгалиев (Bakytzhan_777)

Рейтинг: 62

Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.

Публикация:

№ 657588

Создание 02.08.17 16:03

Обновление 28.08.18 06:57

Статистика:

Просмотры 48366

Загрузки 102

Рейтинг 20

Комментарии 12

Характеристики:

Код открыт Да

Рубрики Инструментарий разработчика

Кому Разработчик

Тип файла Внешний отчет (ert,erf)

Платформа 1С:Предприятие 8

Конфигурация 1C:Бухгалтерия

Операционная система Не имеет значения

Страна Казахстан

Отрасль Не имеет значения

Налоги Не имеет значения

Вид учета Не имеет значения

Доступ к файлу Абонемент ($m)

Пример формирования внешнего отчета программно и в фоновом режиме

Файлы

См. также

Журнал

База знаний

Лаборатория

Анализ & Управление

Сопровождение 1С

Корпоративные решения

Обучение

Маркетплейс

Проектный офис

Мероприятия

Видеозаписи

Биржа заказов

Форум

Мерч

О компании