Многоуровневая нумерация в отчете СКД (программный вывод)

16.01.20

Разработка - СКД

Реализация многоуровневой нумерации при программном выводе отчета СКД основываясь на его структуре.

Скачать файлы

Наименование Файл Версия Размер
Пример внешнего отчета с иерархической нумерацией.
.erf 8,32Kb
17
.erf 8,32Kb 17 Скачать

Задача: нередко при разработке отчетов возникает необходимость многоуровневой нумерации элементов отчета в соответствии с его структурой. Система компоновки данных не предоставляет средств для решения этой задачи. Проблема усугубляется в случае отчетов с иерархической группировкой где количество уровней вложенности произвольно и заранее неизвестно.

Попытки решения данной задачи только средствами СКД успехом не увенчались. Поиск существующих решений желаемых результатов не принес:

  • вариант Ильи Васильева (swimdog) имеет ограничение по уровням вложенности и требует анализа выходного табличного документа для определения размещения номера;
  • вариант Алексея А (Isonic) с произвольной иерархией представляется неудобным в реализации так как вложенность заранее неизвестна и при изменении группировок придется переопределять значение поля иерархической нумерации;

Решение. Предлагаемое решение позволяет решить задачу многоуровневой нумерации путем формирования номера при поэлементном программном выводе отчета. Преимуществом решения является отсутствие привязки к структуре данных, уровень иерархии определяется вложенностью элементов поступающих от процессора компоновки. Для нумерации достаточно создать вычисляемое поле и добавить несложный код вычисления номера в вывод отчета. Настройка размещения и отображения поля осуществляется стандартными средствами СКД.

Фрагмент кода формирования иерархического номера:

///...
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	ПроцессорВывода.НачатьВывод();
	ЭлементРезультата = ПроцессорКомпоновки.Следующий();
	
	КэшМакетов = Новый Структура;
	
//{{Инициализация переменных и создание структур для расчета иерархической нумерации
	НомерПоИерархии = 0;
	Уровень = 0;
	
	СтекНомеров = Новый ТаблицаЗначений;
	СтекНомеров.Колонки.Добавить("Уровень", Новый ОписаниеТипов("Число"));
	СтекНомеров.Колонки.Добавить("Номер", Новый ОписаниеТипов("Число"));
//}}
	Пока ЭлементРезультата <> Неопределено Цикл
//{{Расчет номера по иерархии и его вывод
		Если ЭлементРезультата.ТипЭлемента = ТипЭлементаРезультатаКомпоновкиДанных.Начало Тогда
			Уровень = Уровень + 1;
		ИначеЕсли (ЭлементРезультата.ТипЭлемента = ТипЭлементаРезультатаКомпоновкиДанных.Конец) Тогда
			Уровень = Уровень - 1;
		КонецЕсли;
		
		Если ЭлементРезультата.ЗначенияПараметров.Количество() > 0 Тогда
			
			МассивИменПараметров = ПолучитьИменаПараметровВМакетеКомпоновкиПоИмениПоля("НомерПоИерархии", ЭлементРезультата.Макет, МакетКомпоновкиДанных, КэшМакетов);
			
			Если МассивИменПараметров.Количество() > 0 Тогда
				НомерПоИерархии = ПолучитьМногоуровневыйНомерПоИерархии(Уровень, СтекНомеров);
				
				Для Каждого ИмяПараметра из МассивИменПараметров Цикл
					ЭлементРезультата.ЗначенияПараметров[ИмяПараметра].Значение = НомерПоИерархии;
				КонецЦикла

			КонецЕсли
		КонецЕсли;
//}}
	    ПроцессорВывода.ВывестиЭлемент(ЭлементРезультата);
	    ЭлементРезультата = ПроцессорКомпоновки.Следующий();
	КонецЦикла;
	ПроцессорВывода.ЗакончитьВывод()
КонецПроцедуры

Код функции ПолучитьМногоуровневыйНомерПоИерархии:

Функция ПолучитьМногоуровневыйНомерПоИерархии(УровеньОтчетаСКД, СтекНомеров);
	НомерНаУровне = СтекНомеров.Найти(УровеньОтчетаСКД, "Уровень");
			
	Если НомерНаУровне = Неопределено Тогда
		Стр = СтекНомеров.Добавить();
		Стр.Уровень = УровеньОтчетаСКД;
		Стр.Номер = 1;
	Иначе
		НомерНаУровне.Номер = НомерНаУровне.Номер + 1
	Конецесли;
			
	СтрНомерПоИерархии = "";
	
	НомераКУдалению = Новый Массив;
	Для Каждого Номер Из СтекНомеров Цикл
		Если Номер.Уровень <= УровеньОтчетаСКД Тогда
			СтрНомерПоИерархии = СтрНомерПоИерархии + Номер.Номер + ".";
		Иначе
			//Чистим элементы стека нижних уровней
			НомераКУдалению.Добавить(Номер);
		КонецЕсли
	КонецЦикла;
	Для каждого Номер Из НомераКУдалению Цикл
		СтекНомеров.Удалить(Номер);
	КонецЦикла;
	
	Возврат СтрНомерПоИерархии;
КонецФункции

Также вам потребуется функция "ПолучитьИменаПараметровВМакетеКомпоновкиПоИмениПоля" которую можно взять из статьи о установке собственных значений полей при программном выводе отчета СКД либо скачать пример отчета в котором "все включено".

P.S. Алгоритм разработан для иерархической нумерации по строкам отчета, но работает и при наличии группировок колонок. Вывод номера по колонкам не предусмотрен.

Огромная благодарность Денису Урянскому (dhurricane) за вдумчивое тестирование и подсказки.

Внешний отчет с примером иерархической нумерации тестировался на платформе 8.3.13.1644.

Обновление 16.01.2020: Перезагружен файл с примером. Просьба скачавшим связаться с автором для получения новой версии, либо самостоятельно  обновить код функции ПолучитьИменаПараметровВМакетеКомпоновкиПоИмениПоля() из текста статьи про нее. В прежней реализации возможен несистематический пропуск параметров.

Иерархическая нумерация многоуровневая СКД

См. также

SALE! 20%

Infostart Toolkit: Инструменты разработчика 1С 8.3 на управляемых формах

Инструментарий разработчика Роли и права Запросы СКД Платформа 1С v8.3 Управляемые формы Запросы Система компоновки данных Конфигурации 1cv8 Платные (руб)

Набор инструментов программиста и специалиста 1С для всех конфигураций на управляемых формах. В состав входят инструменты: Консоль запросов, Консоль СКД, Консоль кода, Редактор объекта, Анализ прав доступа, Метаданные, Поиск ссылок, Сравнение объектов, Все функции, Подписки на события и др. Редактор запросов и кода с раскраской и контекстной подсказкой. Доработанный конструктор запросов тонкого клиента. Продукт хорошо оптимизирован и обладает самым широким функционалом среди всех инструментов, представленных на рынке.

10000 8000 руб.

02.09.2020    122363    673    389    

716

Генератор схемы компоновки данных (СКД), написание кода схемы программно

Инструментарий разработчика СКД Платформа 1С v8.3 Конфигурации 1cv8 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

По выбранной схеме компоновки данных генерирует программный код, который генерирует СКД, аналогичную исходной схеме. Есть дополнительные инструменты для просмотра дерева схемы, сравнение исходной схемы и полученной по коду, а также сравнение изменений в сгенерированном коде для исходной схемы и для измененной.

3 стартмани

05.02.2024    4053    25    obmailok    17    

63

Набор-объект для СКД по тексту или запросу

Запросы СКД Платформа 1С v8.3 Управляемые формы Конфигурации 1cv8 Абонемент ($m)

Есть список полей в виде текста, или запрос - закидываем в набор СКД.

1 стартмани

31.01.2024    2006    2    Yashazz    0    

29

СКД на JavaScript в 1С

СКД WEB-интеграция Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Долгое время поддерживаю web-портал, в котором появилась необходимость создавать отчеты. Просмотрев различные фреймворки на js, я решил сделать свое решение, которое позволяло бы быстро разрабатывать и добавлять новые отчеты на web-портал.

2 стартмани

11.12.2023    8170    20    John_d    25    

123

Использование менеджера временных таблиц в СКД

СКД Платформа 1С v8.3 Система компоновки данных Конфигурации 1cv8 Бесплатно (free)

Рассмотрим еще не получивший широкого распространения способ работы с внешними данным в СКД. В процессе обсуждения работы с СКД выяснилось, что многие не знакомы со способом помещения туда временной таблицы, полученной предварительно. Статья будет полезна разработчикам, знакомым с программным созданием СКД.

05.12.2023    4663    PROSTO-1C    13    

61

Модель СКД

Инструментарий разработчика СКД Платформа 1С v8.3 Система компоновки данных Абонемент ($m)

DSL для работы с СКД.

1 стартмани

15.11.2023    5815    15    kalyaka    5    

86

Пользовательские настройки отчетов 1С. Часть 1. Простые и расширенные настройки

СКД Инструкции пользователю Платформа 1С v8.3 Конфигурации 1cv8 1С:Бухгалтерия 3.0 Россия Бесплатно (free)

Простые приемы работы с отчетами на СКД. Что нужно знать пользователю про настройку отчетов, чтобы использовать их на полную катушку.

18.09.2023    6737    accounting_cons    5    

29

Разрыв страницы в СКД. Легко!

СКД Платформа 1С v8.3 Система компоновки данных Бесплатно (free)

Когда отчет надо разделить по страницам, это всегда проблема для разработчика. Поскольку в СКД нет стандартных вариантов, как это сделать. Нашел (на свой взгляд) самое простое и оптимальное решение.

01.09.2023    4533    KVIKS    15    

80
Вознаграждение за ответ
Показать полностью
Комментарии
В избранное Подписаться на ответы Сортировка: Древо развёрнутое
Свернуть все
1. dhurricane 02.07.19 07:48 Сейчас в теме
Спасибо за идею и пример реализации. Единственное, что хотелось бы отметить в качестве недостатка, это анализ типа элемента результата для получения уровня. При работе, например, с таблицей, когда есть группировки не только нумеруемых строк, но и группировки колонок, Ваш алгоритм даст некорректную нумерацию в иерархии.
2. lmnlmn 69 02.07.19 08:27 Сейчас в теме
(1) Спасибо за подсказку. Вообще в реальной ситуации этот алгоритм используется в кросс-таблице с группировкой колонок и проблем нет. Но я добавлю группировку колонок в пример и проверю. Если будут сбои в нумерации - доработаю алгоритм и на этот случай.
3. lmnlmn 69 02.07.19 09:17 Сейчас в теме
(1) Внес исправления в код и пример. Теперь корректно нумерует и при наличии группировок колонок. Но нумерация работает только по строкам. По колонкам лучше не нумеровать.
4. dhurricane 02.07.19 09:42 Сейчас в теме
(3) Спасибо. Есть еще один небольшой недочет, касающийся функции "ПолучитьМногоуровневыйНомерПоИерархии". Вы обходите таблицу номеров стека и в этом же цикле удаляете строки таблицы. Это может привести к ошибкам. Корректнее удалять, например, так:
НомераКУдалению = Новый Массив;
Для Каждого Номер Из СтекНомеров Цикл
	Если Номер.Уровень <= УровеньОтчетаСКД Тогда
		СтрНомерПоИерархии = СтрНомерПоИерархии + Номер.Номер + ".";
	Иначе
		//Чистим элементы стека нижних уровней
		НомераКУдалению.Добавить(Номер);
	КонецЕсли
КонецЦикла;
Для каждого Номер Из НомераКУдалению Цикл
	СтекНомеров.Удалить(Номер);
КонецЦикла;
Показать
Ну и хотел бы предложить небольшое упрощение Вашего алгоритма в целом. А именно избавиться от вычисляемого поля "НомерПоИерархии", а вместо него в выбранные поля добавить "СистемныеПоля.Уровень". Тогда при выводе строк отчета можно значение уровня получать прямо из макета, вычислять номер в иерархии и устанавливать его обратно в системное поле.
5. lmnlmn 69 02.07.19 10:02 Сейчас в теме
(4) Вообще по удалению, формально, ваш вариант "каноничнее", но в данном алгоритме это к проблемам не приведет так как номера нижних уровней надо просто отсечь. Но, да, "дурной тон" в программировании.

С системными полями идея хорошая, но на практике есть одна проблема. Если другой разработчик (да я и сам через полгодика запамятовать могу) будет дорабатывать отчет, то он будет долго и с проклятиями недоумевать что за ерунда вместо уровня пишется, пока разберется в происходящем. А вычисляемое поле с понятным именем путаницу не вносит. Вообще для коллег можно в выражении вычисляемого поля написать "заполняется программно", например.
6. dhurricane 02.07.19 10:23 Сейчас в теме +1 $m
(5)
но в данном алгоритме это к проблемам не приведет
Проблемы будут при удалении нескольких строк, т.е. если разница в уровне между предшествующей и текущей строкой будет больше 1. Для Вашего примера: если "Трансмиссию" переместить на верхний уровень из под подчинения "Автомобилю", то на платформе 8.3.13.1809 в файловой базе получим номера, представленные на скрине ниже.

то он будет долго и с проклятиями недоумевать что за ерунда вместо уровня пишется, пока разберется в происходящем
Согласен, предложенный мной вариант вносит путаницу.
Прикрепленные файлы:
ELInfinito; +1 Ответить
7. lmnlmn 69 02.07.19 10:37 Сейчас в теме
(6)
Проблемы будут при удалении нескольких строк, т.е. если разница в уровне между предшествующей и текущей строкой будет больше 1.

Спасибо, проглядел. Исправил.
Оставьте свое сообщение