Программное управление регламентными заданиями в расширении с использованием БСП

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	ПолучитьНастройкиРегЗадания();
	
КонецПроцедуры

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	УстановитьНадписьРасписанияОбмена();
КонецПроцедуры

&НаСервере
Процедура ПолучитьНастройкиРегЗадания()
	
	УстановитьПривилегированныйРежим(Истина);
	
	НайденноеРегламентноеЗадание = Неопределено;
	
	ИдентификаторРегламентногоЗадания = Объект.ИдентификаторРегламентногоЗадания; 	
	
	Если ЗначениеЗаполнено(ИдентификаторРегламентногоЗадания) Тогда			
		НайденноеРегламентноеЗадание = РегламентныеЗаданияСервер.Задание(ИдентификаторРегламентногоЗадания);
	КонецЕсли;			
	
	Если НайденноеРегламентноеЗадание <> Неопределено Тогда
		
		РасписаниеРегламентногоЗадания = НайденноеРегламентноеЗадание.Расписание;
		
	Иначе
		ИдентификаторРегламентногоЗадания = "";
		РасписаниеРегламентногоЗадания = Неопределено;
		
	КонецЕсли;		
	
КонецПроцедуры

&НаКлиенте
Процедура УстановитьНадписьРасписанияОбмена()
	
	Если РасписаниеРегламентногоЗадания = Неопределено Тогда
		ТекстЗаголовка = НСтр("ru='Настроить расписание обмена'");
	Иначе
		ТекстЗаголовка = РасписаниеРегламентногоЗадания;
	КонецЕсли;
	
	Элементы.НастроитьРасписаниеОбмена.Заголовок = ТекстЗаголовка;
	
КонецПроцедуры

&НаКлиенте
Процедура НастроитьРасписаниеОбмена(Команда)
	
	Если Не ЗначениеЗаполнено(Объект.Ссылка) Тогда
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = "Перед настройкой расписания нужно записать элемент";
		Сообщение.Сообщить();
		
		Возврат;
		
	КонецЕсли;
	
	Если РасписаниеРегламентногоЗадания = Неопределено Тогда
		РасписаниеРегламентногоЗадания = Новый РасписаниеРегламентногоЗадания;
	КонецЕсли;
	
	Диалог = Новый ДиалогРасписанияРегламентногоЗадания(РасписаниеРегламентногоЗадания);
	
	ОписаниеОповещения = Новый ОписаниеОповещения("ЗавершитьИзменятьРасписание", ЭтотОбъект);
	
	Диалог.Показать(ОписаниеОповещения);
	
КонецПроцедуры

&НаКлиенте
Процедура ЗавершитьИзменятьРасписание(РасписаниеЗадания, ДополнительныеПараметры) Экспорт
	
	Если РасписаниеЗадания = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	РасписаниеРегламентногоЗадания = РасписаниеЗадания;
	
	УстановитьНадписьРасписанияОбмена();
	Модифицированность = Истина;
	
КонецПроцедуры

&НаСервере
Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)
	
	Если ЗначениеЗаполнено(ТекущийОбъект.Ссылка) Тогда
		ЗаписатьРегЗадание(ТекущийОбъект);
	Иначе
		ИспользоватьРасписание = Ложь;
	КонецЕсли;
	
КонецПроцедуры

&НаСервере
Процедура ЗаписатьРегЗадание(ТекущийОбъект)
	
	УстановитьПривилегированныйРежим(Истина); 
	
	ИдентификаторРегламентногоЗадания = ТекущийОбъект.ИдентификаторРегламентногоЗадания;
	
	Если Объект.ИспользоватьРасписание Тогда
		
		ИменаИспользуемыхРеглЗаданий = рс_ОбщегоНазначенияПовтИсп.ПолучитьИменаИспользуемыхРеглЗаданий();
		СтруктураРеглЗаданий = рс_ОбщегоНазначенияПовтИсп.ПолучитьИспользуемыеРеглЗадания();
		
		ПараметрыЗапуска = Новый Массив();
		ПараметрыЗапуска.Добавить(СтруктураРеглЗаданий.СинхронизацияДанных);
		ПараметрыЗапуска.Добавить(Объект.Ссылка);
		
		Задание = РегламентныеЗаданияСервер.Задание(ИдентификаторРегламентногоЗадания);
		
		Если Задание <> Неопределено Тогда
			
			ПараметрыИзмененияЗадания = Новый Структура();
			ПараметрыИзмененияЗадания.Вставить("Использование", Истина);
			ПараметрыИзмененияЗадания.Вставить("Параметры", ПараметрыЗапуска);
			ПараметрыИзмененияЗадания.Вставить("Расписание", РасписаниеРегламентногоЗадания);
			ПараметрыИзмененияЗадания.Вставить("ИнтервалПовтораПриАварийномЗавершении", 0);
			ПараметрыИзмененияЗадания.Вставить("КоличествоПовторовПриАварийномЗавершении", 0);
			
			РегламентныеЗаданияСервер.ИзменитьЗадание(ИдентификаторРегламентногоЗадания, ПараметрыИзмененияЗадания);
			
		Иначе
			
			ПараметрыЗадания = Новый Структура();
			ПараметрыЗадания.Вставить("Метаданные", Метаданные.РегламентныеЗадания.ЗапускДополнительныхОбработок);
			ПараметрыЗадания.Вставить("Наименование", ИменаИспользуемыхРеглЗаданий.СинхронизацияДанных + Объект.Наименование);
			ПараметрыЗадания.Вставить("Ключ", ИменаИспользуемыхРеглЗаданий.СинхронизацияДанных + Объект.Наименование);
			ПараметрыЗадания.Вставить("Использование", Истина);
			ПараметрыЗадания.Вставить("ЭксклюзивноеВыполнение", Ложь);
			ПараметрыЗадания.Вставить("Параметры", ПараметрыЗапуска);
			ПараметрыЗадания.Вставить("ИнтервалПовтораПриАварийномЗавершении", 0);
			ПараметрыЗадания.Вставить("КоличествоПовторовПриАварийномЗавершении", 0);
			ПараметрыЗадания.Вставить("Расписание", РасписаниеРегламентногоЗадания);
			
			Задание = РегламентныеЗаданияСервер.ДобавитьЗадание(ПараметрыЗадания);
			
			Если ОбщегоНазначения.РазделениеВключено() Тогда
				
				ИдентификаторРегламентногоЗадания = Задание.Идентификатор.УникальныйИдентификатор();
			Иначе
				
				ИдентификаторРегламентногоЗадания = Задание.УникальныйИдентификатор;
			КонецЕсли;
			
		КонецЕсли;
		
		Если Задание = Неопределено Тогда
			ИдентификаторРегламентногоЗадания = Неопределено;
			
		КонецЕсли;
		
	Иначе
		
		РегламентныеЗаданияСервер.УдалитьЗадание(ИдентификаторРегламентногоЗадания);	
		
		ИдентификаторРегламентногоЗадания = Неопределено;
		
	КонецЕсли;		
	
	ТекущийОбъект.ИдентификаторРегламентногоЗадания = ИдентификаторРегламентногоЗадания;
	
КонецПроцедуры

Функция ПолучитьИспользуемыеРеглЗадания() Экспорт
	
	Результат = Новый Структура();
	Результат.Вставить("СинхронизацияДанных"	 , "рс_НастройкаСинхронизации");
	
	Возврат Результат; 
	
КонецФункции

Функция ПолучитьИменаИспользуемыхРеглЗаданий() Экспорт
	
	Результат = Новый Структура();
	Результат.Вставить("СинхронизацияДанных"	 , "Синхронизация с сайтом: ");
	
	Возврат Результат; 
	
КонецФункции

&Вместо("ВыполнитьОбработкуПоРегламентномуЗаданию")
Процедура рс_ВыполнитьОбработкуПоРегламентномуЗаданию(ВнешняяОбработка, ИдентификаторКоманды) Экспорт
	
	СтруктураРеглЗаданий = рс_ОбщегоНазначенияПовтИсп.ПолучитьИспользуемыеРеглЗадания();	
	
	Если ТипЗнч(ВнешняяОбработка) = Тип("Строка") И ВнешняяОбработка = СтруктураРеглЗаданий.СинхронизацияДанных Тогда
		
        рс_ОбработкаДанных.СинхронизацияПоРасписанию(ИдентификаторКоманды);
		
	Иначе
		
		ПродолжитьВызов(ВнешняяОбработка, ИдентификаторКоманды);
		
	КонецЕсли;	
	
КонецПроцедуры