Программное управление регламентными заданиями в расширении с использованием БСП

31.10.20

Разработка - БСП (Библиотека стандартных подсистем)

В статье описано программное создание, хранение идентификатора в справочнике, изменение и удаление регламентного задания.

Вводные:

1. Реализована функция обмена с внешней системой в расширении от конфигурации с БСП.

2. Есть справочник с настройками обмена с внешней системой.

2. Нужно запускать функцию по расписанию используя настройки справочника.

Реализация:

Настройки хранятся в спр. "рс_Настройки", в него добавляем:

реквизит ИдентификаторРегламентногоЗадания (тип УникальныйИдентификатор).
реквизит ИспользоватьРасписание (тип Булево)

На форме элемента спр. "рс_Настройки"

1. Выводим реквизит "ИспользоватьРасписание" и размещаем надпись "НастроитьРасписаниеОбмена" (вид Гиперссылка)

2. Добавляем реквизит РасписаниеРегламентногоЗадания, (тип Произвольный)

3. Добавляем функции чтения и отображения настроек

Чтение и отображение настроек

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	ПолучитьНастройкиРегЗадания();
	
КонецПроцедуры

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	УстановитьНадписьРасписанияОбмена();
КонецПроцедуры

&НаСервере
Процедура ПолучитьНастройкиРегЗадания()
	
	УстановитьПривилегированныйРежим(Истина);
	
	НайденноеРегламентноеЗадание = Неопределено;
	
	ИдентификаторРегламентногоЗадания = Объект.ИдентификаторРегламентногоЗадания; 	
	
	Если ЗначениеЗаполнено(ИдентификаторРегламентногоЗадания) Тогда			
		НайденноеРегламентноеЗадание = РегламентныеЗаданияСервер.Задание(ИдентификаторРегламентногоЗадания);
	КонецЕсли;			
	
	Если НайденноеРегламентноеЗадание <> Неопределено Тогда
		
		РасписаниеРегламентногоЗадания = НайденноеРегламентноеЗадание.Расписание;
		
	Иначе
		ИдентификаторРегламентногоЗадания = "";
		РасписаниеРегламентногоЗадания = Неопределено;
		
	КонецЕсли;		
	
КонецПроцедуры

&НаКлиенте
Процедура УстановитьНадписьРасписанияОбмена()
	
	Если РасписаниеРегламентногоЗадания = Неопределено Тогда
		ТекстЗаголовка = НСтр("ru='Настроить расписание обмена'");
	Иначе
		ТекстЗаголовка = РасписаниеРегламентногоЗадания;
	КонецЕсли;
	
	Элементы.НастроитьРасписаниеОбмена.Заголовок = ТекстЗаголовка;
	
КонецПроцедуры

4. Добавляем процедуры изменения расписания

Изменение расписания

&НаКлиенте
Процедура НастроитьРасписаниеОбмена(Команда)
	
	Если Не ЗначениеЗаполнено(Объект.Ссылка) Тогда
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = "Перед настройкой расписания нужно записать элемент";
		Сообщение.Сообщить();
		
		Возврат;
		
	КонецЕсли;
	
	Если РасписаниеРегламентногоЗадания = Неопределено Тогда
		РасписаниеРегламентногоЗадания = Новый РасписаниеРегламентногоЗадания;
	КонецЕсли;
	
	Диалог = Новый ДиалогРасписанияРегламентногоЗадания(РасписаниеРегламентногоЗадания);
	
	ОписаниеОповещения = Новый ОписаниеОповещения("ЗавершитьИзменятьРасписание", ЭтотОбъект);
	
	Диалог.Показать(ОписаниеОповещения);
	
КонецПроцедуры

&НаКлиенте
Процедура ЗавершитьИзменятьРасписание(РасписаниеЗадания, ДополнительныеПараметры) Экспорт
	
	Если РасписаниеЗадания = Неопределено Тогда
		Возврат;
	КонецЕсли;
	
	РасписаниеРегламентногоЗадания = РасписаниеЗадания;
	
	УстановитьНадписьРасписанияОбмена();
	Модифицированность = Истина;
	
КонецПроцедуры

5. Добавляем обработку записи рег. задания перед записью элемента.

Использую "Метаданные.РегламентныеЗадания.ЗапускДополнительныхОбработок", который присутствует в конфигурациях на БСП.

Обработка записи рег. задания

&НаСервере
Процедура ПередЗаписьюНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)
	
	Если ЗначениеЗаполнено(ТекущийОбъект.Ссылка) Тогда
		ЗаписатьРегЗадание(ТекущийОбъект);
	Иначе
		ИспользоватьРасписание = Ложь;
	КонецЕсли;
	
КонецПроцедуры

&НаСервере
Процедура ЗаписатьРегЗадание(ТекущийОбъект)
	
	УстановитьПривилегированныйРежим(Истина); 
	
	ИдентификаторРегламентногоЗадания = ТекущийОбъект.ИдентификаторРегламентногоЗадания;
	
	Если Объект.ИспользоватьРасписание Тогда
		
		ИменаИспользуемыхРеглЗаданий = рс_ОбщегоНазначенияПовтИсп.ПолучитьИменаИспользуемыхРеглЗаданий();
		СтруктураРеглЗаданий = рс_ОбщегоНазначенияПовтИсп.ПолучитьИспользуемыеРеглЗадания();
		
		ПараметрыЗапуска = Новый Массив();
		ПараметрыЗапуска.Добавить(СтруктураРеглЗаданий.СинхронизацияДанных);
		ПараметрыЗапуска.Добавить(Объект.Ссылка);
		
		Задание = РегламентныеЗаданияСервер.Задание(ИдентификаторРегламентногоЗадания);
		
		Если Задание <> Неопределено Тогда
			
			ПараметрыИзмененияЗадания = Новый Структура();
			ПараметрыИзмененияЗадания.Вставить("Использование", Истина);
			ПараметрыИзмененияЗадания.Вставить("Параметры", ПараметрыЗапуска);
			ПараметрыИзмененияЗадания.Вставить("Расписание", РасписаниеРегламентногоЗадания);
			ПараметрыИзмененияЗадания.Вставить("ИнтервалПовтораПриАварийномЗавершении", 0);
			ПараметрыИзмененияЗадания.Вставить("КоличествоПовторовПриАварийномЗавершении", 0);
			
			РегламентныеЗаданияСервер.ИзменитьЗадание(ИдентификаторРегламентногоЗадания, ПараметрыИзмененияЗадания);
			
		Иначе
			
			ПараметрыЗадания = Новый Структура();
			ПараметрыЗадания.Вставить("Метаданные", Метаданные.РегламентныеЗадания.ЗапускДополнительныхОбработок);
			ПараметрыЗадания.Вставить("Наименование", ИменаИспользуемыхРеглЗаданий.СинхронизацияДанных + Объект.Наименование);
			ПараметрыЗадания.Вставить("Ключ", ИменаИспользуемыхРеглЗаданий.СинхронизацияДанных + Объект.Наименование);
			ПараметрыЗадания.Вставить("Использование", Истина);
			ПараметрыЗадания.Вставить("ЭксклюзивноеВыполнение", Ложь);
			ПараметрыЗадания.Вставить("Параметры", ПараметрыЗапуска);
			ПараметрыЗадания.Вставить("ИнтервалПовтораПриАварийномЗавершении", 0);
			ПараметрыЗадания.Вставить("КоличествоПовторовПриАварийномЗавершении", 0);
			ПараметрыЗадания.Вставить("Расписание", РасписаниеРегламентногоЗадания);
			
			Задание = РегламентныеЗаданияСервер.ДобавитьЗадание(ПараметрыЗадания);
			
			Если ОбщегоНазначения.РазделениеВключено() Тогда
				
				ИдентификаторРегламентногоЗадания = Задание.Идентификатор.УникальныйИдентификатор();
			Иначе
				
				ИдентификаторРегламентногоЗадания = Задание.УникальныйИдентификатор;
			КонецЕсли;
			
		КонецЕсли;
		
		Если Задание = Неопределено Тогда
			ИдентификаторРегламентногоЗадания = Неопределено;
			
		КонецЕсли;
		
	Иначе
		
		РегламентныеЗаданияСервер.УдалитьЗадание(ИдентификаторРегламентногоЗадания);	
		
		ИдентификаторРегламентногоЗадания = Неопределено;
		
	КонецЕсли;		
	
	ТекущийОбъект.ИдентификаторРегламентногоЗадания = ИдентификаторРегламентногоЗадания;
	
КонецПроцедуры

Описание регл. заданий вынесено в общий модуль.

рс_ОбщегоНазначенияПовтИсп

Функция ПолучитьИспользуемыеРеглЗадания() Экспорт
	
	Результат = Новый Структура();
	Результат.Вставить("СинхронизацияДанных"	 , "рс_НастройкаСинхронизации");
	
	Возврат Результат; 
	
КонецФункции

Функция ПолучитьИменаИспользуемыхРеглЗаданий() Экспорт
	
	Результат = Новый Структура();
	Результат.Вставить("СинхронизацияДанных"	 , "Синхронизация с сайтом: ");
	
	Возврат Результат; 
	
КонецФункции

6. Переносим из основной конфигурации в расширение модуль "ДополнительныеОтчетыИОбработки". Изменяем обработку рег. заданий.

ДополнительныеОтчетыИОбработки

&Вместо("ВыполнитьОбработкуПоРегламентномуЗаданию")
Процедура рс_ВыполнитьОбработкуПоРегламентномуЗаданию(ВнешняяОбработка, ИдентификаторКоманды) Экспорт
	
	СтруктураРеглЗаданий = рс_ОбщегоНазначенияПовтИсп.ПолучитьИспользуемыеРеглЗадания();	
	
	Если ТипЗнч(ВнешняяОбработка) = Тип("Строка") И ВнешняяОбработка = СтруктураРеглЗаданий.СинхронизацияДанных Тогда
		
        рс_ОбработкаДанных.СинхронизацияПоРасписанию(ИдентификаторКоманды);
		
	Иначе
		
		ПродолжитьВызов(ВнешняяОбработка, ИдентификаторКоманды);
		
	КонецЕсли;	
	
КонецПроцедуры

Итог

В расширениях к конфигурациях с БСП можно относительно просто использовать регламентные задания.

Благодарю за внимание.

Вступайте в нашу телеграмм-группу Инфостарт

+27 –

Вы можете заказать платную адаптацию этой статьи под ваши задачи на «Бирже заказов».

0% комиссии — оплата напрямую исполнителю;
Исполнители любого масштаба — от отдельных специалистов до команд под проект;
Прямой обмен контактами между заказчиком и исполнителем;
Безопасная сделка — при необходимости;
Рейтинги, кейсы и прозрачная система откликов.

См. также

Синтакс-помощник БСП

БСП (Библиотека стандартных подсистем) Разработчик Платные (руб)

Синтакс-помощник БСП - cправочник по библиотекам стандартных подсистем и электронных документов. В состав справочника входит описание экспортных процедур и функций, размещенных в областях кода ПрограммныйИнтерфейс БСП и БЭД.

3254 руб.

21.11.2024 14603 51 30

Свой движок выгрузки конфигураций 1С в XML, часть 2: вся БСП байт в байт

Файловый обмен (TXT, XML, DBF), FTP БСП (Библиотека стандартных подсистем) Разработчик 1С:Предприятие 8 1С:Библиотека стандартных подсистем Россия Бесплатно (free)

Продолжение истории о своём движке, который превращает CF в XML без базы и без платформы. Теперь БСП 3.1 выгружается полностью: 9 174 из 9 174 файлов совпадают со штатной выгрузкой байт в байт, ошибок ноль. Для разработчиков, которым интересен внутренний формат 1С и выгрузка конфигураций в файлы.

29.10.2026 2017 vanya_gonchar 21

Самые используемые методы БСП 3.1.12

БСП (Библиотека стандартных подсистем) Разработчик 1С:Предприятие 8 1С:Библиотека стандартных подсистем Бесплатно (free)

Наиболее часто используемые методы БСП 3.1.12. На момент публикации БСП 3.1.12 - является последней версией, и на ней построены все новые типовые конфигурации.

28.09.2026 4825 SergMuravev 2

Шпаргалка по БСП: Топ функций, которые спасут вас от изобретения велосипедов

БСП (Библиотека стандартных подсистем) Разработчик 1С 8.3 1С:Библиотека стандартных подсистем Россия Абонемент ($m)

Все мы когда-то писали свои функции для получения реквизита через точку или парсинга строк. В этой статье собрана выжимка самых полезных и ежедневно необходимых процедур и функций БСП. Никакой сухой документации ИТС — только жизненные кейсы, чистый код и разбор ситуаций, когда стандартные подсистемы делают работу за нас.

1 стартмани

30.07.2026 10167 Elya_Elya 14

БСП - шпаргалка. Вывод сообщений у реквизита формы

БСП (Библиотека стандартных подсистем) Разработчик Стажер 1С:Предприятие 8 1С:Библиотека стандартных подсистем Бесплатно (free)

Часто требуется вывести понятное пользователю сообщение, ткнув его в конкретный проблемный реквизит, что называется, "носом"... И вот тут довольно часто приходится перечитывать параметры функции ОбщегоНазначения[Клиент].СообщениеПользователю. Решила написать для себя шпаргалку и поделиться с сообществом.

24.07.2026 3108 check2 2

БСП, о которой вы не знали: 8 методов, которые избавят вас от написания велосипедов

БСП (Библиотека стандартных подсистем) Разработчик 1С 8.3 1С:Библиотека стандартных подсистем Бесплатно (free)

Каждый раз, когда разработчик 1С пишет очередной цикл для свертки массива или использует конструкцию Попытка / Исключение для проверки наличия реквизита, где-то грустит один архитектор фирмы «1С». Мы привыкли изобретать велосипеды там, где в Библиотеке стандартных подсистем (БСП) уже давно лежат готовые, оптимизированные и протестированные на тысячах баз решения. Ниже — практическая подборка из 8 методов актуальных релизов БСП (3.X), которые сделают ваш код чище, быстрее и профессиональнее. Разберем на примерах «Было / Стало».

04.06.2026 13932 Kaliostr0 21

Интеграция Госключ в 1С

Адаптация типовых решений БСП (Библиотека стандартных подсистем) Кадровый учет ЭДО и ОФД 1C:Бухгалтерия 1С:Зарплата и кадры 7.7 1C:ERP 1С:ЗУП 1С:УТ 1С:ДО Платные (руб)

Наше расширение 1С Госключ обеспечивает интеграцию любой конфигурации 1С на базе БСП с мобильным приложением «Госключ», позволяя сотрудникам подписывать кадровые документы (КЭДО) и документы материальной ответственности (МОЛ, ПБ) усиленной электронной подписью прямо со смартфона. Решение автоматизирует формирование и отправку документов на подпись, отслеживает статусы подписания и хранит подписанные файлы непосредственно в базе 1С

25000 руб.

06.03.2026 2758 4 0

Сведения о внешней обработке. Шаблоны и примеры написания сведений для подключаемых внешних обработок

БСП (Библиотека стандартных подсистем) Универсальные функции Разработчик 1С 8.3 1С:Библиотека стандартных подсистем Бесплатно (free)

Когда появляется необходимость сделать подключаемую внешнюю обработку, будь это печатная форма или отчет - нам всегда приходится прописывать сведения о внешней обработке для подключения их в соответствующий справочник. И это занимает некоторое время, что не очень удобно. Как для себя, так и для вас - я подготовил ряд примеров использования этой функции, можете выбрать один из них, чтобы в дальнейшем использовать их в шаблонах текста. Комментарии по дополнению и исправлению статьи - приветствуются.

06.02.2026 25265 manul1c 7

Комментарии

Подписаться на ответы Инфостарт бот

Свернуть все

1. wrooom 299 16.06.20 21:59 Сейчас в теме

{Расширение ОбщийМодуль.ДополнительныеОтчетыИОбработки.Модуль(9,9)}: Переменная не определена (рс_ОбработкаДанных)
<<?>>рс_ОбработкаДанных.СинхронизацияПоРасписанию(ИдентификаторКоманды); (Проверка: Сервер) при нажатии на кнопку "Обновить"

2. wrooom 299 16.06.20 22:27 Сейчас в теме

(1) рс_ОбработкаДанных.СинхронизацияПоРасписанию это и есть процедура, которую необходимо исполнять по расписанию. Спасибо. работает. Ты очень крут, если это просто.

3. wrooom 299 16.06.20 23:55 Сейчас в теме

А можно ли каким нибудь образом передать параметры в рс_ВыполнитьОбработкуПоРегламентномуЗаданию ?

4. malikov_pro 1409 17.06.20 05:33 Сейчас в теме

(3) Оно и так передается

При формировании создаем массив (два элемента)

ПараметрыЗапуска = Новый Массив();
ПараметрыЗапуска.Добавить(СтруктураРеглЗаданий.СинхронизацияДанных);
ПараметрыЗапуска.Добавить(НастройкаОбмена);

Что передается в "Массив параметров регламентного задания. Количество и состав параметров должны соответствовать параметрам метода регламентного задания."

И при выполнении два параметра функции.
ВыполнитьОбработкуПоРегламентномуЗаданию(ВнешняяОбработка, ИдентификаторКоманды)
Где "ВнешняяОбработка" - наименование, а в "ИдентификаторКоманды" эл. спр. настроек обмена

Процедура СинхронизацияПоРасписанию(НастройкаОбмена) Экспорт

Для отправки сообщения требуется регистрация/авторизация

Автор:

Александр Маликов (malikov_pro)

Рейтинг: 1409

Вы можете заказать платную консультацию или разработку у автора. Будет создан приватный заказ на «Бирже заказов» для автора.

Публикация:

№ 1217840

Создание 31.03.20 14:00

Обновление 31.10.20 12:58

Статистика:

Просмотры 9006

Загрузки 0

Рейтинг 27

Комментарии 4

Характеристики:

Код открыт Да

Рубрики БСП (Библиотека стандартных подсистем)

Кому Разработчик

Тип файла Нет файла

Платформа 1С:Предприятие 8

Конфигурация 1C:Бухгалтерия

Операционная система Не имеет значения

Страна Россия

Отрасль Не имеет значения

Налоги Не имеет значения

Вид учета Не имеет значения

Доступ к файлу Бесплатно (free)

Программное управление регламентными заданиями в расширении с использованием БСП

Вводные:

Реализация:

Итог

См. также

Журнал

База знаний

Лаборатория

Анализ & Управление

Сопровождение 1С

Корпоративные решения

Обучение

Маркетплейс

Проектный офис

Мероприятия

Видеозаписи

Биржа заказов

Форум

Мерч

О компании