Выполнение внешней обработки в фоне с выводом прогресса. Максимум использования БСП

Процедура ОперацияНаМинуту(Параметры, АдресРезультата) Экспорт
    
    ДатаНачала = ТекущаяДата();
    ТекущаяДата    = ДатаНачала; 
    
    Задержка = 60;
    
    ТекущаяДатаЧерезМинуту = ТекущаяДата + Задержка;    
    Пока ТекущаяДата < ТекущаяДатаЧерезМинуту Цикл
        
        ТекущаяДата = ТекущаяДата();
        
        РазностьСекунд = ТекущаяДата - ДатаНачала;
        
        // Сообщим прогресс методом БСП        
        ДлительныеОперации.СообщитьПрогресс(Формат((РазностьСекунд / Задержка) * 100, "ЧДЦ=2"), СтрШаблон( "Прошло %1 секунд из %2", РазностьСекунд, Задержка));
        
        ТекущаяДата = ТекущаяДата();
        
    КонецЦикла;    
    
КонецПроцедуры

&НаКлиенте
Асинх Процедура ВыполнитьВФоне(Команда)
    // Получаем путь к файлу нашей обработки
    Имя = ИмяФайлаОбработки();
    
    // Помещаем на сервер
    Описание = Ждать ПоместитьФайлНаСерверАсинх(,,, Имя, УникальныйИдентификатор);
    Адрес = Описание.Адрес;
    ДлительнаяОперация = ВыполнитьВФонеНаСервере(Адрес); 
    
    ПараметрыОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект);
    ПараметрыОжидания.ВыводитьОкноОжидания = Истина;
    ПараметрыОжидания.ВыводитьПрогрессВыполнения = Истина;

    ОписаниеОповещения = Новый ОписаниеОповещения("ПослеВыполенияОбработки", ЭтотОбъект);
    
    ДлительныеОперацииКлиент.ОжидатьЗавершение(ДлительнаяОперация, ОписаниеОповещения, ПараметрыОжидания);
    
КонецПроцедуры 

&НаСервере
Функция ВыполнитьВФонеНаСервере(АдресФайлаНаСервере)
    
    // Создаем файл в каталоге временных файлов на сервере. Ровно тоже самое будет делать БСП если делать с подключенной обработкой
    ИмяФайлаНаСервере = ПолучитьИмяВременногоФайла("epf");
    ДанныеФайла = ПолучитьИзВременногоХранилища(АдресФайлаНаСервере);
    ДанныеФайла.Записать(ИмяФайлаНаСервере) ;
    
    ПараметрыВыполненияПроцедуры = ДлительныеОперации.ПараметрыВыполненияПроцедуры();
    
    ПараметрыВыполнения = Новый Структура;
    ПараметрыВыполнения.Вставить("ИмяОбработки", ИмяФайлаНаСервере);
    ПараметрыВыполнения.Вставить("ИмяМетода", "ОперацияНаМинуту");
    ПараметрыВыполнения.Вставить("ЭтоВнешняяОбработка", Истина);   
    ПараметрыВыполнения.Вставить("ПараметрыВыполнения", Новый Структура); // Тут параметры произвольным значением. Обычно структурой если их несколько
    
    Адрес = ПоместитьВоВременноеХранилище(Неопределено, УникальныйИдентификатор);
    
    // ДлительныеОперации.ВыполнитьВФоне() устарело. Поэтому используем более современное     
    // Единственная странность, что у процедуры ДлительныеОперации.ВыполнитьПроцедуруМодуляОбъектаОбработки() нет конструктора параметров как
    // ДлительныеОперации.ПараметрыВыполненияПроцедуры() или ДлительныеОперации.ПараметрыВыполненияПФункции() 
    // Однако параметры по примеру ВыполнитьВФоне(), т.е. их 2. 1 - параметры для процедуры\функции, 2 - адрес результата
    Возврат ДлительныеОперации.ВыполнитьПроцедуру(ПараметрыВыполненияПроцедуры, "ДлительныеОперации.ВыполнитьПроцедуруМодуляОбъектаОбработки", ПараметрыВыполнения, Адрес); 
    
КонецФункции

&НаКлиенте
Процедура ВыполнитьВФонеЧерезСправочник(Команда)
    
    ДлительнаяОперация = ВыполнитьВФонеНаСервереЧерезСправочник(); 
    
    ПараметрыОжидания = ДлительныеОперацииКлиент.ПараметрыОжидания(ЭтотОбъект);
    ПараметрыОжидания.ВыводитьОкноОжидания = Истина;
    ПараметрыОжидания.ВыводитьПрогрессВыполнения = Истина;
    
    ОписаниеОповещения = Новый ОписаниеОповещения("ПослеВыполенияОбработки", ЭтотОбъект);
    
    ДлительныеОперацииКлиент.ОжидатьЗавершение(ДлительнаяОперация, ОписаниеОповещения, ПараметрыОжидания);

КонецПроцедуры

&НаСервере
Функция ВыполнитьВФонеНаСервереЧерезСправочник()
                
    ПараметрыВыполненияПроцедуры = ДлительныеОперации.ПараметрыВыполненияПроцедуры();
    
    // Искать лучше по имени объекта, т.к. все остальное можно переопределить в предприятии
    ДополнительнаяОбработкаСсылка = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоРеквизиту("ИмяОбъекта", НаименованиеОбработки());
    
    ПараметрыВыполнения = Новый Структура; 
    //++ В этом случае по факту у этих параметров идет дублирование
    ПараметрыВыполнения.Вставить("ИмяОбработки", "ВнешняяОбработка.ОперацияНаМинуту");   
    ПараметрыВыполнения.Вставить("ИмяМетода", "ОперацияНаМинуту");
    //--
    ПараметрыВыполнения.Вставить("ЭтоВнешняяОбработка", Истина);   
    ПараметрыВыполнения.Вставить("ПараметрыВыполнения", Новый Структура); // Тут параметры произвольным значением. Обычно структурой если их несколько
    ПараметрыВыполнения.Вставить("ДополнительнаяОбработкаСсылка", ДополнительнаяОбработкаСсылка);
    
    Адрес = ПоместитьВоВременноеХранилище(Неопределено, УникальныйИдентификатор);
    
    // ДлительныеОперации.ВыполнитьВФоне() устарело. Поэтому используем более современное     
    // Единственная странность, что у процедуры ДлительныеОперации.ВыполнитьПроцедуруМодуляОбъектаОбработки() нет конструктора параметров как
    // ДлительныеОперации.ПараметрыВыполненияПроцедуры() или ДлительныеОперации.ПараметрыВыполненияПФункции() 
    // Однако параметры по примеру ВыполнитьВФоне(), т.е. их 2. 1 - параметры для процедуры\функции, 2 - адрес результата
    Возврат ДлительныеОперации.ВыполнитьПроцедуру(ПараметрыВыполненияПроцедуры, "ДлительныеОперации.ВыполнитьПроцедуруМодуляОбъектаОбработки", ПараметрыВыполнения, Адрес); 
    
КонецФункции 

&НаСервере
Функция ИмяФайлаОбработки()
	
	Возврат РеквизитФормыВЗначение("Объект").ИспользуемоеИмяФайла;

КонецФункции 

&НаСервере
Функция НаименованиеОбработки()
	
	Возврат РеквизитФормыВЗначение("Объект").Метаданные().Имя;
	
КонецФункции

&НаКлиенте
Процедура ПослеВыполенияОбработки(Результат, ДопПараметры) Экспорт
    
    Текст = "Завершено";
    
    Если Результат = Неопределено Тогда
        Текст = "Задание отменено";
    ИначеЕсли Результат.Статус = "Ошибка" Тогда
        Текст = "Выполение завершилось с ошибкой";
    ИначеЕсли Результат.Статус = "Выполнено" Тогда
        Текст = "Завершено успешно";
    КонецЕсли;
    
    ОбщегоНазначенияКлиент.СообщитьПользователю(Текст);
    
КонецПроцедуры