Проблема совмещения в организации деятельности по УСН и Патенту освещена в Статье на buh.ru.
При реализации товаров (работ, услуг) оплата платежными картами отражается на субсчете 57.03 «Продажи по платежным картам» с момента оплаты и до момента зачисления банком полученных средств на счет организации-продавца.
Поскольку при применении УСН доходы учитываются «по оплате» (кассовым методом), то датой получения дохода от реализации товаров (работ, услуг), оплаченных банковской картой, признается день поступления денежных средств на расчетный счет организации.
Для того, чтобы при погашении задолженность банка-эквайера была отнесена к доходам по деятельности на патенте необходимо несколько условий:
- в отчете о розничных продажах был указан патент;
- в поступлении на расчетный счет должны быть указаны те же банк-эквайер и договор, что и в виде оплат отчета о розничных продажах;
- на дату и время поступлении на расчетный счет должна быть накоплена задолженность банка-эквайера.
Приложенный отчет формируется за период по конкретным организации, контрагенту (банк-эквайеру), и договору эквайринга.
Строчки, требующие внимания, подсвечиваются красным цветом.
- "Оборот прочие расчеты" меньше "Оборот 57.03" означает, что задолженность банка-эквайера менее суммы поступления на расчетный счет. В этом случае необходимо проверить хронологию документов.
- "Оборот УСН.03" меньше "Оборот 57.03" означает, что продаж по патенту с участием этого банка-эквайера накоплено меньше суммы поступления на расчетный счет. В этом случае необходимо проверить указание патента в отчетах о розничных продажах.
Запрос отчета ниже:
ВЫБРАТЬ
Бух5703.Регистратор КАК Регистратор,
Бух5703.СуммаОборот КАК Оборот5703,
ЕСТЬNULL(ПрочиеРасчетыОбороты.СуммаОборот, 0) КАК ОборотПрочиеРасчеты,
ЕСТЬNULL(БухУСН03.СуммаОборот, 0) КАК ОборотУСН03,
ВЫБОР
КОГДА Бух5703.СуммаОборот = ЕСТЬNULL(ПрочиеРасчетыОбороты.СуммаОборот, 0)
И ЕСТЬNULL(ПрочиеРасчетыОбороты.СуммаОборот, 0) = ЕСТЬNULL(БухУСН03.СуммаОборот, 0)
ТОГДА ЛОЖЬ
ИНАЧЕ ИСТИНА
КОНЕЦ КАК Расхождение
ИЗ
РегистрБухгалтерии.Хозрасчетный.Обороты(
,
,
Регистратор,
Счет = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПродажиПоПлатежнымКартам),
,
Организация = &Организация
И Субконто1 = &Контрагент
И Субконто2 = &ДоговорКонтрагента,
,
) КАК Бух5703
ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ПрочиеРасчеты.Обороты(
,
,
Регистратор,
Организация = &Организация
И Контрагент = &Контрагент
И ДоговорКонтрагента = &ДоговорКонтрагента
И СчетУчета = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.ПродажиПоПлатежнымКартам)) КАК ПрочиеРасчетыОбороты
ПО Бух5703.Регистратор = ПрочиеРасчетыОбороты.Регистратор
ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.Обороты(
,
,
Регистратор,
Счет = ЗНАЧЕНИЕ(ПланСчетов.Хозрасчетный.УСНРасчетыСПокупателямиПатент),
,
Организация = &Организация
И Субконто1 = &Контрагент
И Субконто2 = &ДоговорКонтрагента,
,
) КАК БухУСН03
ПО Бух5703.Регистратор = БухУСН03.Регистратор
УПОРЯДОЧИТЬ ПО
Бух5703.Регистратор.МоментВремени
Проверено на конфигурации Бухгалтерия предприятия, редакция 3.0 (3.0.110.29) и платформе 8.3.20.1590.
Вступайте в нашу телеграмм-группу Инфостарт